[mirror_ubuntu-jammy-kernel.git] / include / asm-generic / vmlinux.lds.h

#ifndef LOAD_OFFSET
#define LOAD_OFFSET 0
#endif

#ifndef VMLINUX_SYMBOL
#define VMLINUX_SYMBOL(_sym_) _sym_
#endif

/* Align . to a 8 byte boundary equals to maximum function alignment. */
#define ALIGN_FUNCTION()  . = ALIGN(8)

/* The actual configuration determine if the init/exit sections
 * are handled as text/data or they can be discarded (which
 * often happens at runtime)
 */
#ifdef CONFIG_HOTPLUG
#define DEV_KEEP(sec)    *(.dev##sec)
#define DEV_DISCARD(sec)
#else
#define DEV_KEEP(sec)
#define DEV_DISCARD(sec) *(.dev##sec)
#endif

#ifdef CONFIG_HOTPLUG_CPU
#define CPU_KEEP(sec)    *(.cpu##sec)
#define CPU_DISCARD(sec)
#else
#define CPU_KEEP(sec)
#define CPU_DISCARD(sec) *(.cpu##sec)
#endif

#if defined(CONFIG_MEMORY_HOTPLUG)
#define MEM_KEEP(sec)    *(.mem##sec)
#define MEM_DISCARD(sec)
#else
#define MEM_KEEP(sec)
#define MEM_DISCARD(sec) *(.mem##sec)
#endif

#ifdef CONFIG_FTRACE_MCOUNT_RECORD
#define MCOUNT_REC()	VMLINUX_SYMBOL(__start_mcount_loc) = .; \
			*(__mcount_loc)				\
			VMLINUX_SYMBOL(__stop_mcount_loc) = .;
#else
#define MCOUNT_REC()
#endif

#ifdef CONFIG_TRACE_BRANCH_PROFILING
#define LIKELY_PROFILE()	VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
				*(_ftrace_annotated_branch)			      \
				VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
#else
#define LIKELY_PROFILE()
#endif

#ifdef CONFIG_PROFILE_ALL_BRANCHES
#define BRANCH_PROFILE()	VMLINUX_SYMBOL(__start_branch_profile) = .;   \
				*(_ftrace_branch)			      \
				VMLINUX_SYMBOL(__stop_branch_profile) = .;
#else
#define BRANCH_PROFILE()
#endif

#ifdef CONFIG_EVENT_TRACER
#define FTRACE_EVENTS()	VMLINUX_SYMBOL(__start_ftrace_events) = .;	\
			*(_ftrace_events)				\
			VMLINUX_SYMBOL(__stop_ftrace_events) = .;
#else
#define FTRACE_EVENTS()
#endif

#ifdef CONFIG_TRACING
#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
			 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
			 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
#else
#define TRACE_PRINTKS()
#endif

/* .data section */
#define DATA_DATA							\
	*(.data)							\
	*(.data.init.refok)						\
	*(.ref.data)							\
	DEV_KEEP(init.data)						\
	DEV_KEEP(exit.data)						\
	CPU_KEEP(init.data)						\
	CPU_KEEP(exit.data)						\
	MEM_KEEP(init.data)						\
	MEM_KEEP(exit.data)						\
	. = ALIGN(8);							\
	VMLINUX_SYMBOL(__start___markers) = .;				\
	*(__markers)							\
	VMLINUX_SYMBOL(__stop___markers) = .;				\
	. = ALIGN(32);							\
	VMLINUX_SYMBOL(__start___tracepoints) = .;			\
	*(__tracepoints)						\
	VMLINUX_SYMBOL(__stop___tracepoints) = .;			\
	LIKELY_PROFILE()		       				\
	BRANCH_PROFILE()						\
	TRACE_PRINTKS()							\
	FTRACE_EVENTS()

#define RO_DATA(align)							\
	. = ALIGN((align));						\
	.rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start_rodata) = .;			\
		*(.rodata) *(.rodata.*)					\
		*(__vermagic)		/* Kernel version magic */	\
		*(__markers_strings)	/* Markers: strings */		\
		*(__tracepoints_strings)/* Tracepoints: strings */	\
	}								\
									\
	.rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {		\
		*(.rodata1)						\
	}								\
									\
	BUG_TABLE							\
									\
	/* PCI quirks */						\
	.pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_pci_fixups_early) = .;		\
		*(.pci_fixup_early)					\
		VMLINUX_SYMBOL(__end_pci_fixups_early) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_header) = .;		\
		*(.pci_fixup_header)					\
		VMLINUX_SYMBOL(__end_pci_fixups_header) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_final) = .;		\
		*(.pci_fixup_final)					\
		VMLINUX_SYMBOL(__end_pci_fixups_final) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;		\
		*(.pci_fixup_enable)					\
		VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;		\
		*(.pci_fixup_resume)					\
		VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;	\
		*(.pci_fixup_resume_early)				\
		VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;	\
		VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;		\
		*(.pci_fixup_suspend)					\
		VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;		\
	}								\
									\
	/* Built-in firmware blobs */					\
	.builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_builtin_fw) = .;			\
		*(.builtin_fw)						\
		VMLINUX_SYMBOL(__end_builtin_fw) = .;			\
	}								\
									\
	/* RapidIO route ops */						\
	.rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_rio_route_ops) = .;		\
		*(.rio_route_ops)					\
		VMLINUX_SYMBOL(__end_rio_route_ops) = .;		\
	}								\
									\
	TRACEDATA							\
									\
	/* Kernel symbol table: Normal symbols */			\
	__ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___ksymtab) = .;			\
		*(__ksymtab)						\
		VMLINUX_SYMBOL(__stop___ksymtab) = .;			\
	}								\
									\
	/* Kernel symbol table: GPL-only symbols */			\
	__ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;		\
		*(__ksymtab_gpl)					\
		VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;		\
	}								\
									\
	/* Kernel symbol table: Normal unused symbols */		\
	__ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___ksymtab_unused) = .;		\
		*(__ksymtab_unused)					\
		VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;		\
	}								\
									\
	/* Kernel symbol table: GPL-only unused symbols */		\
	__ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;	\
		*(__ksymtab_unused_gpl)					\
		VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;	\
	}								\
									\
	/* Kernel symbol table: GPL-future-only symbols */		\
	__ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;	\
		*(__ksymtab_gpl_future)					\
		VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;	\
	}								\
									\
	/* Kernel symbol table: Normal symbols */			\
	__kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___kcrctab) = .;			\
		*(__kcrctab)						\
		VMLINUX_SYMBOL(__stop___kcrctab) = .;			\
	}								\
									\
	/* Kernel symbol table: GPL-only symbols */			\
	__kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;		\
		*(__kcrctab_gpl)					\
		VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;		\
	}								\
									\
	/* Kernel symbol table: Normal unused symbols */		\
	__kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___kcrctab_unused) = .;		\
		*(__kcrctab_unused)					\
		VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;		\
	}								\
									\
	/* Kernel symbol table: GPL-only unused symbols */		\
	__kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;	\
		*(__kcrctab_unused_gpl)					\
		VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;	\
	}								\
									\
	/* Kernel symbol table: GPL-future-only symbols */		\
	__kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;	\
		*(__kcrctab_gpl_future)					\
		VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;	\
	}								\
									\
	/* Kernel symbol table: strings */				\
        __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) {	\
		*(__ksymtab_strings)					\
	}								\
									\
	/* __*init sections */						\
	__init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {		\
		*(.ref.rodata)						\
		MCOUNT_REC()						\
		DEV_KEEP(init.rodata)					\
		DEV_KEEP(exit.rodata)					\
		CPU_KEEP(init.rodata)					\
		CPU_KEEP(exit.rodata)					\
		MEM_KEEP(init.rodata)					\
		MEM_KEEP(exit.rodata)					\
	}								\
									\
	/* Built-in module parameters. */				\
	__param : AT(ADDR(__param) - LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__start___param) = .;			\
		*(__param)						\
		VMLINUX_SYMBOL(__stop___param) = .;			\
		. = ALIGN((align));					\
		VMLINUX_SYMBOL(__end_rodata) = .;			\
	}								\
	. = ALIGN((align));

/* RODATA provided for backward compatibility.
 * All archs are supposed to use RO_DATA() */
#define RODATA RO_DATA(4096)

#define SECURITY_INIT							\
	.security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__security_initcall_start) = .;		\
		*(.security_initcall.init) 				\
		VMLINUX_SYMBOL(__security_initcall_end) = .;		\
	}

/* .text section. Map to function alignment to avoid address changes
 * during second ld run in second ld pass when generating System.map */
#define TEXT_TEXT							\
		ALIGN_FUNCTION();					\
		*(.text.hot)						\
		*(.text)						\
		*(.ref.text)						\
		*(.text.init.refok)					\
		*(.exit.text.refok)					\
	DEV_KEEP(init.text)						\
	DEV_KEEP(exit.text)						\
	CPU_KEEP(init.text)						\
	CPU_KEEP(exit.text)						\
	MEM_KEEP(init.text)						\
	MEM_KEEP(exit.text)						\
		*(.text.unlikely)


/* sched.text is aling to function alignment to secure we have same
 * address even at second ld pass when generating System.map */
#define SCHED_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__sched_text_start) = .;			\
		*(.sched.text)						\
		VMLINUX_SYMBOL(__sched_text_end) = .;

/* spinlock.text is aling to function alignment to secure we have same
 * address even at second ld pass when generating System.map */
#define LOCK_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__lock_text_start) = .;			\
		*(.spinlock.text)					\
		VMLINUX_SYMBOL(__lock_text_end) = .;

#define KPROBES_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__kprobes_text_start) = .;		\
		*(.kprobes.text)					\
		VMLINUX_SYMBOL(__kprobes_text_end) = .;

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
#define IRQENTRY_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__irqentry_text_start) = .;		\
		*(.irqentry.text)					\
		VMLINUX_SYMBOL(__irqentry_text_end) = .;
#else
#define IRQENTRY_TEXT
#endif

/* Section used for early init (in .S files) */
#define HEAD_TEXT  *(.head.text)

/* init and exit section handling */
#define INIT_DATA							\
	*(.init.data)							\
	DEV_DISCARD(init.data)						\
	DEV_DISCARD(init.rodata)					\
	CPU_DISCARD(init.data)						\
	CPU_DISCARD(init.rodata)					\
	MEM_DISCARD(init.data)						\
	MEM_DISCARD(init.rodata)					\
	/* implement dynamic printk debug */				\
	VMLINUX_SYMBOL(__start___verbose_strings) = .;                  \
	*(__verbose_strings)                                            \
	VMLINUX_SYMBOL(__stop___verbose_strings) = .;                   \
	. = ALIGN(8);							\
	VMLINUX_SYMBOL(__start___verbose) = .;                          \
	*(__verbose)                                                    \
	VMLINUX_SYMBOL(__stop___verbose) = .;

#define INIT_TEXT							\
	*(.init.text)							\
	DEV_DISCARD(init.text)						\
	CPU_DISCARD(init.text)						\
	MEM_DISCARD(init.text)

#define EXIT_DATA							\
	*(.exit.data)							\
	DEV_DISCARD(exit.data)						\
	DEV_DISCARD(exit.rodata)					\
	CPU_DISCARD(exit.data)						\
	CPU_DISCARD(exit.rodata)					\
	MEM_DISCARD(exit.data)						\
	MEM_DISCARD(exit.rodata)

#define EXIT_TEXT							\
	*(.exit.text)							\
	DEV_DISCARD(exit.text)						\
	CPU_DISCARD(exit.text)						\
	MEM_DISCARD(exit.text)

		/* DWARF debug sections.
		Symbols in the DWARF debugging sections are relative to
		the beginning of the section so we begin them at 0.  */
#define DWARF_DEBUG							\
		/* DWARF 1 */						\
		.debug          0 : { *(.debug) }			\
		.line           0 : { *(.line) }			\
		/* GNU DWARF 1 extensions */				\
		.debug_srcinfo  0 : { *(.debug_srcinfo) }		\
		.debug_sfnames  0 : { *(.debug_sfnames) }		\
		/* DWARF 1.1 and DWARF 2 */				\
		.debug_aranges  0 : { *(.debug_aranges) }		\
		.debug_pubnames 0 : { *(.debug_pubnames) }		\
		/* DWARF 2 */						\
		.debug_info     0 : { *(.debug_info			\
				.gnu.linkonce.wi.*) }			\
		.debug_abbrev   0 : { *(.debug_abbrev) }		\
		.debug_line     0 : { *(.debug_line) }			\
		.debug_frame    0 : { *(.debug_frame) }			\
		.debug_str      0 : { *(.debug_str) }			\
		.debug_loc      0 : { *(.debug_loc) }			\
		.debug_macinfo  0 : { *(.debug_macinfo) }		\
		/* SGI/MIPS DWARF 2 extensions */			\
		.debug_weaknames 0 : { *(.debug_weaknames) }		\
		.debug_funcnames 0 : { *(.debug_funcnames) }		\
		.debug_typenames 0 : { *(.debug_typenames) }		\
		.debug_varnames  0 : { *(.debug_varnames) }		\

		/* Stabs debugging sections.  */
#define STABS_DEBUG							\
		.stab 0 : { *(.stab) }					\
		.stabstr 0 : { *(.stabstr) }				\
		.stab.excl 0 : { *(.stab.excl) }			\
		.stab.exclstr 0 : { *(.stab.exclstr) }			\
		.stab.index 0 : { *(.stab.index) }			\
		.stab.indexstr 0 : { *(.stab.indexstr) }		\
		.comment 0 : { *(.comment) }

#ifdef CONFIG_GENERIC_BUG
#define BUG_TABLE							\
	. = ALIGN(8);							\
	__bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___bug_table) = .;		\
		*(__bug_table)						\
		VMLINUX_SYMBOL(__stop___bug_table) = .;			\
	}
#else
#define BUG_TABLE
#endif

#ifdef CONFIG_PM_TRACE
#define TRACEDATA							\
	. = ALIGN(4);							\
	.tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__tracedata_start) = .;			\
		*(.tracedata)						\
		VMLINUX_SYMBOL(__tracedata_end) = .;			\
	}
#else
#define TRACEDATA
#endif

#define NOTES								\
	.notes : AT(ADDR(.notes) - LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__start_notes) = .;			\
		*(.note.*)						\
		VMLINUX_SYMBOL(__stop_notes) = .;			\
	}

#define INITCALLS							\
	*(.initcallearly.init)						\
	VMLINUX_SYMBOL(__early_initcall_end) = .;			\
  	*(.initcall0.init)						\
  	*(.initcall0s.init)						\
  	*(.initcall1.init)						\
  	*(.initcall1s.init)						\
  	*(.initcall2.init)						\
  	*(.initcall2s.init)						\
  	*(.initcall3.init)						\
  	*(.initcall3s.init)						\
  	*(.initcall4.init)						\
  	*(.initcall4s.init)						\
  	*(.initcall5.init)						\
  	*(.initcall5s.init)						\
	*(.initcallrootfs.init)						\
  	*(.initcall6.init)						\
  	*(.initcall6s.init)						\
  	*(.initcall7.init)						\
  	*(.initcall7s.init)

/**
 * PERCPU_VADDR - define output section for percpu area
 * @vaddr: explicit base address (optional)
 * @phdr: destination PHDR (optional)
 *
 * Macro which expands to output section for percpu area.  If @vaddr
 * is not blank, it specifies explicit base address and all percpu
 * symbols will be offset from the given address.  If blank, @vaddr
 * always equals @laddr + LOAD_OFFSET.
 *
 * @phdr defines the output PHDR to use if not blank.  Be warned that
 * output PHDR is sticky.  If @phdr is specified, the next output
 * section in the linker script will go there too.  @phdr should have
 * a leading colon.
 *
 * Note that this macros defines __per_cpu_load as an absolute symbol.
 * If there is no need to put the percpu section at a predetermined
 * address, use PERCPU().
 */
#define PERCPU_VADDR(vaddr, phdr)					\
	VMLINUX_SYMBOL(__per_cpu_load) = .;				\
	.data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)		\
				- LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__per_cpu_start) = .;			\
		*(.data.percpu.first)					\
		*(.data.percpu.page_aligned)				\
		*(.data.percpu)						\
		*(.data.percpu.shared_aligned)				\
		VMLINUX_SYMBOL(__per_cpu_end) = .;			\
	} phdr								\
	. = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);

/**
 * PERCPU - define output section for percpu area, simple version
 * @align: required alignment
 *
 * Align to @align and outputs output section for percpu area.  This
 * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
 * __per_cpu_start will be identical.
 *
 * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
 * that __per_cpu_load is defined as a relative symbol against
 * .data.percpu which is required for relocatable x86_32
 * configuration.
 */
#define PERCPU(align)							\
	. = ALIGN(align);						\
	.data.percpu	: AT(ADDR(.data.percpu) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__per_cpu_load) = .;			\
		VMLINUX_SYMBOL(__per_cpu_start) = .;			\
		*(.data.percpu.first)					\
		*(.data.percpu.page_aligned)				\
		*(.data.percpu)						\
		*(.data.percpu.shared_aligned)				\
		VMLINUX_SYMBOL(__per_cpu_end) = .;			\
	}
Commit	Line	Data
1da177e4 LT	1	#ifndef LOAD_OFFSET
	2	#define LOAD_OFFSET 0
	3	#endif
	4
	5	#ifndef VMLINUX_SYMBOL
	6	#define VMLINUX_SYMBOL(_sym_) _sym_
	7	#endif
	8
6d30e3a8 SR	9	/* Align . to a 8 byte boundary equals to maximum function alignment. */
	10	#define ALIGN_FUNCTION() . = ALIGN(8)
	11
eb8f6890 SR	12	/* The actual configuration determine if the init/exit sections
	13	* are handled as text/data or they can be discarded (which
	14	* often happens at runtime)
	15	*/
	16	#ifdef CONFIG_HOTPLUG
	17	#define DEV_KEEP(sec) *(.dev##sec)
	18	#define DEV_DISCARD(sec)
	19	#else
	20	#define DEV_KEEP(sec)
	21	#define DEV_DISCARD(sec) *(.dev##sec)
	22	#endif
	23
	24	#ifdef CONFIG_HOTPLUG_CPU
	25	#define CPU_KEEP(sec) *(.cpu##sec)
	26	#define CPU_DISCARD(sec)
	27	#else
	28	#define CPU_KEEP(sec)
	29	#define CPU_DISCARD(sec) *(.cpu##sec)
	30	#endif
	31
1a3fb6d4	32	#if defined(CONFIG_MEMORY_HOTPLUG)
eb8f6890 SR	33	#define MEM_KEEP(sec) *(.mem##sec)
	34	#define MEM_DISCARD(sec)
	35	#else
	36	#define MEM_KEEP(sec)
	37	#define MEM_DISCARD(sec) *(.mem##sec)
	38	#endif
	39
8da3821b SR	40	#ifdef CONFIG_FTRACE_MCOUNT_RECORD
	41	#define MCOUNT_REC() VMLINUX_SYMBOL(__start_mcount_loc) = .; \
	42	*(__mcount_loc) \
	43	VMLINUX_SYMBOL(__stop_mcount_loc) = .;
	44	#else
	45	#define MCOUNT_REC()
	46	#endif
eb8f6890	47
2ed84eeb	48	#ifdef CONFIG_TRACE_BRANCH_PROFILING
45b79749 SR	49	#define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
	50	*(_ftrace_annotated_branch) \
	51	VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
1f0d69a9 SR	52	#else
	53	#define LIKELY_PROFILE()
	54	#endif
	55
2bcd521a SR	56	#ifdef CONFIG_PROFILE_ALL_BRANCHES
	57	#define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
	58	*(_ftrace_branch) \
	59	VMLINUX_SYMBOL(__stop_branch_profile) = .;
	60	#else
	61	#define BRANCH_PROFILE()
	62	#endif
	63
b77e38aa SR	64	#ifdef CONFIG_EVENT_TRACER
	65	#define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \
	66	*(_ftrace_events) \
	67	VMLINUX_SYMBOL(__stop_ftrace_events) = .;
	68	#else
	69	#define FTRACE_EVENTS()
	70	#endif
	71
1ba28e02 LJ	72	#ifdef CONFIG_TRACING
	73	#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
	74	(__trace_printk_fmt) / Trace_printk fmt' pointer */ \
	75	VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
	76	#else
	77	#define TRACE_PRINTKS()
	78	#endif
	79
ca967258 SR	80	/* .data section */
ca967258 SR	81	#define DATA_DATA \
0e0d314e	82	*(.data) \
8256e47c	83	*(.data.init.refok) \
312b1485	84	*(.ref.data) \
eb8f6890 SR	85	DEV_KEEP(init.data) \
	86	DEV_KEEP(exit.data) \
	87	CPU_KEEP(init.data) \
	88	CPU_KEEP(exit.data) \
	89	MEM_KEEP(init.data) \
	90	MEM_KEEP(exit.data) \
8256e47c MD	91	. = ALIGN(8); \
	92	VMLINUX_SYMBOL(__start___markers) = .; \
	93	*(__markers) \
97e1c18e	94	VMLINUX_SYMBOL(__stop___markers) = .; \
7e066fb8	95	. = ALIGN(32); \
97e1c18e MD	96	VMLINUX_SYMBOL(__start___tracepoints) = .; \
97e1c18e MD	97	*(__tracepoints) \
1f0d69a9	98	VMLINUX_SYMBOL(__stop___tracepoints) = .; \
2bcd521a	99	LIKELY_PROFILE() \
b77e38aa	100	BRANCH_PROFILE() \
8a20d84d	101	TRACE_PRINTKS() \
b77e38aa	102	FTRACE_EVENTS()
ca967258	103
4096b46f SR	104	#define RO_DATA(align) \
4096b46f SR	105	. = ALIGN((align)); \
1da177e4	106	.rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
6569580d	107	VMLINUX_SYMBOL(__start_rodata) = .; \
1da177e4 LT	108	(.rodata) (.rodata.*) \
1da177e4 LT	109	(__vermagic) / Kernel version magic */ \
8256e47c	110	(__markers_strings) / Markers: strings */ \
97e1c18e	111	(__tracepoints_strings)/ Tracepoints: strings */ \
1da177e4 LT	112	} \
	113	\
	114	.rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
	115	*(.rodata1) \
	116	} \
	117	\
6360b1fb JB	118	BUG_TABLE \
6360b1fb JB	119	\
1da177e4 LT	120	/* PCI quirks */ \
	121	.pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
	122	VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
	123	*(.pci_fixup_early) \
	124	VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
	125	VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
	126	*(.pci_fixup_header) \
	127	VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
	128	VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
	129	*(.pci_fixup_final) \
	130	VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
	131	VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
	132	*(.pci_fixup_enable) \
	133	VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
1597cacb AC	134	VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
	135	*(.pci_fixup_resume) \
	136	VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
e1a2a51e RW	137	VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
	138	*(.pci_fixup_resume_early) \
	139	VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
	140	VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
	141	*(.pci_fixup_suspend) \
	142	VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
1da177e4 LT	143	} \
1da177e4 LT	144	\
5658c769 DW	145	/* Built-in firmware blobs */ \
	146	.builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
	147	VMLINUX_SYMBOL(__start_builtin_fw) = .; \
	148	*(.builtin_fw) \
	149	VMLINUX_SYMBOL(__end_builtin_fw) = .; \
	150	} \
	151	\
394b701c MP	152	/* RapidIO route ops */ \
	153	.rio_route : AT(ADDR(.rio_route) - LOAD_OFFSET) { \
	154	VMLINUX_SYMBOL(__start_rio_route_ops) = .; \
	155	*(.rio_route_ops) \
	156	VMLINUX_SYMBOL(__end_rio_route_ops) = .; \
	157	} \
	158	\
63687a52 JB	159	TRACEDATA \
63687a52 JB	160	\
1da177e4 LT	161	/* Kernel symbol table: Normal symbols */ \
	162	__ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
	163	VMLINUX_SYMBOL(__start___ksymtab) = .; \
	164	*(__ksymtab) \
	165	VMLINUX_SYMBOL(__stop___ksymtab) = .; \
	166	} \
	167	\
	168	/* Kernel symbol table: GPL-only symbols */ \
	169	__ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
	170	VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
	171	*(__ksymtab_gpl) \
	172	VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
	173	} \
	174	\
f71d20e9 AV	175	/* Kernel symbol table: Normal unused symbols */ \
	176	__ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
	177	VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
	178	*(__ksymtab_unused) \
	179	VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
	180	} \
	181	\
	182	/* Kernel symbol table: GPL-only unused symbols */ \
	183	__ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
	184	VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
	185	*(__ksymtab_unused_gpl) \
	186	VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
	187	} \
	188	\
9f28bb7e GKH	189	/* Kernel symbol table: GPL-future-only symbols */ \
	190	__ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
	191	VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
	192	*(__ksymtab_gpl_future) \
	193	VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
	194	} \
	195	\
1da177e4 LT	196	/* Kernel symbol table: Normal symbols */ \
	197	__kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
	198	VMLINUX_SYMBOL(__start___kcrctab) = .; \
	199	*(__kcrctab) \
	200	VMLINUX_SYMBOL(__stop___kcrctab) = .; \
	201	} \
	202	\
	203	/* Kernel symbol table: GPL-only symbols */ \
	204	__kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
	205	VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
	206	*(__kcrctab_gpl) \
	207	VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
	208	} \
	209	\
f71d20e9 AV	210	/* Kernel symbol table: Normal unused symbols */ \
	211	__kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
	212	VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
	213	*(__kcrctab_unused) \
	214	VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
	215	} \
	216	\
	217	/* Kernel symbol table: GPL-only unused symbols */ \
	218	__kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
	219	VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
	220	*(__kcrctab_unused_gpl) \
	221	VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
	222	} \
	223	\
9f28bb7e GKH	224	/* Kernel symbol table: GPL-future-only symbols */ \
	225	__kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
	226	VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
	227	*(__kcrctab_gpl_future) \
	228	VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
	229	} \
	230	\
1da177e4 LT	231	/* Kernel symbol table: strings */ \
	232	__ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
	233	*(__ksymtab_strings) \
	234	} \
	235	\
eb8f6890 SR	236	/* __init sections / \
eb8f6890 SR	237	__init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
312b1485	238	*(.ref.rodata) \
8da3821b	239	MCOUNT_REC() \
eb8f6890 SR	240	DEV_KEEP(init.rodata) \
	241	DEV_KEEP(exit.rodata) \
	242	CPU_KEEP(init.rodata) \
	243	CPU_KEEP(exit.rodata) \
	244	MEM_KEEP(init.rodata) \
	245	MEM_KEEP(exit.rodata) \
	246	} \
	247	\
1da177e4 LT	248	/* Built-in module parameters. */ \
	249	__param : AT(ADDR(__param) - LOAD_OFFSET) { \
	250	VMLINUX_SYMBOL(__start___param) = .; \
	251	*(__param) \
	252	VMLINUX_SYMBOL(__stop___param) = .; \
edeed305	253	. = ALIGN((align)); \
6569580d	254	VMLINUX_SYMBOL(__end_rodata) = .; \
7583ddfd	255	} \
4096b46f SR	256	. = ALIGN((align));
	257
	258	/* RODATA provided for backward compatibility.
	259	* All archs are supposed to use RO_DATA() */
	260	#define RODATA RO_DATA(4096)
1da177e4 LT	261
1da177e4 LT	262	#define SECURITY_INIT \
60bad7fa	263	.security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
1da177e4 LT	264	VMLINUX_SYMBOL(__security_initcall_start) = .; \
	265	*(.security_initcall.init) \
	266	VMLINUX_SYMBOL(__security_initcall_end) = .; \
	267	}
	268
7664709b SR	269	/* .text section. Map to function alignment to avoid address changes
	270	* during second ld run in second ld pass when generating System.map */
	271	#define TEXT_TEXT \
	272	ALIGN_FUNCTION(); \
fb5e2b37	273	*(.text.hot) \
0e0d314e	274	*(.text) \
312b1485	275	*(.ref.text) \
23ec23c2	276	*(.text.init.refok) \
eb8f6890 SR	277	*(.exit.text.refok) \
	278	DEV_KEEP(init.text) \
	279	DEV_KEEP(exit.text) \
	280	CPU_KEEP(init.text) \
	281	CPU_KEEP(exit.text) \
	282	MEM_KEEP(init.text) \
fb5e2b37 JB	283	MEM_KEEP(exit.text) \
fb5e2b37 JB	284	*(.text.unlikely)
eb8f6890	285
7664709b	286
6d30e3a8 SR	287	/* sched.text is aling to function alignment to secure we have same
6d30e3a8 SR	288	* address even at second ld pass when generating System.map */
1da177e4	289	#define SCHED_TEXT \
6d30e3a8	290	ALIGN_FUNCTION(); \
1da177e4 LT	291	VMLINUX_SYMBOL(__sched_text_start) = .; \
	292	*(.sched.text) \
	293	VMLINUX_SYMBOL(__sched_text_end) = .;
	294
6d30e3a8 SR	295	/* spinlock.text is aling to function alignment to secure we have same
6d30e3a8 SR	296	* address even at second ld pass when generating System.map */
1da177e4	297	#define LOCK_TEXT \
6d30e3a8	298	ALIGN_FUNCTION(); \
1da177e4 LT	299	VMLINUX_SYMBOL(__lock_text_start) = .; \
	300	*(.spinlock.text) \
	301	VMLINUX_SYMBOL(__lock_text_end) = .;
d0aaff97 PP	302
	303	#define KPROBES_TEXT \
	304	ALIGN_FUNCTION(); \
	305	VMLINUX_SYMBOL(__kprobes_text_start) = .; \
	306	*(.kprobes.text) \
	307	VMLINUX_SYMBOL(__kprobes_text_end) = .;
a7d0c210	308
a0343e82 FW	309	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	310	#define IRQENTRY_TEXT \
	311	ALIGN_FUNCTION(); \
	312	VMLINUX_SYMBOL(__irqentry_text_start) = .; \
	313	*(.irqentry.text) \
	314	VMLINUX_SYMBOL(__irqentry_text_end) = .;
	315	#else
	316	#define IRQENTRY_TEXT
	317	#endif
	318
37c514e3 SR	319	/* Section used for early init (in .S files) */
	320	#define HEAD_TEXT *(.head.text)
	321
01ba2bdc	322	/* init and exit section handling */
eb8f6890 SR	323	#define INIT_DATA \
	324	*(.init.data) \
	325	DEV_DISCARD(init.data) \
	326	DEV_DISCARD(init.rodata) \
	327	CPU_DISCARD(init.data) \
	328	CPU_DISCARD(init.rodata) \
	329	MEM_DISCARD(init.data) \
346e15be JB	330	MEM_DISCARD(init.rodata) \
	331	/* implement dynamic printk debug */ \
	332	VMLINUX_SYMBOL(__start___verbose_strings) = .; \
	333	*(__verbose_strings) \
	334	VMLINUX_SYMBOL(__stop___verbose_strings) = .; \
	335	. = ALIGN(8); \
	336	VMLINUX_SYMBOL(__start___verbose) = .; \
	337	*(__verbose) \
	338	VMLINUX_SYMBOL(__stop___verbose) = .;
eb8f6890 SR	339
	340	#define INIT_TEXT \
	341	*(.init.text) \
	342	DEV_DISCARD(init.text) \
	343	CPU_DISCARD(init.text) \
	344	MEM_DISCARD(init.text)
	345
	346	#define EXIT_DATA \
	347	*(.exit.data) \
	348	DEV_DISCARD(exit.data) \
	349	DEV_DISCARD(exit.rodata) \
	350	CPU_DISCARD(exit.data) \
	351	CPU_DISCARD(exit.rodata) \
	352	MEM_DISCARD(exit.data) \
	353	MEM_DISCARD(exit.rodata)
01ba2bdc	354
eb8f6890 SR	355	#define EXIT_TEXT \
	356	*(.exit.text) \
	357	DEV_DISCARD(exit.text) \
	358	CPU_DISCARD(exit.text) \
	359	MEM_DISCARD(exit.text)
01ba2bdc	360
a7d0c210 PBG	361	/* DWARF debug sections.
	362	Symbols in the DWARF debugging sections are relative to
	363	the beginning of the section so we begin them at 0. */
	364	#define DWARF_DEBUG \
	365	/* DWARF 1 */ \
	366	.debug 0 : { *(.debug) } \
	367	.line 0 : { *(.line) } \
	368	/* GNU DWARF 1 extensions */ \
	369	.debug_srcinfo 0 : { *(.debug_srcinfo) } \
	370	.debug_sfnames 0 : { *(.debug_sfnames) } \
	371	/* DWARF 1.1 and DWARF 2 */ \
	372	.debug_aranges 0 : { *(.debug_aranges) } \
	373	.debug_pubnames 0 : { *(.debug_pubnames) } \
	374	/* DWARF 2 */ \
	375	.debug_info 0 : { *(.debug_info \
	376	.gnu.linkonce.wi.*) } \
	377	.debug_abbrev 0 : { *(.debug_abbrev) } \
	378	.debug_line 0 : { *(.debug_line) } \
	379	.debug_frame 0 : { *(.debug_frame) } \
	380	.debug_str 0 : { *(.debug_str) } \
	381	.debug_loc 0 : { *(.debug_loc) } \
	382	.debug_macinfo 0 : { *(.debug_macinfo) } \
	383	/* SGI/MIPS DWARF 2 extensions */ \
	384	.debug_weaknames 0 : { *(.debug_weaknames) } \
	385	.debug_funcnames 0 : { *(.debug_funcnames) } \
	386	.debug_typenames 0 : { *(.debug_typenames) } \
	387	.debug_varnames 0 : { *(.debug_varnames) } \
	388
	389	/* Stabs debugging sections. */
	390	#define STABS_DEBUG \
	391	.stab 0 : { *(.stab) } \
	392	.stabstr 0 : { *(.stabstr) } \
	393	.stab.excl 0 : { *(.stab.excl) } \
	394	.stab.exclstr 0 : { *(.stab.exclstr) } \
	395	.stab.index 0 : { *(.stab.index) } \
	396	.stab.indexstr 0 : { *(.stab.indexstr) } \
	397	.comment 0 : { *(.comment) }
9c9b8b38	398
6360b1fb	399	#ifdef CONFIG_GENERIC_BUG
7664c5a1 JF	400	#define BUG_TABLE \
	401	. = ALIGN(8); \
	402	__bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
c6de0026	403	VMLINUX_SYMBOL(__start___bug_table) = .; \
7664c5a1	404	*(__bug_table) \
c6de0026	405	VMLINUX_SYMBOL(__stop___bug_table) = .; \
7664c5a1	406	}
6360b1fb JB	407	#else
	408	#define BUG_TABLE
	409	#endif
7664c5a1	410
63687a52 JB	411	#ifdef CONFIG_PM_TRACE
	412	#define TRACEDATA \
	413	. = ALIGN(4); \
	414	.tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
c6de0026	415	VMLINUX_SYMBOL(__tracedata_start) = .; \
63687a52	416	*(.tracedata) \
c6de0026	417	VMLINUX_SYMBOL(__tracedata_end) = .; \
63687a52 JB	418	}
	419	#else
	420	#define TRACEDATA
	421	#endif
	422
9c9b8b38	423	#define NOTES \
cbe87121 RM	424	.notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
	425	VMLINUX_SYMBOL(__start_notes) = .; \
	426	(.note.) \
	427	VMLINUX_SYMBOL(__stop_notes) = .; \
	428	}
61ce1efe AM	429
61ce1efe AM	430	#define INITCALLS \
c2147a50	431	*(.initcallearly.init) \
c6de0026	432	VMLINUX_SYMBOL(__early_initcall_end) = .; \
b3438f82 LT	433	*(.initcall0.init) \
b3438f82 LT	434	*(.initcall0s.init) \
61ce1efe	435	*(.initcall1.init) \
735a7ffb	436	*(.initcall1s.init) \
61ce1efe	437	*(.initcall2.init) \
735a7ffb	438	*(.initcall2s.init) \
61ce1efe	439	*(.initcall3.init) \
735a7ffb	440	*(.initcall3s.init) \
61ce1efe	441	*(.initcall4.init) \
735a7ffb	442	*(.initcall4s.init) \
61ce1efe	443	*(.initcall5.init) \
735a7ffb	444	*(.initcall5s.init) \
8d610dd5	445	*(.initcallrootfs.init) \
61ce1efe	446	*(.initcall6.init) \
735a7ffb AM	447	*(.initcall6s.init) \
	448	*(.initcall7.init) \
	449	*(.initcall7s.init)
61ce1efe	450
3e5d8f97	451	/**
6b7c38d5	452	* PERCPU_VADDR - define output section for percpu area
3e5d8f97 TH	453	* @vaddr: explicit base address (optional)
	454	* @phdr: destination PHDR (optional)
	455	*
	456	* Macro which expands to output section for percpu area. If @vaddr
	457	* is not blank, it specifies explicit base address and all percpu
	458	* symbols will be offset from the given address. If blank, @vaddr
	459	* always equals @laddr + LOAD_OFFSET.
	460	*
	461	* @phdr defines the output PHDR to use if not blank. Be warned that
	462	* output PHDR is sticky. If @phdr is specified, the next output
	463	* section in the linker script will go there too. @phdr should have
	464	* a leading colon.
	465	*
3ac6cffe TH	466	* Note that this macros defines __per_cpu_load as an absolute symbol.
	467	* If there is no need to put the percpu section at a predetermined
	468	* address, use PERCPU().
3e5d8f97 TH	469	*/
3e5d8f97 TH	470	#define PERCPU_VADDR(vaddr, phdr) \
dba3d36b IM	471	VMLINUX_SYMBOL(__per_cpu_load) = .; \
dba3d36b IM	472	.data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
6b7c38d5 TH	473	- LOAD_OFFSET) { \
6b7c38d5 TH	474	VMLINUX_SYMBOL(__per_cpu_start) = .; \
0bd74fa8	475	*(.data.percpu.first) \
63cc8c75	476	*(.data.percpu.page_aligned) \
5fb7dc37 FY	477	*(.data.percpu) \
5fb7dc37 FY	478	*(.data.percpu.shared_aligned) \
6b7c38d5 TH	479	VMLINUX_SYMBOL(__per_cpu_end) = .; \
6b7c38d5 TH	480	} phdr \
dba3d36b	481	. = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);
3e5d8f97 TH	482
	483	/**
	484	* PERCPU - define output section for percpu area, simple version
	485	* @align: required alignment
	486	*
	487	* Align to @align and outputs output section for percpu area. This
	488	* macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
	489	* __per_cpu_start will be identical.
3ac6cffe TH	490	*
	491	* This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
	492	* that __per_cpu_load is defined as a relative symbol against
	493	* .data.percpu which is required for relocatable x86_32
	494	* configuration.
3e5d8f97	495	*/
5fb7dc37 FY	496	#define PERCPU(align) \
5fb7dc37 FY	497	. = ALIGN(align); \
3ac6cffe TH	498	.data.percpu : AT(ADDR(.data.percpu) - LOAD_OFFSET) { \
	499	VMLINUX_SYMBOL(__per_cpu_load) = .; \
	500	VMLINUX_SYMBOL(__per_cpu_start) = .; \
	501	*(.data.percpu.first) \
63cc8c75	502	*(.data.percpu.page_aligned) \
5fb7dc37 FY	503	*(.data.percpu) \
5fb7dc37 FY	504	*(.data.percpu.shared_aligned) \
3ac6cffe TH	505	VMLINUX_SYMBOL(__per_cpu_end) = .; \
3ac6cffe TH	506	}