[mirror_ubuntu-hirsute-kernel.git] / arch / x86 / boot / compressed / head_64.S

/*
 *  linux/boot/head.S
 *
 *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
 */

/*
 *  head.S contains the 32-bit startup code.
 *
 * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
 * the page directory will exist. The startup code will be overwritten by
 * the page directory. [According to comments etc elsewhere on a compressed
 * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
 *
 * Page 0 is deliberately kept safe, since System Management Mode code in 
 * laptops may need to access the BIOS data stored there.  This is also
 * useful for future device drivers that either access the BIOS via VM86 
 * mode.
 */

/*
 * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
 */
	.code32
	.text

#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/segment.h>
#include <asm/pgtable_types.h>
#include <asm/page_types.h>
#include <asm/boot.h>
#include <asm/msr.h>
#include <asm/processor-flags.h>
#include <asm/asm-offsets.h>

	__HEAD
	.code32
ENTRY(startup_32)
	/*
	 * 32bit entry is 0 and it is ABI so immutable!
	 * If we come here directly from a bootloader,
	 * kernel(text+data+bss+brk) ramdisk, zero_page, command line
	 * all need to be under the 4G limit.
	 */
	cld
	/*
	 * Test KEEP_SEGMENTS flag to see if the bootloader is asking
	 * us to not reload segments
	 */
	testb $(1<<6), BP_loadflags(%esi)
	jnz 1f

	cli
	movl	$(__KERNEL_DS), %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
1:

/*
 * Calculate the delta between where we were compiled to run
 * at and where we were actually loaded at.  This can only be done
 * with a short local call on x86.  Nothing  else will tell us what
 * address we are running at.  The reserved chunk of the real-mode
 * data at 0x1e4 (defined as a scratch field) are used as the stack
 * for this calculation. Only 4 bytes are needed.
 */
	leal	(BP_scratch+4)(%esi), %esp
	call	1f
1:	popl	%ebp
	subl	$1b, %ebp

/* setup a stack and make sure cpu supports long mode. */
	movl	$boot_stack_end, %eax
	addl	%ebp, %eax
	movl	%eax, %esp

	call	verify_cpu
	testl	%eax, %eax
	jnz	no_longmode

/*
 * Compute the delta between where we were compiled to run at
 * and where the code will actually run at.
 *
 * %ebp contains the address we are loaded at by the boot loader and %ebx
 * contains the address where we should move the kernel image temporarily
 * for safe in-place decompression.
 */

#ifdef CONFIG_RELOCATABLE
	movl	%ebp, %ebx
	movl	BP_kernel_alignment(%esi), %eax
	decl	%eax
	addl	%eax, %ebx
	notl	%eax
	andl	%eax, %ebx
#else
	movl	$LOAD_PHYSICAL_ADDR, %ebx
#endif

	/* Target address to relocate to for decompression */
	addl	$z_extract_offset, %ebx

/*
 * Prepare for entering 64 bit mode
 */

	/* Load new GDT with the 64bit segments using 32bit descriptor */
	leal	gdt(%ebp), %eax
	movl	%eax, gdt+2(%ebp)
	lgdt	gdt(%ebp)

	/* Enable PAE mode */
	movl	$(X86_CR4_PAE), %eax
	movl	%eax, %cr4

 /*
  * Build early 4G boot pagetable
  */
	/* Initialize Page tables to 0 */
	leal	pgtable(%ebx), %edi
	xorl	%eax, %eax
	movl	$((4096*6)/4), %ecx
	rep	stosl

	/* Build Level 4 */
	leal	pgtable + 0(%ebx), %edi
	leal	0x1007 (%edi), %eax
	movl	%eax, 0(%edi)

	/* Build Level 3 */
	leal	pgtable + 0x1000(%ebx), %edi
	leal	0x1007(%edi), %eax
	movl	$4, %ecx
1:	movl	%eax, 0x00(%edi)
	addl	$0x00001000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Build Level 2 */
	leal	pgtable + 0x2000(%ebx), %edi
	movl	$0x00000183, %eax
	movl	$2048, %ecx
1:	movl	%eax, 0(%edi)
	addl	$0x00200000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Enable the boot page tables */
	leal	pgtable(%ebx), %eax
	movl	%eax, %cr3

	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_LME, %eax
	wrmsr

	/* After gdt is loaded */
	xorl	%eax, %eax
	lldt	%ax
	movl    $0x20, %eax
	ltr	%ax

	/*
	 * Setup for the jump to 64bit mode
	 *
	 * When the jump is performend we will be in long mode but
	 * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	 * (and in turn EFER.LMA = 1).	To jump into 64bit mode we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 * We place all of the values on our mini stack so lret can
	 * used to perform that far jump.
	 */
	pushl	$__KERNEL_CS
	leal	startup_64(%ebp), %eax
	pushl	%eax

	/* Enter paged protected Mode, activating Long Mode */
	movl	$(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
	movl	%eax, %cr0

	/* Jump from 32bit compatibility mode into 64bit mode. */
	lret
ENDPROC(startup_32)

	.code64
	.org 0x200
ENTRY(startup_64)
	/*
	 * 64bit entry is 0x200 and it is ABI so immutable!
	 * We come here either from startup_32 or directly from a
	 * 64bit bootloader.
	 * If we come here from a bootloader, kernel(text+data+bss+brk),
	 * ramdisk, zero_page, command line could be above 4G.
	 * We depend on an identity mapped page table being provided
	 * that maps our entire kernel(text+data+bss+brk), zero page
	 * and command line.
	 */
#ifdef CONFIG_EFI_STUB
	/*
	 * The entry point for the PE/COFF executable is efi_pe_entry, so
	 * only legacy boot loaders will execute this jmp.
	 */
	jmp	preferred_addr

ENTRY(efi_pe_entry)
	mov	%rcx, %rdi
	mov	%rdx, %rsi
	pushq	%rdi
	pushq	%rsi
	call	make_boot_params
	cmpq	$0,%rax
	je	1f
	mov	%rax, %rdx
	popq	%rsi
	popq	%rdi

ENTRY(efi_stub_entry)
	call	efi_main
	movq	%rax,%rsi
	cmpq	$0,%rax
	jne	2f
1:
	/* EFI init failed, so hang. */
	hlt
	jmp	1b
2:
	call	3f
3:
	popq	%rax
	subq	$3b, %rax
	subq	BP_pref_address(%rsi), %rax
	add	BP_code32_start(%esi), %eax
	leaq	preferred_addr(%rax), %rax
	jmp	*%rax

preferred_addr:
#endif

	/* Setup data segments. */
	xorl	%eax, %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
	movl	%eax, %fs
	movl	%eax, %gs

	/*
	 * Compute the decompressed kernel start address.  It is where
	 * we were loaded at aligned to a 2M boundary. %rbp contains the
	 * decompressed kernel start address.
	 *
	 * If it is a relocatable kernel then decompress and run the kernel
	 * from load address aligned to 2MB addr, otherwise decompress and
	 * run the kernel from LOAD_PHYSICAL_ADDR
	 *
	 * We cannot rely on the calculation done in 32-bit mode, since we
	 * may have been invoked via the 64-bit entry point.
	 */

	/* Start with the delta to where the kernel will run at. */
#ifdef CONFIG_RELOCATABLE
	leaq	startup_32(%rip) /* - $startup_32 */, %rbp
	movl	BP_kernel_alignment(%rsi), %eax
	decl	%eax
	addq	%rax, %rbp
	notq	%rax
	andq	%rax, %rbp
#else
	movq	$LOAD_PHYSICAL_ADDR, %rbp
#endif

	/* Target address to relocate to for decompression */
	leaq	z_extract_offset(%rbp), %rbx

	/* Set up the stack */
	leaq	boot_stack_end(%rbx), %rsp

	/* Zero EFLAGS */
	pushq	$0
	popfq

/*
 * Copy the compressed kernel to the end of our buffer
 * where decompression in place becomes safe.
 */
	pushq	%rsi
	leaq	(_bss-8)(%rip), %rsi
	leaq	(_bss-8)(%rbx), %rdi
	movq	$_bss /* - $startup_32 */, %rcx
	shrq	$3, %rcx
	std
	rep	movsq
	cld
	popq	%rsi

/*
 * Jump to the relocated address.
 */
	leaq	relocated(%rbx), %rax
	jmp	*%rax

	.text
relocated:

/*
 * Clear BSS (stack is currently empty)
 */
	xorl	%eax, %eax
	leaq    _bss(%rip), %rdi
	leaq    _ebss(%rip), %rcx
	subq	%rdi, %rcx
	shrq	$3, %rcx
	rep	stosq

/*
 * Adjust our own GOT
 */
	leaq	_got(%rip), %rdx
	leaq	_egot(%rip), %rcx
1:
	cmpq	%rcx, %rdx
	jae	2f
	addq	%rbx, (%rdx)
	addq	$8, %rdx
	jmp	1b
2:
	
/*
 * Do the decompression, and jump to the new kernel..
 */
	pushq	%rsi			/* Save the real mode argument */
	movq	%rsi, %rdi		/* real mode address */
	leaq	boot_heap(%rip), %rsi	/* malloc area for uncompression */
	leaq	input_data(%rip), %rdx  /* input_data */
	movl	$z_input_len, %ecx	/* input_len */
	movq	%rbp, %r8		/* output target address */
	call	decompress_kernel
	popq	%rsi

/*
 * Jump to the decompressed kernel.
 */
	jmp	*%rbp

	.code32
no_longmode:
	/* This isn't an x86-64 CPU so hang */
1:
	hlt
	jmp     1b

#include "../../kernel/verify_cpu.S"

	.data
gdt:
	.word	gdt_end - gdt
	.long	gdt
	.word	0
	.quad	0x0000000000000000	/* NULL descriptor */
	.quad	0x00af9a000000ffff	/* __KERNEL_CS */
	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
	.quad	0x0080890000000000	/* TS descriptor */
	.quad   0x0000000000000000	/* TS continued */
gdt_end:

/*
 * Stack and heap for uncompression
 */
	.bss
	.balign 4
boot_heap:
	.fill BOOT_HEAP_SIZE, 1, 0
boot_stack:
	.fill BOOT_STACK_SIZE, 1, 0
boot_stack_end:

/*
 * Space for page tables (not in .bss so not zeroed)
 */
	.section ".pgtable","a",@nobits
	.balign 4096
pgtable:
	.fill 6*4096, 1, 0
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/boot/head.S
	3	*
	4	* Copyright (C) 1991, 1992, 1993 Linus Torvalds
1da177e4 LT	5	*/
	6
	7	/*
	8	* head.S contains the 32-bit startup code.
	9	*
	10	* NOTE!!! Startup happens at absolute address 0x00001000, which is also where
	11	* the page directory will exist. The startup code will be overwritten by
	12	* the page directory. [According to comments etc elsewhere on a compressed
	13	* kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
	14	*
	15	* Page 0 is deliberately kept safe, since System Management Mode code in
	16	* laptops may need to access the BIOS data stored there. This is also
	17	* useful for future device drivers that either access the BIOS via VM86
	18	* mode.
	19	*/
	20
	21	/*
f4549448	22	* High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
1da177e4	23	*/
b40d68d5 PA	24	.code32
b40d68d5 PA	25	.text
1da177e4	26
1dc818c1	27	#include <linux/init.h>
1da177e4 LT	28	#include <linux/linkage.h>
1da177e4 LT	29	#include <asm/segment.h>
0341c14d JF	30	#include <asm/pgtable_types.h>
0341c14d JF	31	#include <asm/page_types.h>
7c539764	32	#include <asm/boot.h>
1ab60e0f	33	#include <asm/msr.h>
e83e31f4	34	#include <asm/processor-flags.h>
bd53147d	35	#include <asm/asm-offsets.h>
1da177e4	36
1dc818c1	37	__HEAD
1da177e4	38	.code32
2d4eeecb	39	ENTRY(startup_32)
8ee2f2df YL	40	/*
	41	* 32bit entry is 0 and it is ABI so immutable!
	42	* If we come here directly from a bootloader,
	43	* kernel(text+data+bss+brk) ramdisk, zero_page, command line
	44	* all need to be under the 4G limit.
	45	*/
1da177e4	46	cld
b40d68d5 PA	47	/*
	48	* Test KEEP_SEGMENTS flag to see if the bootloader is asking
	49	* us to not reload segments
	50	*/
bd53147d EB	51	testb $(1<<6), BP_loadflags(%esi)
	52	jnz 1f
	53
1da177e4	54	cli
1ab60e0f VG	55	movl $(__KERNEL_DS), %eax
	56	movl %eax, %ds
	57	movl %eax, %es
	58	movl %eax, %ss
bd53147d	59	1:
1ab60e0f	60
b40d68d5 PA	61	/*
b40d68d5 PA	62	* Calculate the delta between where we were compiled to run
1ab60e0f VG	63	* at and where we were actually loaded at. This can only be done
	64	* with a short local call on x86. Nothing else will tell us what
	65	* address we are running at. The reserved chunk of the real-mode
85414b69 PA	66	* data at 0x1e4 (defined as a scratch field) are used as the stack
85414b69 PA	67	* for this calculation. Only 4 bytes are needed.
1ab60e0f	68	*/
bd2a3698	69	leal (BP_scratch+4)(%esi), %esp
1ab60e0f VG	70	call 1f
	71	1: popl %ebp
	72	subl $1b, %ebp
	73
a4831e08	74	/* setup a stack and make sure cpu supports long mode. */
7c539764	75	movl $boot_stack_end, %eax
a4831e08 VG	76	addl %ebp, %eax
	77	movl %eax, %esp
	78
	79	call verify_cpu
	80	testl %eax, %eax
	81	jnz no_longmode
	82
b40d68d5 PA	83	/*
b40d68d5 PA	84	* Compute the delta between where we were compiled to run at
1ab60e0f	85	* and where the code will actually run at.
b40d68d5 PA	86	*
b40d68d5 PA	87	* %ebp contains the address we are loaded at by the boot loader and %ebx
1ab60e0f VG	88	* contains the address where we should move the kernel image temporarily
	89	* for safe in-place decompression.
	90	*/
	91
	92	#ifdef CONFIG_RELOCATABLE
	93	movl %ebp, %ebx
37ba7ab5 PA	94	movl BP_kernel_alignment(%esi), %eax
	95	decl %eax
	96	addl %eax, %ebx
	97	notl %eax
	98	andl %eax, %ebx
1ab60e0f	99	#else
40b387a8	100	movl $LOAD_PHYSICAL_ADDR, %ebx
1ab60e0f VG	101	#endif
1ab60e0f VG	102
02a884c0 PA	103	/* Target address to relocate to for decompression */
02a884c0 PA	104	addl $z_extract_offset, %ebx
1da177e4 LT	105
1da177e4 LT	106	/*
1ab60e0f	107	* Prepare for entering 64 bit mode
1da177e4	108	*/
1ab60e0f VG	109
	110	/* Load new GDT with the 64bit segments using 32bit descriptor */
	111	leal gdt(%ebp), %eax
	112	movl %eax, gdt+2(%ebp)
	113	lgdt gdt(%ebp)
	114
	115	/* Enable PAE mode */
4868402d	116	movl $(X86_CR4_PAE), %eax
1ab60e0f VG	117	movl %eax, %cr4
	118
	119	/*
	120	* Build early 4G boot pagetable
	121	*/
b40d68d5	122	/* Initialize Page tables to 0 */
1ab60e0f VG	123	leal pgtable(%ebx), %edi
	124	xorl %eax, %eax
	125	movl $((4096*6)/4), %ecx
	126	rep stosl
	127
	128	/* Build Level 4 */
	129	leal pgtable + 0(%ebx), %edi
	130	leal 0x1007 (%edi), %eax
	131	movl %eax, 0(%edi)
	132
	133	/* Build Level 3 */
	134	leal pgtable + 0x1000(%ebx), %edi
	135	leal 0x1007(%edi), %eax
	136	movl $4, %ecx
	137	1: movl %eax, 0x00(%edi)
	138	addl $0x00001000, %eax
	139	addl $8, %edi
	140	decl %ecx
	141	jnz 1b
	142
	143	/* Build Level 2 */
	144	leal pgtable + 0x2000(%ebx), %edi
	145	movl $0x00000183, %eax
	146	movl $2048, %ecx
	147	1: movl %eax, 0(%edi)
	148	addl $0x00200000, %eax
	149	addl $8, %edi
	150	decl %ecx
	151	jnz 1b
	152
	153	/* Enable the boot page tables */
	154	leal pgtable(%ebx), %eax
	155	movl %eax, %cr3
	156
	157	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	158	movl $MSR_EFER, %ecx
	159	rdmsr
	160	btsl $_EFER_LME, %eax
	161	wrmsr
	162
d3c433bf YL	163	/* After gdt is loaded */
	164	xorl %eax, %eax
	165	lldt %ax
	166	movl $0x20, %eax
	167	ltr %ax
	168
b40d68d5 PA	169	/*
b40d68d5 PA	170	* Setup for the jump to 64bit mode
1ab60e0f VG	171	*
	172	* When the jump is performend we will be in long mode but
	173	* in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	174	* (and in turn EFER.LMA = 1). To jump into 64bit mode we use
	175	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	176	* We place all of the values on our mini stack so lret can
	177	* used to perform that far jump.
	178	*/
	179	pushl $__KERNEL_CS
	180	leal startup_64(%ebp), %eax
	181	pushl %eax
	182
	183	/* Enter paged protected Mode, activating Long Mode */
e83e31f4	184	movl $(X86_CR0_PG \| X86_CR0_PE), %eax /* Enable Paging and Protected mode */
1ab60e0f VG	185	movl %eax, %cr0
	186
	187	/* Jump from 32bit compatibility mode into 64bit mode. */
	188	lret
2d4eeecb	189	ENDPROC(startup_32)
1ab60e0f	190
1ab60e0f	191	.code64
a4831e08	192	.org 0x200
1ab60e0f	193	ENTRY(startup_64)
b40d68d5	194	/*
8ee2f2df	195	* 64bit entry is 0x200 and it is ABI so immutable!
b40d68d5	196	* We come here either from startup_32 or directly from a
8ee2f2df YL	197	* 64bit bootloader.
	198	* If we come here from a bootloader, kernel(text+data+bss+brk),
	199	* ramdisk, zero_page, command line could be above 4G.
	200	* We depend on an identity mapped page table being provided
	201	* that maps our entire kernel(text+data+bss+brk), zero page
	202	* and command line.
1ab60e0f	203	*/
291f3632	204	#ifdef CONFIG_EFI_STUB
b1994304	205	/*
99f857db DW	206	* The entry point for the PE/COFF executable is efi_pe_entry, so
99f857db DW	207	* only legacy boot loaders will execute this jmp.
b1994304 MF	208	*/
	209	jmp preferred_addr
	210
99f857db	211	ENTRY(efi_pe_entry)
291f3632 MF	212	mov %rcx, %rdi
291f3632 MF	213	mov %rdx, %rsi
9ca8f72a MF	214	pushq %rdi
	215	pushq %rsi
	216	call make_boot_params
	217	cmpq $0,%rax
	218	je 1f
	219	mov %rax, %rdx
	220	popq %rsi
	221	popq %rdi
	222
99f857db	223	ENTRY(efi_stub_entry)
291f3632	224	call efi_main
291f3632	225	movq %rax,%rsi
b1994304 MF	226	cmpq $0,%rax
b1994304 MF	227	jne 2f
291f3632	228	1:
b1994304 MF	229	/* EFI init failed, so hang. */
	230	hlt
	231	jmp 1b
	232	2:
	233	call 3f
	234	3:
291f3632	235	popq %rax
b1994304	236	subq $3b, %rax
291f3632 MF	237	subq BP_pref_address(%rsi), %rax
	238	add BP_code32_start(%esi), %eax
	239	leaq preferred_addr(%rax), %rax
	240	jmp *%rax
	241
	242	preferred_addr:
	243	#endif
1ab60e0f VG	244
	245	/* Setup data segments. */
	246	xorl %eax, %eax
	247	movl %eax, %ds
	248	movl %eax, %es
	249	movl %eax, %ss
08da5a2c ZA	250	movl %eax, %fs
08da5a2c ZA	251	movl %eax, %gs
1ab60e0f	252
b40d68d5 PA	253	/*
b40d68d5 PA	254	* Compute the decompressed kernel start address. It is where
1ab60e0f VG	255	* we were loaded at aligned to a 2M boundary. %rbp contains the
	256	* decompressed kernel start address.
	257	*
	258	* If it is a relocatable kernel then decompress and run the kernel
	259	* from load address aligned to 2MB addr, otherwise decompress and
40b387a8	260	* run the kernel from LOAD_PHYSICAL_ADDR
02a884c0 PA	261	*
	262	* We cannot rely on the calculation done in 32-bit mode, since we
	263	* may have been invoked via the 64-bit entry point.
1ab60e0f VG	264	*/
	265
	266	/* Start with the delta to where the kernel will run at. */
	267	#ifdef CONFIG_RELOCATABLE
	268	leaq startup_32(%rip) /* - $startup_32 */, %rbp
37ba7ab5 PA	269	movl BP_kernel_alignment(%rsi), %eax
	270	decl %eax
	271	addq %rax, %rbp
	272	notq %rax
	273	andq %rax, %rbp
1ab60e0f	274	#else
40b387a8	275	movq $LOAD_PHYSICAL_ADDR, %rbp
1ab60e0f VG	276	#endif
1ab60e0f VG	277
02a884c0 PA	278	/* Target address to relocate to for decompression */
02a884c0 PA	279	leaq z_extract_offset(%rbp), %rbx
1ab60e0f	280
0a137736 PA	281	/* Set up the stack */
	282	leaq boot_stack_end(%rbx), %rsp
	283
	284	/* Zero EFLAGS */
	285	pushq $0
	286	popfq
	287
b40d68d5 PA	288	/*
b40d68d5 PA	289	* Copy the compressed kernel to the end of our buffer
1ab60e0f VG	290	* where decompression in place becomes safe.
1ab60e0f VG	291	*/
36d3793c PA	292	pushq %rsi
	293	leaq (_bss-8)(%rip), %rsi
	294	leaq (_bss-8)(%rbx), %rdi
5b11f1ce	295	movq $_bss /* - $startup_32 */, %rcx
36d3793c PA	296	shrq $3, %rcx
	297	std
	298	rep movsq
	299	cld
	300	popq %rsi
1ab60e0f VG	301
	302	/*
	303	* Jump to the relocated address.
	304	*/
	305	leaq relocated(%rbx), %rax
	306	jmp *%rax
	307
b40d68d5	308	.text
1ab60e0f VG	309	relocated:
1ab60e0f VG	310
1da177e4	311	/*
0a137736	312	* Clear BSS (stack is currently empty)
1da177e4	313	*/
36d3793c PA	314	xorl %eax, %eax
	315	leaq _bss(%rip), %rdi
	316	leaq _ebss(%rip), %rcx
1ab60e0f	317	subq %rdi, %rcx
36d3793c PA	318	shrq $3, %rcx
36d3793c PA	319	rep stosq
1ab60e0f	320
22a57f58 PA	321	/*
	322	* Adjust our own GOT
	323	*/
	324	leaq _got(%rip), %rdx
	325	leaq _egot(%rip), %rcx
	326	1:
	327	cmpq %rcx, %rdx
	328	jae 2f
	329	addq %rbx, (%rdx)
	330	addq $8, %rdx
	331	jmp 1b
	332	2:
	333
1da177e4 LT	334	/*
	335	* Do the decompression, and jump to the new kernel..
	336	*/
02a884c0 PA	337	pushq %rsi /* Save the real mode argument */
	338	movq %rsi, %rdi /* real mode address */
	339	leaq boot_heap(%rip), %rsi /* malloc area for uncompression */
	340	leaq input_data(%rip), %rdx /* input_data */
	341	movl $z_input_len, %ecx /* input_len */
	342	movq %rbp, %r8 /* output target address */
1ab60e0f VG	343	call decompress_kernel
1ab60e0f VG	344	popq %rsi
1da177e4	345
1da177e4	346	/*
1ab60e0f	347	* Jump to the decompressed kernel.
1da177e4	348	*/
1ab60e0f	349	jmp *%rbp
1da177e4	350
187a8a73 YL	351	.code32
	352	no_longmode:
	353	/* This isn't an x86-64 CPU so hang */
	354	1:
	355	hlt
	356	jmp 1b
	357
	358	#include "../../kernel/verify_cpu.S"
	359
1ab60e0f VG	360	.data
	361	gdt:
	362	.word gdt_end - gdt
	363	.long gdt
	364	.word 0
	365	.quad 0x0000000000000000 /* NULL descriptor */
	366	.quad 0x00af9a000000ffff /* __KERNEL_CS */
	367	.quad 0x00cf92000000ffff /* __KERNEL_DS */
08da5a2c ZA	368	.quad 0x0080890000000000 /* TS descriptor */
08da5a2c ZA	369	.quad 0x0000000000000000 /* TS continued */
1ab60e0f	370	gdt_end:
7c539764	371
b40d68d5 PA	372	/*
	373	* Stack and heap for uncompression
	374	*/
	375	.bss
	376	.balign 4
7c539764 AH	377	boot_heap:
	378	.fill BOOT_HEAP_SIZE, 1, 0
	379	boot_stack:
	380	.fill BOOT_STACK_SIZE, 1, 0
	381	boot_stack_end:
5b11f1ce PA	382
	383	/*
	384	* Space for page tables (not in .bss so not zeroed)
	385	*/
	386	.section ".pgtable","a",@nobits
	387	.balign 4096
	388	pgtable:
	389	.fill 6*4096, 1, 0