[mirror_ubuntu-focal-kernel.git] / arch / powerpc / kernel / vmlinux.lds.S

/* SPDX-License-Identifier: GPL-2.0 */
#ifdef CONFIG_PPC64
#define PROVIDE32(x)	PROVIDE(__unused__##x)
#else
#define PROVIDE32(x)	PROVIDE(x)
#endif

#define BSS_FIRST_SECTIONS *(.bss.prominit)

#include <asm/page.h>
#include <asm-generic/vmlinux.lds.h>
#include <asm/cache.h>
#include <asm/thread_info.h>

#define STRICT_ALIGN_SIZE	(1 << CONFIG_DATA_SHIFT)
#define ETEXT_ALIGN_SIZE	(1 << CONFIG_ETEXT_SHIFT)

ENTRY(_stext)

PHDRS {
	kernel PT_LOAD FLAGS(7); /* RWX */
	notes PT_NOTE FLAGS(0);
	dummy PT_NOTE FLAGS(0);

	/* binutils < 2.18 has a bug that makes it misbehave when taking an
	   ELF file with all segments at load address 0 as input.  This
	   happens when running "strip" on vmlinux, because of the AT() magic
	   in this linker script.  People using GCC >= 4.2 won't run into
	   this problem, because the "build-id" support will put some data
	   into the "notes" segment (at a non-zero load address).

	   To work around this, we force some data into both the "dummy"
	   segment and the kernel segment, so the dummy segment will get a
	   non-zero load address.  It's not enough to always create the
	   "notes" segment, since if nothing gets assigned to it, its load
	   address will be zero.  */
}

#ifdef CONFIG_PPC64
OUTPUT_ARCH(powerpc:common64)
jiffies = jiffies_64;
#else
OUTPUT_ARCH(powerpc:common)
jiffies = jiffies_64 + 4;
#endif
SECTIONS
{
	. = KERNELBASE;

/*
 * Text, read only data and other permanent read-only sections
 */

	_text = .;
	_stext = .;

	/*
	 * Head text.
	 * This needs to be in its own output section to avoid ld placing
	 * branch trampoline stubs randomly throughout the fixed sections,
	 * which it will do (even if the branch comes from another section)
	 * in order to optimize stub generation.
	 */
	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
#ifdef CONFIG_PPC64
		KEEP(*(.head.text.first_256B));
#ifdef CONFIG_PPC_BOOK3E
#else
		KEEP(*(.head.text.real_vectors));
		*(.head.text.real_trampolines);
		KEEP(*(.head.text.virt_vectors));
		*(.head.text.virt_trampolines);
# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
		KEEP(*(.head.data.fwnmi_page));
# endif
#endif
#else /* !CONFIG_PPC64 */
		HEAD_TEXT
#endif
	} :kernel

	__head_end = .;

#ifdef CONFIG_PPC64
	/*
	 * ALIGN(0) overrides the default output section alignment because
	 * this needs to start right after .head.text in order for fixed
	 * section placement to work.
	 */
	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
#ifdef CONFIG_LD_HEAD_STUB_CATCH
		KEEP(*(.linker_stub_catch));
		. = . ;
#endif

#else
	.text : AT(ADDR(.text) - LOAD_OFFSET) {
		ALIGN_FUNCTION();
#endif
		/* careful! __ftr_alt_* sections need to be close to .text */
		*(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.text);
#endif
		NOINSTR_TEXT
		SCHED_TEXT
		CPUIDLE_TEXT
		LOCK_TEXT
		KPROBES_TEXT
		IRQENTRY_TEXT
		SOFTIRQENTRY_TEXT
		/*
		 * -Os builds call FP save/restore functions. The powerpc64
		 * linker generates those on demand in the .sfpr section.
		 * .sfpr gets placed at the beginning of a group of input
		 * sections, which can break start-of-text offset if it is
		 * included with the main text sections, so put it by itself.
		 */
		*(.sfpr);
		MEM_KEEP(init.text)
		MEM_KEEP(exit.text)

#ifdef CONFIG_PPC32
		*(.got1)
		__got2_start = .;
		*(.got2)
		__got2_end = .;
#endif /* CONFIG_PPC32 */

	} :kernel

	. = ALIGN(ETEXT_ALIGN_SIZE);
	_etext = .;
	PROVIDE32 (etext = .);

	/* Read-only data */
	RO_DATA(PAGE_SIZE)

#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_entry_barrier_fixup = .;
		*(__stf_entry_barrier_fixup)
		__stop___stf_entry_barrier_fixup = .;
	}

	. = ALIGN(8);
	__uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
		__start___uaccess_flush_fixup = .;
		*(__uaccess_flush_fixup)
		__stop___uaccess_flush_fixup = .;
	}

	. = ALIGN(8);
	__entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
		__start___entry_flush_fixup = .;
		*(__entry_flush_fixup)
		__stop___entry_flush_fixup = .;
	}

	. = ALIGN(8);
	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_exit_barrier_fixup = .;
		*(__stf_exit_barrier_fixup)
		__stop___stf_exit_barrier_fixup = .;
	}

	. = ALIGN(8);
	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
		__start___rfi_flush_fixup = .;
		*(__rfi_flush_fixup)
		__stop___rfi_flush_fixup = .;
	}
#endif /* CONFIG_PPC64 */

#ifdef CONFIG_PPC_BARRIER_NOSPEC
	. = ALIGN(8);
	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
		__start___barrier_nospec_fixup = .;
		*(__barrier_nospec_fixup)
		__stop___barrier_nospec_fixup = .;
	}
#endif /* CONFIG_PPC_BARRIER_NOSPEC */

#ifdef CONFIG_PPC_FSL_BOOK3E
	. = ALIGN(8);
	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
		__start__btb_flush_fixup = .;
		*(__btb_flush_fixup)
		__stop__btb_flush_fixup = .;
	}
#endif
	EXCEPTION_TABLE(0)

	NOTES :kernel :notes

	/* The dummy segment contents for the bug workaround mentioned above
	   near PHDRS.  */
	.dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
		LONG(0)
		LONG(0)
		LONG(0)
	} :kernel :dummy

/*
 * Init sections discarded at runtime
 */
	. = ALIGN(STRICT_ALIGN_SIZE);
	__init_begin = .;
	. = ALIGN(PAGE_SIZE);
	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
		_sinittext = .;
		INIT_TEXT

		/*
		 *.init.text might be RO so we must ensure this section ends on
		 * a page boundary.
		 */
		. = ALIGN(PAGE_SIZE);
		_einittext = .;
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.init);
#endif
	} :kernel

	/* .exit.text is discarded at runtime, not link time,
	 * to deal with references from __bug_table
	 */
	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
		EXIT_TEXT
	}

	. = ALIGN(PAGE_SIZE);

	INIT_DATA_SECTION(16)

	. = ALIGN(8);
	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
		__start___ftr_fixup = .;
		KEEP(*(__ftr_fixup))
		__stop___ftr_fixup = .;
	}
	. = ALIGN(8);
	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
		__start___mmu_ftr_fixup = .;
		KEEP(*(__mmu_ftr_fixup))
		__stop___mmu_ftr_fixup = .;
	}
	. = ALIGN(8);
	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
		__start___lwsync_fixup = .;
		KEEP(*(__lwsync_fixup))
		__stop___lwsync_fixup = .;
	}
#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
		__start___fw_ftr_fixup = .;
		KEEP(*(__fw_ftr_fixup))
		__stop___fw_ftr_fixup = .;
	}
#endif

	PERCPU_SECTION(L1_CACHE_BYTES)

	. = ALIGN(8);
	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
		__machine_desc_start = . ;
		KEEP(*(.machine.desc))
		__machine_desc_end = . ;
	}
#ifdef CONFIG_RELOCATABLE
	. = ALIGN(8);
	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
	{
#ifdef CONFIG_PPC32
		__dynamic_symtab = .;
#endif
		*(.dynsym)
	}
	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	{
		__dynamic_start = .;
		*(.dynamic)
	}
	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	{
		__rela_dyn_start = .;
		*(.rela*)
	}
#endif
	/* .exit.data is discarded at runtime, not link time,
	 * to deal with references from .exit.text
	 */
	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
		EXIT_DATA
	}

	/* freed after init ends here */
	. = ALIGN(PAGE_SIZE);
	__init_end = .;

/*
 * And now the various read/write data
 */

	. = ALIGN(PAGE_SIZE);
	_sdata = .;

#ifdef CONFIG_PPC32
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
#ifdef CONFIG_UBSAN
		*(.data..Lubsan_data*)
		*(.data..Lubsan_type*)
#endif
		*(.data.rel*)
		*(SDATA_MAIN)
		*(.sdata2)
		*(.got.plt) *(.got)
		*(.plt)
		*(.branch_lt)
	}
#else
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
		*(.data.rel*)
		*(.toc1)
		*(.branch_lt)
	}

	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
		__start_opd = .;
		KEEP(*(.opd))
		__end_opd = .;
	}

	. = ALIGN(256);
	.got : AT(ADDR(.got) - LOAD_OFFSET) {
		__toc_start = .;
#ifndef CONFIG_RELOCATABLE
		__prom_init_toc_start = .;
		arch/powerpc/kernel/prom_init.o*(.toc .got)
		__prom_init_toc_end = .;
#endif
		*(.got)
		*(.toc)
	}
#endif

	/* The initial task and kernel stack */
	INIT_TASK_DATA_SECTION(THREAD_SIZE)

	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
		PAGE_ALIGNED_DATA(PAGE_SIZE)
	}

	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
	}

	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
		READ_MOSTLY_DATA(L1_CACHE_BYTES)
	}

	. = ALIGN(PAGE_SIZE);
	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
		NOSAVE_DATA
	}

	BUG_TABLE

	. = ALIGN(PAGE_SIZE);
	_edata  =  .;
	PROVIDE32 (edata = .);

/*
 * And finally the bss
 */

	BSS_SECTION(0, 0, 0)

	. = ALIGN(PAGE_SIZE);
	_end = . ;
	PROVIDE32 (end = .);

	STABS_DEBUG

	DWARF_DEBUG

	DISCARDS
	/DISCARD/ : {
		*(*.EMB.apuinfo)
		*(.glink .iplt .plt .rela* .comment)
		*(.gnu.version*)
		*(.gnu.attributes)
		*(.eh_frame)
	}
}
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
c51e3a41	2	#ifdef CONFIG_PPC64
e8222502	3	#define PROVIDE32(x) PROVIDE(__unused__##x)
c51e3a41	4	#else
e8222502	5	#define PROVIDE32(x) PROVIDE(x)
c51e3a41	6	#endif
5f69e388 BH	7
	8	#define BSS_FIRST_SECTIONS *(.bss.prominit)
	9
4846c5de	10	#include <asm/page.h>
14cf11af	11	#include <asm-generic/vmlinux.lds.h>
bd67fcf9	12	#include <asm/cache.h>
62bef288	13	#include <asm/thread_info.h>
14cf11af	14
166d97d9 CL	15	#define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT)
166d97d9 CL	16	#define ETEXT_ALIGN_SIZE (1 << CONFIG_ETEXT_SHIFT)
d924cc3f	17
e19e4ab4 ME	18	ENTRY(_stext)
e19e4ab4 ME	19
c69cccc9 SB	20	PHDRS {
	21	kernel PT_LOAD FLAGS(7); /* RWX */
	22	notes PT_NOTE FLAGS(0);
	23	dummy PT_NOTE FLAGS(0);
	24
	25	/* binutils < 2.18 has a bug that makes it misbehave when taking an
	26	ELF file with all segments at load address 0 as input. This
	27	happens when running "strip" on vmlinux, because of the AT() magic
	28	in this linker script. People using GCC >= 4.2 won't run into
	29	this problem, because the "build-id" support will put some data
	30	into the "notes" segment (at a non-zero load address).
	31
	32	To work around this, we force some data into both the "dummy"
	33	segment and the kernel segment, so the dummy segment will get a
	34	non-zero load address. It's not enough to always create the
	35	"notes" segment, since if nothing gets assigned to it, its load
	36	address will be zero. */
	37	}
	38
cabb5587 SR	39	#ifdef CONFIG_PPC64
	40	OUTPUT_ARCH(powerpc:common64)
	41	jiffies = jiffies_64;
	42	#else
14cf11af PM	43	OUTPUT_ARCH(powerpc:common)
14cf11af PM	44	jiffies = jiffies_64 + 4;
cabb5587	45	#endif
14cf11af PM	46	SECTIONS
14cf11af PM	47	{
e8222502	48	. = KERNELBASE;
14cf11af	49
e8222502 BH	50	/*
	51	* Text, read only data and other permanent read-only sections
	52	*/
	53
57f26649 NP	54	_text = .;
	55	_stext = .;
	56
	57	/*
	58	* Head text.
	59	* This needs to be in its own output section to avoid ld placing
	60	* branch trampoline stubs randomly throughout the fixed sections,
	61	* which it will do (even if the branch comes from another section)
	62	* in order to optimize stub generation.
	63	*/
	64	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
	65	#ifdef CONFIG_PPC64
	66	KEEP(*(.head.text.first_256B));
	67	#ifdef CONFIG_PPC_BOOK3E
57f26649 NP	68	#else
	69	KEEP(*(.head.text.real_vectors));
	70	*(.head.text.real_trampolines);
	71	KEEP(*(.head.text.virt_vectors));
	72	*(.head.text.virt_trampolines);
	73	# if defined(CONFIG_PPC_PSERIES) \|\| defined(CONFIG_PPC_POWERNV)
	74	KEEP(*(.head.data.fwnmi_page));
57f26649 NP	75	# endif
57f26649 NP	76	#endif
57f26649 NP	77	#else /* !CONFIG_PPC64 */
	78	HEAD_TEXT
	79	#endif
	80	} :kernel
	81
7aa5b018 NR	82	__head_end = .;
7aa5b018 NR	83
dadc4a1b NP	84	#ifdef CONFIG_PPC64
dadc4a1b NP	85	/*
a652758a	86	* ALIGN(0) overrides the default output section alignment because
dadc4a1b NP	87	* this needs to start right after .head.text in order for fixed
	88	* section placement to work.
	89	*/
a652758a	90	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
951eedeb	91	#ifdef CONFIG_LD_HEAD_STUB_CATCH
4c1d9bb0	92	KEEP(*(.linker_stub_catch));
951eedeb NP	93	. = . ;
	94	#endif
	95
dadc4a1b	96	#else
366234f6	97	.text : AT(ADDR(.text) - LOAD_OFFSET) {
748a7683	98	ALIGN_FUNCTION();
dadc4a1b	99	#endif
13beadd9	100	/* careful! __ftr_alt_* sections need to be close to .text */
1188ad81	101	(.text.hot .text.hot. TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
67361cf8 NR	102	#ifdef CONFIG_PPC64
	103	*(.tramp.ftrace.text);
	104	#endif
a971cfbb	105	NOINSTR_TEXT
e8222502	106	SCHED_TEXT
6727ad9e	107	CPUIDLE_TEXT
e8222502 BH	108	LOCK_TEXT
e8222502 BH	109	KPROBES_TEXT
6794c782	110	IRQENTRY_TEXT
be7635e7	111	SOFTIRQENTRY_TEXT
e8c68825 NP	112	/*
	113	* -Os builds call FP save/restore functions. The powerpc64
	114	* linker generates those on demand in the .sfpr section.
	115	* .sfpr gets placed at the beginning of a group of input
	116	* sections, which can break start-of-text offset if it is
	117	* included with the main text sections, so put it by itself.
	118	*/
	119	*(.sfpr);
7de3b27b ME	120	MEM_KEEP(init.text)
7de3b27b ME	121	MEM_KEEP(exit.text)
14cf11af	122
e8222502 BH	123	#ifdef CONFIG_PPC32
	124	*(.got1)
	125	__got2_start = .;
	126	*(.got2)
	127	__got2_end = .;
	128	#endif /* CONFIG_PPC32 */
	129
c69cccc9	130	} :kernel
e8222502	131
166d97d9	132	. = ALIGN(ETEXT_ALIGN_SIZE);
303996da SR	133	_etext = .;
	134	PROVIDE32 (etext = .);
	135
e8222502	136	/* Read-only data */
d924cc3f	137	RO_DATA(PAGE_SIZE)
e8222502	138
aa8a5e00	139	#ifdef CONFIG_PPC64
a048a07d NP	140	. = ALIGN(8);
	141	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
	142	__start___stf_entry_barrier_fixup = .;
	143	*(__stf_entry_barrier_fixup)
	144	__stop___stf_entry_barrier_fixup = .;
	145	}
	146
02c8606e NP	147	. = ALIGN(8);
	148	__uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
	149	__start___uaccess_flush_fixup = .;
	150	*(__uaccess_flush_fixup)
	151	__stop___uaccess_flush_fixup = .;
	152	}
	153
94ad55a1 NP	154	. = ALIGN(8);
	155	__entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
	156	__start___entry_flush_fixup = .;
	157	*(__entry_flush_fixup)
	158	__stop___entry_flush_fixup = .;
	159	}
	160
a048a07d NP	161	. = ALIGN(8);
	162	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
	163	__start___stf_exit_barrier_fixup = .;
	164	*(__stf_exit_barrier_fixup)
	165	__stop___stf_exit_barrier_fixup = .;
	166	}
	167
aa8a5e00 ME	168	. = ALIGN(8);
	169	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
	170	__start___rfi_flush_fixup = .;
	171	*(__rfi_flush_fixup)
	172	__stop___rfi_flush_fixup = .;
	173	}
179ab1cb	174	#endif /* CONFIG_PPC64 */
2eea7f06	175
179ab1cb	176	#ifdef CONFIG_PPC_BARRIER_NOSPEC
2eea7f06 MS	177	. = ALIGN(8);
	178	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
	179	__start___barrier_nospec_fixup = .;
	180	*(__barrier_nospec_fixup)
	181	__stop___barrier_nospec_fixup = .;
	182	}
179ab1cb	183	#endif /* CONFIG_PPC_BARRIER_NOSPEC */
aa8a5e00	184
76a5eaa3 DC	185	#ifdef CONFIG_PPC_FSL_BOOK3E
	186	. = ALIGN(8);
	187	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
	188	__start__btb_flush_fixup = .;
	189	*(__btb_flush_fixup)
	190	__stop__btb_flush_fixup = .;
	191	}
	192	#endif
62bef288	193	EXCEPTION_TABLE(0)
14cf11af	194
c69cccc9 SB	195	NOTES :kernel :notes
	196
	197	/* The dummy segment contents for the bug workaround mentioned above
	198	near PHDRS. */
80c60bf9	199	.dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
e16459c6 MM	200	LONG(0)
	201	LONG(0)
	202	LONG(0)
c69cccc9	203	} :kernel :dummy
8fb775ee	204
e8222502 BH	205	/*
	206	* Init sections discarded at runtime
	207	*/
d924cc3f	208	. = ALIGN(STRICT_ALIGN_SIZE);
e8222502	209	__init_begin = .;
67361cf8 NR	210	. = ALIGN(PAGE_SIZE);
	211	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
	212	_sinittext = .;
	213	INIT_TEXT
1b07618f AM	214
	215	/*
	216	*.init.text might be RO so we must ensure this section ends on
	217	* a page boundary.
	218	*/
	219	. = ALIGN(PAGE_SIZE);
67361cf8 NR	220	_einittext = .;
	221	#ifdef CONFIG_PPC64
	222	*(.tramp.ftrace.init);
	223	#endif
	224	} :kernel
e8222502 BH	225
	226	/* .exit.text is discarded at runtime, not link time,
	227	* to deal with references from __bug_table
	228	*/
366234f6	229	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
01ba2bdc SR	230	EXIT_TEXT
01ba2bdc SR	231	}
e8222502	232
1b07618f AM	233	. = ALIGN(PAGE_SIZE);
1b07618f AM	234
cfa540d0	235	INIT_DATA_SECTION(16)
e8222502	236
e8222502	237	. = ALIGN(8);
366234f6	238	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
cabb5587	239	__start___ftr_fixup = .;
4c1d9bb0	240	KEEP(*(__ftr_fixup))
cabb5587 SR	241	__stop___ftr_fixup = .;
cabb5587 SR	242	}
2d1b2027	243	. = ALIGN(8);
7c03d653 BH	244	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
7c03d653 BH	245	__start___mmu_ftr_fixup = .;
4c1d9bb0	246	KEEP(*(__mmu_ftr_fixup))
7c03d653 BH	247	__stop___mmu_ftr_fixup = .;
	248	}
	249	. = ALIGN(8);
2d1b2027 KG	250	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
2d1b2027 KG	251	__start___lwsync_fixup = .;
4c1d9bb0	252	KEEP(*(__lwsync_fixup))
2d1b2027 KG	253	__stop___lwsync_fixup = .;
2d1b2027 KG	254	}
3f639ee8 SR	255	#ifdef CONFIG_PPC64
3f639ee8 SR	256	. = ALIGN(8);
366234f6	257	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
3f639ee8	258	__start___fw_ftr_fixup = .;
4c1d9bb0	259	KEEP(*(__fw_ftr_fixup))
3f639ee8 SR	260	__stop___fw_ftr_fixup = .;
	261	}
	262	#endif
62bef288	263
0415b00d	264	PERCPU_SECTION(L1_CACHE_BYTES)
14cf11af	265
e8222502	266	. = ALIGN(8);
366234f6	267	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
e8222502	268	__machine_desc_start = . ;
4c1d9bb0	269	KEEP(*(.machine.desc))
e8222502 BH	270	__machine_desc_end = . ;
e8222502 BH	271	}
2a4b9c5a	272	#ifdef CONFIG_RELOCATABLE
549e8152	273	. = ALIGN(8);
9c5f7d39 SP	274	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
9c5f7d39 SP	275	{
27d11496	276	#ifdef CONFIG_PPC32
9c5f7d39 SP	277	__dynamic_symtab = .;
	278	#endif
	279	*(.dynsym)
	280	}
549e8152 PM	281	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	282	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	283	{
	284	__dynamic_start = .;
	285	*(.dynamic)
	286	}
	287	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
	288	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	289	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	290	{
	291	__rela_dyn_start = .;
	292	(.rela)
	293	}
2a4b9c5a	294	#endif
4c812318 SR	295	/* .exit.data is discarded at runtime, not link time,
	296	* to deal with references from .exit.text
	297	*/
	298	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
	299	EXIT_DATA
	300	}
e8222502 BH	301
	302	/* freed after init ends here */
	303	. = ALIGN(PAGE_SIZE);
	304	__init_end = .;
	305
	306	/*
	307	* And now the various read/write data
	308	*/
	309
	310	. = ALIGN(PAGE_SIZE);
	311	_sdata = .;
14cf11af	312
cabb5587	313	#ifdef CONFIG_PPC32
366234f6	314	.data : AT(ADDR(.data) - LOAD_OFFSET) {
ca967258	315	DATA_DATA
beba24ac MM	316	#ifdef CONFIG_UBSAN
	317	(.data..Lubsan_data)
	318	(.data..Lubsan_type)
	319	#endif
a1072607	320	(.data.rel)
4c1d9bb0	321	*(SDATA_MAIN)
83a092cf	322	*(.sdata2)
e8222502	323	(.got.plt) (.got)
83a092cf	324	*(.plt)
98ecc676	325	*(.branch_lt)
e8222502	326	}
cabb5587	327	#else
366234f6	328	.data : AT(ADDR(.data) - LOAD_OFFSET) {
3ae0aa9f MD	329	DATA_DATA
	330	(.data.rel)
	331	*(.toc1)
e8222502 BH	332	*(.branch_lt)
e8222502 BH	333	}
14cf11af	334
366234f6	335	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
5633e85b	336	__start_opd = .;
4c1d9bb0	337	KEEP(*(.opd))
5633e85b	338	__end_opd = .;
e8222502 BH	339	}
e8222502 BH	340
5e95235c	341	. = ALIGN(256);
366234f6	342	.got : AT(ADDR(.got) - LOAD_OFFSET) {
e8222502	343	__toc_start = .;
5ac47f7a AB	344	#ifndef CONFIG_RELOCATABLE
	345	__prom_init_toc_start = .;
	346	arch/powerpc/kernel/prom_init.o*(.toc .got)
	347	__prom_init_toc_end = .;
	348	#endif
e8222502 BH	349	*(.got)
	350	*(.toc)
	351	}
cabb5587	352	#endif
14cf11af	353
e8222502	354	/* The initial task and kernel stack */
2af7687f	355	INIT_TASK_DATA_SECTION(THREAD_SIZE)
14cf11af	356
75b13483	357	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
62bef288	358	PAGE_ALIGNED_DATA(PAGE_SIZE)
e8222502	359	}
14cf11af	360
4af57b78	361	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
62bef288	362	CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
e8222502	363	}
14cf11af	364
54cb27a7	365	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
62bef288	366	READ_MOSTLY_DATA(L1_CACHE_BYTES)
bd67fcf9 TB	367	}
bd67fcf9 TB	368
5be2a213	369	. = ALIGN(PAGE_SIZE);
366234f6	370	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
62bef288	371	NOSAVE_DATA
e8222502	372	}
4a288563	373
b5effd38 PZ	374	BUG_TABLE
b5effd38 PZ	375
903444e4 ME	376	. = ALIGN(PAGE_SIZE);
	377	_edata = .;
	378	PROVIDE32 (edata = .);
	379
e8222502 BH	380	/*
	381	* And finally the bss
	382	*/
	383
62bef288	384	BSS_SECTION(0, 0, 0)
14cf11af	385
e8222502 BH	386	. = ALIGN(PAGE_SIZE);
	387	_end = . ;
	388	PROVIDE32 (end = .);
023bf6f1	389
83a092cf NP	390	STABS_DEBUG
	391
	392	DWARF_DEBUG
	393
023bf6f1	394	DISCARDS
83a092cf NP	395	/DISCARD/ : {
	396	(.EMB.apuinfo)
	397	(.glink .iplt .plt .rela .comment)
	398	(.gnu.version)
	399	*(.gnu.attributes)
	400	*(.eh_frame)
	401	}
14cf11af	402	}