[mirror_ubuntu-hirsute-kernel.git] / arch / powerpc / kernel / vmlinux.lds.S

/* SPDX-License-Identifier: GPL-2.0 */
#ifdef CONFIG_PPC64
#define PROVIDE32(x)	PROVIDE(__unused__##x)
#else
#define PROVIDE32(x)	PROVIDE(x)
#endif

#define BSS_FIRST_SECTIONS *(.bss.prominit)
#define EMITS_PT_NOTE
#define RO_EXCEPTION_TABLE_ALIGN	0

#include <asm/page.h>
#include <asm-generic/vmlinux.lds.h>
#include <asm/cache.h>
#include <asm/thread_info.h>

#define STRICT_ALIGN_SIZE	(1 << CONFIG_DATA_SHIFT)

ENTRY(_stext)

PHDRS {
	text PT_LOAD FLAGS(7); /* RWX */
	note PT_NOTE FLAGS(0);
}

#ifdef CONFIG_PPC64
OUTPUT_ARCH(powerpc:common64)
jiffies = jiffies_64;
#else
OUTPUT_ARCH(powerpc:common)
jiffies = jiffies_64 + 4;
#endif
SECTIONS
{
	. = KERNELBASE;

/*
 * Text, read only data and other permanent read-only sections
 */

	_text = .;
	_stext = .;

	/*
	 * Head text.
	 * This needs to be in its own output section to avoid ld placing
	 * branch trampoline stubs randomly throughout the fixed sections,
	 * which it will do (even if the branch comes from another section)
	 * in order to optimize stub generation.
	 */
	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
#ifdef CONFIG_PPC64
		KEEP(*(.head.text.first_256B));
#ifdef CONFIG_PPC_BOOK3E
#else
		KEEP(*(.head.text.real_vectors));
		*(.head.text.real_trampolines);
		KEEP(*(.head.text.virt_vectors));
		*(.head.text.virt_trampolines);
# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
		KEEP(*(.head.data.fwnmi_page));
# endif
#endif
#else /* !CONFIG_PPC64 */
		HEAD_TEXT
#endif
	} :text

	__head_end = .;

#ifdef CONFIG_PPC64
	/*
	 * ALIGN(0) overrides the default output section alignment because
	 * this needs to start right after .head.text in order for fixed
	 * section placement to work.
	 */
	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
#ifdef CONFIG_LD_HEAD_STUB_CATCH
		KEEP(*(.linker_stub_catch));
		. = . ;
#endif

#else
	.text : AT(ADDR(.text) - LOAD_OFFSET) {
		ALIGN_FUNCTION();
#endif
		/* careful! __ftr_alt_* sections need to be close to .text */
		*(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.text);
#endif
		NOINSTR_TEXT
		SCHED_TEXT
		CPUIDLE_TEXT
		LOCK_TEXT
		KPROBES_TEXT
		IRQENTRY_TEXT
		SOFTIRQENTRY_TEXT
		/*
		 * -Os builds call FP save/restore functions. The powerpc64
		 * linker generates those on demand in the .sfpr section.
		 * .sfpr gets placed at the beginning of a group of input
		 * sections, which can break start-of-text offset if it is
		 * included with the main text sections, so put it by itself.
		 */
		*(.sfpr);
		MEM_KEEP(init.text)
		MEM_KEEP(exit.text)

#ifdef CONFIG_PPC32
		*(.got1)
		__got2_start = .;
		*(.got2)
		__got2_end = .;
#endif /* CONFIG_PPC32 */

	} :text

	. = ALIGN(PAGE_SIZE);
	_etext = .;
	PROVIDE32 (etext = .);

	/* Read-only data */
	RO_DATA(PAGE_SIZE)

#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_entry_barrier_fixup = .;
		*(__stf_entry_barrier_fixup)
		__stop___stf_entry_barrier_fixup = .;
	}

	. = ALIGN(8);
	__uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
		__start___uaccess_flush_fixup = .;
		*(__uaccess_flush_fixup)
		__stop___uaccess_flush_fixup = .;
	}

	. = ALIGN(8);
	__entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
		__start___entry_flush_fixup = .;
		*(__entry_flush_fixup)
		__stop___entry_flush_fixup = .;
	}

	. = ALIGN(8);
	__scv_entry_flush_fixup : AT(ADDR(__scv_entry_flush_fixup) - LOAD_OFFSET) {
		__start___scv_entry_flush_fixup = .;
		*(__scv_entry_flush_fixup)
		__stop___scv_entry_flush_fixup = .;
	}

	. = ALIGN(8);
	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_exit_barrier_fixup = .;
		*(__stf_exit_barrier_fixup)
		__stop___stf_exit_barrier_fixup = .;
	}

	. = ALIGN(8);
	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
		__start___rfi_flush_fixup = .;
		*(__rfi_flush_fixup)
		__stop___rfi_flush_fixup = .;
	}
#endif /* CONFIG_PPC64 */

#ifdef CONFIG_PPC_BARRIER_NOSPEC
	. = ALIGN(8);
	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
		__start___barrier_nospec_fixup = .;
		*(__barrier_nospec_fixup)
		__stop___barrier_nospec_fixup = .;
	}
#endif /* CONFIG_PPC_BARRIER_NOSPEC */

#ifdef CONFIG_PPC_FSL_BOOK3E
	. = ALIGN(8);
	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
		__start__btb_flush_fixup = .;
		*(__btb_flush_fixup)
		__stop__btb_flush_fixup = .;
	}
#endif

/*
 * Init sections discarded at runtime
 */
	. = ALIGN(STRICT_ALIGN_SIZE);
	__init_begin = .;
	. = ALIGN(PAGE_SIZE);
	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
		_sinittext = .;
		INIT_TEXT

		/*
		 *.init.text might be RO so we must ensure this section ends on
		 * a page boundary.
		 */
		. = ALIGN(PAGE_SIZE);
		_einittext = .;
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.init);
#endif
	} :text

	/* .exit.text is discarded at runtime, not link time,
	 * to deal with references from __bug_table
	 */
	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
		EXIT_TEXT
	}

	. = ALIGN(PAGE_SIZE);

	INIT_DATA_SECTION(16)

	. = ALIGN(8);
	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
		__start___ftr_fixup = .;
		KEEP(*(__ftr_fixup))
		__stop___ftr_fixup = .;
	}
	. = ALIGN(8);
	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
		__start___mmu_ftr_fixup = .;
		KEEP(*(__mmu_ftr_fixup))
		__stop___mmu_ftr_fixup = .;
	}
	. = ALIGN(8);
	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
		__start___lwsync_fixup = .;
		KEEP(*(__lwsync_fixup))
		__stop___lwsync_fixup = .;
	}
#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
		__start___fw_ftr_fixup = .;
		KEEP(*(__fw_ftr_fixup))
		__stop___fw_ftr_fixup = .;
	}
#endif

	PERCPU_SECTION(L1_CACHE_BYTES)

	. = ALIGN(8);
	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
		__machine_desc_start = . ;
		KEEP(*(.machine.desc))
		__machine_desc_end = . ;
	}
#ifdef CONFIG_RELOCATABLE
	. = ALIGN(8);
	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
	{
#ifdef CONFIG_PPC32
		__dynamic_symtab = .;
#endif
		*(.dynsym)
	}
	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	{
		__dynamic_start = .;
		*(.dynamic)
	}
	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
	.gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) }
	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	{
		__rela_dyn_start = .;
		*(.rela*)
	}
#endif
	/* .exit.data is discarded at runtime, not link time,
	 * to deal with references from .exit.text
	 */
	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
		EXIT_DATA
	}

	/* freed after init ends here */
	. = ALIGN(PAGE_SIZE);
	__init_end = .;

/*
 * And now the various read/write data
 */

	. = ALIGN(PAGE_SIZE);
	_sdata = .;

#ifdef CONFIG_PPC32
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
#ifdef CONFIG_UBSAN
		*(.data..Lubsan_data*)
		*(.data..Lubsan_type*)
#endif
		*(.data.rel*)
		*(SDATA_MAIN)
		*(.sdata2)
		*(.got.plt) *(.got)
		*(.plt)
		*(.branch_lt)
	}
#else
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
#ifdef CONFIG_UBSAN
		*(.data..Lubsan_data*)
		*(.data..Lubsan_type*)
#endif
		*(.data.rel*)
		*(.toc1)
		*(.branch_lt)
	}

	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
		__start_opd = .;
		KEEP(*(.opd))
		__end_opd = .;
	}

	. = ALIGN(256);
	.got : AT(ADDR(.got) - LOAD_OFFSET) {
		__toc_start = .;
#ifndef CONFIG_RELOCATABLE
		__prom_init_toc_start = .;
		arch/powerpc/kernel/prom_init.o*(.toc .got)
		__prom_init_toc_end = .;
#endif
		*(.got)
		*(.toc)
	}
#endif

	/* The initial task and kernel stack */
	INIT_TASK_DATA_SECTION(THREAD_ALIGN)

	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
		PAGE_ALIGNED_DATA(PAGE_SIZE)
	}

	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
	}

	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
		READ_MOSTLY_DATA(L1_CACHE_BYTES)
	}

	. = ALIGN(PAGE_SIZE);
	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
		NOSAVE_DATA
	}

	BUG_TABLE

	. = ALIGN(PAGE_SIZE);
	_edata  =  .;
	PROVIDE32 (edata = .);

/*
 * And finally the bss
 */

	BSS_SECTION(0, 0, 0)

	. = ALIGN(PAGE_SIZE);
	_end = . ;
	PROVIDE32 (end = .);

	STABS_DEBUG
	DWARF_DEBUG
	ELF_DETAILS

	DISCARDS
	/DISCARD/ : {
		*(*.EMB.apuinfo)
		*(.glink .iplt .plt .rela* .comment)
		*(.gnu.version*)
		*(.gnu.attributes)
		*(.eh_frame)
	}
}
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
c51e3a41	2	#ifdef CONFIG_PPC64
e8222502	3	#define PROVIDE32(x) PROVIDE(__unused__##x)
c51e3a41	4	#else
e8222502	5	#define PROVIDE32(x) PROVIDE(x)
c51e3a41	6	#endif
5f69e388 BH	7
5f69e388 BH	8	#define BSS_FIRST_SECTIONS *(.bss.prominit)
441110a5	9	#define EMITS_PT_NOTE
4e9e559a	10	#define RO_EXCEPTION_TABLE_ALIGN 0
5f69e388	11
4846c5de	12	#include <asm/page.h>
14cf11af	13	#include <asm-generic/vmlinux.lds.h>
bd67fcf9	14	#include <asm/cache.h>
62bef288	15	#include <asm/thread_info.h>
14cf11af	16
166d97d9	17	#define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT)
d924cc3f	18
e19e4ab4 ME	19	ENTRY(_stext)
e19e4ab4 ME	20
c69cccc9	21	PHDRS {
af0f3e9e	22	text PT_LOAD FLAGS(7); /* RWX */
ec556271	23	note PT_NOTE FLAGS(0);
c69cccc9 SB	24	}
c69cccc9 SB	25
cabb5587 SR	26	#ifdef CONFIG_PPC64
	27	OUTPUT_ARCH(powerpc:common64)
	28	jiffies = jiffies_64;
	29	#else
14cf11af PM	30	OUTPUT_ARCH(powerpc:common)
14cf11af PM	31	jiffies = jiffies_64 + 4;
cabb5587	32	#endif
14cf11af PM	33	SECTIONS
14cf11af PM	34	{
e8222502	35	. = KERNELBASE;
14cf11af	36
e8222502 BH	37	/*
	38	* Text, read only data and other permanent read-only sections
	39	*/
	40
57f26649 NP	41	_text = .;
	42	_stext = .;
	43
	44	/*
	45	* Head text.
	46	* This needs to be in its own output section to avoid ld placing
	47	* branch trampoline stubs randomly throughout the fixed sections,
	48	* which it will do (even if the branch comes from another section)
	49	* in order to optimize stub generation.
	50	*/
	51	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
	52	#ifdef CONFIG_PPC64
	53	KEEP(*(.head.text.first_256B));
	54	#ifdef CONFIG_PPC_BOOK3E
57f26649 NP	55	#else
	56	KEEP(*(.head.text.real_vectors));
	57	*(.head.text.real_trampolines);
	58	KEEP(*(.head.text.virt_vectors));
	59	*(.head.text.virt_trampolines);
	60	# if defined(CONFIG_PPC_PSERIES) \|\| defined(CONFIG_PPC_POWERNV)
	61	KEEP(*(.head.data.fwnmi_page));
57f26649 NP	62	# endif
57f26649 NP	63	#endif
57f26649 NP	64	#else /* !CONFIG_PPC64 */
	65	HEAD_TEXT
	66	#endif
af0f3e9e	67	} :text
57f26649	68
7aa5b018 NR	69	__head_end = .;
7aa5b018 NR	70
dadc4a1b NP	71	#ifdef CONFIG_PPC64
dadc4a1b NP	72	/*
a652758a	73	* ALIGN(0) overrides the default output section alignment because
dadc4a1b NP	74	* this needs to start right after .head.text in order for fixed
	75	* section placement to work.
	76	*/
a652758a	77	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
951eedeb	78	#ifdef CONFIG_LD_HEAD_STUB_CATCH
4c1d9bb0	79	KEEP(*(.linker_stub_catch));
951eedeb NP	80	. = . ;
	81	#endif
	82
dadc4a1b	83	#else
366234f6	84	.text : AT(ADDR(.text) - LOAD_OFFSET) {
748a7683	85	ALIGN_FUNCTION();
dadc4a1b	86	#endif
13beadd9	87	/* careful! __ftr_alt_* sections need to be close to .text */
3ce47d95	88	(.text.hot .text.hot. TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
67361cf8 NR	89	#ifdef CONFIG_PPC64
	90	*(.tramp.ftrace.text);
	91	#endif
65538966	92	NOINSTR_TEXT
e8222502	93	SCHED_TEXT
6727ad9e	94	CPUIDLE_TEXT
e8222502 BH	95	LOCK_TEXT
e8222502 BH	96	KPROBES_TEXT
6794c782	97	IRQENTRY_TEXT
be7635e7	98	SOFTIRQENTRY_TEXT
e8c68825 NP	99	/*
	100	* -Os builds call FP save/restore functions. The powerpc64
	101	* linker generates those on demand in the .sfpr section.
	102	* .sfpr gets placed at the beginning of a group of input
	103	* sections, which can break start-of-text offset if it is
	104	* included with the main text sections, so put it by itself.
	105	*/
	106	*(.sfpr);
7de3b27b ME	107	MEM_KEEP(init.text)
7de3b27b ME	108	MEM_KEEP(exit.text)
14cf11af	109
e8222502 BH	110	#ifdef CONFIG_PPC32
	111	*(.got1)
	112	__got2_start = .;
	113	*(.got2)
	114	__got2_end = .;
	115	#endif /* CONFIG_PPC32 */
	116
af0f3e9e	117	} :text
e8222502	118
a0591b60	119	. = ALIGN(PAGE_SIZE);
303996da SR	120	_etext = .;
	121	PROVIDE32 (etext = .);
	122
e8222502	123	/* Read-only data */
d924cc3f	124	RO_DATA(PAGE_SIZE)
e8222502	125
aa8a5e00	126	#ifdef CONFIG_PPC64
a048a07d NP	127	. = ALIGN(8);
	128	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
	129	__start___stf_entry_barrier_fixup = .;
	130	*(__stf_entry_barrier_fixup)
	131	__stop___stf_entry_barrier_fixup = .;
	132	}
	133
9a32a7e7 NP	134	. = ALIGN(8);
	135	__uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
	136	__start___uaccess_flush_fixup = .;
	137	*(__uaccess_flush_fixup)
	138	__stop___uaccess_flush_fixup = .;
	139	}
	140
f7964378 NP	141	. = ALIGN(8);
	142	__entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
	143	__start___entry_flush_fixup = .;
	144	*(__entry_flush_fixup)
	145	__stop___entry_flush_fixup = .;
	146	}
	147
08685be7 NP	148	. = ALIGN(8);
	149	__scv_entry_flush_fixup : AT(ADDR(__scv_entry_flush_fixup) - LOAD_OFFSET) {
	150	__start___scv_entry_flush_fixup = .;
	151	*(__scv_entry_flush_fixup)
	152	__stop___scv_entry_flush_fixup = .;
	153	}
	154
a048a07d NP	155	. = ALIGN(8);
	156	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
	157	__start___stf_exit_barrier_fixup = .;
	158	*(__stf_exit_barrier_fixup)
	159	__stop___stf_exit_barrier_fixup = .;
	160	}
	161
aa8a5e00 ME	162	. = ALIGN(8);
	163	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
	164	__start___rfi_flush_fixup = .;
	165	*(__rfi_flush_fixup)
	166	__stop___rfi_flush_fixup = .;
	167	}
179ab1cb	168	#endif /* CONFIG_PPC64 */
2eea7f06	169
179ab1cb	170	#ifdef CONFIG_PPC_BARRIER_NOSPEC
2eea7f06 MS	171	. = ALIGN(8);
	172	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
	173	__start___barrier_nospec_fixup = .;
	174	*(__barrier_nospec_fixup)
	175	__stop___barrier_nospec_fixup = .;
	176	}
179ab1cb	177	#endif /* CONFIG_PPC_BARRIER_NOSPEC */
aa8a5e00	178
76a5eaa3 DC	179	#ifdef CONFIG_PPC_FSL_BOOK3E
	180	. = ALIGN(8);
	181	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
	182	__start__btb_flush_fixup = .;
	183	*(__btb_flush_fixup)
	184	__stop__btb_flush_fixup = .;
	185	}
	186	#endif
14cf11af	187
e8222502 BH	188	/*
	189	* Init sections discarded at runtime
	190	*/
d924cc3f	191	. = ALIGN(STRICT_ALIGN_SIZE);
e8222502	192	__init_begin = .;
67361cf8 NR	193	. = ALIGN(PAGE_SIZE);
	194	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
	195	_sinittext = .;
	196	INIT_TEXT
2225a8dd AM	197
	198	/*
	199	*.init.text might be RO so we must ensure this section ends on
	200	* a page boundary.
	201	*/
	202	. = ALIGN(PAGE_SIZE);
67361cf8 NR	203	_einittext = .;
	204	#ifdef CONFIG_PPC64
	205	*(.tramp.ftrace.init);
	206	#endif
af0f3e9e	207	} :text
e8222502 BH	208
	209	/* .exit.text is discarded at runtime, not link time,
	210	* to deal with references from __bug_table
	211	*/
366234f6	212	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
01ba2bdc SR	213	EXIT_TEXT
01ba2bdc SR	214	}
e8222502	215
2225a8dd AM	216	. = ALIGN(PAGE_SIZE);
2225a8dd AM	217
fdcfeaba	218	INIT_DATA_SECTION(16)
e8222502	219
e8222502	220	. = ALIGN(8);
366234f6	221	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
cabb5587	222	__start___ftr_fixup = .;
4c1d9bb0	223	KEEP(*(__ftr_fixup))
cabb5587 SR	224	__stop___ftr_fixup = .;
cabb5587 SR	225	}
2d1b2027	226	. = ALIGN(8);
7c03d653 BH	227	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
7c03d653 BH	228	__start___mmu_ftr_fixup = .;
4c1d9bb0	229	KEEP(*(__mmu_ftr_fixup))
7c03d653 BH	230	__stop___mmu_ftr_fixup = .;
	231	}
	232	. = ALIGN(8);
2d1b2027 KG	233	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
2d1b2027 KG	234	__start___lwsync_fixup = .;
4c1d9bb0	235	KEEP(*(__lwsync_fixup))
2d1b2027 KG	236	__stop___lwsync_fixup = .;
2d1b2027 KG	237	}
3f639ee8 SR	238	#ifdef CONFIG_PPC64
3f639ee8 SR	239	. = ALIGN(8);
366234f6	240	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
3f639ee8	241	__start___fw_ftr_fixup = .;
4c1d9bb0	242	KEEP(*(__fw_ftr_fixup))
3f639ee8 SR	243	__stop___fw_ftr_fixup = .;
	244	}
	245	#endif
62bef288	246
0415b00d	247	PERCPU_SECTION(L1_CACHE_BYTES)
14cf11af	248
e8222502	249	. = ALIGN(8);
366234f6	250	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
e8222502	251	__machine_desc_start = . ;
4c1d9bb0	252	KEEP(*(.machine.desc))
e8222502 BH	253	__machine_desc_end = . ;
e8222502 BH	254	}
2a4b9c5a	255	#ifdef CONFIG_RELOCATABLE
549e8152	256	. = ALIGN(8);
9c5f7d39 SP	257	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
9c5f7d39 SP	258	{
27d11496	259	#ifdef CONFIG_PPC32
9c5f7d39 SP	260	__dynamic_symtab = .;
	261	#endif
	262	*(.dynsym)
	263	}
549e8152 PM	264	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	265	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	266	{
	267	__dynamic_start = .;
	268	*(.dynamic)
	269	}
	270	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
ead98360	271	.gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) }
549e8152 PM	272	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	273	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	274	{
	275	__rela_dyn_start = .;
	276	(.rela)
	277	}
2a4b9c5a	278	#endif
4c812318 SR	279	/* .exit.data is discarded at runtime, not link time,
	280	* to deal with references from .exit.text
	281	*/
	282	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
	283	EXIT_DATA
	284	}
e8222502 BH	285
	286	/* freed after init ends here */
	287	. = ALIGN(PAGE_SIZE);
	288	__init_end = .;
	289
	290	/*
	291	* And now the various read/write data
	292	*/
	293
	294	. = ALIGN(PAGE_SIZE);
	295	_sdata = .;
14cf11af	296
cabb5587	297	#ifdef CONFIG_PPC32
366234f6	298	.data : AT(ADDR(.data) - LOAD_OFFSET) {
ca967258	299	DATA_DATA
beba24ac MM	300	#ifdef CONFIG_UBSAN
	301	(.data..Lubsan_data)
	302	(.data..Lubsan_type)
	303	#endif
a1072607	304	(.data.rel)
4c1d9bb0	305	*(SDATA_MAIN)
83a092cf	306	*(.sdata2)
e8222502	307	(.got.plt) (.got)
83a092cf	308	*(.plt)
98ecc676	309	*(.branch_lt)
e8222502	310	}
cabb5587	311	#else
366234f6	312	.data : AT(ADDR(.data) - LOAD_OFFSET) {
3ae0aa9f	313	DATA_DATA
d0a3ac54 KC	314	#ifdef CONFIG_UBSAN
	315	(.data..Lubsan_data)
	316	(.data..Lubsan_type)
	317	#endif
3ae0aa9f MD	318	(.data.rel)
3ae0aa9f MD	319	*(.toc1)
e8222502 BH	320	*(.branch_lt)
e8222502 BH	321	}
14cf11af	322
366234f6	323	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
5633e85b	324	__start_opd = .;
4c1d9bb0	325	KEEP(*(.opd))
5633e85b	326	__end_opd = .;
e8222502 BH	327	}
e8222502 BH	328
5e95235c	329	. = ALIGN(256);
366234f6	330	.got : AT(ADDR(.got) - LOAD_OFFSET) {
e8222502	331	__toc_start = .;
5ac47f7a AB	332	#ifndef CONFIG_RELOCATABLE
	333	__prom_init_toc_start = .;
	334	arch/powerpc/kernel/prom_init.o*(.toc .got)
	335	__prom_init_toc_end = .;
	336	#endif
e8222502 BH	337	*(.got)
	338	*(.toc)
	339	}
cabb5587	340	#endif
14cf11af	341
e8222502	342	/* The initial task and kernel stack */
63289e7d	343	INIT_TASK_DATA_SECTION(THREAD_ALIGN)
14cf11af	344
75b13483	345	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
62bef288	346	PAGE_ALIGNED_DATA(PAGE_SIZE)
e8222502	347	}
14cf11af	348
4af57b78	349	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
62bef288	350	CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
e8222502	351	}
14cf11af	352
54cb27a7	353	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
62bef288	354	READ_MOSTLY_DATA(L1_CACHE_BYTES)
bd67fcf9 TB	355	}
bd67fcf9 TB	356
5be2a213	357	. = ALIGN(PAGE_SIZE);
366234f6	358	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
62bef288	359	NOSAVE_DATA
e8222502	360	}
4a288563	361
b5effd38 PZ	362	BUG_TABLE
b5effd38 PZ	363
903444e4 ME	364	. = ALIGN(PAGE_SIZE);
	365	_edata = .;
	366	PROVIDE32 (edata = .);
	367
e8222502 BH	368	/*
	369	* And finally the bss
	370	*/
	371
62bef288	372	BSS_SECTION(0, 0, 0)
14cf11af	373
e8222502 BH	374	. = ALIGN(PAGE_SIZE);
	375	_end = . ;
	376	PROVIDE32 (end = .);
023bf6f1	377
83a092cf	378	STABS_DEBUG
83a092cf	379	DWARF_DEBUG
c604abc3	380	ELF_DETAILS
83a092cf	381
023bf6f1	382	DISCARDS
83a092cf NP	383	/DISCARD/ : {
	384	(.EMB.apuinfo)
	385	(.glink .iplt .plt .rela .comment)
	386	(.gnu.version)
	387	*(.gnu.attributes)
	388	*(.eh_frame)
	389	}
14cf11af	390	}