[mirror_ubuntu-zesty-kernel.git] / scripts / kconfig / zconf.l

%option nostdinit noyywrap never-interactive full ecs
%option 8bit nodefault perf-report perf-report
%option noinput
%x COMMAND HELP STRING PARAM
%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <limits.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <unistd.h>

#include "lkc.h"

#define START_STRSIZE	16

static struct {
	struct file *file;
	int lineno;
} current_pos;

static char *text;
static int text_size, text_asize;

struct buffer {
	struct buffer *parent;
	YY_BUFFER_STATE state;
};

struct buffer *current_buf;

static int last_ts, first_ts;

static void zconf_endhelp(void);
static void zconf_endfile(void);

static void new_string(void)
{
	text = xmalloc(START_STRSIZE);
	text_asize = START_STRSIZE;
	text_size = 0;
	*text = 0;
}

static void append_string(const char *str, int size)
{
	int new_size = text_size + size + 1;
	if (new_size > text_asize) {
		new_size += START_STRSIZE - 1;
		new_size &= -START_STRSIZE;
		text = realloc(text, new_size);
		text_asize = new_size;
	}
	memcpy(text + text_size, str, size);
	text_size += size;
	text[text_size] = 0;
}

static void alloc_string(const char *str, int size)
{
	text = xmalloc(size + 1);
	memcpy(text, str, size);
	text[size] = 0;
}

static void warn_ignored_character(char chr)
{
	fprintf(stderr,
	        "%s:%d:warning: ignoring unsupported character '%c'\n",
	        zconf_curname(), zconf_lineno(), chr);
}
%}

n	[A-Za-z0-9_-]

%%
	int str = 0;
	int ts, i;

[ \t]*#.*\n	|
[ \t]*\n	{
	current_file->lineno++;
	return T_EOL;
}
[ \t]*#.*


[ \t]+	{
	BEGIN(COMMAND);
}

.	{
	unput(yytext[0]);
	BEGIN(COMMAND);
}


<COMMAND>{
	{n}+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		BEGIN(PARAM);
		current_pos.file = current_file;
		current_pos.lineno = current_file->lineno;
		if (id && id->flags & TF_COMMAND) {
			zconflval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD;
	}
	.	warn_ignored_character(*yytext);
	\n	{
		BEGIN(INITIAL);
		current_file->lineno++;
		return T_EOL;
	}
}

<PARAM>{
	"&&"	return T_AND;
	"||"	return T_OR;
	"("	return T_OPEN_PAREN;
	")"	return T_CLOSE_PAREN;
	"!"	return T_NOT;
	"="	return T_EQUAL;
	"!="	return T_UNEQUAL;
	"<="	return T_LESS_EQUAL;
	">="	return T_GREATER_EQUAL;
	"<"	return T_LESS;
	">"	return T_GREATER;
	\"|\'	{
		str = yytext[0];
		new_string();
		BEGIN(STRING);
	}
	\n	BEGIN(INITIAL); current_file->lineno++; return T_EOL;
	({n}|[/.])+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		if (id && id->flags & TF_PARAM) {
			zconflval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD;
	}
	#.*	/* comment */
	\\\n	current_file->lineno++;
	[[:blank:]]+
	.	warn_ignored_character(*yytext);
	<<EOF>> {
		BEGIN(INITIAL);
	}
}

<STRING>{
	[^'"\\\n]+/\n	{
		append_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD_QUOTE;
	}
	[^'"\\\n]+	{
		append_string(yytext, yyleng);
	}
	\\.?/\n	{
		append_string(yytext + 1, yyleng - 1);
		zconflval.string = text;
		return T_WORD_QUOTE;
	}
	\\.?	{
		append_string(yytext + 1, yyleng - 1);
	}
	\'|\"	{
		if (str == yytext[0]) {
			BEGIN(PARAM);
			zconflval.string = text;
			return T_WORD_QUOTE;
		} else
			append_string(yytext, 1);
	}
	\n	{
		printf("%s:%d:warning: multi-line strings not supported\n", zconf_curname(), zconf_lineno());
		current_file->lineno++;
		BEGIN(INITIAL);
		return T_EOL;
	}
	<<EOF>>	{
		BEGIN(INITIAL);
	}
}

<HELP>{
	[ \t]+	{
		ts = 0;
		for (i = 0; i < yyleng; i++) {
			if (yytext[i] == '\t')
				ts = (ts & ~7) + 8;
			else
				ts++;
		}
		last_ts = ts;
		if (first_ts) {
			if (ts < first_ts) {
				zconf_endhelp();
				return T_HELPTEXT;
			}
			ts -= first_ts;
			while (ts > 8) {
				append_string("        ", 8);
				ts -= 8;
			}
			append_string("        ", ts);
		}
	}
	[ \t]*\n/[^ \t\n] {
		current_file->lineno++;
		zconf_endhelp();
		return T_HELPTEXT;
	}
	[ \t]*\n	{
		current_file->lineno++;
		append_string("\n", 1);
	}
	[^ \t\n].* {
		while (yyleng) {
			if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
				break;
			yyleng--;
		}
		append_string(yytext, yyleng);
		if (!first_ts)
			first_ts = last_ts;
	}
	<<EOF>>	{
		zconf_endhelp();
		return T_HELPTEXT;
	}
}

<<EOF>>	{
	if (current_file) {
		zconf_endfile();
		return T_EOL;
	}
	fclose(yyin);
	yyterminate();
}

%%
void zconf_starthelp(void)
{
	new_string();
	last_ts = first_ts = 0;
	BEGIN(HELP);
}

static void zconf_endhelp(void)
{
	zconflval.string = text;
	BEGIN(INITIAL);
}


/*
 * Try to open specified file with following names:
 * ./name
 * $(srctree)/name
 * The latter is used when srctree is separate from objtree
 * when compiling the kernel.
 * Return NULL if file is not found.
 */
FILE *zconf_fopen(const char *name)
{
	char *env, fullname[PATH_MAX+1];
	FILE *f;

	f = fopen(name, "r");
	if (!f && name != NULL && name[0] != '/') {
		env = getenv(SRCTREE);
		if (env) {
			sprintf(fullname, "%s/%s", env, name);
			f = fopen(fullname, "r");
		}
	}
	return f;
}

void zconf_initscan(const char *name)
{
	yyin = zconf_fopen(name);
	if (!yyin) {
		printf("can't find file %s\n", name);
		exit(1);
	}

	current_buf = xmalloc(sizeof(*current_buf));
	memset(current_buf, 0, sizeof(*current_buf));

	current_file = file_lookup(name);
	current_file->lineno = 1;
}

void zconf_nextfile(const char *name)
{
	struct file *iter;
	struct file *file = file_lookup(name);
	struct buffer *buf = xmalloc(sizeof(*buf));
	memset(buf, 0, sizeof(*buf));

	current_buf->state = YY_CURRENT_BUFFER;
	yyin = zconf_fopen(file->name);
	if (!yyin) {
		printf("%s:%d: can't open file \"%s\"\n",
		    zconf_curname(), zconf_lineno(), file->name);
		exit(1);
	}
	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	buf->parent = current_buf;
	current_buf = buf;

	for (iter = current_file->parent; iter; iter = iter->parent ) {
		if (!strcmp(current_file->name,iter->name) ) {
			printf("%s:%d: recursive inclusion detected. "
			       "Inclusion path:\n  current file : '%s'\n",
			       zconf_curname(), zconf_lineno(),
			       zconf_curname());
			iter = current_file->parent;
			while (iter && \
			       strcmp(iter->name,current_file->name)) {
				printf("  included from: '%s:%d'\n",
				       iter->name, iter->lineno-1);
				iter = iter->parent;
			}
			if (iter)
				printf("  included from: '%s:%d'\n",
				       iter->name, iter->lineno+1);
			exit(1);
		}
	}
	file->lineno = 1;
	file->parent = current_file;
	current_file = file;
}

static void zconf_endfile(void)
{
	struct buffer *parent;

	current_file = current_file->parent;

	parent = current_buf->parent;
	if (parent) {
		fclose(yyin);
		yy_delete_buffer(YY_CURRENT_BUFFER);
		yy_switch_to_buffer(parent->state);
	}
	free(current_buf);
	current_buf = parent;
}

int zconf_lineno(void)
{
	return current_pos.lineno;
}

const char *zconf_curname(void)
{
	return current_pos.file ? current_pos.file->name : "<none>";
}
Commit	Line	Data
674eed8a AL	1	%option nostdinit noyywrap never-interactive full ecs
674eed8a AL	2	%option 8bit nodefault perf-report perf-report
be2be1d5	3	%option noinput
1da177e4 LT	4	%x COMMAND HELP STRING PARAM
	5	%{
	6	/*
	7	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	8	* Released under the terms of the GNU GPL v2.0.
	9	*/
	10
	11	#include <limits.h>
	12	#include <stdio.h>
	13	#include <stdlib.h>
	14	#include <string.h>
	15	#include <unistd.h>
	16
1da177e4 LT	17	#include "lkc.h"
	18
	19	#define START_STRSIZE 16
	20
a02f0570 RZ	21	static struct {
	22	struct file *file;
	23	int lineno;
	24	} current_pos;
	25
7a88488b	26	static char *text;
1da177e4 LT	27	static int text_size, text_asize;
	28
	29	struct buffer {
bb66fc67 MY	30	struct buffer *parent;
bb66fc67 MY	31	YY_BUFFER_STATE state;
1da177e4 LT	32	};
	33
	34	struct buffer *current_buf;
	35
	36	static int last_ts, first_ts;
	37
	38	static void zconf_endhelp(void);
a02f0570	39	static void zconf_endfile(void);
1da177e4	40
65166571	41	static void new_string(void)
1da177e4	42	{
177acf78	43	text = xmalloc(START_STRSIZE);
1da177e4	44	text_asize = START_STRSIZE;
1da177e4	45	text_size = 0;
7a88488b	46	*text = 0;
1da177e4 LT	47	}
1da177e4 LT	48
65166571	49	static void append_string(const char *str, int size)
1da177e4 LT	50	{
	51	int new_size = text_size + size + 1;
	52	if (new_size > text_asize) {
7a88488b RZ	53	new_size += START_STRSIZE - 1;
7a88488b RZ	54	new_size &= -START_STRSIZE;
1da177e4 LT	55	text = realloc(text, new_size);
1da177e4 LT	56	text_asize = new_size;
1da177e4	57	}
7a88488b	58	memcpy(text + text_size, str, size);
1da177e4	59	text_size += size;
7a88488b	60	text[text_size] = 0;
1da177e4 LT	61	}
1da177e4 LT	62
65166571	63	static void alloc_string(const char *str, int size)
1da177e4	64	{
177acf78	65	text = xmalloc(size + 1);
1da177e4 LT	66	memcpy(text, str, size);
	67	text[size] = 0;
	68	}
c2264564 AR	69
	70	static void warn_ignored_character(char chr)
	71	{
	72	fprintf(stderr,
	73	"%s:%d:warning: ignoring unsupported character '%c'\n",
	74	zconf_curname(), zconf_lineno(), chr);
	75	}
1da177e4 LT	76	%}
1da177e4 LT	77
c2264564	78	n [A-Za-z0-9_-]
1da177e4 LT	79
	80	%%
	81	int str = 0;
	82	int ts, i;
	83
a02f0570 RZ	84	[ \t]#.\n \|
	85	[ \t]*\n {
	86	current_file->lineno++;
	87	return T_EOL;
	88	}
1da177e4 LT	89	[ \t]#.
1da177e4 LT	90
1da177e4 LT	91
	92	[ \t]+ {
	93	BEGIN(COMMAND);
	94	}
	95
	96	. {
	97	unput(yytext[0]);
	98	BEGIN(COMMAND);
	99	}
	100
	101
	102	<COMMAND>{
1da177e4	103	{n}+ {
61f956f5	104	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
a02f0570 RZ	105	BEGIN(PARAM);
	106	current_pos.file = current_file;
	107	current_pos.lineno = current_file->lineno;
7a88488b	108	if (id && id->flags & TF_COMMAND) {
3370f9f0	109	zconflval.id = id;
7a88488b RZ	110	return id->token;
7a88488b RZ	111	}
1da177e4 LT	112	alloc_string(yytext, yyleng);
	113	zconflval.string = text;
	114	return T_WORD;
	115	}
c2264564	116	. warn_ignored_character(*yytext);
a02f0570 RZ	117	\n {
	118	BEGIN(INITIAL);
	119	current_file->lineno++;
	120	return T_EOL;
	121	}
1da177e4 LT	122	}
	123
	124	<PARAM>{
	125	"&&" return T_AND;
	126	"\|\|" return T_OR;
	127	"(" return T_OPEN_PAREN;
	128	")" return T_CLOSE_PAREN;
	129	"!" return T_NOT;
	130	"=" return T_EQUAL;
	131	"!=" return T_UNEQUAL;
31847b67 JB	132	"<=" return T_LESS_EQUAL;
	133	">=" return T_GREATER_EQUAL;
	134	"<" return T_LESS;
	135	">" return T_GREATER;
1da177e4 LT	136	\"\|\' {
	137	str = yytext[0];
	138	new_string();
	139	BEGIN(STRING);
	140	}
	141	\n BEGIN(INITIAL); current_file->lineno++; return T_EOL;
c2264564	142	({n}\|[/.])+ {
61f956f5	143	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
3370f9f0 RZ	144	if (id && id->flags & TF_PARAM) {
3370f9f0 RZ	145	zconflval.id = id;
7a88488b	146	return id->token;
3370f9f0	147	}
1da177e4 LT	148	alloc_string(yytext, yyleng);
	149	zconflval.string = text;
	150	return T_WORD;
	151	}
	152	#.* /* comment */
	153	\\\n current_file->lineno++;
2e0d737f	154	[[:blank:]]+
c2264564	155	. warn_ignored_character(*yytext);
1da177e4 LT	156	<<EOF>> {
	157	BEGIN(INITIAL);
	158	}
	159	}
	160
	161	<STRING>{
	162	[^'"\\\n]+/\n {
	163	append_string(yytext, yyleng);
	164	zconflval.string = text;
	165	return T_WORD_QUOTE;
	166	}
	167	[^'"\\\n]+ {
	168	append_string(yytext, yyleng);
	169	}
	170	\\.?/\n {
	171	append_string(yytext + 1, yyleng - 1);
	172	zconflval.string = text;
	173	return T_WORD_QUOTE;
	174	}
	175	\\.? {
	176	append_string(yytext + 1, yyleng - 1);
	177	}
	178	\'\|\" {
	179	if (str == yytext[0]) {
	180	BEGIN(PARAM);
	181	zconflval.string = text;
	182	return T_WORD_QUOTE;
	183	} else
	184	append_string(yytext, 1);
	185	}
	186	\n {
	187	printf("%s:%d:warning: multi-line strings not supported\n", zconf_curname(), zconf_lineno());
	188	current_file->lineno++;
	189	BEGIN(INITIAL);
	190	return T_EOL;
	191	}
	192	<<EOF>> {
	193	BEGIN(INITIAL);
	194	}
	195	}
	196
	197	<HELP>{
	198	[ \t]+ {
	199	ts = 0;
	200	for (i = 0; i < yyleng; i++) {
	201	if (yytext[i] == '\t')
	202	ts = (ts & ~7) + 8;
	203	else
	204	ts++;
	205	}
	206	last_ts = ts;
	207	if (first_ts) {
	208	if (ts < first_ts) {
	209	zconf_endhelp();
	210	return T_HELPTEXT;
	211	}
	212	ts -= first_ts;
	213	while (ts > 8) {
	214	append_string(" ", 8);
	215	ts -= 8;
	216	}
	217	append_string(" ", ts);
	218	}
	219	}
220	[ \t]*\n/[^ \t\n] {
221	current_file->lineno++;
222	zconf_endhelp();
223	return T_HELPTEXT;
224	}
225	[ \t]*\n {
226	current_file->lineno++;
227	append_string("\n", 1);
228	}
229	[^ \t\n].* {
f7a4b4cd EG	230	while (yyleng) {
	231	if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
	232	break;
	233	yyleng--;
	234	}
1da177e4 LT	235	append_string(yytext, yyleng);
	236	if (!first_ts)
	237	first_ts = last_ts;
	238	}
	239	<<EOF>> {
	240	zconf_endhelp();
	241	return T_HELPTEXT;
	242	}
	243	}
	244
	245	<<EOF>> {
a02f0570	246	if (current_file) {
1da177e4	247	zconf_endfile();
a02f0570	248	return T_EOL;
1da177e4 LT	249	}
	250	fclose(yyin);
	251	yyterminate();
	252	}
	253
	254	%%
	255	void zconf_starthelp(void)
	256	{
	257	new_string();
	258	last_ts = first_ts = 0;
	259	BEGIN(HELP);
	260	}
	261
	262	static void zconf_endhelp(void)
	263	{
	264	zconflval.string = text;
	265	BEGIN(INITIAL);
	266	}
	267
	268
	269	/*
	270	* Try to open specified file with following names:
	271	* ./name
	272	* $(srctree)/name
	273	* The latter is used when srctree is separate from objtree
	274	* when compiling the kernel.
	275	* Return NULL if file is not found.
	276	*/
	277	FILE zconf_fopen(const char name)
	278	{
	279	char *env, fullname[PATH_MAX+1];
	280	FILE *f;
	281
	282	f = fopen(name, "r");
11de39e2	283	if (!f && name != NULL && name[0] != '/') {
1da177e4 LT	284	env = getenv(SRCTREE);
	285	if (env) {
	286	sprintf(fullname, "%s/%s", env, name);
	287	f = fopen(fullname, "r");
	288	}
	289	}
	290	return f;
	291	}
	292
	293	void zconf_initscan(const char *name)
	294	{
	295	yyin = zconf_fopen(name);
	296	if (!yyin) {
	297	printf("can't find file %s\n", name);
	298	exit(1);
	299	}
	300
177acf78	301	current_buf = xmalloc(sizeof(*current_buf));
1da177e4 LT	302	memset(current_buf, 0, sizeof(*current_buf));
	303
	304	current_file = file_lookup(name);
	305	current_file->lineno = 1;
1da177e4 LT	306	}
	307
	308	void zconf_nextfile(const char *name)
	309	{
f094f8a1	310	struct file *iter;
1da177e4	311	struct file *file = file_lookup(name);
177acf78	312	struct buffer buf = xmalloc(sizeof(buf));
1da177e4 LT	313	memset(buf, 0, sizeof(*buf));
	314
	315	current_buf->state = YY_CURRENT_BUFFER;
e82dae90	316	yyin = zconf_fopen(file->name);
1da177e4	317	if (!yyin) {
e82dae90 AL	318	printf("%s:%d: can't open file \"%s\"\n",
e82dae90 AL	319	zconf_curname(), zconf_lineno(), file->name);
1da177e4 LT	320	exit(1);
	321	}
	322	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	323	buf->parent = current_buf;
	324	current_buf = buf;
	325
f094f8a1 YM	326	for (iter = current_file->parent; iter; iter = iter->parent ) {
	327	if (!strcmp(current_file->name,iter->name) ) {
	328	printf("%s:%d: recursive inclusion detected. "
	329	"Inclusion path:\n current file : '%s'\n",
	330	zconf_curname(), zconf_lineno(),
	331	zconf_curname());
	332	iter = current_file->parent;
	333	while (iter && \
	334	strcmp(iter->name,current_file->name)) {
	335	printf(" included from: '%s:%d'\n",
	336	iter->name, iter->lineno-1);
	337	iter = iter->parent;
	338	}
	339	if (iter)
	340	printf(" included from: '%s:%d'\n",
	341	iter->name, iter->lineno+1);
	342	exit(1);
	343	}
1da177e4	344	}
1da177e4 LT	345	file->lineno = 1;
	346	file->parent = current_file;
	347	current_file = file;
	348	}
	349
a02f0570	350	static void zconf_endfile(void)
1da177e4 LT	351	{
	352	struct buffer *parent;
	353
1da177e4 LT	354	current_file = current_file->parent;
	355
	356	parent = current_buf->parent;
	357	if (parent) {
	358	fclose(yyin);
	359	yy_delete_buffer(YY_CURRENT_BUFFER);
	360	yy_switch_to_buffer(parent->state);
	361	}
	362	free(current_buf);
	363	current_buf = parent;
1da177e4 LT	364	}
	365
	366	int zconf_lineno(void)
	367	{
a02f0570	368	return current_pos.lineno;
1da177e4 LT	369	}
1da177e4 LT	370
2e7a0918	371	const char *zconf_curname(void)
1da177e4	372	{
a02f0570	373	return current_pos.file ? current_pos.file->name : "<none>";
1da177e4	374	}