[mirror_ubuntu-zesty-kernel.git] / scripts / kconfig / streamline_config.pl

#!/usr/bin/perl -w
#
# Copyright 2005-2009 - Steven Rostedt
# Licensed under the terms of the GNU GPL License version 2
#
#  It's simple enough to figure out how this works.
#  If not, then you can ask me at stripconfig@goodmis.org
#
# What it does?
#
#   If you have installed a Linux kernel from a distribution
#   that turns on way too many modules than you need, and
#   you only want the modules you use, then this program
#   is perfect for you.
#
#   It gives you the ability to turn off all the modules that are
#   not loaded on your system.
#
# Howto:
#
#  1. Boot up the kernel that you want to stream line the config on.
#  2. Change directory to the directory holding the source of the
#       kernel that you just booted.
#  3. Copy the configuraton file to this directory as .config
#  4. Have all your devices that you need modules for connected and
#      operational (make sure that their corresponding modules are loaded)
#  5. Run this script redirecting the output to some other file
#       like config_strip.
#  6. Back up your old config (if you want too).
#  7. copy the config_strip file to .config
#  8. Run "make oldconfig"
#
#  Now your kernel is ready to be built with only the modules that
#  are loaded.
#
# Here's what I did with my Debian distribution.
#
#    cd /usr/src/linux-2.6.10
#    cp /boot/config-2.6.10-1-686-smp .config
#    ~/bin/streamline_config > config_strip
#    mv .config config_sav
#    mv config_strip .config
#    make oldconfig
#
use strict;
use Getopt::Long;

# set the environment variable LOCALMODCONFIG_DEBUG to get
# debug output.
my $debugprint = 0;
$debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));

sub dprint {
    return if (!$debugprint);
    print STDERR @_;
}

my $config = ".config";

my $uname = `uname -r`;
chomp $uname;

my @searchconfigs = (
	{
	    "file" => ".config",
	    "exec" => "cat",
	},
	{
	    "file" => "/proc/config.gz",
	    "exec" => "zcat",
	},
	{
	    "file" => "/boot/config-$uname",
	    "exec" => "cat",
	},
	{
	    "file" => "/boot/vmlinuz-$uname",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "vmlinux",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "kernel/configs.ko",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "kernel/configs.o",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
);

sub read_config {
    foreach my $conf (@searchconfigs) {
	my $file = $conf->{"file"};

	next if ( ! -f "$file");

	if (defined($conf->{"test"})) {
	    `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
	    next if ($?);
	}

	my $exec = $conf->{"exec"};

	print STDERR "using config: '$file'\n";

	open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
	my @x = <$infile>;
	close $infile;
	return @x;
    }
    die "No config file found";
}

my @config_file = read_config;

# Parse options
my $localmodconfig = 0;
my $localyesconfig = 0;

GetOptions("localmodconfig" => \$localmodconfig,
	   "localyesconfig" => \$localyesconfig);

# Get the build source and top level Kconfig file (passed in)
my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
my $kconfig = $ARGV[1];
my $lsmod_file = $ENV{'LSMOD'};

my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
chomp @makefiles;

my %depends;
my %selects;
my %prompts;
my %objects;
my $var;
my $iflevel = 0;
my @ifdeps;

# prevent recursion
my %read_kconfigs;

sub read_kconfig {
    my ($kconfig) = @_;

    my $state = "NONE";
    my $config;
    my @kconfigs;

    my $cont = 0;
    my $line;

    my $source = "$ksource/$kconfig";
    my $last_source = "";

    # Check for any environment variables used
    while ($source =~ /\$(\w+)/ && $last_source ne $source) {
	my $env = $1;
	$last_source = $source;
	$source =~ s/\$$env/$ENV{$env}/;
    }

    open(my $kinfile, '<', $source) || die "Can't open $kconfig";
    while (<$kinfile>) {
	chomp;

	# Make sure that lines ending with \ continue
	if ($cont) {
	    $_ = $line . " " . $_;
	}

	if (s/\\$//) {
	    $cont = 1;
	    $line = $_;
	    next;
	}

	$cont = 0;

	# collect any Kconfig sources
	if (/^source\s*"(.*)"/) {
	    $kconfigs[$#kconfigs+1] = $1;
	}

	# configs found
	if (/^\s*(menu)?config\s+(\S+)\s*$/) {
	    $state = "NEW";
	    $config = $2;

	    # Add depends for 'if' nesting
	    for (my $i = 0; $i < $iflevel; $i++) {
		if ($i) {
		    $depends{$config} .= " " . $ifdeps[$i];
		} else {
		    $depends{$config} = $ifdeps[$i];
		}
		$state = "DEP";
	    }

	# collect the depends for the config
	} elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
	    $state = "DEP";
	    $depends{$config} = $1;
	} elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
	    $depends{$config} .= " " . $1;

	# Get the configs that select this config
	} elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
	    my $conf = $1;
	    if (defined($selects{$conf})) {
		$selects{$conf} .= " " . $config;
	    } else {
		$selects{$conf} = $config;
	    }

	# configs without prompts must be selected
	} elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
	    # note if the config has a prompt
	    $prompts{$config} = 1;

	# Check for if statements
	} elsif (/^if\s+(.*\S)\s*$/) {
	    my $deps = $1;
	    # remove beginning and ending non text
	    $deps =~ s/^[^a-zA-Z0-9_]*//;
	    $deps =~ s/[^a-zA-Z0-9_]*$//;

	    my @deps = split /[^a-zA-Z0-9_]+/, $deps;

	    $ifdeps[$iflevel++] = join ':', @deps;

	} elsif (/^endif/) {

	    $iflevel-- if ($iflevel);

	# stop on "help"
	} elsif (/^\s*help\s*$/) {
	    $state = "NONE";
	}
    }
    close($kinfile);

    # read in any configs that were found.
    foreach my $kconfig (@kconfigs) {
	if (!defined($read_kconfigs{$kconfig})) {
	    $read_kconfigs{$kconfig} = 1;
	    read_kconfig($kconfig);
	}
    }
}

if ($kconfig) {
    read_kconfig($kconfig);
}

# Makefiles can use variables to define their dependencies
sub convert_vars {
    my ($line, %vars) = @_;

    my $process = "";

    while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
	my $start = $1;
	my $variable = $2;
	my $var = $3;

	if (defined($vars{$var})) {
	    $process .= $start . $vars{$var};
	} else {
	    $process .= $start . $variable;
	}
    }

    $process .= $line;

    return $process;
}

# Read all Makefiles to map the configs to the objects
foreach my $makefile (@makefiles) {

    my $line = "";
    my %make_vars;

    open(my $infile, '<', $makefile) || die "Can't open $makefile";
    while (<$infile>) {
	# if this line ends with a backslash, continue
	chomp;
	if (/^(.*)\\$/) {
	    $line .= $1;
	    next;
	}

	$line .= $_;
	$_ = $line;
	$line = "";

	my $objs;

	# Convert variables in a line (could define configs)
	$_ = convert_vars($_, %make_vars);

	# collect objects after obj-$(CONFIG_FOO_BAR)
	if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
	    $var = $1;
	    $objs = $2;

	# check if variables are set
	} elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
	    $make_vars{$1} = $2;
	}
	if (defined($objs)) {
	    foreach my $obj (split /\s+/,$objs) {
		$obj =~ s/-/_/g;
		if ($obj =~ /(.*)\.o$/) {
		    # Objects may be enabled by more than one config.
		    # Store configs in an array.
		    my @arr;

		    if (defined($objects{$1})) {
			@arr = @{$objects{$1}};
		    }

		    $arr[$#arr+1] = $var;

		    # The objects have a hash mapping to a reference
		    # of an array of configs.
		    $objects{$1} = \@arr;
		}
	    }
	}
    }
    close($infile);
}

my %modules;
my $linfile;

if (defined($lsmod_file)) {
    if ( ! -f $lsmod_file) {
	if ( -f $ENV{'objtree'}."/".$lsmod_file) {
	    $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
	} else {
		die "$lsmod_file not found";
	}
    }

    my $otype = ( -x $lsmod_file) ? '-|' : '<';
    open($linfile, $otype, $lsmod_file);

} else {

    # see what modules are loaded on this system
    my $lsmod;

    foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
	if ( -x "$dir/lsmod" ) {
	    $lsmod = "$dir/lsmod";
	    last;
	}
}
    if (!defined($lsmod)) {
	# try just the path
	$lsmod = "lsmod";
    }

    open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
}

while (<$linfile>) {
	next if (/^Module/);  # Skip the first line.
	if (/^(\S+)/) {
		$modules{$1} = 1;
	}
}
close ($linfile);

# add to the configs hash all configs that are needed to enable
# a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
# where we know we need bar.o so we add FOO to the list.
my %configs;
foreach my $module (keys(%modules)) {
    if (defined($objects{$module})) {
	my @arr = @{$objects{$module}};
	foreach my $conf (@arr) {
	    $configs{$conf} = $module;
	    dprint "$conf added by direct ($module)\n";
	}
    } else {
	# Most likely, someone has a custom (binary?) module loaded.
	print STDERR "$module config not found!!\n";
    }
}

# Read the current config, and see what is enabled. We want to
# ignore configs that we would not enable anyway.

my %orig_configs;
my $valid = "A-Za-z_0-9";

foreach my $line (@config_file) {
    $_ = $line;

    if (/(CONFIG_[$valid]*)=(m|y)/) {
	$orig_configs{$1} = $2;
    }
}

my $repeat = 1;

my $depconfig;

#
# Note, we do not care about operands (like: &&, ||, !) we want to add any
# config that is in the depend list of another config. This script does
# not enable configs that are not already enabled. If we come across a
# config A that depends on !B, we can still add B to the list of depends
# to keep on. If A was on in the original config, B would not have been
# and B would not be turned on by this script.
#
sub parse_config_depends
{
    my ($p) = @_;

    while ($p =~ /[$valid]/) {

	if ($p =~ /^[^$valid]*([$valid]+)/) {
	    my $conf = "CONFIG_" . $1;

	    $p =~ s/^[^$valid]*[$valid]+//;

	    # We only need to process if the depend config is a module
	    if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
		next;
	    }

	    if (!defined($configs{$conf})) {
		# We must make sure that this config has its
		# dependencies met.
		$repeat = 1; # do again
		dprint "$conf selected by depend $depconfig\n";
		$configs{$conf} = 1;
	    }
	} else {
	    die "this should never happen";
	}
    }
}

# Select is treated a bit differently than depends. We call this
# when a config has no prompt and requires another config to be
# selected. We use to just select all configs that selected this
# config, but found that that can balloon into enabling hundreds
# of configs that we do not care about.
#
# The idea is we look at all the configs that select it. If one
# is already in our list of configs to enable, then there's nothing
# else to do. If there isn't, we pick the first config that was
# enabled in the orignal config and use that.
sub parse_config_selects
{
    my ($config, $p) = @_;

    my $next_config;

    while ($p =~ /[$valid]/) {

	if ($p =~ /^[^$valid]*([$valid]+)/) {
	    my $conf = "CONFIG_" . $1;

	    $p =~ s/^[^$valid]*[$valid]+//;

	    # Make sure that this config exists in the current .config file
	    if (!defined($orig_configs{$conf})) {
		dprint "$conf not set for $config select\n";
		next;
	    }

	    # Check if something other than a module selects this config
	    if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
		dprint "$conf (non module) selects config, we are good\n";
		# we are good with this
		return;
	    }
	    if (defined($configs{$conf})) {
		dprint "$conf selects $config so we are good\n";
		# A set config selects this config, we are good
		return;
	    }
	    # Set this config to be selected
	    if (!defined($next_config)) {
		$next_config = $conf;
	    }
	} else {
	    die "this should never happen";
	}
    }

    # If no possible config selected this, then something happened.
    if (!defined($next_config)) {
	print STDERR "WARNING: $config is required, but nothing in the\n";
	print STDERR "  current config selects it.\n";
	return;
    }

    # If we are here, then we found no config that is set and
    # selects this config. Repeat.
    $repeat = 1;
    # Make this config need to be selected
    $configs{$next_config} = 1;
    dprint "$next_config selected by select $config\n";
}

my %process_selects;

# loop through all configs, select their dependencies.
sub loop_depend {
    $repeat = 1;

    while ($repeat) {
	$repeat = 0;

      forloop:
	foreach my $config (keys %configs) {

	    # If this config is not a module, we do not need to process it
	    if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
		next forloop;
	    }

	    $config =~ s/^CONFIG_//;
	    $depconfig = $config;

	    if (defined($depends{$config})) {
		# This config has dependencies. Make sure they are also included
		parse_config_depends $depends{$config};
	    }

	    # If the config has no prompt, then we need to check if a config
	    # that is enabled selected it. Or if we need to enable one.
	    if (!defined($prompts{$config}) && defined($selects{$config})) {
		$process_selects{$config} = 1;
	    }
	}
    }
}

sub loop_select {

    foreach my $config (keys %process_selects) {
	$config =~ s/^CONFIG_//;

	dprint "Process select $config\n";

	# config has no prompt and must be selected.
	parse_config_selects $config, $selects{$config};
    }
}

while ($repeat) {
    # Get the first set of configs and their dependencies.
    loop_depend;

    $repeat = 0;

    # Now we need to see if we have to check selects;
    loop_select;
}	    

my %setconfigs;

# Finally, read the .config file and turn off any module enabled that
# we could not find a reason to keep enabled.
foreach my $line (@config_file) {
    $_ = $line;

    if (/CONFIG_IKCONFIG/) {
	if (/# CONFIG_IKCONFIG is not set/) {
	    # enable IKCONFIG at least as a module
	    print "CONFIG_IKCONFIG=m\n";
	    # don't ask about PROC
	    print "# CONFIG_IKCONFIG_PROC is not set\n";
	} else {
	    print;
	}
	next;
    }

    if (/^(CONFIG.*)=(m|y)/) {
	if (defined($configs{$1})) {
	    if ($localyesconfig) {
	        $setconfigs{$1} = 'y';
	    } else {
	        $setconfigs{$1} = $2;
	    }
	} elsif ($2 eq "m") {
	    print "# $1 is not set\n";
	    next;
	}
    }
    print;
}

# Integrity check, make sure all modules that we want enabled do
# indeed have their configs set.
loop:
foreach my $module (keys(%modules)) {
    if (defined($objects{$module})) {
	my @arr = @{$objects{$module}};
	foreach my $conf (@arr) {
	    if (defined($setconfigs{$conf})) {
		next loop;
	    }
	}
	print STDERR "module $module did not have configs";
	foreach my $conf (@arr) {
	    print STDERR " " , $conf;
	}
	print STDERR "\n";
    }
}
Commit	Line	Data
dcc60243 SR	1	#!/usr/bin/perl -w
dcc60243 SR	2	#
cce1dac8	3	# Copyright 2005-2009 - Steven Rostedt
dcc60243 SR	4	# Licensed under the terms of the GNU GPL License version 2
	5	#
	6	# It's simple enough to figure out how this works.
	7	# If not, then you can ask me at stripconfig@goodmis.org
	8	#
	9	# What it does?
	10	#
	11	# If you have installed a Linux kernel from a distribution
	12	# that turns on way too many modules than you need, and
	13	# you only want the modules you use, then this program
	14	# is perfect for you.
	15	#
	16	# It gives you the ability to turn off all the modules that are
	17	# not loaded on your system.
	18	#
	19	# Howto:
	20	#
	21	# 1. Boot up the kernel that you want to stream line the config on.
	22	# 2. Change directory to the directory holding the source of the
	23	# kernel that you just booted.
	24	# 3. Copy the configuraton file to this directory as .config
	25	# 4. Have all your devices that you need modules for connected and
	26	# operational (make sure that their corresponding modules are loaded)
	27	# 5. Run this script redirecting the output to some other file
	28	# like config_strip.
	29	# 6. Back up your old config (if you want too).
	30	# 7. copy the config_strip file to .config
	31	# 8. Run "make oldconfig"
	32	#
	33	# Now your kernel is ready to be built with only the modules that
	34	# are loaded.
	35	#
	36	# Here's what I did with my Debian distribution.
	37	#
	38	# cd /usr/src/linux-2.6.10
	39	# cp /boot/config-2.6.10-1-686-smp .config
	40	# ~/bin/streamline_config > config_strip
	41	# mv .config config_sav
	42	# mv config_strip .config
	43	# make oldconfig
	44	#
cf5a189d	45	use strict;
22d550ae	46	use Getopt::Long;
cf5a189d	47
4503379c SR	48	# set the environment variable LOCALMODCONFIG_DEBUG to get
	49	# debug output.
	50	my $debugprint = 0;
	51	$debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
	52
	53	sub dprint {
	54	return if (!$debugprint);
	55	print STDERR @_;
	56	}
	57
dcc60243	58	my $config = ".config";
dcc60243	59
cdfc4795 SR	60	my $uname = `uname -r`;
	61	chomp $uname;
	62
	63	my @searchconfigs = (
a9024838 SR	64	{
	65	"file" => ".config",
	66	"exec" => "cat",
	67	},
cdfc4795 SR	68	{
	69	"file" => "/proc/config.gz",
	70	"exec" => "zcat",
	71	},
810b2be6 SR	72	{
	73	"file" => "/boot/config-$uname",
	74	"exec" => "cat",
	75	},
cdfc4795 SR	76	{
	77	"file" => "/boot/vmlinuz-$uname",
	78	"exec" => "scripts/extract-ikconfig",
	79	"test" => "scripts/extract-ikconfig",
	80	},
	81	{
	82	"file" => "vmlinux",
	83	"exec" => "scripts/extract-ikconfig",
	84	"test" => "scripts/extract-ikconfig",
	85	},
	86	{
	87	"file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
	88	"exec" => "scripts/extract-ikconfig",
	89	"test" => "scripts/extract-ikconfig",
	90	},
	91	{
	92	"file" => "kernel/configs.ko",
	93	"exec" => "scripts/extract-ikconfig",
	94	"test" => "scripts/extract-ikconfig",
	95	},
	96	{
	97	"file" => "kernel/configs.o",
	98	"exec" => "scripts/extract-ikconfig",
	99	"test" => "scripts/extract-ikconfig",
	100	},
cdfc4795 SR	101	);
cdfc4795 SR	102
3f0c5413	103	sub read_config {
cdfc4795 SR	104	foreach my $conf (@searchconfigs) {
	105	my $file = $conf->{"file"};
	106
	107	next if ( ! -f "$file");
	108
	109	if (defined($conf->{"test"})) {
	110	`$conf->{"test"} $conf->{"file"} 2>/dev/null`;
	111	next if ($?);
	112	}
	113
	114	my $exec = $conf->{"exec"};
	115
	116	print STDERR "using config: '$file'\n";
	117
3f0c5413 BP	118	open(my $infile, '-\|', "$exec $file") \|\| die "Failed to run $exec $file";
	119	my @x = <$infile>;
	120	close $infile;
	121	return @x;
cdfc4795 SR	122	}
	123	die "No config file found";
	124	}
	125
3f0c5413	126	my @config_file = read_config;
4f4c51c9	127
22d550ae AL	128	# Parse options
	129	my $localmodconfig = 0;
	130	my $localyesconfig = 0;
	131
	132	GetOptions("localmodconfig" => \$localmodconfig,
	133	"localyesconfig" => \$localyesconfig);
	134
463bf900	135	# Get the build source and top level Kconfig file (passed in)
224a2571	136	my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
463bf900	137	my $kconfig = $ARGV[1];
f597a718	138	my $lsmod_file = $ENV{'LSMOD'};
463bf900	139
17431928 TF	140	my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
	141	chomp @makefiles;
	142
dcc60243 SR	143	my %depends;
	144	my %selects;
	145	my %prompts;
	146	my %objects;
	147	my $var;
13d7e938 SR	148	my $iflevel = 0;
13d7e938 SR	149	my @ifdeps;
dcc60243	150
dcc60243 SR	151	# prevent recursion
	152	my %read_kconfigs;
	153
	154	sub read_kconfig {
	155	my ($kconfig) = @_;
	156
	157	my $state = "NONE";
	158	my $config;
	159	my @kconfigs;
	160
20d19047 SR	161	my $cont = 0;
	162	my $line;
	163
4908980b SR	164	my $source = "$ksource/$kconfig";
	165	my $last_source = "";
	166
	167	# Check for any environment variables used
	168	while ($source =~ /\$(\w+)/ && $last_source ne $source) {
	169	my $env = $1;
	170	$last_source = $source;
	171	$source =~ s/\$$env/$ENV{$env}/;
	172	}
	173
e0d28694 BP	174	open(my $kinfile, '<', $source) \|\| die "Can't open $kconfig";
e0d28694 BP	175	while (<$kinfile>) {
dcc60243 SR	176	chomp;
dcc60243 SR	177
20d19047 SR	178	# Make sure that lines ending with \ continue
	179	if ($cont) {
	180	$_ = $line . " " . $_;
	181	}
	182
	183	if (s/\\$//) {
	184	$cont = 1;
	185	$line = $_;
	186	next;
	187	}
	188
	189	$cont = 0;
	190
dcc60243 SR	191	# collect any Kconfig sources
	192	if (/^source\s"(.)"/) {
	193	$kconfigs[$#kconfigs+1] = $1;
	194	}
	195
	196	# configs found
8ef17fa2	197	if (/^\s(menu)?config\s+(\S+)\s$/) {
dcc60243	198	$state = "NEW";
8ef17fa2	199	$config = $2;
dcc60243	200
0b58a99e	201	# Add depends for 'if' nesting
13d7e938 SR	202	for (my $i = 0; $i < $iflevel; $i++) {
	203	if ($i) {
	204	$depends{$config} .= " " . $ifdeps[$i];
	205	} else {
	206	$depends{$config} = $ifdeps[$i];
	207	}
	208	$state = "DEP";
	209	}
	210
dcc60243 SR	211	# collect the depends for the config
	212	} elsif ($state eq "NEW" && /^\sdepends\s+on\s+(.)$/) {
	213	$state = "DEP";
	214	$depends{$config} = $1;
	215	} elsif ($state eq "DEP" && /^\sdepends\s+on\s+(.)$/) {
	216	$depends{$config} .= " " . $1;
	217
	218	# Get the configs that select this config
	219	} elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
0b58a99e SR	220	my $conf = $1;
	221	if (defined($selects{$conf})) {
	222	$selects{$conf} .= " " . $config;
dcc60243	223	} else {
0b58a99e	224	$selects{$conf} = $config;
dcc60243 SR	225	}
	226
	227	# configs without prompts must be selected
	228	} elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
	229	# note if the config has a prompt
ccece60a	230	$prompts{$config} = 1;
dcc60243	231
13d7e938 SR	232	# Check for if statements
	233	} elsif (/^if\s+(.\S)\s$/) {
	234	my $deps = $1;
	235	# remove beginning and ending non text
	236	$deps =~ s/^[^a-zA-Z0-9_]*//;
	237	$deps =~ s/[^a-zA-Z0-9_]*$//;
	238
	239	my @deps = split /[^a-zA-Z0-9_]+/, $deps;
	240
	241	$ifdeps[$iflevel++] = join ':', @deps;
	242
	243	} elsif (/^endif/) {
	244
	245	$iflevel-- if ($iflevel);
	246
dcc60243 SR	247	# stop on "help"
	248	} elsif (/^\shelp\s$/) {
	249	$state = "NONE";
	250	}
	251	}
e0d28694	252	close($kinfile);
dcc60243 SR	253
dcc60243 SR	254	# read in any configs that were found.
45f4c81d	255	foreach my $kconfig (@kconfigs) {
dcc60243 SR	256	if (!defined($read_kconfigs{$kconfig})) {
	257	$read_kconfigs{$kconfig} = 1;
	258	read_kconfig($kconfig);
	259	}
	260	}
	261	}
	262
	263	if ($kconfig) {
	264	read_kconfig($kconfig);
	265	}
	266
0b58a99e	267	# Makefiles can use variables to define their dependencies
364212fd SR	268	sub convert_vars {
	269	my ($line, %vars) = @_;
	270
	271	my $process = "";
	272
	273	while ($line =~ s/^(.?)(\$\((.?)\))//) {
	274	my $start = $1;
	275	my $variable = $2;
	276	my $var = $3;
	277
	278	if (defined($vars{$var})) {
	279	$process .= $start . $vars{$var};
	280	} else {
	281	$process .= $start . $variable;
	282	}
	283	}
	284
	285	$process .= $line;
	286
	287	return $process;
	288	}
	289
dcc60243 SR	290	# Read all Makefiles to map the configs to the objects
dcc60243 SR	291	foreach my $makefile (@makefiles) {
dcc60243	292
d060d963	293	my $line = "";
364212fd	294	my %make_vars;
20d19047	295
e0d28694 BP	296	open(my $infile, '<', $makefile) \|\| die "Can't open $makefile";
e0d28694 BP	297	while (<$infile>) {
d060d963 SR	298	# if this line ends with a backslash, continue
	299	chomp;
	300	if (/^(.*)\\$/) {
	301	$line .= $1;
	302	next;
dcc60243	303	}
d060d963 SR	304
	305	$line .= $_;
	306	$_ = $line;
	307	$line = "";
	308
	309	my $objs;
dcc60243	310
0b58a99e	311	# Convert variables in a line (could define configs)
364212fd SR	312	$_ = convert_vars($_, %make_vars);
364212fd SR	313
dcc60243 SR	314	# collect objects after obj-$(CONFIG_FOO_BAR)
	315	if (/obj-\$\((CONFIG_[^\)])\)\s[+:]?=\s(.)/) {
	316	$var = $1;
	317	$objs = $2;
364212fd SR	318
	319	# check if variables are set
	320	} elsif (/^\s(\S+)\s[:]?=\s(.\S)/) {
	321	$make_vars{$1} = $2;
dcc60243 SR	322	}
dcc60243 SR	323	if (defined($objs)) {
dcc60243 SR	324	foreach my $obj (split /\s+/,$objs) {
	325	$obj =~ s/-/_/g;
	326	if ($obj =~ /(.*)\.o$/) {
1d1d1fea	327	# Objects may be enabled by more than one config.
dcc60243 SR	328	# Store configs in an array.
	329	my @arr;
	330
	331	if (defined($objects{$1})) {
	332	@arr = @{$objects{$1}};
	333	}
	334
	335	$arr[$#arr+1] = $var;
	336
	337	# The objects have a hash mapping to a reference
	338	# of an array of configs.
	339	$objects{$1} = \@arr;
	340	}
	341	}
	342	}
	343	}
e0d28694	344	close($infile);
dcc60243 SR	345	}
	346
	347	my %modules;
e0d28694	348	my $linfile;
dcc60243	349
615f0833 SR	350	if (defined($lsmod_file)) {
615f0833 SR	351	if ( ! -f $lsmod_file) {
f597a718 AL	352	if ( -f $ENV{'objtree'}."/".$lsmod_file) {
	353	$lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
	354	} else {
	355	die "$lsmod_file not found";
	356	}
615f0833	357	}
e0d28694 BP	358
	359	my $otype = ( -x $lsmod_file) ? '-\|' : '<';
	360	open($linfile, $otype, $lsmod_file);
	361
615f0833 SR	362	} else {
	363
	364	# see what modules are loaded on this system
	365	my $lsmod;
	366
cf5a189d	367	foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
615f0833 SR	368	if ( -x "$dir/lsmod" ) {
	369	$lsmod = "$dir/lsmod";
	370	last;
	371	}
88f66ea9	372	}
615f0833 SR	373	if (!defined($lsmod)) {
	374	# try just the path
	375	$lsmod = "lsmod";
	376	}
	377
e0d28694	378	open($linfile, '-\|', $lsmod) \|\| die "Can not call lsmod with $lsmod";
88f66ea9 SR	379	}
88f66ea9 SR	380
e0d28694	381	while (<$linfile>) {
dcc60243 SR	382	next if (/^Module/); # Skip the first line.
	383	if (/^(\S+)/) {
	384	$modules{$1} = 1;
	385	}
	386	}
e0d28694	387	close ($linfile);
dcc60243 SR	388
dcc60243 SR	389	# add to the configs hash all configs that are needed to enable
0b58a99e SR	390	# a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
0b58a99e SR	391	# where we know we need bar.o so we add FOO to the list.
dcc60243 SR	392	my %configs;
	393	foreach my $module (keys(%modules)) {
	394	if (defined($objects{$module})) {
e5199edb	395	my @arr = @{$objects{$module}};
dcc60243 SR	396	foreach my $conf (@arr) {
dcc60243 SR	397	$configs{$conf} = $module;
4503379c	398	dprint "$conf added by direct ($module)\n";
dcc60243 SR	399	}
	400	} else {
	401	# Most likely, someone has a custom (binary?) module loaded.
	402	print STDERR "$module config not found!!\n";
	403	}
	404	}
	405
4f4c51c9 SR	406	# Read the current config, and see what is enabled. We want to
	407	# ignore configs that we would not enable anyway.
	408
	409	my %orig_configs;
dcc60243	410	my $valid = "A-Za-z_0-9";
4f4c51c9 SR	411
	412	foreach my $line (@config_file) {
	413	$_ = $line;
	414
	415	if (/(CONFIG_[$valid]*)=(m\|y)/) {
	416	$orig_configs{$1} = $2;
	417	}
	418	}
	419
dcc60243 SR	420	my $repeat = 1;
dcc60243 SR	421
4503379c SR	422	my $depconfig;
4503379c SR	423
dcc60243 SR	424	#
	425	# Note, we do not care about operands (like: &&, \|\|, !) we want to add any
	426	# config that is in the depend list of another config. This script does
	427	# not enable configs that are not already enabled. If we come across a
	428	# config A that depends on !B, we can still add B to the list of depends
	429	# to keep on. If A was on in the original config, B would not have been
	430	# and B would not be turned on by this script.
	431	#
d4bb58b5	432	sub parse_config_depends
dcc60243 SR	433	{
	434	my ($p) = @_;
	435
	436	while ($p =~ /[$valid]/) {
	437
	438	if ($p =~ /^[^$valid]*([$valid]+)/) {
	439	my $conf = "CONFIG_" . $1;
	440
	441	$p =~ s/^[^$valid]*[$valid]+//;
	442
4f4c51c9 SR	443	# We only need to process if the depend config is a module
	444	if (!defined($orig_configs{$conf}) \|\| !$orig_configs{conf} eq "m") {
	445	next;
	446	}
	447
dcc60243 SR	448	if (!defined($configs{$conf})) {
	449	# We must make sure that this config has its
	450	# dependencies met.
	451	$repeat = 1; # do again
4503379c	452	dprint "$conf selected by depend $depconfig\n";
dcc60243 SR	453	$configs{$conf} = 1;
	454	}
	455	} else {
	456	die "this should never happen";
	457	}
	458	}
	459	}
	460
d4bb58b5 SR	461	# Select is treated a bit differently than depends. We call this
	462	# when a config has no prompt and requires another config to be
	463	# selected. We use to just select all configs that selected this
	464	# config, but found that that can balloon into enabling hundreds
	465	# of configs that we do not care about.
	466	#
	467	# The idea is we look at all the configs that select it. If one
	468	# is already in our list of configs to enable, then there's nothing
	469	# else to do. If there isn't, we pick the first config that was
	470	# enabled in the orignal config and use that.
	471	sub parse_config_selects
	472	{
	473	my ($config, $p) = @_;
dcc60243	474
d4bb58b5 SR	475	my $next_config;
	476
	477	while ($p =~ /[$valid]/) {
	478
	479	if ($p =~ /^[^$valid]*([$valid]+)/) {
	480	my $conf = "CONFIG_" . $1;
	481
	482	$p =~ s/^[^$valid]*[$valid]+//;
dcc60243	483
d4bb58b5 SR	484	# Make sure that this config exists in the current .config file
d4bb58b5 SR	485	if (!defined($orig_configs{$conf})) {
4503379c	486	dprint "$conf not set for $config select\n";
d4bb58b5 SR	487	next;
	488	}
	489
	490	# Check if something other than a module selects this config
	491	if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
4503379c	492	dprint "$conf (non module) selects config, we are good\n";
d4bb58b5 SR	493	# we are good with this
	494	return;
	495	}
	496	if (defined($configs{$conf})) {
4503379c	497	dprint "$conf selects $config so we are good\n";
d4bb58b5 SR	498	# A set config selects this config, we are good
	499	return;
	500	}
	501	# Set this config to be selected
	502	if (!defined($next_config)) {
	503	$next_config = $conf;
	504	}
	505	} else {
	506	die "this should never happen";
dcc60243	507	}
d4bb58b5	508	}
dcc60243	509
d4bb58b5 SR	510	# If no possible config selected this, then something happened.
	511	if (!defined($next_config)) {
	512	print STDERR "WARNING: $config is required, but nothing in the\n";
	513	print STDERR " current config selects it.\n";
	514	return;
	515	}
	516
	517	# If we are here, then we found no config that is set and
	518	# selects this config. Repeat.
	519	$repeat = 1;
	520	# Make this config need to be selected
	521	$configs{$next_config} = 1;
4503379c	522	dprint "$next_config selected by select $config\n";
d4bb58b5 SR	523	}
	524
	525	my %process_selects;
	526
	527	# loop through all configs, select their dependencies.
	528	sub loop_depend {
	529	$repeat = 1;
	530
	531	while ($repeat) {
	532	$repeat = 0;
	533
	534	forloop:
	535	foreach my $config (keys %configs) {
	536
	537	# If this config is not a module, we do not need to process it
	538	if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
	539	next forloop;
	540	}
	541
	542	$config =~ s/^CONFIG_//;
4503379c	543	$depconfig = $config;
d4bb58b5 SR	544
	545	if (defined($depends{$config})) {
	546	# This config has dependencies. Make sure they are also included
	547	parse_config_depends $depends{$config};
	548	}
	549
	550	# If the config has no prompt, then we need to check if a config
	551	# that is enabled selected it. Or if we need to enable one.
	552	if (!defined($prompts{$config}) && defined($selects{$config})) {
	553	$process_selects{$config} = 1;
	554	}
dcc60243	555	}
d4bb58b5 SR	556	}
	557	}
	558
	559	sub loop_select {
	560
	561	foreach my $config (keys %process_selects) {
	562	$config =~ s/^CONFIG_//;
dcc60243	563
4503379c SR	564	dprint "Process select $config\n";
4503379c SR	565
dcc60243	566	# config has no prompt and must be selected.
d4bb58b5	567	parse_config_selects $config, $selects{$config};
dcc60243 SR	568	}
	569	}
	570
d4bb58b5 SR	571	while ($repeat) {
	572	# Get the first set of configs and their dependencies.
	573	loop_depend;
	574
	575	$repeat = 0;
	576
	577	# Now we need to see if we have to check selects;
	578	loop_select;
	579	}
	580
dcc60243 SR	581	my %setconfigs;
	582
	583	# Finally, read the .config file and turn off any module enabled that
	584	# we could not find a reason to keep enabled.
4f4c51c9 SR	585	foreach my $line (@config_file) {
4f4c51c9 SR	586	$_ = $line;
744ffcbe SR	587
	588	if (/CONFIG_IKCONFIG/) {
	589	if (/# CONFIG_IKCONFIG is not set/) {
	590	# enable IKCONFIG at least as a module
	591	print "CONFIG_IKCONFIG=m\n";
	592	# don't ask about PROC
d08ca277	593	print "# CONFIG_IKCONFIG_PROC is not set\n";
744ffcbe SR	594	} else {
	595	print;
	596	}
	597	next;
	598	}
	599
	600	if (/^(CONFIG.*)=(m\|y)/) {
	601	if (defined($configs{$1})) {
22d550ae AL	602	if ($localyesconfig) {
	603	$setconfigs{$1} = 'y';
	604	} else {
	605	$setconfigs{$1} = $2;
	606	}
744ffcbe SR	607	} elsif ($2 eq "m") {
744ffcbe SR	608	print "# $1 is not set\n";
d08ca277	609	next;
dcc60243	610	}
744ffcbe	611	}
d08ca277	612	print;
dcc60243	613	}
dcc60243 SR	614
	615	# Integrity check, make sure all modules that we want enabled do
	616	# indeed have their configs set.
	617	loop:
	618	foreach my $module (keys(%modules)) {
	619	if (defined($objects{$module})) {
	620	my @arr = @{$objects{$module}};
	621	foreach my $conf (@arr) {
	622	if (defined($setconfigs{$conf})) {
	623	next loop;
	624	}
	625	}
	626	print STDERR "module $module did not have configs";
	627	foreach my $conf (@arr) {
	628	print STDERR " " , $conf;
	629	}
	630	print STDERR "\n";
	631	}
	632	}