[mirror_ubuntu-artful-kernel.git] / arch / mips / kernel / mcount.S

/*
 * MIPS specific _mcount support
 *
 * This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file "COPYING" in the main directory of this archive for
 * more details.
 *
 * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
 * Copyright (C) 2010 DSLab, Lanzhou University, China
 * Author: Wu Zhangjin <wuzhangjin@gmail.com>
 */

#include <asm/export.h>
#include <asm/regdef.h>
#include <asm/stackframe.h>
#include <asm/ftrace.h>

	.text
	.set noreorder
	.set noat

	.macro MCOUNT_SAVE_REGS
	PTR_SUBU	sp, PT_SIZE
	PTR_S	ra, PT_R31(sp)
	PTR_S	AT, PT_R1(sp)
	PTR_S	a0, PT_R4(sp)
	PTR_S	a1, PT_R5(sp)
	PTR_S	a2, PT_R6(sp)
	PTR_S	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_S	a4, PT_R8(sp)
	PTR_S	a5, PT_R9(sp)
	PTR_S	a6, PT_R10(sp)
	PTR_S	a7, PT_R11(sp)
#endif
	.endm

	.macro MCOUNT_RESTORE_REGS
	PTR_L	ra, PT_R31(sp)
	PTR_L	AT, PT_R1(sp)
	PTR_L	a0, PT_R4(sp)
	PTR_L	a1, PT_R5(sp)
	PTR_L	a2, PT_R6(sp)
	PTR_L	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_L	a4, PT_R8(sp)
	PTR_L	a5, PT_R9(sp)
	PTR_L	a6, PT_R10(sp)
	PTR_L	a7, PT_R11(sp)
#endif
	PTR_ADDIU	sp, PT_SIZE
	.endm

	.macro RETURN_BACK
	jr ra
	 move ra, AT
	.endm

/*
 * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
 * the location of the parent's return address.
 */
#define MCOUNT_RA_ADDRESS_REG	$12

#ifdef CONFIG_DYNAMIC_FTRACE

NESTED(ftrace_caller, PT_SIZE, ra)
	.globl _mcount
_mcount:
EXPORT_SYMBOL(_mcount)
	b	ftrace_stub
#ifdef CONFIG_32BIT
	 addiu sp,sp,8
#else
	 nop
#endif

	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
	MCOUNT_SAVE_REGS
#ifdef KBUILD_MCOUNT_RA_ADDRESS
	PTR_S	MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
#endif

	PTR_SUBU a0, ra, 8	/* arg1: self address */
	PTR_LA   t1, _stext
	sltu     t2, a0, t1	/* t2 = (a0 < _stext) */
	PTR_LA   t1, _etext
	sltu     t3, t1, a0	/* t3 = (a0 > _etext) */
	or       t1, t2, t3
	beqz     t1, ftrace_call
	 nop
#if defined(KBUILD_MCOUNT_RA_ADDRESS) && defined(CONFIG_32BIT)
	PTR_SUBU a0, a0, 16	/* arg1: adjust to module's recorded callsite */
#else
	PTR_SUBU a0, a0, 12
#endif

	.globl ftrace_call
ftrace_call:
	nop	/* a placeholder for the call to a real tracing function */
	 move	a1, AT		/* arg2: parent's return address */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	.globl ftrace_graph_call
ftrace_graph_call:
	nop
	 nop
#endif

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(ftrace_caller)

#else	/* ! CONFIG_DYNAMIC_FTRACE */

NESTED(_mcount, PT_SIZE, ra)
EXPORT_SYMBOL(_mcount)
	PTR_LA	t1, ftrace_stub
	PTR_L	t2, ftrace_trace_function /* Prepare t2 for (1) */
	bne	t1, t2, static_trace
	 nop

#ifdef	CONFIG_FUNCTION_GRAPH_TRACER
	PTR_L	t3, ftrace_graph_return
	bne	t1, t3, ftrace_graph_caller
	 nop
	PTR_LA	t1, ftrace_graph_entry_stub
	PTR_L	t3, ftrace_graph_entry
	bne	t1, t3, ftrace_graph_caller
	 nop
#endif
	b	ftrace_stub
#ifdef CONFIG_32BIT
	 addiu sp, sp, 8
#else
	 nop
#endif

static_trace:
	MCOUNT_SAVE_REGS

	move	a0, ra		/* arg1: self return address */
	jalr	t2		/* (1) call *ftrace_trace_function */
	 move	a1, AT		/* arg2: parent's return address */

	MCOUNT_RESTORE_REGS
#ifdef CONFIG_32BIT
	addiu sp, sp, 8
#endif
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(_mcount)

#endif	/* ! CONFIG_DYNAMIC_FTRACE */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER

NESTED(ftrace_graph_caller, PT_SIZE, ra)
#ifndef CONFIG_DYNAMIC_FTRACE
	MCOUNT_SAVE_REGS
#endif

	/* arg1: Get the location of the parent's return address */
#ifdef KBUILD_MCOUNT_RA_ADDRESS
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a0, PT_R12(sp)
#else
	move	a0, MCOUNT_RA_ADDRESS_REG
#endif
	bnez	a0, 1f	/* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
	 nop
#endif
	PTR_LA	a0, PT_R1(sp)	/* leaf func: the location in current stack */
1:

	/* arg2: Get self return address */
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a1, PT_R31(sp)
#else
	move	a1, ra
#endif

	/* arg3: Get frame pointer of current stack */
#ifdef CONFIG_64BIT
	PTR_LA	a2, PT_SIZE(sp)
#else
	PTR_LA	a2, (PT_SIZE+8)(sp)
#endif

	jal	prepare_ftrace_return
	 nop
	MCOUNT_RESTORE_REGS
#ifndef CONFIG_DYNAMIC_FTRACE
#ifdef CONFIG_32BIT
	addiu sp, sp, 8
#endif
#endif
	RETURN_BACK
	END(ftrace_graph_caller)

	.align	2
	.globl	return_to_handler
return_to_handler:
	PTR_SUBU	sp, PT_SIZE
	PTR_S	v0, PT_R2(sp)

	jal	ftrace_return_to_handler
	 PTR_S	v1, PT_R3(sp)

	/* restore the real parent address: v0 -> ra */
	move	ra, v0

	PTR_L	v0, PT_R2(sp)
	PTR_L	v1, PT_R3(sp)
	jr	ra
	 PTR_ADDIU	sp, PT_SIZE
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */

	.set at
	.set reorder
Commit	Line	Data
d2bb0762 WZ	1	/*
	2	* MIPS specific _mcount support
	3	*
	4	* This file is subject to the terms and conditions of the GNU General Public
	5	* License. See the file "COPYING" in the main directory of this archive for
	6	* more details.
	7	*
	8	* Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
042e571d	9	* Copyright (C) 2010 DSLab, Lanzhou University, China
f7a904df	10	* Author: Wu Zhangjin <wuzhangjin@gmail.com>
d2bb0762 WZ	11	*/
d2bb0762 WZ	12
827456e7	13	#include <asm/export.h>
d2bb0762 WZ	14	#include <asm/regdef.h>
	15	#include <asm/stackframe.h>
	16	#include <asm/ftrace.h>
	17
	18	.text
	19	.set noreorder
	20	.set noat
	21
	22	.macro MCOUNT_SAVE_REGS
	23	PTR_SUBU sp, PT_SIZE
	24	PTR_S ra, PT_R31(sp)
	25	PTR_S AT, PT_R1(sp)
	26	PTR_S a0, PT_R4(sp)
	27	PTR_S a1, PT_R5(sp)
	28	PTR_S a2, PT_R6(sp)
	29	PTR_S a3, PT_R7(sp)
	30	#ifdef CONFIG_64BIT
	31	PTR_S a4, PT_R8(sp)
	32	PTR_S a5, PT_R9(sp)
	33	PTR_S a6, PT_R10(sp)
	34	PTR_S a7, PT_R11(sp)
	35	#endif
	36	.endm
	37
	38	.macro MCOUNT_RESTORE_REGS
	39	PTR_L ra, PT_R31(sp)
	40	PTR_L AT, PT_R1(sp)
	41	PTR_L a0, PT_R4(sp)
	42	PTR_L a1, PT_R5(sp)
	43	PTR_L a2, PT_R6(sp)
	44	PTR_L a3, PT_R7(sp)
	45	#ifdef CONFIG_64BIT
	46	PTR_L a4, PT_R8(sp)
	47	PTR_L a5, PT_R9(sp)
	48	PTR_L a6, PT_R10(sp)
	49	PTR_L a7, PT_R11(sp)
d2bb0762	50	#endif
ad8c3969 DD	51	PTR_ADDIU sp, PT_SIZE
ad8c3969 DD	52	.endm
d2bb0762 WZ	53
	54	.macro RETURN_BACK
	55	jr ra
	56	move ra, AT
	57	.endm
	58
56b49cd3 WZ	59	/*
	60	* The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
	61	* the location of the parent's return address.
	62	*/
	63	#define MCOUNT_RA_ADDRESS_REG $12
	64
538f1952 WZ	65	#ifdef CONFIG_DYNAMIC_FTRACE
	66
	67	NESTED(ftrace_caller, PT_SIZE, ra)
	68	.globl _mcount
	69	_mcount:
827456e7	70	EXPORT_SYMBOL(_mcount)
538f1952	71	b ftrace_stub
ad8c3969 DD	72	#ifdef CONFIG_32BIT
	73	addiu sp,sp,8
	74	#else
	75	nop
	76	#endif
58b69401 AC	77
58b69401 AC	78	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
538f1952	79	MCOUNT_SAVE_REGS
7326c4e5	80	#ifdef KBUILD_MCOUNT_RA_ADDRESS
56b49cd3	81	PTR_S MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
7326c4e5	82	#endif
538f1952	83
05f22639	84	PTR_SUBU a0, ra, 8 /* arg1: self address */
dce0e7d5 PG	85	PTR_LA t1, _stext
	86	sltu t2, a0, t1 /* t2 = (a0 < _stext) */
	87	PTR_LA t1, _etext
	88	sltu t3, t1, a0 /* t3 = (a0 > _etext) */
	89	or t1, t2, t3
	90	beqz t1, ftrace_call
	91	nop
	92	#if defined(KBUILD_MCOUNT_RA_ADDRESS) && defined(CONFIG_32BIT)
	93	PTR_SUBU a0, a0, 16 /* arg1: adjust to module's recorded callsite */
	94	#else
	95	PTR_SUBU a0, a0, 12
	96	#endif
	97
538f1952 WZ	98	.globl ftrace_call
	99	ftrace_call:
	100	nop /* a placeholder for the call to a real tracing function */
042e571d	101	move a1, AT /* arg2: parent's return address */
538f1952	102
e17ff5fe WZ	103	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	104	.globl ftrace_graph_call
	105	ftrace_graph_call:
	106	nop
	107	nop
	108	#endif
	109
538f1952 WZ	110	MCOUNT_RESTORE_REGS
	111	.globl ftrace_stub
	112	ftrace_stub:
	113	RETURN_BACK
	114	END(ftrace_caller)
	115
	116	#else /* ! CONFIG_DYNAMIC_FTRACE */
	117
d2bb0762	118	NESTED(_mcount, PT_SIZE, ra)
827456e7	119	EXPORT_SYMBOL(_mcount)
fc49a3be WZ	120	PTR_LA t1, ftrace_stub
	121	PTR_L t2, ftrace_trace_function /* Prepare t2 for (1) */
	122	bne t1, t2, static_trace
d2bb0762	123	nop
29c5d346 WZ	124
29c5d346 WZ	125	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
fc49a3be WZ	126	PTR_L t3, ftrace_graph_return
fc49a3be WZ	127	bne t1, t3, ftrace_graph_caller
29c5d346	128	nop
fc49a3be WZ	129	PTR_LA t1, ftrace_graph_entry_stub
	130	PTR_L t3, ftrace_graph_entry
	131	bne t1, t3, ftrace_graph_caller
29c5d346 WZ	132	nop
29c5d346 WZ	133	#endif
d2bb0762	134	b ftrace_stub
8a574cfa MC	135	#ifdef CONFIG_32BIT
	136	addiu sp, sp, 8
	137	#else
d2bb0762	138	nop
8a574cfa	139	#endif
d2bb0762 WZ	140
	141	static_trace:
	142	MCOUNT_SAVE_REGS
	143
042e571d	144	move a0, ra /* arg1: self return address */
fc49a3be	145	jalr t2 /* (1) call ftrace_trace_function /
042e571d	146	move a1, AT /* arg2: parent's return address */
d2bb0762 WZ	147
d2bb0762 WZ	148	MCOUNT_RESTORE_REGS
8a574cfa MC	149	#ifdef CONFIG_32BIT
	150	addiu sp, sp, 8
	151	#endif
d2bb0762 WZ	152	.globl ftrace_stub
	153	ftrace_stub:
	154	RETURN_BACK
	155	END(_mcount)
	156
538f1952 WZ	157	#endif /* ! CONFIG_DYNAMIC_FTRACE */
538f1952 WZ	158
29c5d346 WZ	159	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	160
	161	NESTED(ftrace_graph_caller, PT_SIZE, ra)
cbe555b0	162	#ifndef CONFIG_DYNAMIC_FTRACE
29c5d346	163	MCOUNT_SAVE_REGS
e17ff5fe	164	#endif
7326c4e5	165
cbe555b0	166	/* arg1: Get the location of the parent's return address */
7326c4e5	167	#ifdef KBUILD_MCOUNT_RA_ADDRESS
cbe555b0 WZ	168	#ifdef CONFIG_DYNAMIC_FTRACE
	169	PTR_L a0, PT_R12(sp)
	170	#else
56b49cd3	171	move a0, MCOUNT_RA_ADDRESS_REG
cbe555b0	172	#endif
56b49cd3	173	bnez a0, 1f /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
7326c4e5	174	nop
cbe555b0 WZ	175	#endif
	176	PTR_LA a0, PT_R1(sp) /* leaf func: the location in current stack */
	177	1:
	178
	179	/* arg2: Get self return address */
	180	#ifdef CONFIG_DYNAMIC_FTRACE
	181	PTR_L a1, PT_R31(sp)
7326c4e5	182	#else
cbe555b0	183	move a1, ra
7326c4e5	184	#endif
cbe555b0 WZ	185
cbe555b0 WZ	186	/* arg3: Get frame pointer of current stack */
046199ca	187	#ifdef CONFIG_64BIT
65ab2826	188	PTR_LA a2, PT_SIZE(sp)
046199ca	189	#else
65ab2826	190	PTR_LA a2, (PT_SIZE+8)(sp)
046199ca	191	#endif
29c5d346	192
cbe555b0 WZ	193	jal prepare_ftrace_return
cbe555b0 WZ	194	nop
29c5d346	195	MCOUNT_RESTORE_REGS
8a574cfa MC	196	#ifndef CONFIG_DYNAMIC_FTRACE
	197	#ifdef CONFIG_32BIT
	198	addiu sp, sp, 8
	199	#endif
	200	#endif
29c5d346 WZ	201	RETURN_BACK
	202	END(ftrace_graph_caller)
	203
	204	.align 2
	205	.globl return_to_handler
	206	return_to_handler:
	207	PTR_SUBU sp, PT_SIZE
	208	PTR_S v0, PT_R2(sp)
	209
	210	jal ftrace_return_to_handler
	211	PTR_S v1, PT_R3(sp)
	212
	213	/* restore the real parent address: v0 -> ra */
	214	move ra, v0
	215
	216	PTR_L v0, PT_R2(sp)
	217	PTR_L v1, PT_R3(sp)
	218	jr ra
	219	PTR_ADDIU sp, PT_SIZE
	220	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
	221
d2bb0762 WZ	222	.set at
d2bb0762 WZ	223	.set reorder