[mirror_ubuntu-hirsute-kernel.git] / arch / x86 / boot / compressed / head_64.S

/*
 *  linux/boot/head.S
 *
 *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
 */

/*
 *  head.S contains the 32-bit startup code.
 *
 * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
 * the page directory will exist. The startup code will be overwritten by
 * the page directory. [According to comments etc elsewhere on a compressed
 * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
 *
 * Page 0 is deliberately kept safe, since System Management Mode code in 
 * laptops may need to access the BIOS data stored there.  This is also
 * useful for future device drivers that either access the BIOS via VM86 
 * mode.
 */

/*
 * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
 */
	.code32
	.text

#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/segment.h>
#include <asm/pgtable_types.h>
#include <asm/page_types.h>
#include <asm/boot.h>
#include <asm/msr.h>
#include <asm/processor-flags.h>
#include <asm/asm-offsets.h>

	__HEAD
	.code32
ENTRY(startup_32)
	cld
	/*
	 * Test KEEP_SEGMENTS flag to see if the bootloader is asking
	 * us to not reload segments
	 */
	testb $(1<<6), BP_loadflags(%esi)
	jnz 1f

	cli
	movl	$(__KERNEL_DS), %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
1:

/*
 * Calculate the delta between where we were compiled to run
 * at and where we were actually loaded at.  This can only be done
 * with a short local call on x86.  Nothing  else will tell us what
 * address we are running at.  The reserved chunk of the real-mode
 * data at 0x1e4 (defined as a scratch field) are used as the stack
 * for this calculation. Only 4 bytes are needed.
 */
	leal	(BP_scratch+4)(%esi), %esp
	call	1f
1:	popl	%ebp
	subl	$1b, %ebp

/* setup a stack and make sure cpu supports long mode. */
	movl	$boot_stack_end, %eax
	addl	%ebp, %eax
	movl	%eax, %esp

	call	verify_cpu
	testl	%eax, %eax
	jnz	no_longmode

/*
 * Compute the delta between where we were compiled to run at
 * and where the code will actually run at.
 *
 * %ebp contains the address we are loaded at by the boot loader and %ebx
 * contains the address where we should move the kernel image temporarily
 * for safe in-place decompression.
 */

#ifdef CONFIG_RELOCATABLE
	movl	%ebp, %ebx
	movl	BP_kernel_alignment(%esi), %eax
	decl	%eax
	addl	%eax, %ebx
	notl	%eax
	andl	%eax, %ebx
#else
	movl	$LOAD_PHYSICAL_ADDR, %ebx
#endif

	/* Target address to relocate to for decompression */
	addl	$z_extract_offset, %ebx

/*
 * Prepare for entering 64 bit mode
 */

	/* Load new GDT with the 64bit segments using 32bit descriptor */
	leal	gdt(%ebp), %eax
	movl	%eax, gdt+2(%ebp)
	lgdt	gdt(%ebp)

	/* Enable PAE mode */
	movl	$(X86_CR4_PAE), %eax
	movl	%eax, %cr4

 /*
  * Build early 4G boot pagetable
  */
	/* Initialize Page tables to 0 */
	leal	pgtable(%ebx), %edi
	xorl	%eax, %eax
	movl	$((4096*6)/4), %ecx
	rep	stosl

	/* Build Level 4 */
	leal	pgtable + 0(%ebx), %edi
	leal	0x1007 (%edi), %eax
	movl	%eax, 0(%edi)

	/* Build Level 3 */
	leal	pgtable + 0x1000(%ebx), %edi
	leal	0x1007(%edi), %eax
	movl	$4, %ecx
1:	movl	%eax, 0x00(%edi)
	addl	$0x00001000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Build Level 2 */
	leal	pgtable + 0x2000(%ebx), %edi
	movl	$0x00000183, %eax
	movl	$2048, %ecx
1:	movl	%eax, 0(%edi)
	addl	$0x00200000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Enable the boot page tables */
	leal	pgtable(%ebx), %eax
	movl	%eax, %cr3

	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_LME, %eax
	wrmsr

	/* After gdt is loaded */
	xorl	%eax, %eax
	lldt	%ax
	movl    $0x20, %eax
	ltr	%ax

	/*
	 * Setup for the jump to 64bit mode
	 *
	 * When the jump is performend we will be in long mode but
	 * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	 * (and in turn EFER.LMA = 1).	To jump into 64bit mode we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 * We place all of the values on our mini stack so lret can
	 * used to perform that far jump.
	 */
	pushl	$__KERNEL_CS
	leal	startup_64(%ebp), %eax
	pushl	%eax

	/* Enter paged protected Mode, activating Long Mode */
	movl	$(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
	movl	%eax, %cr0

	/* Jump from 32bit compatibility mode into 64bit mode. */
	lret
ENDPROC(startup_32)

	/*
	 * Be careful here startup_64 needs to be at a predictable
	 * address so I can export it in an ELF header.  Bootloaders
	 * should look at the ELF header to find this address, as
	 * it may change in the future.
	 */
	.code64
	.org 0x200
ENTRY(startup_64)
	/*
	 * We come here either from startup_32 or directly from a
	 * 64bit bootloader.  If we come here from a bootloader we depend on
	 * an identity mapped page table being provied that maps our
	 * entire text+data+bss and hopefully all of memory.
	 */
#ifdef CONFIG_EFI_STUB
	/*
	 * The entry point for the PE/COFF executable is 0x210, so only
	 * legacy boot loaders will execute this jmp.
	 */
	jmp	preferred_addr

	.org 0x210
	mov	%rcx, %rdi
	mov	%rdx, %rsi
	pushq	%rdi
	pushq	%rsi
	call	make_boot_params
	cmpq	$0,%rax
	je	1f
	mov	%rax, %rdx
	popq	%rsi
	popq	%rdi

	.org 0x230,0x90
	call	efi_main
	movq	%rax,%rsi
	cmpq	$0,%rax
	jne	2f
1:
	/* EFI init failed, so hang. */
	hlt
	jmp	1b
2:
	call	3f
3:
	popq	%rax
	subq	$3b, %rax
	subq	BP_pref_address(%rsi), %rax
	add	BP_code32_start(%esi), %eax
	leaq	preferred_addr(%rax), %rax
	jmp	*%rax

preferred_addr:
#endif

	/* Setup data segments. */
	xorl	%eax, %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
	movl	%eax, %fs
	movl	%eax, %gs

	/*
	 * Compute the decompressed kernel start address.  It is where
	 * we were loaded at aligned to a 2M boundary. %rbp contains the
	 * decompressed kernel start address.
	 *
	 * If it is a relocatable kernel then decompress and run the kernel
	 * from load address aligned to 2MB addr, otherwise decompress and
	 * run the kernel from LOAD_PHYSICAL_ADDR
	 *
	 * We cannot rely on the calculation done in 32-bit mode, since we
	 * may have been invoked via the 64-bit entry point.
	 */

	/* Start with the delta to where the kernel will run at. */
#ifdef CONFIG_RELOCATABLE
	leaq	startup_32(%rip) /* - $startup_32 */, %rbp
	movl	BP_kernel_alignment(%rsi), %eax
	decl	%eax
	addq	%rax, %rbp
	notq	%rax
	andq	%rax, %rbp
#else
	movq	$LOAD_PHYSICAL_ADDR, %rbp
#endif

	/* Target address to relocate to for decompression */
	leaq	z_extract_offset(%rbp), %rbx

	/* Set up the stack */
	leaq	boot_stack_end(%rbx), %rsp

	/* Zero EFLAGS */
	pushq	$0
	popfq

/*
 * Copy the compressed kernel to the end of our buffer
 * where decompression in place becomes safe.
 */
	pushq	%rsi
	leaq	(_bss-8)(%rip), %rsi
	leaq	(_bss-8)(%rbx), %rdi
	movq	$_bss /* - $startup_32 */, %rcx
	shrq	$3, %rcx
	std
	rep	movsq
	cld
	popq	%rsi

/*
 * Jump to the relocated address.
 */
	leaq	relocated(%rbx), %rax
	jmp	*%rax

	.text
relocated:

/*
 * Clear BSS (stack is currently empty)
 */
	xorl	%eax, %eax
	leaq    _bss(%rip), %rdi
	leaq    _ebss(%rip), %rcx
	subq	%rdi, %rcx
	shrq	$3, %rcx
	rep	stosq

/*
 * Adjust our own GOT
 */
	leaq	_got(%rip), %rdx
	leaq	_egot(%rip), %rcx
1:
	cmpq	%rcx, %rdx
	jae	2f
	addq	%rbx, (%rdx)
	addq	$8, %rdx
	jmp	1b
2:
	
/*
 * Do the decompression, and jump to the new kernel..
 */
	pushq	%rsi			/* Save the real mode argument */
	movq	%rsi, %rdi		/* real mode address */
	leaq	boot_heap(%rip), %rsi	/* malloc area for uncompression */
	leaq	input_data(%rip), %rdx  /* input_data */
	movl	$z_input_len, %ecx	/* input_len */
	movq	%rbp, %r8		/* output target address */
	call	decompress_kernel
	popq	%rsi

/*
 * Jump to the decompressed kernel.
 */
	jmp	*%rbp

	.code32
no_longmode:
	/* This isn't an x86-64 CPU so hang */
1:
	hlt
	jmp     1b

#include "../../kernel/verify_cpu.S"

	.data
gdt:
	.word	gdt_end - gdt
	.long	gdt
	.word	0
	.quad	0x0000000000000000	/* NULL descriptor */
	.quad	0x00af9a000000ffff	/* __KERNEL_CS */
	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
	.quad	0x0080890000000000	/* TS descriptor */
	.quad   0x0000000000000000	/* TS continued */
gdt_end:

/*
 * Stack and heap for uncompression
 */
	.bss
	.balign 4
boot_heap:
	.fill BOOT_HEAP_SIZE, 1, 0
boot_stack:
	.fill BOOT_STACK_SIZE, 1, 0
boot_stack_end:

/*
 * Space for page tables (not in .bss so not zeroed)
 */
	.section ".pgtable","a",@nobits
	.balign 4096
pgtable:
	.fill 6*4096, 1, 0
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/boot/head.S
	3	*
	4	* Copyright (C) 1991, 1992, 1993 Linus Torvalds
1da177e4 LT	5	*/
	6
	7	/*
	8	* head.S contains the 32-bit startup code.
	9	*
	10	* NOTE!!! Startup happens at absolute address 0x00001000, which is also where
	11	* the page directory will exist. The startup code will be overwritten by
	12	* the page directory. [According to comments etc elsewhere on a compressed
	13	* kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
	14	*
	15	* Page 0 is deliberately kept safe, since System Management Mode code in
	16	* laptops may need to access the BIOS data stored there. This is also
	17	* useful for future device drivers that either access the BIOS via VM86
	18	* mode.
	19	*/
	20
	21	/*
f4549448	22	* High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
1da177e4	23	*/
b40d68d5 PA	24	.code32
b40d68d5 PA	25	.text
1da177e4	26
1dc818c1	27	#include <linux/init.h>
1da177e4 LT	28	#include <linux/linkage.h>
1da177e4 LT	29	#include <asm/segment.h>
0341c14d JF	30	#include <asm/pgtable_types.h>
0341c14d JF	31	#include <asm/page_types.h>
7c539764	32	#include <asm/boot.h>
1ab60e0f	33	#include <asm/msr.h>
e83e31f4	34	#include <asm/processor-flags.h>
bd53147d	35	#include <asm/asm-offsets.h>
1da177e4	36
1dc818c1	37	__HEAD
1da177e4	38	.code32
2d4eeecb	39	ENTRY(startup_32)
1da177e4	40	cld
b40d68d5 PA	41	/*
	42	* Test KEEP_SEGMENTS flag to see if the bootloader is asking
	43	* us to not reload segments
	44	*/
bd53147d EB	45	testb $(1<<6), BP_loadflags(%esi)
	46	jnz 1f
	47
1da177e4	48	cli
1ab60e0f VG	49	movl $(__KERNEL_DS), %eax
	50	movl %eax, %ds
	51	movl %eax, %es
	52	movl %eax, %ss
bd53147d	53	1:
1ab60e0f	54
b40d68d5 PA	55	/*
b40d68d5 PA	56	* Calculate the delta between where we were compiled to run
1ab60e0f VG	57	* at and where we were actually loaded at. This can only be done
	58	* with a short local call on x86. Nothing else will tell us what
	59	* address we are running at. The reserved chunk of the real-mode
85414b69 PA	60	* data at 0x1e4 (defined as a scratch field) are used as the stack
85414b69 PA	61	* for this calculation. Only 4 bytes are needed.
1ab60e0f	62	*/
bd2a3698	63	leal (BP_scratch+4)(%esi), %esp
1ab60e0f VG	64	call 1f
	65	1: popl %ebp
	66	subl $1b, %ebp
	67
a4831e08	68	/* setup a stack and make sure cpu supports long mode. */
7c539764	69	movl $boot_stack_end, %eax
a4831e08 VG	70	addl %ebp, %eax
	71	movl %eax, %esp
	72
	73	call verify_cpu
	74	testl %eax, %eax
	75	jnz no_longmode
	76
b40d68d5 PA	77	/*
b40d68d5 PA	78	* Compute the delta between where we were compiled to run at
1ab60e0f	79	* and where the code will actually run at.
b40d68d5 PA	80	*
b40d68d5 PA	81	* %ebp contains the address we are loaded at by the boot loader and %ebx
1ab60e0f VG	82	* contains the address where we should move the kernel image temporarily
	83	* for safe in-place decompression.
	84	*/
	85
	86	#ifdef CONFIG_RELOCATABLE
	87	movl %ebp, %ebx
37ba7ab5 PA	88	movl BP_kernel_alignment(%esi), %eax
	89	decl %eax
	90	addl %eax, %ebx
	91	notl %eax
	92	andl %eax, %ebx
1ab60e0f	93	#else
40b387a8	94	movl $LOAD_PHYSICAL_ADDR, %ebx
1ab60e0f VG	95	#endif
1ab60e0f VG	96
02a884c0 PA	97	/* Target address to relocate to for decompression */
02a884c0 PA	98	addl $z_extract_offset, %ebx
1da177e4 LT	99
1da177e4 LT	100	/*
1ab60e0f	101	* Prepare for entering 64 bit mode
1da177e4	102	*/
1ab60e0f VG	103
	104	/* Load new GDT with the 64bit segments using 32bit descriptor */
	105	leal gdt(%ebp), %eax
	106	movl %eax, gdt+2(%ebp)
	107	lgdt gdt(%ebp)
	108
	109	/* Enable PAE mode */
4868402d	110	movl $(X86_CR4_PAE), %eax
1ab60e0f VG	111	movl %eax, %cr4
	112
	113	/*
	114	* Build early 4G boot pagetable
	115	*/
b40d68d5	116	/* Initialize Page tables to 0 */
1ab60e0f VG	117	leal pgtable(%ebx), %edi
	118	xorl %eax, %eax
	119	movl $((4096*6)/4), %ecx
	120	rep stosl
	121
	122	/* Build Level 4 */
	123	leal pgtable + 0(%ebx), %edi
	124	leal 0x1007 (%edi), %eax
	125	movl %eax, 0(%edi)
	126
	127	/* Build Level 3 */
	128	leal pgtable + 0x1000(%ebx), %edi
	129	leal 0x1007(%edi), %eax
	130	movl $4, %ecx
	131	1: movl %eax, 0x00(%edi)
	132	addl $0x00001000, %eax
	133	addl $8, %edi
	134	decl %ecx
	135	jnz 1b
	136
	137	/* Build Level 2 */
	138	leal pgtable + 0x2000(%ebx), %edi
	139	movl $0x00000183, %eax
	140	movl $2048, %ecx
	141	1: movl %eax, 0(%edi)
	142	addl $0x00200000, %eax
	143	addl $8, %edi
	144	decl %ecx
	145	jnz 1b
	146
	147	/* Enable the boot page tables */
	148	leal pgtable(%ebx), %eax
	149	movl %eax, %cr3
	150
	151	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	152	movl $MSR_EFER, %ecx
	153	rdmsr
	154	btsl $_EFER_LME, %eax
	155	wrmsr
	156
d3c433bf YL	157	/* After gdt is loaded */
	158	xorl %eax, %eax
	159	lldt %ax
	160	movl $0x20, %eax
	161	ltr %ax
	162
b40d68d5 PA	163	/*
b40d68d5 PA	164	* Setup for the jump to 64bit mode
1ab60e0f VG	165	*
	166	* When the jump is performend we will be in long mode but
	167	* in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	168	* (and in turn EFER.LMA = 1). To jump into 64bit mode we use
	169	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	170	* We place all of the values on our mini stack so lret can
	171	* used to perform that far jump.
	172	*/
	173	pushl $__KERNEL_CS
	174	leal startup_64(%ebp), %eax
	175	pushl %eax
	176
	177	/* Enter paged protected Mode, activating Long Mode */
e83e31f4	178	movl $(X86_CR0_PG \| X86_CR0_PE), %eax /* Enable Paging and Protected mode */
1ab60e0f VG	179	movl %eax, %cr0
	180
	181	/* Jump from 32bit compatibility mode into 64bit mode. */
	182	lret
2d4eeecb	183	ENDPROC(startup_32)
1ab60e0f	184
b40d68d5 PA	185	/*
b40d68d5 PA	186	* Be careful here startup_64 needs to be at a predictable
1ab60e0f VG	187	* address so I can export it in an ELF header. Bootloaders
	188	* should look at the ELF header to find this address, as
	189	* it may change in the future.
	190	*/
	191	.code64
a4831e08	192	.org 0x200
1ab60e0f	193	ENTRY(startup_64)
b40d68d5 PA	194	/*
b40d68d5 PA	195	* We come here either from startup_32 or directly from a
1ab60e0f VG	196	* 64bit bootloader. If we come here from a bootloader we depend on
	197	* an identity mapped page table being provied that maps our
	198	* entire text+data+bss and hopefully all of memory.
	199	*/
291f3632	200	#ifdef CONFIG_EFI_STUB
b1994304 MF	201	/*
	202	* The entry point for the PE/COFF executable is 0x210, so only
	203	* legacy boot loaders will execute this jmp.
	204	*/
	205	jmp preferred_addr
	206
	207	.org 0x210
291f3632 MF	208	mov %rcx, %rdi
291f3632 MF	209	mov %rdx, %rsi
9ca8f72a MF	210	pushq %rdi
	211	pushq %rsi
	212	call make_boot_params
	213	cmpq $0,%rax
	214	je 1f
	215	mov %rax, %rdx
	216	popq %rsi
	217	popq %rdi
	218
	219	.org 0x230,0x90
291f3632	220	call efi_main
291f3632	221	movq %rax,%rsi
b1994304 MF	222	cmpq $0,%rax
b1994304 MF	223	jne 2f
291f3632	224	1:
b1994304 MF	225	/* EFI init failed, so hang. */
	226	hlt
	227	jmp 1b
	228	2:
	229	call 3f
	230	3:
291f3632	231	popq %rax
b1994304	232	subq $3b, %rax
291f3632 MF	233	subq BP_pref_address(%rsi), %rax
	234	add BP_code32_start(%esi), %eax
	235	leaq preferred_addr(%rax), %rax
	236	jmp *%rax
	237
	238	preferred_addr:
	239	#endif
1ab60e0f VG	240
	241	/* Setup data segments. */
	242	xorl %eax, %eax
	243	movl %eax, %ds
	244	movl %eax, %es
	245	movl %eax, %ss
08da5a2c ZA	246	movl %eax, %fs
08da5a2c ZA	247	movl %eax, %gs
1ab60e0f	248
b40d68d5 PA	249	/*
b40d68d5 PA	250	* Compute the decompressed kernel start address. It is where
1ab60e0f VG	251	* we were loaded at aligned to a 2M boundary. %rbp contains the
	252	* decompressed kernel start address.
	253	*
	254	* If it is a relocatable kernel then decompress and run the kernel
	255	* from load address aligned to 2MB addr, otherwise decompress and
40b387a8	256	* run the kernel from LOAD_PHYSICAL_ADDR
02a884c0 PA	257	*
	258	* We cannot rely on the calculation done in 32-bit mode, since we
	259	* may have been invoked via the 64-bit entry point.
1ab60e0f VG	260	*/
	261
	262	/* Start with the delta to where the kernel will run at. */
	263	#ifdef CONFIG_RELOCATABLE
	264	leaq startup_32(%rip) /* - $startup_32 */, %rbp
37ba7ab5 PA	265	movl BP_kernel_alignment(%rsi), %eax
	266	decl %eax
	267	addq %rax, %rbp
	268	notq %rax
	269	andq %rax, %rbp
1ab60e0f	270	#else
40b387a8	271	movq $LOAD_PHYSICAL_ADDR, %rbp
1ab60e0f VG	272	#endif
1ab60e0f VG	273
02a884c0 PA	274	/* Target address to relocate to for decompression */
02a884c0 PA	275	leaq z_extract_offset(%rbp), %rbx
1ab60e0f	276
0a137736 PA	277	/* Set up the stack */
	278	leaq boot_stack_end(%rbx), %rsp
	279
	280	/* Zero EFLAGS */
	281	pushq $0
	282	popfq
	283
b40d68d5 PA	284	/*
b40d68d5 PA	285	* Copy the compressed kernel to the end of our buffer
1ab60e0f VG	286	* where decompression in place becomes safe.
1ab60e0f VG	287	*/
36d3793c PA	288	pushq %rsi
	289	leaq (_bss-8)(%rip), %rsi
	290	leaq (_bss-8)(%rbx), %rdi
5b11f1ce	291	movq $_bss /* - $startup_32 */, %rcx
36d3793c PA	292	shrq $3, %rcx
	293	std
	294	rep movsq
	295	cld
	296	popq %rsi
1ab60e0f VG	297
	298	/*
	299	* Jump to the relocated address.
	300	*/
	301	leaq relocated(%rbx), %rax
	302	jmp *%rax
	303
b40d68d5	304	.text
1ab60e0f VG	305	relocated:
1ab60e0f VG	306
1da177e4	307	/*
0a137736	308	* Clear BSS (stack is currently empty)
1da177e4	309	*/
36d3793c PA	310	xorl %eax, %eax
	311	leaq _bss(%rip), %rdi
	312	leaq _ebss(%rip), %rcx
1ab60e0f	313	subq %rdi, %rcx
36d3793c PA	314	shrq $3, %rcx
36d3793c PA	315	rep stosq
1ab60e0f	316
22a57f58 PA	317	/*
	318	* Adjust our own GOT
	319	*/
	320	leaq _got(%rip), %rdx
	321	leaq _egot(%rip), %rcx
	322	1:
	323	cmpq %rcx, %rdx
	324	jae 2f
	325	addq %rbx, (%rdx)
	326	addq $8, %rdx
	327	jmp 1b
	328	2:
	329
1da177e4 LT	330	/*
	331	* Do the decompression, and jump to the new kernel..
	332	*/
02a884c0 PA	333	pushq %rsi /* Save the real mode argument */
	334	movq %rsi, %rdi /* real mode address */
	335	leaq boot_heap(%rip), %rsi /* malloc area for uncompression */
	336	leaq input_data(%rip), %rdx /* input_data */
	337	movl $z_input_len, %ecx /* input_len */
	338	movq %rbp, %r8 /* output target address */
1ab60e0f VG	339	call decompress_kernel
1ab60e0f VG	340	popq %rsi
1da177e4	341
1da177e4	342	/*
1ab60e0f	343	* Jump to the decompressed kernel.
1da177e4	344	*/
1ab60e0f	345	jmp *%rbp
1da177e4	346
187a8a73 YL	347	.code32
	348	no_longmode:
	349	/* This isn't an x86-64 CPU so hang */
	350	1:
	351	hlt
	352	jmp 1b
	353
	354	#include "../../kernel/verify_cpu.S"
	355
1ab60e0f VG	356	.data
	357	gdt:
	358	.word gdt_end - gdt
	359	.long gdt
	360	.word 0
	361	.quad 0x0000000000000000 /* NULL descriptor */
	362	.quad 0x00af9a000000ffff /* __KERNEL_CS */
	363	.quad 0x00cf92000000ffff /* __KERNEL_DS */
08da5a2c ZA	364	.quad 0x0080890000000000 /* TS descriptor */
08da5a2c ZA	365	.quad 0x0000000000000000 /* TS continued */
1ab60e0f	366	gdt_end:
7c539764	367
b40d68d5 PA	368	/*
	369	* Stack and heap for uncompression
	370	*/
	371	.bss
	372	.balign 4
7c539764 AH	373	boot_heap:
	374	.fill BOOT_HEAP_SIZE, 1, 0
	375	boot_stack:
	376	.fill BOOT_STACK_SIZE, 1, 0
	377	boot_stack_end:
5b11f1ce PA	378
	379	/*
	380	* Space for page tables (not in .bss so not zeroed)
	381	*/
	382	.section ".pgtable","a",@nobits
	383	.balign 4096
	384	pgtable:
	385	.fill 6*4096, 1, 0