[mirror_ubuntu-jammy-kernel.git] / arch / arm64 / kernel / vmlinux.lds.S

/*
 * ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 */

#include <asm-generic/vmlinux.lds.h>
#include <asm/kernel-pgtable.h>
#include <asm/thread_info.h>
#include <asm/memory.h>
#include <asm/page.h>
#include <asm/pgtable.h>

#include "image.h"

/* .exit.text needed in case of alternative patching */
#define ARM_EXIT_KEEP(x)	x
#define ARM_EXIT_DISCARD(x)

OUTPUT_ARCH(aarch64)
ENTRY(_text)

jiffies = jiffies_64;

#define HYPERVISOR_TEXT					\
	/*						\
	 * Align to 4 KB so that			\
	 * a) the HYP vector table is at its minimum	\
	 *    alignment of 2048 bytes			\
	 * b) the HYP init code will not cross a page	\
	 *    boundary if its size does not exceed	\
	 *    4 KB (see related ASSERT() below)		\
	 */						\
	. = ALIGN(SZ_4K);				\
	VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;	\
	*(.hyp.idmap.text)				\
	VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;	\
	VMLINUX_SYMBOL(__hyp_text_start) = .;		\
	*(.hyp.text)					\
	VMLINUX_SYMBOL(__hyp_text_end) = .;

#define IDMAP_TEXT					\
	. = ALIGN(SZ_4K);				\
	VMLINUX_SYMBOL(__idmap_text_start) = .;		\
	*(.idmap.text)					\
	VMLINUX_SYMBOL(__idmap_text_end) = .;

/*
 * The size of the PE/COFF section that covers the kernel image, which
 * runs from stext to _edata, must be a round multiple of the PE/COFF
 * FileAlignment, which we set to its minimum value of 0x200. 'stext'
 * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
 * boundary should be sufficient.
 */
PECOFF_FILE_ALIGNMENT = 0x200;

#ifdef CONFIG_EFI
#define PECOFF_EDATA_PADDING	\
	.pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
#else
#define PECOFF_EDATA_PADDING
#endif

#ifdef CONFIG_DEBUG_ALIGN_RODATA
#define ALIGN_DEBUG_RO			. = ALIGN(1<<SECTION_SHIFT);
#define ALIGN_DEBUG_RO_MIN(min)		ALIGN_DEBUG_RO
#else
#define ALIGN_DEBUG_RO
#define ALIGN_DEBUG_RO_MIN(min)		. = ALIGN(min);
#endif

SECTIONS
{
	/*
	 * XXX: The linker does not define how output sections are
	 * assigned to input sections when there are multiple statements
	 * matching the same input section name.  There is no documented
	 * order of matching.
	 */
	/DISCARD/ : {
		ARM_EXIT_DISCARD(EXIT_TEXT)
		ARM_EXIT_DISCARD(EXIT_DATA)
		EXIT_CALL
		*(.discard)
		*(.discard.*)
	}

	. = PAGE_OFFSET + TEXT_OFFSET;

	.head.text : {
		_text = .;
		HEAD_TEXT
	}
	ALIGN_DEBUG_RO
	.text : {			/* Real text segment		*/
		_stext = .;		/* Text and read-only data	*/
			__exception_text_start = .;
			*(.exception.text)
			__exception_text_end = .;
			IRQENTRY_TEXT
			TEXT_TEXT
			SCHED_TEXT
			LOCK_TEXT
			HYPERVISOR_TEXT
			IDMAP_TEXT
			*(.fixup)
			*(.gnu.warning)
		. = ALIGN(16);
		*(.got)			/* Global offset table		*/
	}

	ALIGN_DEBUG_RO
	RO_DATA(PAGE_SIZE)
	EXCEPTION_TABLE(8)
	NOTES
	ALIGN_DEBUG_RO
	_etext = .;			/* End of text and rodata section */

	ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
	__init_begin = .;

	INIT_TEXT_SECTION(8)
	.exit.text : {
		ARM_EXIT_KEEP(EXIT_TEXT)
	}

	ALIGN_DEBUG_RO_MIN(16)
	.init.data : {
		INIT_DATA
		INIT_SETUP(16)
		INIT_CALLS
		CON_INITCALL
		SECURITY_INITCALL
		INIT_RAM_FS
	}
	.exit.data : {
		ARM_EXIT_KEEP(EXIT_DATA)
	}

	PERCPU_SECTION(64)

	. = ALIGN(PAGE_SIZE);
	__init_end = .;

	. = ALIGN(4);
	.altinstructions : {
		__alt_instructions = .;
		*(.altinstructions)
		__alt_instructions_end = .;
	}
	.altinstr_replacement : {
		*(.altinstr_replacement)
	}

	. = ALIGN(PAGE_SIZE);
	_data = .;
	_sdata = .;
	RW_DATA_SECTION(64, PAGE_SIZE, THREAD_SIZE)
	PECOFF_EDATA_PADDING
	_edata = .;

	BSS_SECTION(0, 0, 0)

	. = ALIGN(PAGE_SIZE);
	idmap_pg_dir = .;
	. += IDMAP_DIR_SIZE;
	swapper_pg_dir = .;
	. += SWAPPER_DIR_SIZE;

	_end = .;

	STABS_DEBUG

	HEAD_SYMBOLS
}

/*
 * The HYP init code and ID map text can't be longer than a page each,
 * and should not cross a page boundary.
 */
ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
	"HYP init code too big or misaligned")
ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
	"ID map text too big or misaligned")

/*
 * If padding is applied before .head.text, virt<->phys conversions will fail.
 */
ASSERT(_text == (PAGE_OFFSET + TEXT_OFFSET), "HEAD is misaligned")
Commit	Line	Data
8c2c3df3 CM	1	/*
	2	* ld script to make ARM Linux kernel
	3	* taken from the i386 version by Russell King
	4	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	5	*/
	6
	7	#include <asm-generic/vmlinux.lds.h>
87d1587b	8	#include <asm/kernel-pgtable.h>
8c2c3df3 CM	9	#include <asm/thread_info.h>
	10	#include <asm/memory.h>
	11	#include <asm/page.h>
da141706	12	#include <asm/pgtable.h>
8c2c3df3	13
a2c1d73b MR	14	#include "image.h"
a2c1d73b MR	15
07c802bd WD	16	/* .exit.text needed in case of alternative patching */
	17	#define ARM_EXIT_KEEP(x) x
	18	#define ARM_EXIT_DISCARD(x)
8c2c3df3 CM	19
8c2c3df3 CM	20	OUTPUT_ARCH(aarch64)
af885f40	21	ENTRY(_text)
8c2c3df3 CM	22
	23	jiffies = jiffies_64;
	24
2240bbb6 MZ	25	#define HYPERVISOR_TEXT \
2240bbb6 MZ	26	/* \
06f75a1f AB	27	* Align to 4 KB so that \
	28	* a) the HYP vector table is at its minimum \
	29	* alignment of 2048 bytes \
	30	* b) the HYP init code will not cross a page \
	31	* boundary if its size does not exceed \
	32	* 4 KB (see related ASSERT() below) \
2240bbb6	33	*/ \
06f75a1f	34	. = ALIGN(SZ_4K); \
2240bbb6 MZ	35	VMLINUX_SYMBOL(__hyp_idmap_text_start) = .; \
	36	*(.hyp.idmap.text) \
	37	VMLINUX_SYMBOL(__hyp_idmap_text_end) = .; \
	38	VMLINUX_SYMBOL(__hyp_text_start) = .; \
	39	*(.hyp.text) \
	40	VMLINUX_SYMBOL(__hyp_text_end) = .;
	41
5dfe9d7d AB	42	#define IDMAP_TEXT \
	43	. = ALIGN(SZ_4K); \
	44	VMLINUX_SYMBOL(__idmap_text_start) = .; \
	45	*(.idmap.text) \
	46	VMLINUX_SYMBOL(__idmap_text_end) = .;
	47
a352ea3e AB	48	/*
	49	* The size of the PE/COFF section that covers the kernel image, which
	50	* runs from stext to _edata, must be a round multiple of the PE/COFF
	51	* FileAlignment, which we set to its minimum value of 0x200. 'stext'
	52	* itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
	53	* boundary should be sufficient.
	54	*/
	55	PECOFF_FILE_ALIGNMENT = 0x200;
	56
	57	#ifdef CONFIG_EFI
	58	#define PECOFF_EDATA_PADDING \
	59	.pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
	60	#else
	61	#define PECOFF_EDATA_PADDING
	62	#endif
	63
da141706 LA	64	#ifdef CONFIG_DEBUG_ALIGN_RODATA
	65	#define ALIGN_DEBUG_RO . = ALIGN(1<<SECTION_SHIFT);
	66	#define ALIGN_DEBUG_RO_MIN(min) ALIGN_DEBUG_RO
	67	#else
	68	#define ALIGN_DEBUG_RO
	69	#define ALIGN_DEBUG_RO_MIN(min) . = ALIGN(min);
	70	#endif
	71
8c2c3df3 CM	72	SECTIONS
	73	{
	74	/*
	75	* XXX: The linker does not define how output sections are
	76	* assigned to input sections when there are multiple statements
	77	* matching the same input section name. There is no documented
	78	* order of matching.
	79	*/
	80	/DISCARD/ : {
	81	ARM_EXIT_DISCARD(EXIT_TEXT)
	82	ARM_EXIT_DISCARD(EXIT_DATA)
	83	EXIT_CALL
	84	*(.discard)
	85	(.discard.)
	86	}
	87
	88	. = PAGE_OFFSET + TEXT_OFFSET;
	89
	90	.head.text : {
	91	_text = .;
	92	HEAD_TEXT
	93	}
da141706	94	ALIGN_DEBUG_RO
8c2c3df3 CM	95	.text : { /* Real text segment */
8c2c3df3 CM	96	_stext = .; /* Text and read-only data */
8c2c3df3 CM	97	__exception_text_start = .;
	98	*(.exception.text)
	99	__exception_text_end = .;
	100	IRQENTRY_TEXT
	101	TEXT_TEXT
	102	SCHED_TEXT
	103	LOCK_TEXT
2240bbb6	104	HYPERVISOR_TEXT
5dfe9d7d	105	IDMAP_TEXT
8c2c3df3 CM	106	*(.fixup)
	107	*(.gnu.warning)
	108	. = ALIGN(16);
	109	(.got) / Global offset table */
	110	}
	111
da141706	112	ALIGN_DEBUG_RO
8c2c3df3	113	RO_DATA(PAGE_SIZE)
adace895	114	EXCEPTION_TABLE(8)
c80b7ee8	115	NOTES
da141706	116	ALIGN_DEBUG_RO
8c2c3df3 CM	117	_etext = .; /* End of text and rodata section */
8c2c3df3 CM	118
da141706	119	ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
8c2c3df3 CM	120	__init_begin = .;
	121
	122	INIT_TEXT_SECTION(8)
	123	.exit.text : {
	124	ARM_EXIT_KEEP(EXIT_TEXT)
	125	}
da141706 LA	126
da141706 LA	127	ALIGN_DEBUG_RO_MIN(16)
8c2c3df3 CM	128	.init.data : {
	129	INIT_DATA
	130	INIT_SETUP(16)
	131	INIT_CALLS
	132	CON_INITCALL
	133	SECURITY_INITCALL
	134	INIT_RAM_FS
	135	}
	136	.exit.data : {
	137	ARM_EXIT_KEEP(EXIT_DATA)
	138	}
	139
	140	PERCPU_SECTION(64)
	141
562c85ca	142	. = ALIGN(PAGE_SIZE);
8c2c3df3	143	__init_end = .;
3c620626	144
e039ee4e AP	145	. = ALIGN(4);
	146	.altinstructions : {
	147	__alt_instructions = .;
	148	*(.altinstructions)
	149	__alt_instructions_end = .;
	150	}
	151	.altinstr_replacement : {
	152	*(.altinstr_replacement)
	153	}
	154
	155	. = ALIGN(PAGE_SIZE);
3c620626	156	_data = .;
3c620626 MS	157	_sdata = .;
3c620626 MS	158	RW_DATA_SECTION(64, PAGE_SIZE, THREAD_SIZE)
a352ea3e	159	PECOFF_EDATA_PADDING
3c620626	160	_edata = .;
8c2c3df3	161
8c2c3df3	162	BSS_SECTION(0, 0, 0)
bd00cd5f MR	163
	164	. = ALIGN(PAGE_SIZE);
	165	idmap_pg_dir = .;
	166	. += IDMAP_DIR_SIZE;
	167	swapper_pg_dir = .;
	168	. += SWAPPER_DIR_SIZE;
	169
8c2c3df3 CM	170	_end = .;
	171
	172	STABS_DEBUG
a2c1d73b MR	173
a2c1d73b MR	174	HEAD_SYMBOLS
8c2c3df3	175	}
2240bbb6 MZ	176
2240bbb6 MZ	177	/*
5dfe9d7d	178	* The HYP init code and ID map text can't be longer than a page each,
06f75a1f	179	* and should not cross a page boundary.
2240bbb6	180	*/
06f75a1f AB	181	ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
06f75a1f AB	182	"HYP init code too big or misaligned")
5dfe9d7d AB	183	ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
5dfe9d7d AB	184	"ID map text too big or misaligned")
da57a369 MR	185
	186	/*
	187	* If padding is applied before .head.text, virt<->phys conversions will fail.
	188	*/
	189	ASSERT(_text == (PAGE_OFFSET + TEXT_OFFSET), "HEAD is misaligned")