]>
Commit | Line | Data |
---|---|---|
1da177e4 LT |
1 | /* |
2 | * Linux/PA-RISC Project (http://www.parisc-linux.org/) | |
3 | * | |
4 | * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai> | |
5 | * Licensed under the GNU GPL. | |
6 | * thanks to Philipp Rumpf, Mike Shaver and various others | |
7 | * sorry about the wall, puffin.. | |
8 | */ | |
9 | ||
0013a854 | 10 | #include <asm/asm-offsets.h> |
1da177e4 LT |
11 | #include <asm/unistd.h> |
12 | #include <asm/errno.h> | |
1c593571 | 13 | #include <asm/page.h> |
1da177e4 LT |
14 | #include <asm/psw.h> |
15 | #include <asm/thread_info.h> | |
1da177e4 LT |
16 | #include <asm/assembly.h> |
17 | #include <asm/processor.h> | |
18 | ||
8e9e9844 HD |
19 | #include <linux/linkage.h> |
20 | ||
1da177e4 LT |
21 | /* We fill the empty parts of the gateway page with |
22 | * something that will kill the kernel or a | |
23 | * userspace application. | |
24 | */ | |
25 | #define KILL_INSN break 0,0 | |
26 | ||
0b3d643f | 27 | .level LEVEL |
8e9e9844 | 28 | |
dfcf753b | 29 | .text |
1da177e4 LT |
30 | |
31 | .import syscall_exit,code | |
32 | .import syscall_exit_rfi,code | |
1da177e4 LT |
33 | |
34 | /* Linux gateway page is aliased to virtual page 0 in the kernel | |
35 | * address space. Since it is a gateway page it cannot be | |
36 | * dereferenced, so null pointers will still fault. We start | |
37 | * the actual entry point at 0x100. We put break instructions | |
38 | * at the beginning of the page to trap null indirect function | |
39 | * pointers. | |
40 | */ | |
41 | ||
1c593571 | 42 | .align PAGE_SIZE |
8e9e9844 | 43 | ENTRY(linux_gateway_page) |
1da177e4 LT |
44 | |
45 | /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */ | |
46 | .rept 44 | |
47 | KILL_INSN | |
48 | .endr | |
49 | ||
50 | /* ADDRESS 0xb0 to 0xb4, lws uses 1 insns for entry */ | |
51 | /* Light-weight-syscall entry must always be located at 0xb0 */ | |
52 | /* WARNING: Keep this number updated with table size changes */ | |
53 | #define __NR_lws_entries (2) | |
54 | ||
55 | lws_entry: | |
56 | /* Unconditional branch to lws_start, located on the | |
57 | same gateway page */ | |
58 | b,n lws_start | |
59 | ||
60 | /* Fill from 0xb4 to 0xe0 */ | |
61 | .rept 11 | |
62 | KILL_INSN | |
63 | .endr | |
64 | ||
65 | /* This function MUST be located at 0xe0 for glibc's threading | |
66 | mechanism to work. DO NOT MOVE THIS CODE EVER! */ | |
67 | set_thread_pointer: | |
68 | gate .+8, %r0 /* increase privilege */ | |
69 | depi 3, 31, 2, %r31 /* Ensure we return into user mode. */ | |
70 | be 0(%sr7,%r31) /* return to user space */ | |
71 | mtctl %r26, %cr27 /* move arg0 to the control register */ | |
72 | ||
73 | /* Increase the chance of trapping if random jumps occur to this | |
74 | address, fill from 0xf0 to 0x100 */ | |
75 | .rept 4 | |
76 | KILL_INSN | |
77 | .endr | |
78 | ||
79 | /* This address must remain fixed at 0x100 for glibc's syscalls to work */ | |
80 | .align 256 | |
81 | linux_gateway_entry: | |
82 | gate .+8, %r0 /* become privileged */ | |
83 | mtsp %r0,%sr4 /* get kernel space into sr4 */ | |
84 | mtsp %r0,%sr5 /* get kernel space into sr5 */ | |
85 | mtsp %r0,%sr6 /* get kernel space into sr6 */ | |
86 | mfsp %sr7,%r1 /* save user sr7 */ | |
87 | mtsp %r1,%sr3 /* and store it in sr3 */ | |
88 | ||
413059f2 | 89 | #ifdef CONFIG_64BIT |
1da177e4 LT |
90 | /* for now we can *always* set the W bit on entry to the syscall |
91 | * since we don't support wide userland processes. We could | |
92 | * also save the current SM other than in r0 and restore it on | |
93 | * exit from the syscall, and also use that value to know | |
94 | * whether to do narrow or wide syscalls. -PB | |
95 | */ | |
96 | ssm PSW_SM_W, %r1 | |
97 | extrd,u %r1,PSW_W_BIT,1,%r1 | |
98 | /* sp must be aligned on 4, so deposit the W bit setting into | |
99 | * the bottom of sp temporarily */ | |
100 | or,ev %r1,%r30,%r30 | |
101 | b,n 1f | |
102 | /* The top halves of argument registers must be cleared on syscall | |
103 | * entry from narrow executable. | |
104 | */ | |
105 | depdi 0, 31, 32, %r26 | |
106 | depdi 0, 31, 32, %r25 | |
107 | depdi 0, 31, 32, %r24 | |
108 | depdi 0, 31, 32, %r23 | |
109 | depdi 0, 31, 32, %r22 | |
110 | depdi 0, 31, 32, %r21 | |
111 | 1: | |
112 | #endif | |
113 | mfctl %cr30,%r1 | |
114 | xor %r1,%r30,%r30 /* ye olde xor trick */ | |
115 | xor %r1,%r30,%r1 | |
116 | xor %r1,%r30,%r30 | |
117 | ||
118 | ldo THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30 /* set up kernel stack */ | |
119 | ||
120 | /* N.B.: It is critical that we don't set sr7 to 0 until r30 | |
121 | * contains a valid kernel stack pointer. It is also | |
122 | * critical that we don't start using the kernel stack | |
123 | * until after sr7 has been set to 0. | |
124 | */ | |
125 | ||
126 | mtsp %r0,%sr7 /* get kernel space into sr7 */ | |
127 | STREGM %r1,FRAME_SIZE(%r30) /* save r1 (usp) here for now */ | |
128 | mfctl %cr30,%r1 /* get task ptr in %r1 */ | |
129 | LDREG TI_TASK(%r1),%r1 | |
130 | ||
131 | /* Save some registers for sigcontext and potential task | |
132 | switch (see entry.S for the details of which ones are | |
133 | saved/restored). TASK_PT_PSW is zeroed so we can see whether | |
134 | a process is on a syscall or not. For an interrupt the real | |
135 | PSW value is stored. This is needed for gdb and sys_ptrace. */ | |
136 | STREG %r0, TASK_PT_PSW(%r1) | |
137 | STREG %r2, TASK_PT_GR2(%r1) /* preserve rp */ | |
138 | STREG %r19, TASK_PT_GR19(%r1) | |
139 | ||
140 | LDREGM -FRAME_SIZE(%r30), %r2 /* get users sp back */ | |
413059f2 | 141 | #ifdef CONFIG_64BIT |
1da177e4 LT |
142 | extrd,u %r2,63,1,%r19 /* W hidden in bottom bit */ |
143 | #if 0 | |
144 | xor %r19,%r2,%r2 /* clear bottom bit */ | |
145 | depd,z %r19,1,1,%r19 | |
146 | std %r19,TASK_PT_PSW(%r1) | |
147 | #endif | |
148 | #endif | |
149 | STREG %r2, TASK_PT_GR30(%r1) /* ... and save it */ | |
150 | ||
aa0eecb0 | 151 | STREG %r20, TASK_PT_GR20(%r1) /* Syscall number */ |
1da177e4 LT |
152 | STREG %r21, TASK_PT_GR21(%r1) |
153 | STREG %r22, TASK_PT_GR22(%r1) | |
154 | STREG %r23, TASK_PT_GR23(%r1) /* 4th argument */ | |
155 | STREG %r24, TASK_PT_GR24(%r1) /* 3rd argument */ | |
156 | STREG %r25, TASK_PT_GR25(%r1) /* 2nd argument */ | |
157 | STREG %r26, TASK_PT_GR26(%r1) /* 1st argument */ | |
158 | STREG %r27, TASK_PT_GR27(%r1) /* user dp */ | |
159 | STREG %r28, TASK_PT_GR28(%r1) /* return value 0 */ | |
160 | STREG %r28, TASK_PT_ORIG_R28(%r1) /* return value 0 (saved for signals) */ | |
161 | STREG %r29, TASK_PT_GR29(%r1) /* return value 1 */ | |
162 | STREG %r31, TASK_PT_GR31(%r1) /* preserve syscall return ptr */ | |
163 | ||
164 | ldo TASK_PT_FR0(%r1), %r27 /* save fpregs from the kernel */ | |
165 | save_fp %r27 /* or potential task switch */ | |
166 | ||
167 | mfctl %cr11, %r27 /* i.e. SAR */ | |
168 | STREG %r27, TASK_PT_SAR(%r1) | |
169 | ||
170 | loadgp | |
171 | ||
413059f2 | 172 | #ifdef CONFIG_64BIT |
1da177e4 LT |
173 | ldo -16(%r30),%r29 /* Reference param save area */ |
174 | copy %r19,%r2 /* W bit back to r2 */ | |
175 | #else | |
176 | /* no need to save these on stack in wide mode because the first 8 | |
177 | * args are passed in registers */ | |
178 | stw %r22, -52(%r30) /* 5th argument */ | |
179 | stw %r21, -56(%r30) /* 6th argument */ | |
180 | #endif | |
181 | ||
182 | /* Are we being ptraced? */ | |
183 | mfctl %cr30, %r1 | |
184 | LDREG TI_TASK(%r1),%r1 | |
376e210b | 185 | ldw TASK_PTRACE(%r1), %r1 |
1da177e4 LT |
186 | bb,<,n %r1,31,.Ltracesys |
187 | ||
188 | /* Note! We cannot use the syscall table that is mapped | |
189 | nearby since the gateway page is mapped execute-only. */ | |
190 | ||
413059f2 | 191 | #ifdef CONFIG_64BIT |
1da177e4 LT |
192 | ldil L%sys_call_table, %r1 |
193 | or,= %r2,%r2,%r2 | |
194 | addil L%(sys_call_table64-sys_call_table), %r1 | |
195 | ldo R%sys_call_table(%r1), %r19 | |
196 | or,= %r2,%r2,%r2 | |
197 | ldo R%sys_call_table64(%r1), %r19 | |
198 | #else | |
199 | ldil L%sys_call_table, %r1 | |
200 | ldo R%sys_call_table(%r1), %r19 | |
201 | #endif | |
3bb457af | 202 | comiclr,>> __NR_Linux_syscalls, %r20, %r0 |
1da177e4 LT |
203 | b,n .Lsyscall_nosys |
204 | ||
205 | LDREGX %r20(%r19), %r19 | |
206 | ||
207 | /* If this is a sys_rt_sigreturn call, and the signal was received | |
208 | * when not in_syscall, then we want to return via syscall_exit_rfi, | |
209 | * not syscall_exit. Signal no. in r20, in_syscall in r25 (see | |
210 | * trampoline code in signal.c). | |
211 | */ | |
212 | ldi __NR_rt_sigreturn,%r2 | |
213 | comb,= %r2,%r20,.Lrt_sigreturn | |
214 | .Lin_syscall: | |
215 | ldil L%syscall_exit,%r2 | |
216 | be 0(%sr7,%r19) | |
217 | ldo R%syscall_exit(%r2),%r2 | |
218 | .Lrt_sigreturn: | |
219 | comib,<> 0,%r25,.Lin_syscall | |
220 | ldil L%syscall_exit_rfi,%r2 | |
221 | be 0(%sr7,%r19) | |
222 | ldo R%syscall_exit_rfi(%r2),%r2 | |
223 | ||
224 | /* Note! Because we are not running where we were linked, any | |
225 | calls to functions external to this file must be indirect. To | |
226 | be safe, we apply the opposite rule to functions within this | |
227 | file, with local labels given to them to ensure correctness. */ | |
228 | ||
229 | .Lsyscall_nosys: | |
230 | syscall_nosys: | |
231 | ldil L%syscall_exit,%r1 | |
232 | be R%syscall_exit(%sr7,%r1) | |
233 | ldo -ENOSYS(%r0),%r28 /* set errno */ | |
234 | ||
235 | ||
236 | /* Warning! This trace code is a virtual duplicate of the code above so be | |
237 | * sure to maintain both! */ | |
238 | .Ltracesys: | |
239 | tracesys: | |
240 | /* Need to save more registers so the debugger can see where we | |
241 | * are. This saves only the lower 8 bits of PSW, so that the C | |
242 | * bit is still clear on syscalls, and the D bit is set if this | |
243 | * full register save path has been executed. We check the D | |
244 | * bit on syscall_return_rfi to determine which registers to | |
245 | * restore. An interrupt results in a full PSW saved with the | |
246 | * C bit set, a non-straced syscall entry results in C and D clear | |
247 | * in the saved PSW. | |
248 | */ | |
249 | ldo -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1 /* get task ptr */ | |
250 | LDREG TI_TASK(%r1), %r1 | |
251 | ssm 0,%r2 | |
252 | STREG %r2,TASK_PT_PSW(%r1) /* Lower 8 bits only!! */ | |
253 | mfsp %sr0,%r2 | |
254 | STREG %r2,TASK_PT_SR0(%r1) | |
255 | mfsp %sr1,%r2 | |
256 | STREG %r2,TASK_PT_SR1(%r1) | |
257 | mfsp %sr2,%r2 | |
258 | STREG %r2,TASK_PT_SR2(%r1) | |
259 | mfsp %sr3,%r2 | |
260 | STREG %r2,TASK_PT_SR3(%r1) | |
261 | STREG %r2,TASK_PT_SR4(%r1) | |
262 | STREG %r2,TASK_PT_SR5(%r1) | |
263 | STREG %r2,TASK_PT_SR6(%r1) | |
264 | STREG %r2,TASK_PT_SR7(%r1) | |
265 | STREG %r2,TASK_PT_IASQ0(%r1) | |
266 | STREG %r2,TASK_PT_IASQ1(%r1) | |
267 | LDREG TASK_PT_GR31(%r1),%r2 | |
268 | STREG %r2,TASK_PT_IAOQ0(%r1) | |
269 | ldo 4(%r2),%r2 | |
270 | STREG %r2,TASK_PT_IAOQ1(%r1) | |
271 | ldo TASK_REGS(%r1),%r2 | |
272 | /* reg_save %r2 */ | |
273 | STREG %r3,PT_GR3(%r2) | |
274 | STREG %r4,PT_GR4(%r2) | |
275 | STREG %r5,PT_GR5(%r2) | |
276 | STREG %r6,PT_GR6(%r2) | |
277 | STREG %r7,PT_GR7(%r2) | |
278 | STREG %r8,PT_GR8(%r2) | |
279 | STREG %r9,PT_GR9(%r2) | |
280 | STREG %r10,PT_GR10(%r2) | |
281 | STREG %r11,PT_GR11(%r2) | |
282 | STREG %r12,PT_GR12(%r2) | |
283 | STREG %r13,PT_GR13(%r2) | |
284 | STREG %r14,PT_GR14(%r2) | |
285 | STREG %r15,PT_GR15(%r2) | |
286 | STREG %r16,PT_GR16(%r2) | |
287 | STREG %r17,PT_GR17(%r2) | |
288 | STREG %r18,PT_GR18(%r2) | |
289 | /* Finished saving things for the debugger */ | |
290 | ||
291 | ldil L%syscall_trace,%r1 | |
292 | ldil L%tracesys_next,%r2 | |
293 | be R%syscall_trace(%sr7,%r1) | |
294 | ldo R%tracesys_next(%r2),%r2 | |
295 | ||
296 | tracesys_next: | |
297 | ldil L%sys_call_table,%r1 | |
298 | ldo R%sys_call_table(%r1), %r19 | |
299 | ||
300 | ldo -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1 /* get task ptr */ | |
301 | LDREG TI_TASK(%r1), %r1 | |
302 | LDREG TASK_PT_GR20(%r1), %r20 | |
303 | LDREG TASK_PT_GR26(%r1), %r26 /* Restore the users args */ | |
304 | LDREG TASK_PT_GR25(%r1), %r25 | |
305 | LDREG TASK_PT_GR24(%r1), %r24 | |
306 | LDREG TASK_PT_GR23(%r1), %r23 | |
413059f2 | 307 | #ifdef CONFIG_64BIT |
1da177e4 LT |
308 | LDREG TASK_PT_GR22(%r1), %r22 |
309 | LDREG TASK_PT_GR21(%r1), %r21 | |
310 | ldo -16(%r30),%r29 /* Reference param save area */ | |
311 | #endif | |
312 | ||
313 | comiclr,>>= __NR_Linux_syscalls, %r20, %r0 | |
314 | b,n .Lsyscall_nosys | |
315 | ||
316 | LDREGX %r20(%r19), %r19 | |
317 | ||
318 | /* If this is a sys_rt_sigreturn call, and the signal was received | |
319 | * when not in_syscall, then we want to return via syscall_exit_rfi, | |
320 | * not syscall_exit. Signal no. in r20, in_syscall in r25 (see | |
321 | * trampoline code in signal.c). | |
322 | */ | |
323 | ldi __NR_rt_sigreturn,%r2 | |
324 | comb,= %r2,%r20,.Ltrace_rt_sigreturn | |
325 | .Ltrace_in_syscall: | |
326 | ldil L%tracesys_exit,%r2 | |
327 | be 0(%sr7,%r19) | |
328 | ldo R%tracesys_exit(%r2),%r2 | |
329 | ||
330 | /* Do *not* call this function on the gateway page, because it | |
331 | makes a direct call to syscall_trace. */ | |
332 | ||
333 | tracesys_exit: | |
334 | ldo -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1 /* get task ptr */ | |
335 | LDREG TI_TASK(%r1), %r1 | |
413059f2 | 336 | #ifdef CONFIG_64BIT |
1da177e4 LT |
337 | ldo -16(%r30),%r29 /* Reference param save area */ |
338 | #endif | |
339 | bl syscall_trace, %r2 | |
340 | STREG %r28,TASK_PT_GR28(%r1) /* save return value now */ | |
341 | ldo -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1 /* get task ptr */ | |
342 | LDREG TI_TASK(%r1), %r1 | |
343 | LDREG TASK_PT_GR28(%r1), %r28 /* Restore return val. */ | |
344 | ||
345 | ldil L%syscall_exit,%r1 | |
346 | be,n R%syscall_exit(%sr7,%r1) | |
347 | ||
348 | .Ltrace_rt_sigreturn: | |
349 | comib,<> 0,%r25,.Ltrace_in_syscall | |
350 | ldil L%tracesys_sigexit,%r2 | |
351 | be 0(%sr7,%r19) | |
352 | ldo R%tracesys_sigexit(%r2),%r2 | |
353 | ||
354 | tracesys_sigexit: | |
355 | ldo -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1 /* get task ptr */ | |
356 | LDREG 0(%r1), %r1 | |
413059f2 | 357 | #ifdef CONFIG_64BIT |
1da177e4 LT |
358 | ldo -16(%r30),%r29 /* Reference param save area */ |
359 | #endif | |
360 | bl syscall_trace, %r2 | |
361 | nop | |
362 | ||
363 | ldil L%syscall_exit_rfi,%r1 | |
364 | be,n R%syscall_exit_rfi(%sr7,%r1) | |
365 | ||
366 | ||
367 | /********************************************************* | |
c84c3a69 | 368 | 32/64-bit Light-Weight-Syscall ABI |
1da177e4 | 369 | |
c84c3a69 HD |
370 | * - Indicates a hint for userspace inline asm |
371 | implementations. | |
1da177e4 | 372 | |
c84c3a69 HD |
373 | Syscall number (caller-saves) |
374 | - %r20 | |
375 | * In asm clobber. | |
1da177e4 | 376 | |
c84c3a69 HD |
377 | Argument registers (caller-saves) |
378 | - %r26, %r25, %r24, %r23, %r22 | |
379 | * In asm input. | |
380 | ||
381 | Return registers (caller-saves) | |
382 | - %r28 (return), %r21 (errno) | |
383 | * In asm output. | |
384 | ||
385 | Caller-saves registers | |
386 | - %r1, %r27, %r29 | |
387 | - %r2 (return pointer) | |
388 | - %r31 (ble link register) | |
389 | * In asm clobber. | |
390 | ||
391 | Callee-saves registers | |
392 | - %r3-%r18 | |
393 | - %r30 (stack pointer) | |
394 | * Not in asm clobber. | |
395 | ||
396 | If userspace is 32-bit: | |
397 | Callee-saves registers | |
398 | - %r19 (32-bit PIC register) | |
399 | ||
400 | Differences from 32-bit calling convention: | |
401 | - Syscall number in %r20 | |
402 | - Additional argument register %r22 (arg4) | |
403 | - Callee-saves %r19. | |
404 | ||
405 | If userspace is 64-bit: | |
406 | Callee-saves registers | |
407 | - %r27 (64-bit PIC register) | |
408 | ||
409 | Differences from 64-bit calling convention: | |
410 | - Syscall number in %r20 | |
411 | - Additional argument register %r22 (arg4) | |
412 | - Callee-saves %r27. | |
1da177e4 LT |
413 | |
414 | Error codes returned by entry path: | |
415 | ||
416 | ENOSYS - r20 was an invalid LWS number. | |
417 | ||
418 | *********************************************************/ | |
419 | lws_start: | |
420 | /* Gate and ensure we return to userspace */ | |
421 | gate .+8, %r0 | |
422 | depi 3, 31, 2, %r31 /* Ensure we return to userspace */ | |
423 | ||
413059f2 | 424 | #ifdef CONFIG_64BIT |
1da177e4 LT |
425 | /* FIXME: If we are a 64-bit kernel just |
426 | * turn this on unconditionally. | |
427 | */ | |
428 | ssm PSW_SM_W, %r1 | |
429 | extrd,u %r1,PSW_W_BIT,1,%r1 | |
430 | /* sp must be aligned on 4, so deposit the W bit setting into | |
431 | * the bottom of sp temporarily */ | |
432 | or,ev %r1,%r30,%r30 | |
433 | ||
434 | /* Clip LWS number to a 32-bit value always */ | |
435 | depdi 0, 31, 32, %r20 | |
436 | #endif | |
437 | ||
438 | /* Is the lws entry number valid? */ | |
439 | comiclr,>>= __NR_lws_entries, %r20, %r0 | |
440 | b,n lws_exit_nosys | |
441 | ||
442 | /* WARNING: Trashing sr2 and sr3 */ | |
443 | mfsp %sr7,%r1 /* get userspace into sr3 */ | |
444 | mtsp %r1,%sr3 | |
445 | mtsp %r0,%sr2 /* get kernel space into sr2 */ | |
446 | ||
447 | /* Load table start */ | |
448 | ldil L%lws_table, %r1 | |
449 | ldo R%lws_table(%r1), %r28 /* Scratch use of r28 */ | |
450 | LDREGX %r20(%sr2,r28), %r21 /* Scratch use of r21 */ | |
451 | ||
452 | /* Jump to lws, lws table pointers already relocated */ | |
453 | be,n 0(%sr2,%r21) | |
454 | ||
455 | lws_exit_nosys: | |
456 | ldo -ENOSYS(%r0),%r21 /* set errno */ | |
457 | /* Fall through: Return to userspace */ | |
458 | ||
459 | lws_exit: | |
413059f2 | 460 | #ifdef CONFIG_64BIT |
1da177e4 LT |
461 | /* decide whether to reset the wide mode bit |
462 | * | |
463 | * For a syscall, the W bit is stored in the lowest bit | |
464 | * of sp. Extract it and reset W if it is zero */ | |
465 | extrd,u,*<> %r30,63,1,%r1 | |
466 | rsm PSW_SM_W, %r0 | |
467 | /* now reset the lowest bit of sp if it was set */ | |
468 | xor %r30,%r1,%r30 | |
469 | #endif | |
470 | be,n 0(%sr3, %r31) | |
471 | ||
472 | ||
473 | ||
474 | /*************************************************** | |
475 | Implementing CAS as an atomic operation: | |
476 | ||
477 | %r26 - Address to examine | |
478 | %r25 - Old value to check (old) | |
479 | %r24 - New value to set (new) | |
480 | %r28 - Return prev through this register. | |
481 | %r21 - Kernel error code | |
482 | ||
483 | If debugging is DISabled: | |
484 | ||
485 | %r21 has the following meanings: | |
486 | ||
487 | EAGAIN - CAS is busy, ldcw failed, try again. | |
488 | EFAULT - Read or write failed. | |
489 | ||
490 | If debugging is enabled: | |
491 | ||
492 | EDEADLOCK - CAS called recursively. | |
493 | EAGAIN && r28 == 1 - CAS is busy. Lock contended. | |
494 | EAGAIN && r28 == 2 - CAS is busy. ldcw failed. | |
495 | EFAULT - Read or write failed. | |
496 | ||
497 | Scratch: r20, r28, r1 | |
498 | ||
499 | ****************************************************/ | |
500 | ||
501 | /* Do not enable LWS debugging */ | |
502 | #define ENABLE_LWS_DEBUG 0 | |
503 | ||
504 | /* ELF64 Process entry path */ | |
505 | lws_compare_and_swap64: | |
413059f2 | 506 | #ifdef CONFIG_64BIT |
1da177e4 LT |
507 | b,n lws_compare_and_swap |
508 | #else | |
509 | /* If we are not a 64-bit kernel, then we don't | |
c84c3a69 HD |
510 | * have 64-bit input registers, and calling |
511 | * the 64-bit LWS CAS returns ENOSYS. | |
1da177e4 LT |
512 | */ |
513 | b,n lws_exit_nosys | |
514 | #endif | |
515 | ||
516 | /* ELF32 Process entry path */ | |
517 | lws_compare_and_swap32: | |
413059f2 | 518 | #ifdef CONFIG_64BIT |
1da177e4 LT |
519 | /* Clip all the input registers */ |
520 | depdi 0, 31, 32, %r26 | |
521 | depdi 0, 31, 32, %r25 | |
522 | depdi 0, 31, 32, %r24 | |
523 | #endif | |
524 | ||
525 | lws_compare_and_swap: | |
526 | #ifdef CONFIG_SMP | |
527 | /* Load start of lock table */ | |
528 | ldil L%lws_lock_start, %r20 | |
529 | ldo R%lws_lock_start(%r20), %r28 | |
530 | ||
531 | /* Extract four bits from r26 and hash lock (Bits 4-7) */ | |
532 | extru %r26, 27, 4, %r20 | |
533 | ||
534 | /* Find lock to use, the hash is either one of 0 to | |
535 | 15, multiplied by 16 (keep it 16-byte aligned) | |
536 | and add to the lock table offset. */ | |
537 | shlw %r20, 4, %r20 | |
538 | add %r20, %r28, %r20 | |
539 | ||
b5e8b733 | 540 | # if ENABLE_LWS_DEBUG |
1da177e4 LT |
541 | /* |
542 | DEBUG, check for deadlock! | |
543 | If the thread register values are the same | |
544 | then we were the one that locked it last and | |
545 | this is a recurisve call that will deadlock. | |
546 | We *must* giveup this call and fail. | |
547 | */ | |
548 | ldw 4(%sr2,%r20), %r28 /* Load thread register */ | |
aa0eecb0 | 549 | /* WARNING: If cr27 cycles to the same value we have problems */ |
1da177e4 LT |
550 | mfctl %cr27, %r21 /* Get current thread register */ |
551 | cmpb,<>,n %r21, %r28, cas_lock /* Called recursive? */ | |
552 | b lws_exit /* Return error! */ | |
553 | ldo -EDEADLOCK(%r0), %r21 | |
554 | cas_lock: | |
555 | cmpb,=,n %r0, %r28, cas_nocontend /* Is nobody using it? */ | |
556 | ldo 1(%r0), %r28 /* 1st case */ | |
557 | b lws_exit /* Contended... */ | |
558 | ldo -EAGAIN(%r0), %r21 /* Spin in userspace */ | |
559 | cas_nocontend: | |
560 | # endif | |
561 | /* ENABLE_LWS_DEBUG */ | |
562 | ||
64f49532 | 563 | LDCW 0(%sr2,%r20), %r28 /* Try to acquire the lock */ |
1da177e4 LT |
564 | cmpb,<>,n %r0, %r28, cas_action /* Did we get it? */ |
565 | cas_wouldblock: | |
566 | ldo 2(%r0), %r28 /* 2nd case */ | |
567 | b lws_exit /* Contended... */ | |
568 | ldo -EAGAIN(%r0), %r21 /* Spin in userspace */ | |
569 | #endif | |
570 | /* CONFIG_SMP */ | |
571 | ||
572 | /* | |
573 | prev = *addr; | |
574 | if ( prev == old ) | |
575 | *addr = new; | |
576 | return prev; | |
577 | */ | |
578 | ||
579 | /* NOTES: | |
580 | This all works becuse intr_do_signal | |
581 | and schedule both check the return iasq | |
582 | and see that we are on the kernel page | |
583 | so this process is never scheduled off | |
584 | or is ever sent any signal of any sort, | |
585 | thus it is wholly atomic from usrspaces | |
586 | perspective | |
587 | */ | |
588 | cas_action: | |
b5e8b733 | 589 | #if defined CONFIG_SMP && ENABLE_LWS_DEBUG |
1da177e4 LT |
590 | /* DEBUG */ |
591 | mfctl %cr27, %r1 | |
592 | stw %r1, 4(%sr2,%r20) | |
593 | #endif | |
594 | /* The load and store could fail */ | |
595 | 1: ldw 0(%sr3,%r26), %r28 | |
596 | sub,<> %r28, %r25, %r0 | |
597 | 2: stw %r24, 0(%sr3,%r26) | |
598 | #ifdef CONFIG_SMP | |
599 | /* Free lock */ | |
600 | stw %r20, 0(%sr2,%r20) | |
b5e8b733 | 601 | # if ENABLE_LWS_DEBUG |
1da177e4 LT |
602 | /* Clear thread register indicator */ |
603 | stw %r0, 4(%sr2,%r20) | |
604 | # endif | |
605 | #endif | |
606 | /* Return to userspace, set no error */ | |
607 | b lws_exit | |
608 | copy %r0, %r21 | |
609 | ||
610 | 3: | |
611 | /* Error occured on load or store */ | |
612 | #ifdef CONFIG_SMP | |
613 | /* Free lock */ | |
614 | stw %r20, 0(%sr2,%r20) | |
b5e8b733 | 615 | # if ENABLE_LWS_DEBUG |
1da177e4 LT |
616 | stw %r0, 4(%sr2,%r20) |
617 | # endif | |
618 | #endif | |
619 | b lws_exit | |
620 | ldo -EFAULT(%r0),%r21 /* set errno */ | |
621 | nop | |
622 | nop | |
623 | nop | |
624 | nop | |
625 | ||
626 | /* Two exception table entries, one for the load, | |
627 | the other for the store. Either return -EFAULT. | |
628 | Each of the entries must be relocated. */ | |
629 | .section __ex_table,"aw" | |
0b3d643f HD |
630 | ASM_ULONG_INSN (1b - linux_gateway_page), (3b - linux_gateway_page) |
631 | ASM_ULONG_INSN (2b - linux_gateway_page), (3b - linux_gateway_page) | |
1da177e4 LT |
632 | .previous |
633 | ||
1da177e4 LT |
634 | |
635 | /* Make sure nothing else is placed on this page */ | |
1c593571 | 636 | .align PAGE_SIZE |
8e9e9844 HD |
637 | END(linux_gateway_page) |
638 | ENTRY(end_linux_gateway_page) | |
1da177e4 LT |
639 | |
640 | /* Relocate symbols assuming linux_gateway_page is mapped | |
641 | to virtual address 0x0 */ | |
8e9e9844 | 642 | |
0b3d643f | 643 | #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page) |
1da177e4 | 644 | |
1bcdd854 HD |
645 | .section .rodata,"a" |
646 | ||
1c593571 | 647 | .align PAGE_SIZE |
1da177e4 LT |
648 | /* Light-weight-syscall table */ |
649 | /* Start of lws table. */ | |
8e9e9844 | 650 | ENTRY(lws_table) |
1da177e4 LT |
651 | LWS_ENTRY(compare_and_swap32) /* 0 - ELF32 Atomic compare and swap */ |
652 | LWS_ENTRY(compare_and_swap64) /* 1 - ELF64 Atomic compare and swap */ | |
8e9e9844 | 653 | END(lws_table) |
1da177e4 LT |
654 | /* End of lws table */ |
655 | ||
1c593571 | 656 | .align PAGE_SIZE |
8e9e9844 | 657 | ENTRY(sys_call_table) |
1da177e4 | 658 | #include "syscall_table.S" |
8e9e9844 | 659 | END(sys_call_table) |
1da177e4 | 660 | |
413059f2 | 661 | #ifdef CONFIG_64BIT |
1c593571 | 662 | .align PAGE_SIZE |
8e9e9844 | 663 | ENTRY(sys_call_table64) |
1da177e4 LT |
664 | #define SYSCALL_TABLE_64BIT |
665 | #include "syscall_table.S" | |
8e9e9844 | 666 | END(sys_call_table64) |
1da177e4 LT |
667 | #endif |
668 | ||
669 | #ifdef CONFIG_SMP | |
670 | /* | |
671 | All light-weight-syscall atomic operations | |
672 | will use this set of locks | |
c84c3a69 HD |
673 | |
674 | NOTE: The lws_lock_start symbol must be | |
675 | at least 16-byte aligned for safe use | |
676 | with ldcw. | |
1da177e4 | 677 | */ |
dfcf753b | 678 | .section .data |
873d50e2 | 679 | .align PAGE_SIZE |
8e9e9844 | 680 | ENTRY(lws_lock_start) |
1da177e4 | 681 | /* lws locks */ |
1da177e4 LT |
682 | .rept 16 |
683 | /* Keep locks aligned at 16-bytes */ | |
684 | .word 1 | |
685 | .word 0 | |
686 | .word 0 | |
687 | .word 0 | |
688 | .endr | |
8e9e9844 | 689 | END(lws_lock_start) |
1da177e4 LT |
690 | .previous |
691 | #endif | |
692 | /* CONFIG_SMP for lws_lock_start */ | |
693 | ||
694 | .end | |
695 | ||
696 |