projects / mirror_ubuntu-zesty-kernel.git / blame
| Commit | Line | Data |
|---|---|---|
| 1da177e4 LT |
1 | /* |
| 2 | * Linker script for vsyscall DSO. The vsyscall page is an ELF shared | |
| 3 | * object prelinked to its virtual address. This script controls its layout. | |
| 4 | */ | |
| 5 | ||
| 6 | /* This must match <asm/fixmap.h>. */ | |
| 7 | VSYSCALL_BASE = 0xffffe000; | |
| 8 | ||
| 9 | SECTIONS | |
| 10 | { | |
| 11 | . = VSYSCALL_BASE + SIZEOF_HEADERS; | |
| 12 | ||
| 13 | .hash : { *(.hash) } :text | |
| 14 | .dynsym : { *(.dynsym) } | |
| 15 | .dynstr : { *(.dynstr) } | |
| 16 | .gnu.version : { *(.gnu.version) } | |
| 17 | .gnu.version_d : { *(.gnu.version_d) } | |
| 18 | .gnu.version_r : { *(.gnu.version_r) } | |
| 19 | ||
| 20 | /* This linker script is used both with -r and with -shared. | |
| 21 | For the layouts to match, we need to skip more than enough | |
| 22 | space for the dynamic symbol table et al. If this amount | |
| 23 | is insufficient, ld -shared will barf. Just increase it here. */ | |
| 24 | . = VSYSCALL_BASE + 0x400; | |
| 25 | ||
| 26 | .text.vsyscall : { *(.text.vsyscall) } :text =0x90909090 | |
| 27 | ||
| 28 | /* This is an 32bit object and we cannot easily get the offsets | |
| 29 | into the 64bit kernel. Just hardcode them here. This assumes | |
| 30 | that all the stubs don't need more than 0x100 bytes. */ | |
| 31 | . = VSYSCALL_BASE + 0x500; | |
| 32 | ||
| 33 | .text.sigreturn : { *(.text.sigreturn) } :text =0x90909090 | |
| 34 | ||
| 35 | . = VSYSCALL_BASE + 0x600; | |
| 36 | ||
| 37 | .text.rtsigreturn : { *(.text.rtsigreturn) } :text =0x90909090 | |
| 38 | ||
| c60c3906 | 39 | .note : { *(.note.*) } :text :note |
| 1da177e4 LT |
40 | .eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr |
| 41 | .eh_frame : { KEEP (*(.eh_frame)) } :text | |
| 42 | .dynamic : { *(.dynamic) } :text :dynamic | |
| 43 | .useless : { | |
| 44 | *(.got.plt) *(.got) | |
| 45 | *(.data .data.* .gnu.linkonce.d.*) | |
| 46 | *(.dynbss) | |
| 47 | *(.bss .bss.* .gnu.linkonce.b.*) | |
| 48 | } :text | |
| 49 | } | |
| 50 | ||
| 51 | /* | |
| 52 | * We must supply the ELF program headers explicitly to get just one | |
| 53 | * PT_LOAD segment, and set the flags explicitly to make segments read-only. | |
| 54 | */ | |
| 55 | PHDRS | |
| 56 | { | |
| 57 | text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */ | |
| 58 | dynamic PT_DYNAMIC FLAGS(4); /* PF_R */ | |
| c60c3906 | 59 | note PT_NOTE FLAGS(4); /* PF_R */ |
| 1da177e4 LT |
60 | eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */ |
| 61 | } | |
| 62 | ||
| 63 | /* | |
| 64 | * This controls what symbols we export from the DSO. | |
| 65 | */ | |
| 66 | VERSION | |
| 67 | { | |
| 68 | LINUX_2.5 { | |
| 69 | global: | |
| 70 | __kernel_vsyscall; | |
| 71 | __kernel_sigreturn; | |
| 72 | __kernel_rt_sigreturn; | |
| 73 | ||
| 74 | local: *; | |
| 75 | }; | |
| 76 | } | |
| 77 | ||
| 78 | /* The ELF entry point can be used to set the AT_SYSINFO value. */ | |
| 79 | ENTRY(__kernel_vsyscall); |