[mirror_ubuntu-bionic-kernel.git] / arch / x86 / entry / vdso / vdso-layout.lds.S

/* SPDX-License-Identifier: GPL-2.0 */
#include <asm/vdso.h>

/*
 * Linker script for vDSO.  This is an ELF shared object prelinked to
 * its virtual address, and with only one read-only segment.
 * This script controls its layout.
 */

#if defined(BUILD_VDSO64)
# define SHDR_SIZE 64
#elif defined(BUILD_VDSO32) || defined(BUILD_VDSOX32)
# define SHDR_SIZE 40
#else
# error unknown VDSO target
#endif

#define NUM_FAKE_SHDRS 13

SECTIONS
{
	/*
	 * User/kernel shared data is before the vDSO.  This may be a little
	 * uglier than putting it after the vDSO, but it avoids issues with
	 * non-allocatable things that dangle past the end of the PT_LOAD
	 * segment.
	 */

	vvar_start = . - 3 * PAGE_SIZE;
	vvar_page = vvar_start;

	/* Place all vvars at the offsets in asm/vvar.h. */
#define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
#define __VVAR_KERNEL_LDS
#include <asm/vvar.h>
#undef __VVAR_KERNEL_LDS
#undef EMIT_VVAR

	pvclock_page = vvar_start + PAGE_SIZE;
	hvclock_page = vvar_start + 2 * PAGE_SIZE;

	. = SIZEOF_HEADERS;

	.hash		: { *(.hash) }			:text
	.gnu.hash	: { *(.gnu.hash) }
	.dynsym		: { *(.dynsym) }
	.dynstr		: { *(.dynstr) }
	.gnu.version	: { *(.gnu.version) }
	.gnu.version_d	: { *(.gnu.version_d) }
	.gnu.version_r	: { *(.gnu.version_r) }

	.dynamic	: { *(.dynamic) }		:text	:dynamic

	.rodata		: {
		*(.rodata*)
		*(.data*)
		*(.sdata*)
		*(.got.plt) *(.got)
		*(.gnu.linkonce.d.*)
		*(.bss*)
		*(.dynbss*)
		*(.gnu.linkonce.b.*)

		/*
		 * Ideally this would live in a C file, but that won't
		 * work cleanly for x32 until we start building the x32
		 * C code using an x32 toolchain.
		 */
		VDSO_FAKE_SECTION_TABLE_START = .;
		. = . + NUM_FAKE_SHDRS * SHDR_SIZE;
		VDSO_FAKE_SECTION_TABLE_END = .;
	}						:text

	.fake_shstrtab	: { *(.fake_shstrtab) }		:text


	.note		: { *(.note.*) }		:text	:note

	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
	.eh_frame	: { KEEP (*(.eh_frame)) }	:text


	/*
	 * Text is well-separated from actual data: there's plenty of
	 * stuff that isn't used at runtime in between.
	 */

	.text		: { *(.text*) }			:text	=0x90909090,

	/*
	 * At the end so that eu-elflint stays happy when vdso2c strips
	 * these.  A better implementation would avoid allocating space
	 * for these.
	 */
	.altinstructions	: { *(.altinstructions) }	:text
	.altinstr_replacement	: { *(.altinstr_replacement) }	:text

	/DISCARD/ : {
		*(.discard)
		*(.discard.*)
		*(__bug_table)
	}
}

/*
 * Very old versions of ld do not recognize this name token; use the constant.
 */
#define PT_GNU_EH_FRAME	0x6474e550

/*
 * We must supply the ELF program headers explicitly to get just one
 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 */
PHDRS
{
	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
	note		PT_NOTE		FLAGS(4);		/* PF_R */
	eh_frame_hdr	PT_GNU_EH_FRAME;
}
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
18d0a6fd AL	2	#include <asm/vdso.h>
18d0a6fd AL	3
f6b46ebf RM	4	/*
	5	* Linker script for vDSO. This is an ELF shared object prelinked to
	6	* its virtual address, and with only one read-only segment.
	7	* This script controls its layout.
	8	*/
	9
bfad381c AL	10	#if defined(BUILD_VDSO64)
	11	# define SHDR_SIZE 64
	12	#elif defined(BUILD_VDSO32) \|\| defined(BUILD_VDSOX32)
	13	# define SHDR_SIZE 40
	14	#else
	15	# error unknown VDSO target
	16	#endif
	17
0e3727a8	18	#define NUM_FAKE_SHDRS 13
bfad381c	19
f6b46ebf RM	20	SECTIONS
f6b46ebf RM	21	{
e6577a7c AL	22	/*
	23	* User/kernel shared data is before the vDSO. This may be a little
	24	* uglier than putting it after the vDSO, but it avoids issues with
	25	* non-allocatable things that dangle past the end of the PT_LOAD
	26	* segment.
	27	*/
	28
90b20432	29	vvar_start = . - 3 * PAGE_SIZE;
e6577a7c AL	30	vvar_page = vvar_start;
	31
	32	/* Place all vvars at the offsets in asm/vvar.h. */
	33	#define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
	34	#define __VVAR_KERNEL_LDS
	35	#include <asm/vvar.h>
	36	#undef __VVAR_KERNEL_LDS
	37	#undef EMIT_VVAR
	38
1ed95e52	39	pvclock_page = vvar_start + PAGE_SIZE;
90b20432	40	hvclock_page = vvar_start + 2 * PAGE_SIZE;
e6577a7c	41
b0b49f26	42	. = SIZEOF_HEADERS;
f6b46ebf RM	43
	44	.hash : { *(.hash) } :text
	45	.gnu.hash : { *(.gnu.hash) }
	46	.dynsym : { *(.dynsym) }
	47	.dynstr : { *(.dynstr) }
	48	.gnu.version : { *(.gnu.version) }
	49	.gnu.version_d : { *(.gnu.version_d) }
	50	.gnu.version_r : { *(.gnu.version_r) }
	51
f6b46ebf RM	52	.dynamic : { *(.dynamic) } :text :dynamic
f6b46ebf RM	53
bfad381c AL	54	.rodata : {
bfad381c AL	55	(.rodata)
0e3727a8 AL	56	(.data)
	57	(.sdata)
	58	(.got.plt) (.got)
	59	(.gnu.linkonce.d.)
	60	(.bss)
	61	(.dynbss)
	62	(.gnu.linkonce.b.)
bfad381c AL	63
	64	/*
	65	* Ideally this would live in a C file, but that won't
	66	* work cleanly for x32 until we start building the x32
	67	* C code using an x32 toolchain.
	68	*/
	69	VDSO_FAKE_SECTION_TABLE_START = .;
	70	. = . + NUM_FAKE_SHDRS * SHDR_SIZE;
	71	VDSO_FAKE_SECTION_TABLE_END = .;
	72	} :text
	73
	74	.fake_shstrtab : { *(.fake_shstrtab) } :text
	75
f6b46ebf	76
0e3727a8 AL	77	.note : { (.note.) } :text :note
	78
	79	.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
	80	.eh_frame : { KEEP (*(.eh_frame)) } :text
	81
f6b46ebf RM	82
f6b46ebf RM	83	/*
0e3727a8 AL	84	* Text is well-separated from actual data: there's plenty of
0e3727a8 AL	85	* stuff that isn't used at runtime in between.
f6b46ebf	86	*/
f6b46ebf	87
378ed3cc AL	88	.text : { (.text) } :text =0x90909090,
378ed3cc AL	89
0e3727a8 AL	90	/*
	91	* At the end so that eu-elflint stays happy when vdso2c strips
	92	* these. A better implementation would avoid allocating space
	93	* for these.
	94	*/
	95	.altinstructions : { *(.altinstructions) } :text
	96	.altinstr_replacement : { *(.altinstr_replacement) } :text
	97
26f5ef2e PA	98	/DISCARD/ : {
	99	*(.discard)
	100	(.discard.)
5f56e716	101	*(__bug_table)
26f5ef2e	102	}
f6b46ebf RM	103	}
	104
	105	/*
	106	* Very old versions of ld do not recognize this name token; use the constant.
	107	*/
	108	#define PT_GNU_EH_FRAME 0x6474e550
	109
	110	/*
	111	* We must supply the ELF program headers explicitly to get just one
	112	* PT_LOAD segment, and set the flags explicitly to make segments read-only.
	113	*/
	114	PHDRS
	115	{
	116	text PT_LOAD FLAGS(5) FILEHDR PHDRS; /* PF_R\|PF_X */
	117	dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
	118	note PT_NOTE FLAGS(4); /* PF_R */
	119	eh_frame_hdr PT_GNU_EH_FRAME;
	120	}