[mirror_ubuntu-artful-kernel.git] / arch / sparc / lib / NGmemcpy.S

/* NGmemcpy.S: Niagara optimized memcpy.
 *
 * Copyright (C) 2006, 2007 David S. Miller (davem@davemloft.net)
 */

#ifdef __KERNEL__
#include <linux/linkage.h>
#include <asm/asi.h>
#include <asm/thread_info.h>
#define GLOBAL_SPARE	%g7
#define RESTORE_ASI(TMP)	\
	ldub	[%g6 + TI_CURRENT_DS], TMP;  \
	wr	TMP, 0x0, %asi;
#else
#define GLOBAL_SPARE	%g5
#define RESTORE_ASI(TMP)	\
	wr	%g0, ASI_PNF, %asi
#endif

#ifdef __sparc_v9__
#define SAVE_AMOUNT	128
#else
#define SAVE_AMOUNT	64
#endif

#ifndef STORE_ASI
#define STORE_ASI	ASI_BLK_INIT_QUAD_LDD_P
#endif

#ifndef EX_LD
#define EX_LD(x,y)	x
#endif

#ifndef EX_ST
#define EX_ST(x,y)	x
#endif

#ifndef LOAD
#ifndef MEMCPY_DEBUG
#define LOAD(type,addr,dest)	type [addr], dest
#else
#define LOAD(type,addr,dest)	type##a [addr] 0x80, dest
#endif
#endif

#ifndef LOAD_TWIN
#define LOAD_TWIN(addr_reg,dest0,dest1)	\
	ldda [addr_reg] ASI_BLK_INIT_QUAD_LDD_P, dest0
#endif

#ifndef STORE
#define STORE(type,src,addr)	type src, [addr]
#endif

#ifndef STORE_INIT
#ifndef SIMULATE_NIAGARA_ON_NON_NIAGARA
#define STORE_INIT(src,addr)	stxa src, [addr] %asi
#else
#define STORE_INIT(src,addr)	stx src, [addr + 0x00]
#endif
#endif

#ifndef FUNC_NAME
#define FUNC_NAME	NGmemcpy
#endif

#ifndef PREAMBLE
#define PREAMBLE
#endif

#ifndef XCC
#define XCC xcc
#endif

	.register	%g2,#scratch
	.register	%g3,#scratch

	.text
#ifndef EX_RETVAL
#define EX_RETVAL(x)	x
__restore_asi:
	ret
	wr	%g0, ASI_AIUS, %asi
	 restore
ENTRY(NG_ret_i2_plus_i4_plus_1)
	ba,pt	%xcc, __restore_asi
	 add	%i2, %i5, %i0
ENDPROC(NG_ret_i2_plus_i4_plus_1)
ENTRY(NG_ret_i2_plus_g1)
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1)
ENTRY(NG_ret_i2_plus_g1_minus_8)
	sub	%g1, 8, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_8)
ENTRY(NG_ret_i2_plus_g1_minus_16)
	sub	%g1, 16, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_16)
ENTRY(NG_ret_i2_plus_g1_minus_24)
	sub	%g1, 24, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_24)
ENTRY(NG_ret_i2_plus_g1_minus_32)
	sub	%g1, 32, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_32)
ENTRY(NG_ret_i2_plus_g1_minus_40)
	sub	%g1, 40, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_40)
ENTRY(NG_ret_i2_plus_g1_minus_48)
	sub	%g1, 48, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_48)
ENTRY(NG_ret_i2_plus_g1_minus_56)
	sub	%g1, 56, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_minus_56)
ENTRY(NG_ret_i2_plus_i4)
	ba,pt	%xcc, __restore_asi
	 add	%i2, %i4, %i0
ENDPROC(NG_ret_i2_plus_i4)
ENTRY(NG_ret_i2_plus_i4_minus_8)
	sub	%i4, 8, %i4
	ba,pt	%xcc, __restore_asi
	 add	%i2, %i4, %i0
ENDPROC(NG_ret_i2_plus_i4_minus_8)
ENTRY(NG_ret_i2_plus_8)
	ba,pt	%xcc, __restore_asi
	 add	%i2, 8, %i0
ENDPROC(NG_ret_i2_plus_8)
ENTRY(NG_ret_i2_plus_4)
	ba,pt	%xcc, __restore_asi
	 add	%i2, 4, %i0
ENDPROC(NG_ret_i2_plus_4)
ENTRY(NG_ret_i2_plus_1)
	ba,pt	%xcc, __restore_asi
	 add	%i2, 1, %i0
ENDPROC(NG_ret_i2_plus_1)
ENTRY(NG_ret_i2_plus_g1_plus_1)
	add	%g1, 1, %g1
	ba,pt	%xcc, __restore_asi
	 add	%i2, %g1, %i0
ENDPROC(NG_ret_i2_plus_g1_plus_1)
ENTRY(NG_ret_i2)
	ba,pt	%xcc, __restore_asi
	 mov	%i2, %i0
ENDPROC(NG_ret_i2)
ENTRY(NG_ret_i2_and_7_plus_i4)
	and	%i2, 7, %i2
	ba,pt	%xcc, __restore_asi
	 add	%i2, %i4, %i0
ENDPROC(NG_ret_i2_and_7_plus_i4)
#endif

	.align		64

	.globl	FUNC_NAME
	.type	FUNC_NAME,#function
FUNC_NAME:	/* %i0=dst, %i1=src, %i2=len */
	PREAMBLE
	save		%sp, -SAVE_AMOUNT, %sp
	srlx		%i2, 31, %g2
	cmp		%g2, 0
	tne		%xcc, 5
	mov		%i0, %o0
	cmp		%i2, 0
	be,pn		%XCC, 85f
	 or		%o0, %i1, %i3
	cmp		%i2, 16
	blu,a,pn	%XCC, 80f
	 or		%i3, %i2, %i3

	/* 2 blocks (128 bytes) is the minimum we can do the block
	 * copy with.  We need to ensure that we'll iterate at least
	 * once in the block copy loop.  At worst we'll need to align
	 * the destination to a 64-byte boundary which can chew up
	 * to (64 - 1) bytes from the length before we perform the
	 * block copy loop.
	 */
	cmp		%i2, (2 * 64)
	blu,pt		%XCC, 70f
	 andcc		%i3, 0x7, %g0

	/* %o0:	dst
	 * %i1:	src
	 * %i2:	len  (known to be >= 128)
	 *
	 * The block copy loops will use %i4/%i5,%g2/%g3 as
	 * temporaries while copying the data.
	 */

	LOAD(prefetch, %i1, #one_read)
	wr		%g0, STORE_ASI, %asi

	/* Align destination on 64-byte boundary.  */
	andcc		%o0, (64 - 1), %i4
	be,pt		%XCC, 2f
	 sub		%i4, 64, %i4
	sub		%g0, %i4, %i4	! bytes to align dst
	sub		%i2, %i4, %i2
1:	subcc		%i4, 1, %i4
	EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_i4_plus_1)
	EX_ST(STORE(stb, %g1, %o0), NG_ret_i2_plus_i4_plus_1)
	add		%i1, 1, %i1
	bne,pt		%XCC, 1b
	add		%o0, 1, %o0

	/* If the source is on a 16-byte boundary we can do
	 * the direct block copy loop.  If it is 8-byte aligned
	 * we can do the 16-byte loads offset by -8 bytes and the
	 * init stores offset by one register.
	 *
	 * If the source is not even 8-byte aligned, we need to do
	 * shifting and masking (basically integer faligndata).
	 *
	 * The careful bit with init stores is that if we store
	 * to any part of the cache line we have to store the whole
	 * cacheline else we can end up with corrupt L2 cache line
	 * contents.  Since the loop works on 64-bytes of 64-byte
	 * aligned store data at a time, this is easy to ensure.
	 */
2:
	andcc		%i1, (16 - 1), %i4
	andn		%i2, (64 - 1), %g1	! block copy loop iterator
	be,pt		%XCC, 50f
	 sub		%i2, %g1, %i2		! final sub-block copy bytes

	cmp		%i4, 8
	be,pt		%XCC, 10f
	 sub		%i1, %i4, %i1

	/* Neither 8-byte nor 16-byte aligned, shift and mask.  */
	and		%i4, 0x7, GLOBAL_SPARE
	sll		GLOBAL_SPARE, 3, GLOBAL_SPARE
	mov		64, %i5
	EX_LD(LOAD_TWIN(%i1, %g2, %g3), NG_ret_i2_plus_g1)
	sub		%i5, GLOBAL_SPARE, %i5
	mov		16, %o4
	mov		32, %o5
	mov		48, %o7
	mov		64, %i3

	bg,pn	   	%XCC, 9f
	 nop

#define MIX_THREE_WORDS(WORD1, WORD2, WORD3, PRE_SHIFT, POST_SHIFT, TMP) \
	sllx		WORD1, POST_SHIFT, WORD1; \
	srlx		WORD2, PRE_SHIFT, TMP; \
	sllx		WORD2, POST_SHIFT, WORD2; \
	or		WORD1, TMP, WORD1; \
	srlx		WORD3, PRE_SHIFT, TMP; \
	or		WORD2, TMP, WORD2;

8:	EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
	MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
	LOAD(prefetch, %i1 + %i3, #one_read)

	EX_ST(STORE_INIT(%g2, %o0 + 0x00), NG_ret_i2_plus_g1)
	EX_ST(STORE_INIT(%g3, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)

	EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
	MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)

	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
	MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%g2, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	EX_ST(STORE_INIT(%g3, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)

	EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
	add		%i1, 64, %i1
	MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
	EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)

	subcc		%g1, 64, %g1
	bne,pt		%XCC, 8b
	 add		%o0, 64, %o0

	ba,pt		%XCC, 60f
	 add		%i1, %i4, %i1

9:	EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
	MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
	LOAD(prefetch, %i1 + %i3, #one_read)

	EX_ST(STORE_INIT(%g3, %o0 + 0x00), NG_ret_i2_plus_g1)
	EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)

	EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
	MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%g2, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)

	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
	MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%g3, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)

	EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
	add		%i1, 64, %i1
	MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)

	EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
	EX_ST(STORE_INIT(%g2, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)

	subcc		%g1, 64, %g1
	bne,pt		%XCC, 9b
	 add		%o0, 64, %o0

	ba,pt		%XCC, 60f
	 add		%i1, %i4, %i1

10:	/* Destination is 64-byte aligned, source was only 8-byte
	 * aligned but it has been subtracted by 8 and we perform
	 * one twin load ahead, then add 8 back into source when
	 * we finish the loop.
	 */
	EX_LD(LOAD_TWIN(%i1, %o4, %o5), NG_ret_i2_plus_g1)
	mov	16, %o7
	mov	32, %g2
	mov	48, %g3
	mov	64, %o1
1:	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
	LOAD(prefetch, %i1 + %o1, #one_read)
	EX_ST(STORE_INIT(%o5, %o0 + 0x00), NG_ret_i2_plus_g1)	! initializes cache line
	EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
	EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%o4, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
	EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
	EX_ST(STORE_INIT(%o5, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
	EX_LD(LOAD_TWIN(%i1 + %o1, %o4, %o5), NG_ret_i2_plus_g1_minus_48)
	add		%i1, 64, %i1
	EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
	EX_ST(STORE_INIT(%o4, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
	subcc		%g1, 64, %g1
	bne,pt		%XCC, 1b
	 add		%o0, 64, %o0

	ba,pt		%XCC, 60f
	 add		%i1, 0x8, %i1

50:	/* Destination is 64-byte aligned, and source is 16-byte
	 * aligned.
	 */
	mov	16, %o7
	mov	32, %g2
	mov	48, %g3
	mov	64, %o1
1:	EX_LD(LOAD_TWIN(%i1 + %g0, %o4, %o5), NG_ret_i2_plus_g1)
	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
	LOAD(prefetch, %i1 + %o1, #one_read)
	EX_ST(STORE_INIT(%o4, %o0 + 0x00), NG_ret_i2_plus_g1)	! initializes cache line
	EX_ST(STORE_INIT(%o5, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
	EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
	EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
	add	%i1, 64, %i1
	EX_ST(STORE_INIT(%o4, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	EX_ST(STORE_INIT(%o5, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
	EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
	EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
	subcc	%g1, 64, %g1
	bne,pt	%XCC, 1b
	 add	%o0, 64, %o0
	/* fall through */

60:	
	membar		#Sync

	/* %i2 contains any final bytes still needed to be copied
	 * over. If anything is left, we copy it one byte at a time.
	 */
	RESTORE_ASI(%i3)
	brz,pt		%i2, 85f
	 sub		%o0, %i1, %i3
	ba,a,pt		%XCC, 90f
	 nop

	.align		64
70: /* 16 < len <= 64 */
	bne,pn		%XCC, 75f
	 sub		%o0, %i1, %i3

72:
	andn		%i2, 0xf, %i4
	and		%i2, 0xf, %i2
1:	subcc		%i4, 0x10, %i4
	EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_i4)
	add		%i1, 0x08, %i1
	EX_LD(LOAD(ldx, %i1, %g1), NG_ret_i2_plus_i4)
	sub		%i1, 0x08, %i1
	EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_i4)
	add		%i1, 0x8, %i1
	EX_ST(STORE(stx, %g1, %i1 + %i3), NG_ret_i2_plus_i4_minus_8)
	bgu,pt		%XCC, 1b
	 add		%i1, 0x8, %i1
73:	andcc		%i2, 0x8, %g0
	be,pt		%XCC, 1f
	 nop
	sub		%i2, 0x8, %i2
	EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_8)
	EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_8)
	add		%i1, 0x8, %i1
1:	andcc		%i2, 0x4, %g0
	be,pt		%XCC, 1f
	 nop
	sub		%i2, 0x4, %i2
	EX_LD(LOAD(lduw, %i1, %i5), NG_ret_i2_plus_4)
	EX_ST(STORE(stw, %i5, %i1 + %i3), NG_ret_i2_plus_4)
	add		%i1, 0x4, %i1
1:	cmp		%i2, 0
	be,pt		%XCC, 85f
	 nop
	ba,pt		%xcc, 90f
	 nop

75:
	andcc		%o0, 0x7, %g1
	sub		%g1, 0x8, %g1
	be,pn		%icc, 2f
	 sub		%g0, %g1, %g1
	sub		%i2, %g1, %i2

1:	subcc		%g1, 1, %g1
	EX_LD(LOAD(ldub, %i1, %i5), NG_ret_i2_plus_g1_plus_1)
	EX_ST(STORE(stb, %i5, %i1 + %i3), NG_ret_i2_plus_g1_plus_1)
	bgu,pt		%icc, 1b
	 add		%i1, 1, %i1

2:	add		%i1, %i3, %o0
	andcc		%i1, 0x7, %g1
	bne,pt		%icc, 8f
	 sll		%g1, 3, %g1

	cmp		%i2, 16
	bgeu,pt		%icc, 72b
	 nop
	ba,a,pt		%xcc, 73b

8:	mov		64, %i3
	andn		%i1, 0x7, %i1
	EX_LD(LOAD(ldx, %i1, %g2), NG_ret_i2)
	sub		%i3, %g1, %i3
	andn		%i2, 0x7, %i4
	sllx		%g2, %g1, %g2
1:	add		%i1, 0x8, %i1
	EX_LD(LOAD(ldx, %i1, %g3), NG_ret_i2_and_7_plus_i4)
	subcc		%i4, 0x8, %i4
	srlx		%g3, %i3, %i5
	or		%i5, %g2, %i5
	EX_ST(STORE(stx, %i5, %o0), NG_ret_i2_and_7_plus_i4)
	add		%o0, 0x8, %o0
	bgu,pt		%icc, 1b
	 sllx		%g3, %g1, %g2

	srl		%g1, 3, %g1
	andcc		%i2, 0x7, %i2
	be,pn		%icc, 85f
	 add		%i1, %g1, %i1
	ba,pt		%xcc, 90f
	 sub		%o0, %i1, %i3

	.align		64
80: /* 0 < len <= 16 */
	andcc		%i3, 0x3, %g0
	bne,pn		%XCC, 90f
	 sub		%o0, %i1, %i3

1:
	subcc		%i2, 4, %i2
	EX_LD(LOAD(lduw, %i1, %g1), NG_ret_i2_plus_4)
	EX_ST(STORE(stw, %g1, %i1 + %i3), NG_ret_i2_plus_4)
	bgu,pt		%XCC, 1b
	 add		%i1, 4, %i1

85:	ret
	 restore	EX_RETVAL(%i0), %g0, %o0

	.align		32
90:
	subcc		%i2, 1, %i2
	EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_1)
	EX_ST(STORE(stb, %g1, %i1 + %i3), NG_ret_i2_plus_1)
	bgu,pt		%XCC, 90b
	 add		%i1, 1, %i1
	ret
	 restore	EX_RETVAL(%i0), %g0, %o0

	.size		FUNC_NAME, .-FUNC_NAME
Commit	Line	Data
398d1083 DM	1	/* NGmemcpy.S: Niagara optimized memcpy.
398d1083 DM	2	*
25e5566e	3	* Copyright (C) 2006, 2007 David S. Miller (davem@davemloft.net)
398d1083 DM	4	*/
	5
	6	#ifdef __KERNEL__
7ae3aaf5	7	#include <linux/linkage.h>
398d1083	8	#include <asm/asi.h>
0d4bc95b	9	#include <asm/thread_info.h>
398d1083	10	#define GLOBAL_SPARE %g7
0d4bc95b DM	11	#define RESTORE_ASI(TMP) \
	12	ldub [%g6 + TI_CURRENT_DS], TMP; \
	13	wr TMP, 0x0, %asi;
398d1083 DM	14	#else
398d1083 DM	15	#define GLOBAL_SPARE %g5
0d4bc95b DM	16	#define RESTORE_ASI(TMP) \
0d4bc95b DM	17	wr %g0, ASI_PNF, %asi
398d1083 DM	18	#endif
398d1083 DM	19
25e5566e DM	20	#ifdef __sparc_v9__
	21	#define SAVE_AMOUNT 128
	22	#else
	23	#define SAVE_AMOUNT 64
	24	#endif
	25
398d1083 DM	26	#ifndef STORE_ASI
	27	#define STORE_ASI ASI_BLK_INIT_QUAD_LDD_P
	28	#endif
	29
	30	#ifndef EX_LD
7ae3aaf5	31	#define EX_LD(x,y) x
398d1083 DM	32	#endif
	33
	34	#ifndef EX_ST
7ae3aaf5	35	#define EX_ST(x,y) x
398d1083 DM	36	#endif
	37
	38	#ifndef LOAD
	39	#ifndef MEMCPY_DEBUG
	40	#define LOAD(type,addr,dest) type [addr], dest
	41	#else
	42	#define LOAD(type,addr,dest) type##a [addr] 0x80, dest
	43	#endif
	44	#endif
	45
	46	#ifndef LOAD_TWIN
	47	#define LOAD_TWIN(addr_reg,dest0,dest1) \
	48	ldda [addr_reg] ASI_BLK_INIT_QUAD_LDD_P, dest0
	49	#endif
	50
	51	#ifndef STORE
	52	#define STORE(type,src,addr) type src, [addr]
	53	#endif
	54
	55	#ifndef STORE_INIT
25e5566e	56	#ifndef SIMULATE_NIAGARA_ON_NON_NIAGARA
398d1083	57	#define STORE_INIT(src,addr) stxa src, [addr] %asi
25e5566e DM	58	#else
	59	#define STORE_INIT(src,addr) stx src, [addr + 0x00]
	60	#endif
398d1083 DM	61	#endif
	62
	63	#ifndef FUNC_NAME
	64	#define FUNC_NAME NGmemcpy
	65	#endif
	66
	67	#ifndef PREAMBLE
	68	#define PREAMBLE
	69	#endif
	70
	71	#ifndef XCC
	72	#define XCC xcc
	73	#endif
	74
	75	.register %g2,#scratch
	76	.register %g3,#scratch
	77
	78	.text
7ae3aaf5 DM	79	#ifndef EX_RETVAL
	80	#define EX_RETVAL(x) x
	81	__restore_asi:
	82	ret
	83	wr %g0, ASI_AIUS, %asi
	84	restore
	85	ENTRY(NG_ret_i2_plus_i4_plus_1)
	86	ba,pt %xcc, __restore_asi
	87	add %i2, %i5, %i0
	88	ENDPROC(NG_ret_i2_plus_i4_plus_1)
	89	ENTRY(NG_ret_i2_plus_g1)
	90	ba,pt %xcc, __restore_asi
	91	add %i2, %g1, %i0
	92	ENDPROC(NG_ret_i2_plus_g1)
	93	ENTRY(NG_ret_i2_plus_g1_minus_8)
	94	sub %g1, 8, %g1
	95	ba,pt %xcc, __restore_asi
	96	add %i2, %g1, %i0
	97	ENDPROC(NG_ret_i2_plus_g1_minus_8)
	98	ENTRY(NG_ret_i2_plus_g1_minus_16)
	99	sub %g1, 16, %g1
	100	ba,pt %xcc, __restore_asi
	101	add %i2, %g1, %i0
	102	ENDPROC(NG_ret_i2_plus_g1_minus_16)
	103	ENTRY(NG_ret_i2_plus_g1_minus_24)
	104	sub %g1, 24, %g1
	105	ba,pt %xcc, __restore_asi
	106	add %i2, %g1, %i0
	107	ENDPROC(NG_ret_i2_plus_g1_minus_24)
	108	ENTRY(NG_ret_i2_plus_g1_minus_32)
	109	sub %g1, 32, %g1
	110	ba,pt %xcc, __restore_asi
	111	add %i2, %g1, %i0
	112	ENDPROC(NG_ret_i2_plus_g1_minus_32)
	113	ENTRY(NG_ret_i2_plus_g1_minus_40)
	114	sub %g1, 40, %g1
	115	ba,pt %xcc, __restore_asi
	116	add %i2, %g1, %i0
	117	ENDPROC(NG_ret_i2_plus_g1_minus_40)
	118	ENTRY(NG_ret_i2_plus_g1_minus_48)
	119	sub %g1, 48, %g1
	120	ba,pt %xcc, __restore_asi
	121	add %i2, %g1, %i0
	122	ENDPROC(NG_ret_i2_plus_g1_minus_48)
	123	ENTRY(NG_ret_i2_plus_g1_minus_56)
	124	sub %g1, 56, %g1
	125	ba,pt %xcc, __restore_asi
	126	add %i2, %g1, %i0
	127	ENDPROC(NG_ret_i2_plus_g1_minus_56)
	128	ENTRY(NG_ret_i2_plus_i4)
	129	ba,pt %xcc, __restore_asi
	130	add %i2, %i4, %i0
	131	ENDPROC(NG_ret_i2_plus_i4)
	132	ENTRY(NG_ret_i2_plus_i4_minus_8)
	133	sub %i4, 8, %i4
	134	ba,pt %xcc, __restore_asi
	135	add %i2, %i4, %i0
	136	ENDPROC(NG_ret_i2_plus_i4_minus_8)
	137	ENTRY(NG_ret_i2_plus_8)
	138	ba,pt %xcc, __restore_asi
	139	add %i2, 8, %i0
	140	ENDPROC(NG_ret_i2_plus_8)
	141	ENTRY(NG_ret_i2_plus_4)
	142	ba,pt %xcc, __restore_asi
143	add %i2, 4, %i0
144	ENDPROC(NG_ret_i2_plus_4)
145	ENTRY(NG_ret_i2_plus_1)
146	ba,pt %xcc, __restore_asi
147	add %i2, 1, %i0
148	ENDPROC(NG_ret_i2_plus_1)
149	ENTRY(NG_ret_i2_plus_g1_plus_1)
150	add %g1, 1, %g1
151	ba,pt %xcc, __restore_asi
152	add %i2, %g1, %i0
153	ENDPROC(NG_ret_i2_plus_g1_plus_1)
154	ENTRY(NG_ret_i2)
155	ba,pt %xcc, __restore_asi
156	mov %i2, %i0
157	ENDPROC(NG_ret_i2)
158	ENTRY(NG_ret_i2_and_7_plus_i4)
159	and %i2, 7, %i2
160	ba,pt %xcc, __restore_asi
161	add %i2, %i4, %i0
162	ENDPROC(NG_ret_i2_and_7_plus_i4)
163	#endif
164
398d1083 DM	165	.align 64
	166
	167	.globl FUNC_NAME
	168	.type FUNC_NAME,#function
25e5566e DM	169	FUNC_NAME: /* %i0=dst, %i1=src, %i2=len */
	170	PREAMBLE
	171	save %sp, -SAVE_AMOUNT, %sp
	172	srlx %i2, 31, %g2
398d1083 DM	173	cmp %g2, 0
398d1083 DM	174	tne %xcc, 5
25e5566e DM	175	mov %i0, %o0
25e5566e DM	176	cmp %i2, 0
398d1083	177	be,pn %XCC, 85f
25e5566e DM	178	or %o0, %i1, %i3
25e5566e DM	179	cmp %i2, 16
398d1083	180	blu,a,pn %XCC, 80f
25e5566e	181	or %i3, %i2, %i3
398d1083 DM	182
	183	/* 2 blocks (128 bytes) is the minimum we can do the block
	184	* copy with. We need to ensure that we'll iterate at least
	185	* once in the block copy loop. At worst we'll need to align
	186	* the destination to a 64-byte boundary which can chew up
	187	* to (64 - 1) bytes from the length before we perform the
	188	* block copy loop.
	189	*/
25e5566e	190	cmp %i2, (2 * 64)
398d1083	191	blu,pt %XCC, 70f
25e5566e	192	andcc %i3, 0x7, %g0
398d1083 DM	193
398d1083 DM	194	/* %o0: dst
25e5566e DM	195	* %i1: src
25e5566e DM	196	* %i2: len (known to be >= 128)
398d1083	197	*
25e5566e	198	* The block copy loops will use %i4/%i5,%g2/%g3 as
398d1083 DM	199	* temporaries while copying the data.
	200	*/
	201
25e5566e	202	LOAD(prefetch, %i1, #one_read)
398d1083 DM	203	wr %g0, STORE_ASI, %asi
	204
	205	/* Align destination on 64-byte boundary. */
25e5566e	206	andcc %o0, (64 - 1), %i4
398d1083	207	be,pt %XCC, 2f
25e5566e DM	208	sub %i4, 64, %i4
	209	sub %g0, %i4, %i4 ! bytes to align dst
	210	sub %i2, %i4, %i2
	211	1: subcc %i4, 1, %i4
7ae3aaf5 DM	212	EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_i4_plus_1)
7ae3aaf5 DM	213	EX_ST(STORE(stb, %g1, %o0), NG_ret_i2_plus_i4_plus_1)
25e5566e	214	add %i1, 1, %i1
398d1083 DM	215	bne,pt %XCC, 1b
	216	add %o0, 1, %o0
	217
	218	/* If the source is on a 16-byte boundary we can do
	219	* the direct block copy loop. If it is 8-byte aligned
	220	* we can do the 16-byte loads offset by -8 bytes and the
	221	* init stores offset by one register.
	222	*
	223	* If the source is not even 8-byte aligned, we need to do
	224	* shifting and masking (basically integer faligndata).
	225	*
	226	* The careful bit with init stores is that if we store
	227	* to any part of the cache line we have to store the whole
	228	* cacheline else we can end up with corrupt L2 cache line
	229	* contents. Since the loop works on 64-bytes of 64-byte
	230	* aligned store data at a time, this is easy to ensure.
	231	*/
	232	2:
25e5566e DM	233	andcc %i1, (16 - 1), %i4
25e5566e DM	234	andn %i2, (64 - 1), %g1 ! block copy loop iterator
398d1083	235	be,pt %XCC, 50f
25e5566e DM	236	sub %i2, %g1, %i2 ! final sub-block copy bytes
	237
	238	cmp %i4, 8
	239	be,pt %XCC, 10f
	240	sub %i1, %i4, %i1
398d1083 DM	241
398d1083 DM	242	/* Neither 8-byte nor 16-byte aligned, shift and mask. */
25e5566e DM	243	and %i4, 0x7, GLOBAL_SPARE
	244	sll GLOBAL_SPARE, 3, GLOBAL_SPARE
	245	mov 64, %i5
7ae3aaf5	246	EX_LD(LOAD_TWIN(%i1, %g2, %g3), NG_ret_i2_plus_g1)
25e5566e DM	247	sub %i5, GLOBAL_SPARE, %i5
	248	mov 16, %o4
	249	mov 32, %o5
	250	mov 48, %o7
	251	mov 64, %i3
	252
	253	bg,pn %XCC, 9f
	254	nop
398d1083	255
25e5566e DM	256	#define MIX_THREE_WORDS(WORD1, WORD2, WORD3, PRE_SHIFT, POST_SHIFT, TMP) \
	257	sllx WORD1, POST_SHIFT, WORD1; \
	258	srlx WORD2, PRE_SHIFT, TMP; \
	259	sllx WORD2, POST_SHIFT, WORD2; \
	260	or WORD1, TMP, WORD1; \
	261	srlx WORD3, PRE_SHIFT, TMP; \
	262	or WORD2, TMP, WORD2;
	263
7ae3aaf5	264	8: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
25e5566e DM	265	MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
	266	LOAD(prefetch, %i1 + %i3, #one_read)
	267
7ae3aaf5 DM	268	EX_ST(STORE_INIT(%g2, %o0 + 0x00), NG_ret_i2_plus_g1)
7ae3aaf5 DM	269	EX_ST(STORE_INIT(%g3, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
25e5566e	270
7ae3aaf5	271	EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
25e5566e DM	272	MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
25e5566e DM	273
7ae3aaf5 DM	274	EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
7ae3aaf5 DM	275	EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
25e5566e	276
7ae3aaf5	277	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
25e5566e DM	278	MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
25e5566e DM	279
7ae3aaf5 DM	280	EX_ST(STORE_INIT(%g2, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
7ae3aaf5 DM	281	EX_ST(STORE_INIT(%g3, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
25e5566e	282
7ae3aaf5	283	EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
25e5566e DM	284	add %i1, 64, %i1
	285	MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
	286
7ae3aaf5 DM	287	EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
7ae3aaf5 DM	288	EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
25e5566e DM	289
	290	subcc %g1, 64, %g1
	291	bne,pt %XCC, 8b
398d1083 DM	292	add %o0, 64, %o0
398d1083 DM	293
25e5566e DM	294	ba,pt %XCC, 60f
	295	add %i1, %i4, %i1
	296
7ae3aaf5	297	9: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
25e5566e DM	298	MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
	299	LOAD(prefetch, %i1 + %i3, #one_read)
	300
7ae3aaf5 DM	301	EX_ST(STORE_INIT(%g3, %o0 + 0x00), NG_ret_i2_plus_g1)
7ae3aaf5 DM	302	EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
25e5566e	303
7ae3aaf5	304	EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
25e5566e DM	305	MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
25e5566e DM	306
7ae3aaf5 DM	307	EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
7ae3aaf5 DM	308	EX_ST(STORE_INIT(%g2, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
25e5566e	309
7ae3aaf5	310	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
25e5566e DM	311	MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
25e5566e DM	312
7ae3aaf5 DM	313	EX_ST(STORE_INIT(%g3, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
7ae3aaf5 DM	314	EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
25e5566e	315
7ae3aaf5	316	EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
25e5566e DM	317	add %i1, 64, %i1
	318	MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
	319
7ae3aaf5 DM	320	EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
7ae3aaf5 DM	321	EX_ST(STORE_INIT(%g2, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
25e5566e DM	322
	323	subcc %g1, 64, %g1
	324	bne,pt %XCC, 9b
	325	add %o0, 64, %o0
398d1083	326
398d1083	327	ba,pt %XCC, 60f
25e5566e	328	add %i1, %i4, %i1
398d1083 DM	329
	330	10: /* Destination is 64-byte aligned, source was only 8-byte
	331	* aligned but it has been subtracted by 8 and we perform
	332	* one twin load ahead, then add 8 back into source when
	333	* we finish the loop.
	334	*/
7ae3aaf5	335	EX_LD(LOAD_TWIN(%i1, %o4, %o5), NG_ret_i2_plus_g1)
25e5566e DM	336	mov 16, %o7
	337	mov 32, %g2
	338	mov 48, %g3
	339	mov 64, %o1
7ae3aaf5	340	1: EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
25e5566e	341	LOAD(prefetch, %i1 + %o1, #one_read)
7ae3aaf5 DM	342	EX_ST(STORE_INIT(%o5, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
	343	EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
	344	EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
	345	EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	346	EX_ST(STORE_INIT(%o4, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
	347	EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
	348	EX_ST(STORE_INIT(%o5, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	349	EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
	350	EX_LD(LOAD_TWIN(%i1 + %o1, %o4, %o5), NG_ret_i2_plus_g1_minus_48)
25e5566e	351	add %i1, 64, %i1
7ae3aaf5 DM	352	EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
7ae3aaf5 DM	353	EX_ST(STORE_INIT(%o4, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
398d1083 DM	354	subcc %g1, 64, %g1
	355	bne,pt %XCC, 1b
	356	add %o0, 64, %o0
	357
	358	ba,pt %XCC, 60f
25e5566e	359	add %i1, 0x8, %i1
398d1083 DM	360
	361	50: /* Destination is 64-byte aligned, and source is 16-byte
	362	* aligned.
	363	*/
25e5566e DM	364	mov 16, %o7
	365	mov 32, %g2
	366	mov 48, %g3
	367	mov 64, %o1
7ae3aaf5 DM	368	1: EX_LD(LOAD_TWIN(%i1 + %g0, %o4, %o5), NG_ret_i2_plus_g1)
7ae3aaf5 DM	369	EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
25e5566e	370	LOAD(prefetch, %i1 + %o1, #one_read)
7ae3aaf5 DM	371	EX_ST(STORE_INIT(%o4, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
	372	EX_ST(STORE_INIT(%o5, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
	373	EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
	374	EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
	375	EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
	376	EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
25e5566e	377	add %i1, 64, %i1
7ae3aaf5 DM	378	EX_ST(STORE_INIT(%o4, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
	379	EX_ST(STORE_INIT(%o5, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
	380	EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
	381	EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
398d1083 DM	382	subcc %g1, 64, %g1
	383	bne,pt %XCC, 1b
	384	add %o0, 64, %o0
	385	/* fall through */
	386
	387	60:
24d559ca DM	388	membar #Sync
24d559ca DM	389
25e5566e	390	/* %i2 contains any final bytes still needed to be copied
398d1083 DM	391	* over. If anything is left, we copy it one byte at a time.
398d1083 DM	392	*/
25e5566e DM	393	RESTORE_ASI(%i3)
	394	brz,pt %i2, 85f
	395	sub %o0, %i1, %i3
398d1083	396	ba,a,pt %XCC, 90f
0ae2d26f	397	nop
398d1083 DM	398
	399	.align 64
	400	70: /* 16 < len <= 64 */
	401	bne,pn %XCC, 75f
25e5566e	402	sub %o0, %i1, %i3
398d1083 DM	403
398d1083 DM	404	72:
25e5566e DM	405	andn %i2, 0xf, %i4
	406	and %i2, 0xf, %i2
	407	1: subcc %i4, 0x10, %i4
7ae3aaf5	408	EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_i4)
25e5566e	409	add %i1, 0x08, %i1
7ae3aaf5	410	EX_LD(LOAD(ldx, %i1, %g1), NG_ret_i2_plus_i4)
25e5566e	411	sub %i1, 0x08, %i1
7ae3aaf5	412	EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_i4)
25e5566e	413	add %i1, 0x8, %i1
7ae3aaf5	414	EX_ST(STORE(stx, %g1, %i1 + %i3), NG_ret_i2_plus_i4_minus_8)
398d1083	415	bgu,pt %XCC, 1b
25e5566e DM	416	add %i1, 0x8, %i1
25e5566e DM	417	73: andcc %i2, 0x8, %g0
398d1083 DM	418	be,pt %XCC, 1f
398d1083 DM	419	nop
25e5566e	420	sub %i2, 0x8, %i2
7ae3aaf5 DM	421	EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_8)
7ae3aaf5 DM	422	EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_8)
25e5566e DM	423	add %i1, 0x8, %i1
25e5566e DM	424	1: andcc %i2, 0x4, %g0
398d1083 DM	425	be,pt %XCC, 1f
398d1083 DM	426	nop
25e5566e	427	sub %i2, 0x4, %i2
7ae3aaf5 DM	428	EX_LD(LOAD(lduw, %i1, %i5), NG_ret_i2_plus_4)
7ae3aaf5 DM	429	EX_ST(STORE(stw, %i5, %i1 + %i3), NG_ret_i2_plus_4)
25e5566e DM	430	add %i1, 0x4, %i1
25e5566e DM	431	1: cmp %i2, 0
398d1083 DM	432	be,pt %XCC, 85f
	433	nop
	434	ba,pt %xcc, 90f
	435	nop
	436
	437	75:
	438	andcc %o0, 0x7, %g1
	439	sub %g1, 0x8, %g1
	440	be,pn %icc, 2f
	441	sub %g0, %g1, %g1
25e5566e	442	sub %i2, %g1, %i2
398d1083 DM	443
398d1083 DM	444	1: subcc %g1, 1, %g1
7ae3aaf5 DM	445	EX_LD(LOAD(ldub, %i1, %i5), NG_ret_i2_plus_g1_plus_1)
7ae3aaf5 DM	446	EX_ST(STORE(stb, %i5, %i1 + %i3), NG_ret_i2_plus_g1_plus_1)
398d1083	447	bgu,pt %icc, 1b
25e5566e	448	add %i1, 1, %i1
398d1083	449
25e5566e DM	450	2: add %i1, %i3, %o0
25e5566e DM	451	andcc %i1, 0x7, %g1
398d1083 DM	452	bne,pt %icc, 8f
	453	sll %g1, 3, %g1
	454
25e5566e	455	cmp %i2, 16
398d1083 DM	456	bgeu,pt %icc, 72b
	457	nop
	458	ba,a,pt %xcc, 73b
	459
25e5566e DM	460	8: mov 64, %i3
25e5566e DM	461	andn %i1, 0x7, %i1
7ae3aaf5	462	EX_LD(LOAD(ldx, %i1, %g2), NG_ret_i2)
25e5566e DM	463	sub %i3, %g1, %i3
25e5566e DM	464	andn %i2, 0x7, %i4
398d1083	465	sllx %g2, %g1, %g2
25e5566e	466	1: add %i1, 0x8, %i1
7ae3aaf5	467	EX_LD(LOAD(ldx, %i1, %g3), NG_ret_i2_and_7_plus_i4)
25e5566e DM	468	subcc %i4, 0x8, %i4
	469	srlx %g3, %i3, %i5
	470	or %i5, %g2, %i5
7ae3aaf5	471	EX_ST(STORE(stx, %i5, %o0), NG_ret_i2_and_7_plus_i4)
398d1083 DM	472	add %o0, 0x8, %o0
	473	bgu,pt %icc, 1b
	474	sllx %g3, %g1, %g2
	475
	476	srl %g1, 3, %g1
25e5566e	477	andcc %i2, 0x7, %i2
398d1083	478	be,pn %icc, 85f
25e5566e	479	add %i1, %g1, %i1
398d1083	480	ba,pt %xcc, 90f
25e5566e	481	sub %o0, %i1, %i3
398d1083 DM	482
	483	.align 64
	484	80: /* 0 < len <= 16 */
25e5566e	485	andcc %i3, 0x3, %g0
398d1083	486	bne,pn %XCC, 90f
25e5566e	487	sub %o0, %i1, %i3
398d1083 DM	488
398d1083 DM	489	1:
25e5566e	490	subcc %i2, 4, %i2
7ae3aaf5 DM	491	EX_LD(LOAD(lduw, %i1, %g1), NG_ret_i2_plus_4)
7ae3aaf5 DM	492	EX_ST(STORE(stw, %g1, %i1 + %i3), NG_ret_i2_plus_4)
398d1083	493	bgu,pt %XCC, 1b
25e5566e	494	add %i1, 4, %i1
398d1083	495
25e5566e DM	496	85: ret
25e5566e DM	497	restore EX_RETVAL(%i0), %g0, %o0
398d1083 DM	498
	499	.align 32
	500	90:
25e5566e	501	subcc %i2, 1, %i2
7ae3aaf5 DM	502	EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_1)
7ae3aaf5 DM	503	EX_ST(STORE(stb, %g1, %i1 + %i3), NG_ret_i2_plus_1)
398d1083	504	bgu,pt %XCC, 90b
25e5566e DM	505	add %i1, 1, %i1
	506	ret
	507	restore EX_RETVAL(%i0), %g0, %o0
398d1083 DM	508
398d1083 DM	509	.size FUNC_NAME, .-FUNC_NAME