[mirror_ubuntu-artful-kernel.git] / arch / x86 / kernel / mcount_64.S

/*
 *  linux/arch/x86_64/mcount_64.S
 *
 *  Copyright (C) 2014  Steven Rostedt, Red Hat Inc
 */

#include <linux/linkage.h>
#include <asm/ptrace.h>
#include <asm/ftrace.h>


	.code64
	.section .entry.text, "ax"


#ifdef CONFIG_FUNCTION_TRACER

#ifdef CC_USING_FENTRY
# define function_hook	__fentry__
#else
# define function_hook	mcount
#endif

/* All cases save the original rbp (8 bytes) */
#ifdef CONFIG_FRAME_POINTER
# ifdef CC_USING_FENTRY
/* Save parent and function stack frames (rip and rbp) */
#  define MCOUNT_FRAME_SIZE	(8+16*2)
# else
/* Save just function stack frame (rip and rbp) */
#  define MCOUNT_FRAME_SIZE	(8+16)
# endif
#else
/* No need to save a stack frame */
# define MCOUNT_FRAME_SIZE	8
#endif /* CONFIG_FRAME_POINTER */

/* Size of stack used to save mcount regs in save_mcount_regs */
#define MCOUNT_REG_SIZE		(SS+8 + MCOUNT_FRAME_SIZE)

/*
 * gcc -pg option adds a call to 'mcount' in most functions.
 * When -mfentry is used, the call is to 'fentry' and not 'mcount'
 * and is done before the function's stack frame is set up.
 * They both require a set of regs to be saved before calling
 * any C code and restored before returning back to the function.
 *
 * On boot up, all these calls are converted into nops. When tracing
 * is enabled, the call can jump to either ftrace_caller or
 * ftrace_regs_caller. Callbacks (tracing functions) that require
 * ftrace_regs_caller (like kprobes) need to have pt_regs passed to
 * it. For this reason, the size of the pt_regs structure will be
 * allocated on the stack and the required mcount registers will
 * be saved in the locations that pt_regs has them in.
 */

/*
 * @added: the amount of stack added before calling this
 *
 * After this is called, the following registers contain:
 *
 *  %rdi - holds the address that called the trampoline
 *  %rsi - holds the parent function (traced function's return address)
 *  %rdx - holds the original %rbp
 */
.macro save_mcount_regs added=0

	/* Always save the original rbp */
	pushq %rbp

#ifdef CONFIG_FRAME_POINTER
	/*
	 * Stack traces will stop at the ftrace trampoline if the frame pointer
	 * is not set up properly. If fentry is used, we need to save a frame
	 * pointer for the parent as well as the function traced, because the
	 * fentry is called before the stack frame is set up, where as mcount
	 * is called afterward.
	 */
#ifdef CC_USING_FENTRY
	/* Save the parent pointer (skip orig rbp and our return address) */
	pushq \added+8*2(%rsp)
	pushq %rbp
	movq %rsp, %rbp
	/* Save the return address (now skip orig rbp, rbp and parent) */
	pushq \added+8*3(%rsp)
#else
	/* Can't assume that rip is before this (unless added was zero) */
	pushq \added+8(%rsp)
#endif
	pushq %rbp
	movq %rsp, %rbp
#endif /* CONFIG_FRAME_POINTER */

	/*
	 * We add enough stack to save all regs.
	 */
	subq $(MCOUNT_REG_SIZE - MCOUNT_FRAME_SIZE), %rsp
	movq %rax, RAX(%rsp)
	movq %rcx, RCX(%rsp)
	movq %rdx, RDX(%rsp)
	movq %rsi, RSI(%rsp)
	movq %rdi, RDI(%rsp)
	movq %r8, R8(%rsp)
	movq %r9, R9(%rsp)
	/*
	 * Save the original RBP. Even though the mcount ABI does not
	 * require this, it helps out callers.
	 */
	movq MCOUNT_REG_SIZE-8(%rsp), %rdx
	movq %rdx, RBP(%rsp)

	/* Copy the parent address into %rsi (second parameter) */
#ifdef CC_USING_FENTRY
	movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
#else
	/* %rdx contains original %rbp */
	movq 8(%rdx), %rsi
#endif

	 /* Move RIP to its proper location */
	movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
	movq %rdi, RIP(%rsp)

	/*
	 * Now %rdi (the first parameter) has the return address of
	 * where ftrace_call returns. But the callbacks expect the
	 * address of the call itself.
	 */
	subq $MCOUNT_INSN_SIZE, %rdi
	.endm

.macro restore_mcount_regs
	movq R9(%rsp), %r9
	movq R8(%rsp), %r8
	movq RDI(%rsp), %rdi
	movq RSI(%rsp), %rsi
	movq RDX(%rsp), %rdx
	movq RCX(%rsp), %rcx
	movq RAX(%rsp), %rax

	/* ftrace_regs_caller can modify %rbp */
	movq RBP(%rsp), %rbp

	addq $MCOUNT_REG_SIZE, %rsp

	.endm

#ifdef CONFIG_DYNAMIC_FTRACE

ENTRY(function_hook)
	retq
END(function_hook)

ENTRY(ftrace_caller)
	/* save_mcount_regs fills in first two parameters */
	save_mcount_regs

GLOBAL(ftrace_caller_op_ptr)
	/* Load the ftrace_ops into the 3rd parameter */
	movq function_trace_op(%rip), %rdx

	/* regs go into 4th parameter (but make it NULL) */
	movq $0, %rcx

GLOBAL(ftrace_call)
	call ftrace_stub

	restore_mcount_regs

	/*
	 * The copied trampoline must call ftrace_return as it
	 * still may need to call the function graph tracer.
	 */
GLOBAL(ftrace_caller_end)

GLOBAL(ftrace_return)

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
GLOBAL(ftrace_graph_call)
	jmp ftrace_stub
#endif

GLOBAL(ftrace_stub)
	retq
END(ftrace_caller)

ENTRY(ftrace_regs_caller)
	/* Save the current flags before any operations that can change them */
	pushfq

	/* added 8 bytes to save flags */
	save_mcount_regs 8
	/* save_mcount_regs fills in first two parameters */

GLOBAL(ftrace_regs_caller_op_ptr)
	/* Load the ftrace_ops into the 3rd parameter */
	movq function_trace_op(%rip), %rdx

	/* Save the rest of pt_regs */
	movq %r15, R15(%rsp)
	movq %r14, R14(%rsp)
	movq %r13, R13(%rsp)
	movq %r12, R12(%rsp)
	movq %r11, R11(%rsp)
	movq %r10, R10(%rsp)
	movq %rbx, RBX(%rsp)
	/* Copy saved flags */
	movq MCOUNT_REG_SIZE(%rsp), %rcx
	movq %rcx, EFLAGS(%rsp)
	/* Kernel segments */
	movq $__KERNEL_DS, %rcx
	movq %rcx, SS(%rsp)
	movq $__KERNEL_CS, %rcx
	movq %rcx, CS(%rsp)
	/* Stack - skipping return address and flags */
	leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
	movq %rcx, RSP(%rsp)

	/* regs go into 4th parameter */
	leaq (%rsp), %rcx

GLOBAL(ftrace_regs_call)
	call ftrace_stub

	/* Copy flags back to SS, to restore them */
	movq EFLAGS(%rsp), %rax
	movq %rax, MCOUNT_REG_SIZE(%rsp)

	/* Handlers can change the RIP */
	movq RIP(%rsp), %rax
	movq %rax, MCOUNT_REG_SIZE+8(%rsp)

	/* restore the rest of pt_regs */
	movq R15(%rsp), %r15
	movq R14(%rsp), %r14
	movq R13(%rsp), %r13
	movq R12(%rsp), %r12
	movq R10(%rsp), %r10
	movq RBX(%rsp), %rbx

	restore_mcount_regs

	/* Restore flags */
	popfq

	/*
	 * As this jmp to ftrace_return can be a short jump
	 * it must not be copied into the trampoline.
	 * The trampoline will add the code to jump
	 * to the return.
	 */
GLOBAL(ftrace_regs_caller_end)

	jmp ftrace_return

END(ftrace_regs_caller)


#else /* ! CONFIG_DYNAMIC_FTRACE */

ENTRY(function_hook)
	cmpq $ftrace_stub, ftrace_trace_function
	jnz trace

fgraph_trace:
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	cmpq $ftrace_stub, ftrace_graph_return
	jnz ftrace_graph_caller

	cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
	jnz ftrace_graph_caller
#endif

GLOBAL(ftrace_stub)
	retq

trace:
	/* save_mcount_regs fills in first two parameters */
	save_mcount_regs

	/*
	 * When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
	 * set (see include/asm/ftrace.h and include/linux/ftrace.h).  Only the
	 * ip and parent ip are used and the list function is called when
	 * function tracing is enabled.
	 */
	call   *ftrace_trace_function

	restore_mcount_regs

	jmp fgraph_trace
END(function_hook)
#endif /* CONFIG_DYNAMIC_FTRACE */
#endif /* CONFIG_FUNCTION_TRACER */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
ENTRY(ftrace_graph_caller)
	/* Saves rbp into %rdx and fills first parameter  */
	save_mcount_regs

#ifdef CC_USING_FENTRY
	leaq MCOUNT_REG_SIZE+8(%rsp), %rsi
	movq $0, %rdx	/* No framepointers needed */
#else
	/* Save address of the return address of traced function */
	leaq 8(%rdx), %rsi
	/* ftrace does sanity checks against frame pointers */
	movq (%rdx), %rdx
#endif
	call	prepare_ftrace_return

	restore_mcount_regs

	retq
END(ftrace_graph_caller)

GLOBAL(return_to_handler)
	subq  $24, %rsp

	/* Save the return values */
	movq %rax, (%rsp)
	movq %rdx, 8(%rsp)
	movq %rbp, %rdi

	call ftrace_return_to_handler

	movq %rax, %rdi
	movq 8(%rsp), %rdx
	movq (%rsp), %rax
	addq $24, %rsp
	jmp *%rdi
#endif
Commit	Line	Data
e18eead3 SR	1	/*
	2	* linux/arch/x86_64/mcount_64.S
	3	*
	4	* Copyright (C) 2014 Steven Rostedt, Red Hat Inc
	5	*/
	6
	7	#include <linux/linkage.h>
	8	#include <asm/ptrace.h>
	9	#include <asm/ftrace.h>
	10
	11
	12	.code64
	13	.section .entry.text, "ax"
	14
	15
	16	#ifdef CONFIG_FUNCTION_TRACER
	17
	18	#ifdef CC_USING_FENTRY
	19	# define function_hook __fentry__
	20	#else
	21	# define function_hook mcount
	22	#endif
	23
0687c36e SRRH	24	/* All cases save the original rbp (8 bytes) */
	25	#ifdef CONFIG_FRAME_POINTER
	26	# ifdef CC_USING_FENTRY
	27	/* Save parent and function stack frames (rip and rbp) */
	28	# define MCOUNT_FRAME_SIZE (8+16*2)
	29	# else
	30	/* Save just function stack frame (rip and rbp) */
	31	# define MCOUNT_FRAME_SIZE (8+16)
	32	# endif
	33	#else
	34	/* No need to save a stack frame */
	35	# define MCOUNT_FRAME_SIZE 8
	36	#endif /* CONFIG_FRAME_POINTER */
	37
85f6f029	38	/* Size of stack used to save mcount regs in save_mcount_regs */
0687c36e	39	#define MCOUNT_REG_SIZE (SS+8 + MCOUNT_FRAME_SIZE)
85f6f029	40
05df710e SRRH	41	/*
	42	* gcc -pg option adds a call to 'mcount' in most functions.
	43	* When -mfentry is used, the call is to 'fentry' and not 'mcount'
	44	* and is done before the function's stack frame is set up.
	45	* They both require a set of regs to be saved before calling
	46	* any C code and restored before returning back to the function.
	47	*
	48	* On boot up, all these calls are converted into nops. When tracing
	49	* is enabled, the call can jump to either ftrace_caller or
	50	* ftrace_regs_caller. Callbacks (tracing functions) that require
	51	* ftrace_regs_caller (like kprobes) need to have pt_regs passed to
	52	* it. For this reason, the size of the pt_regs structure will be
	53	* allocated on the stack and the required mcount registers will
	54	* be saved in the locations that pt_regs has them in.
	55	*/
	56
f1ab00af SRRH	57	/*
	58	* @added: the amount of stack added before calling this
	59	*
	60	* After this is called, the following registers contain:
	61	*
	62	* %rdi - holds the address that called the trampoline
	63	* %rsi - holds the parent function (traced function's return address)
	64	* %rdx - holds the original %rbp
	65	*/
527aa75b	66	.macro save_mcount_regs added=0
0687c36e SRRH	67
	68	/* Always save the original rbp */
	69	pushq %rbp
	70
	71	#ifdef CONFIG_FRAME_POINTER
	72	/*
	73	* Stack traces will stop at the ftrace trampoline if the frame pointer
	74	* is not set up properly. If fentry is used, we need to save a frame
	75	* pointer for the parent as well as the function traced, because the
	76	* fentry is called before the stack frame is set up, where as mcount
	77	* is called afterward.
	78	*/
	79	#ifdef CC_USING_FENTRY
	80	/* Save the parent pointer (skip orig rbp and our return address) */
	81	pushq \added+8*2(%rsp)
	82	pushq %rbp
	83	movq %rsp, %rbp
	84	/* Save the return address (now skip orig rbp, rbp and parent) */
	85	pushq \added+8*3(%rsp)
	86	#else
	87	/* Can't assume that rip is before this (unless added was zero) */
	88	pushq \added+8(%rsp)
	89	#endif
	90	pushq %rbp
	91	movq %rsp, %rbp
	92	#endif /* CONFIG_FRAME_POINTER */
	93
	94	/*
	95	* We add enough stack to save all regs.
	96	*/
	97	subq $(MCOUNT_REG_SIZE - MCOUNT_FRAME_SIZE), %rsp
4bcdf152 SRRH	98	movq %rax, RAX(%rsp)
	99	movq %rcx, RCX(%rsp)
	100	movq %rdx, RDX(%rsp)
	101	movq %rsi, RSI(%rsp)
	102	movq %rdi, RDI(%rsp)
	103	movq %r8, R8(%rsp)
	104	movq %r9, R9(%rsp)
0687c36e SRRH	105	/*
	106	* Save the original RBP. Even though the mcount ABI does not
	107	* require this, it helps out callers.
	108	*/
	109	movq MCOUNT_REG_SIZE-8(%rsp), %rdx
	110	movq %rdx, RBP(%rsp)
	111
f1ab00af SRRH	112	/* Copy the parent address into %rsi (second parameter) */
	113	#ifdef CC_USING_FENTRY
	114	movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
	115	#else
	116	/* %rdx contains original %rbp */
	117	movq 8(%rdx), %rsi
	118	#endif
	119
4bcdf152	120	/* Move RIP to its proper location */
85f6f029	121	movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
094dfc54	122	movq %rdi, RIP(%rsp)
f1ab00af SRRH	123
	124	/*
	125	* Now %rdi (the first parameter) has the return address of
	126	* where ftrace_call returns. But the callbacks expect the
6a06bdbf	127	* address of the call itself.
f1ab00af SRRH	128	*/
f1ab00af SRRH	129	subq $MCOUNT_INSN_SIZE, %rdi
4bcdf152 SRRH	130	.endm
4bcdf152 SRRH	131
527aa75b	132	.macro restore_mcount_regs
4bcdf152 SRRH	133	movq R9(%rsp), %r9
	134	movq R8(%rsp), %r8
	135	movq RDI(%rsp), %rdi
	136	movq RSI(%rsp), %rsi
	137	movq RDX(%rsp), %rdx
	138	movq RCX(%rsp), %rcx
	139	movq RAX(%rsp), %rax
0687c36e SRRH	140
	141	/* ftrace_regs_caller can modify %rbp */
	142	movq RBP(%rsp), %rbp
	143
85f6f029	144	addq $MCOUNT_REG_SIZE, %rsp
0687c36e	145
4bcdf152 SRRH	146	.endm
4bcdf152 SRRH	147
76c2f13c SRRH	148	#ifdef CONFIG_DYNAMIC_FTRACE
	149
	150	ENTRY(function_hook)
	151	retq
	152	END(function_hook)
	153
e18eead3	154	ENTRY(ftrace_caller)
f1ab00af SRRH	155	/* save_mcount_regs fills in first two parameters */
	156	save_mcount_regs
	157
	158	GLOBAL(ftrace_caller_op_ptr)
	159	/* Load the ftrace_ops into the 3rd parameter */
	160	movq function_trace_op(%rip), %rdx
	161
e18eead3 SR	162	/* regs go into 4th parameter (but make it NULL) */
	163	movq $0, %rcx
	164
	165	GLOBAL(ftrace_call)
	166	call ftrace_stub
	167
05df710e	168	restore_mcount_regs
f3bea491 SRRH	169
	170	/*
	171	* The copied trampoline must call ftrace_return as it
	172	* still may need to call the function graph tracer.
	173	*/
	174	GLOBAL(ftrace_caller_end)
	175
	176	GLOBAL(ftrace_return)
e18eead3 SR	177
	178	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	179	GLOBAL(ftrace_graph_call)
	180	jmp ftrace_stub
	181	#endif
	182
	183	GLOBAL(ftrace_stub)
	184	retq
	185	END(ftrace_caller)
	186
	187	ENTRY(ftrace_regs_caller)
527aa75b	188	/* Save the current flags before any operations that can change them */
e18eead3 SR	189	pushfq
e18eead3 SR	190
527aa75b	191	/* added 8 bytes to save flags */
f1ab00af SRRH	192	save_mcount_regs 8
	193	/* save_mcount_regs fills in first two parameters */
	194
	195	GLOBAL(ftrace_regs_caller_op_ptr)
	196	/* Load the ftrace_ops into the 3rd parameter */
	197	movq function_trace_op(%rip), %rdx
e18eead3 SR	198
	199	/* Save the rest of pt_regs */
	200	movq %r15, R15(%rsp)
	201	movq %r14, R14(%rsp)
	202	movq %r13, R13(%rsp)
	203	movq %r12, R12(%rsp)
	204	movq %r11, R11(%rsp)
	205	movq %r10, R10(%rsp)
e18eead3 SR	206	movq %rbx, RBX(%rsp)
e18eead3 SR	207	/* Copy saved flags */
85f6f029	208	movq MCOUNT_REG_SIZE(%rsp), %rcx
e18eead3 SR	209	movq %rcx, EFLAGS(%rsp)
	210	/* Kernel segments */
	211	movq $__KERNEL_DS, %rcx
	212	movq %rcx, SS(%rsp)
	213	movq $__KERNEL_CS, %rcx
	214	movq %rcx, CS(%rsp)
527aa75b	215	/* Stack - skipping return address and flags */
85f6f029	216	leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
e18eead3 SR	217	movq %rcx, RSP(%rsp)
	218
	219	/* regs go into 4th parameter */
	220	leaq (%rsp), %rcx
	221
	222	GLOBAL(ftrace_regs_call)
	223	call ftrace_stub
	224
	225	/* Copy flags back to SS, to restore them */
	226	movq EFLAGS(%rsp), %rax
85f6f029	227	movq %rax, MCOUNT_REG_SIZE(%rsp)
e18eead3 SR	228
	229	/* Handlers can change the RIP */
	230	movq RIP(%rsp), %rax
85f6f029	231	movq %rax, MCOUNT_REG_SIZE+8(%rsp)
e18eead3 SR	232
	233	/* restore the rest of pt_regs */
	234	movq R15(%rsp), %r15
	235	movq R14(%rsp), %r14
	236	movq R13(%rsp), %r13
	237	movq R12(%rsp), %r12
	238	movq R10(%rsp), %r10
e18eead3 SR	239	movq RBX(%rsp), %rbx
e18eead3 SR	240
527aa75b	241	restore_mcount_regs
e18eead3 SR	242
	243	/* Restore flags */
	244	popfq
	245
f3bea491 SRRH	246	/*
	247	* As this jmp to ftrace_return can be a short jump
	248	* it must not be copied into the trampoline.
	249	* The trampoline will add the code to jump
	250	* to the return.
	251	*/
	252	GLOBAL(ftrace_regs_caller_end)
	253
e18eead3	254	jmp ftrace_return
fdc841b5	255
e18eead3 SR	256	END(ftrace_regs_caller)
	257
	258
	259	#else /* ! CONFIG_DYNAMIC_FTRACE */
	260
	261	ENTRY(function_hook)
e18eead3 SR	262	cmpq $ftrace_stub, ftrace_trace_function
	263	jnz trace
	264
62a207d7	265	fgraph_trace:
e18eead3 SR	266	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	267	cmpq $ftrace_stub, ftrace_graph_return
	268	jnz ftrace_graph_caller
	269
	270	cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
	271	jnz ftrace_graph_caller
	272	#endif
	273
	274	GLOBAL(ftrace_stub)
	275	retq
	276
	277	trace:
f1ab00af SRRH	278	/* save_mcount_regs fills in first two parameters */
f1ab00af SRRH	279	save_mcount_regs
e18eead3	280
112677d6 NK	281	/*
	282	* When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
	283	* set (see include/asm/ftrace.h and include/linux/ftrace.h). Only the
	284	* ip and parent ip are used and the list function is called when
	285	* function tracing is enabled.
	286	*/
e18eead3 SR	287	call *ftrace_trace_function
e18eead3 SR	288
05df710e	289	restore_mcount_regs
e18eead3	290
62a207d7	291	jmp fgraph_trace
e18eead3 SR	292	END(function_hook)
	293	#endif /* CONFIG_DYNAMIC_FTRACE */
	294	#endif /* CONFIG_FUNCTION_TRACER */
	295
	296	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	297	ENTRY(ftrace_graph_caller)
6a06bdbf	298	/* Saves rbp into %rdx and fills first parameter */
05df710e	299	save_mcount_regs
e18eead3 SR	300
e18eead3 SR	301	#ifdef CC_USING_FENTRY
6a06bdbf	302	leaq MCOUNT_REG_SIZE+8(%rsp), %rsi
e18eead3 SR	303	movq $0, %rdx /* No framepointers needed */
e18eead3 SR	304	#else
f1ab00af	305	/* Save address of the return address of traced function */
6a06bdbf	306	leaq 8(%rdx), %rsi
f1ab00af	307	/* ftrace does sanity checks against frame pointers */
0687c36e	308	movq (%rdx), %rdx
e18eead3	309	#endif
e18eead3 SR	310	call prepare_ftrace_return
e18eead3 SR	311
05df710e	312	restore_mcount_regs
e18eead3 SR	313
	314	retq
	315	END(ftrace_graph_caller)
	316
	317	GLOBAL(return_to_handler)
	318	subq $24, %rsp
	319
	320	/* Save the return values */
	321	movq %rax, (%rsp)
	322	movq %rdx, 8(%rsp)
	323	movq %rbp, %rdi
	324
	325	call ftrace_return_to_handler
	326
	327	movq %rax, %rdi
	328	movq 8(%rsp), %rdx
	329	movq (%rsp), %rax
	330	addq $24, %rsp
	331	jmp *%rdi
	332	#endif