[mirror_ubuntu-jammy-kernel.git] / scripts / kconfig / zconf.l

%option nostdinit noyywrap never-interactive full ecs
%option 8bit nodefault yylineno
%x COMMAND HELP STRING PARAM ASSIGN_VAL
%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <assert.h>
#include <limits.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <unistd.h>

#include "lkc.h"

#define YY_DECL		static int yylex1(void)

#define START_STRSIZE	16

static struct {
	struct file *file;
	int lineno;
} current_pos;

static int prev_token = T_EOL;
static char *text;
static int text_size, text_asize;

struct buffer {
	struct buffer *parent;
	YY_BUFFER_STATE state;
};

struct buffer *current_buf;

static int last_ts, first_ts;

static char *expand_token(const char *in, size_t n);
static void append_expanded_string(const char *in);
static void zconf_endhelp(void);
static void zconf_endfile(void);

static void new_string(void)
{
	text = xmalloc(START_STRSIZE);
	text_asize = START_STRSIZE;
	text_size = 0;
	*text = 0;
}

static void append_string(const char *str, int size)
{
	int new_size = text_size + size + 1;
	if (new_size > text_asize) {
		new_size += START_STRSIZE - 1;
		new_size &= -START_STRSIZE;
		text = xrealloc(text, new_size);
		text_asize = new_size;
	}
	memcpy(text + text_size, str, size);
	text_size += size;
	text[text_size] = 0;
}

static void alloc_string(const char *str, int size)
{
	text = xmalloc(size + 1);
	memcpy(text, str, size);
	text[size] = 0;
}

static void warn_ignored_character(char chr)
{
	fprintf(stderr,
	        "%s:%d:warning: ignoring unsupported character '%c'\n",
	        current_file->name, yylineno, chr);
}
%}

n	[A-Za-z0-9_-]

%%
	int str = 0;
	int ts, i;

[ \t]*#.*\n	|
[ \t]*\n	{
	return T_EOL;
}
[ \t]*#.*
.	{
	unput(yytext[0]);
	BEGIN(COMMAND);
}


<COMMAND>{
	{n}+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		current_pos.file = current_file;
		current_pos.lineno = yylineno;
		if (id && id->flags & TF_COMMAND) {
			BEGIN(PARAM);
			yylval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_VARIABLE;
	}
	({n}|$)+	{
		/* this token includes at least one '$' */
		yylval.string = expand_token(yytext, yyleng);
		if (strlen(yylval.string))
			return T_VARIABLE;
		free(yylval.string);
	}
	"="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
	":="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
	"+="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
	[[:blank:]]+
	.	warn_ignored_character(*yytext);
	\n	{
		BEGIN(INITIAL);
		return T_EOL;
	}
}

<ASSIGN_VAL>{
	[^[:blank:]\n]+.*	{
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_ASSIGN_VAL;
	}
	\n	{ BEGIN(INITIAL); return T_EOL; }
	.
}

<PARAM>{
	"&&"	return T_AND;
	"||"	return T_OR;
	"("	return T_OPEN_PAREN;
	")"	return T_CLOSE_PAREN;
	"!"	return T_NOT;
	"="	return T_EQUAL;
	"!="	return T_UNEQUAL;
	"<="	return T_LESS_EQUAL;
	">="	return T_GREATER_EQUAL;
	"<"	return T_LESS;
	">"	return T_GREATER;
	\"|\'	{
		str = yytext[0];
		new_string();
		BEGIN(STRING);
	}
	\n	BEGIN(INITIAL); return T_EOL;
	({n}|[/.])+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		if (id && id->flags & TF_PARAM) {
			yylval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_WORD;
	}
	({n}|[/.$])+	{
		/* this token includes at least one '$' */
		yylval.string = expand_token(yytext, yyleng);
		if (strlen(yylval.string))
			return T_WORD;
		free(yylval.string);
	}
	#.*	/* comment */
	\\\n	;
	[[:blank:]]+
	.	warn_ignored_character(*yytext);
	<<EOF>> {
		BEGIN(INITIAL);
	}
}

<STRING>{
	"$".*	append_expanded_string(yytext);
	[^$'"\\\n]+	{
		append_string(yytext, yyleng);
	}
	\\.?	{
		append_string(yytext + 1, yyleng - 1);
	}
	\'|\"	{
		if (str == yytext[0]) {
			BEGIN(PARAM);
			yylval.string = text;
			return T_WORD_QUOTE;
		} else
			append_string(yytext, 1);
	}
	\n	{
		fprintf(stderr,
			"%s:%d:warning: multi-line strings not supported\n",
			zconf_curname(), zconf_lineno());
		unput('\n');
		BEGIN(INITIAL);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
	<<EOF>>	{
		BEGIN(INITIAL);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
}

<HELP>{
	[ \t]+	{
		ts = 0;
		for (i = 0; i < yyleng; i++) {
			if (yytext[i] == '\t')
				ts = (ts & ~7) + 8;
			else
				ts++;
		}
		last_ts = ts;
		if (first_ts) {
			if (ts < first_ts) {
				zconf_endhelp();
				return T_HELPTEXT;
			}
			ts -= first_ts;
			while (ts > 8) {
				append_string("        ", 8);
				ts -= 8;
			}
			append_string("        ", ts);
		}
	}
	[ \t]*\n/[^ \t\n] {
		zconf_endhelp();
		return T_HELPTEXT;
	}
	[ \t]*\n	{
		append_string("\n", 1);
	}
	[^ \t\n].* {
		while (yyleng) {
			if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
				break;
			yyleng--;
		}
		append_string(yytext, yyleng);
		if (!first_ts)
			first_ts = last_ts;
	}
	<<EOF>>	{
		zconf_endhelp();
		return T_HELPTEXT;
	}
}

<<EOF>>	{
	if (current_file) {
		zconf_endfile();
		return T_EOL;
	}
	fclose(yyin);
	yyterminate();
}

%%

/* second stage lexer */
int yylex(void)
{
	int token;

repeat:
	token = yylex1();

	/* Do not pass unneeded T_EOL to the parser. */
	if ((prev_token == T_EOL || prev_token == T_HELPTEXT) && token == T_EOL)
		goto repeat;

	prev_token = token;

	return token;
}

static char *expand_token(const char *in, size_t n)
{
	char *out;
	int c;
	char c2;
	const char *rest, *end;

	new_string();
	append_string(in, n);

	/* get the whole line because we do not know the end of token. */
	while ((c = input()) != EOF) {
		if (c == '\n') {
			unput(c);
			break;
		}
		c2 = c;
		append_string(&c2, 1);
	}

	rest = text;
	out = expand_one_token(&rest);

	/* push back unused characters to the input stream */
	end = rest + strlen(rest);
	while (end > rest)
		unput(*--end);

	free(text);

	return out;
}

static void append_expanded_string(const char *str)
{
	const char *end;
	char *res;

	str++;

	res = expand_dollar(&str);

	/* push back unused characters to the input stream */
	end = str + strlen(str);
	while (end > str)
		unput(*--end);

	append_string(res, strlen(res));

	free(res);
}

void zconf_starthelp(void)
{
	new_string();
	last_ts = first_ts = 0;
	BEGIN(HELP);
}

static void zconf_endhelp(void)
{
	yylval.string = text;
	BEGIN(INITIAL);
}


/*
 * Try to open specified file with following names:
 * ./name
 * $(srctree)/name
 * The latter is used when srctree is separate from objtree
 * when compiling the kernel.
 * Return NULL if file is not found.
 */
FILE *zconf_fopen(const char *name)
{
	char *env, fullname[PATH_MAX+1];
	FILE *f;

	f = fopen(name, "r");
	if (!f && name != NULL && name[0] != '/') {
		env = getenv(SRCTREE);
		if (env) {
			sprintf(fullname, "%s/%s", env, name);
			f = fopen(fullname, "r");
		}
	}
	return f;
}

void zconf_initscan(const char *name)
{
	yyin = zconf_fopen(name);
	if (!yyin) {
		fprintf(stderr, "can't find file %s\n", name);
		exit(1);
	}

	current_buf = xmalloc(sizeof(*current_buf));
	memset(current_buf, 0, sizeof(*current_buf));

	current_file = file_lookup(name);
	yylineno = 1;
}

void zconf_nextfile(const char *name)
{
	struct file *iter;
	struct file *file = file_lookup(name);
	struct buffer *buf = xmalloc(sizeof(*buf));
	memset(buf, 0, sizeof(*buf));

	current_buf->state = YY_CURRENT_BUFFER;
	yyin = zconf_fopen(file->name);
	if (!yyin) {
		fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
			zconf_curname(), zconf_lineno(), file->name);
		exit(1);
	}
	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	buf->parent = current_buf;
	current_buf = buf;

	current_file->lineno = yylineno;
	file->parent = current_file;

	for (iter = current_file; iter; iter = iter->parent) {
		if (!strcmp(iter->name, file->name)) {
			fprintf(stderr,
				"Recursive inclusion detected.\n"
				"Inclusion path:\n"
				"  current file : %s\n", file->name);
			iter = file;
			do {
				iter = iter->parent;
				fprintf(stderr, "  included from: %s:%d\n",
					iter->name, iter->lineno - 1);
			} while (strcmp(iter->name, file->name));
			exit(1);
		}
	}

	yylineno = 1;
	current_file = file;
}

static void zconf_endfile(void)
{
	struct buffer *parent;

	current_file = current_file->parent;
	if (current_file)
		yylineno = current_file->lineno;

	parent = current_buf->parent;
	if (parent) {
		fclose(yyin);
		yy_delete_buffer(YY_CURRENT_BUFFER);
		yy_switch_to_buffer(parent->state);
	}
	free(current_buf);
	current_buf = parent;
}

int zconf_lineno(void)
{
	return current_pos.lineno;
}

const char *zconf_curname(void)
{
	return current_pos.file ? current_pos.file->name : "<none>";
}
Commit	Line	Data
674eed8a	1	%option nostdinit noyywrap never-interactive full ecs
18492685	2	%option 8bit nodefault yylineno
9ced3bdd	3	%x COMMAND HELP STRING PARAM ASSIGN_VAL
1da177e4 LT	4	%{
	5	/*
	6	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	7	* Released under the terms of the GNU GPL v2.0.
	8	*/
	9
9ced3bdd	10	#include <assert.h>
1da177e4 LT	11	#include <limits.h>
	12	#include <stdio.h>
	13	#include <stdlib.h>
	14	#include <string.h>
	15	#include <unistd.h>
	16
1da177e4 LT	17	#include "lkc.h"
1da177e4 LT	18
cc66bca7 MY	19	#define YY_DECL static int yylex1(void)
cc66bca7 MY	20
1da177e4 LT	21	#define START_STRSIZE 16
1da177e4 LT	22
a02f0570 RZ	23	static struct {
	24	struct file *file;
	25	int lineno;
	26	} current_pos;
	27
cc66bca7	28	static int prev_token = T_EOL;
7a88488b	29	static char *text;
1da177e4 LT	30	static int text_size, text_asize;
	31
	32	struct buffer {
bb66fc67 MY	33	struct buffer *parent;
bb66fc67 MY	34	YY_BUFFER_STATE state;
1da177e4 LT	35	};
	36
	37	struct buffer *current_buf;
	38
	39	static int last_ts, first_ts;
	40
104daea1 MY	41	static char expand_token(const char in, size_t n);
104daea1 MY	42	static void append_expanded_string(const char *in);
1da177e4	43	static void zconf_endhelp(void);
a02f0570	44	static void zconf_endfile(void);
1da177e4	45
65166571	46	static void new_string(void)
1da177e4	47	{
177acf78	48	text = xmalloc(START_STRSIZE);
1da177e4	49	text_asize = START_STRSIZE;
1da177e4	50	text_size = 0;
7a88488b	51	*text = 0;
1da177e4 LT	52	}
1da177e4 LT	53
65166571	54	static void append_string(const char *str, int size)
1da177e4 LT	55	{
	56	int new_size = text_size + size + 1;
	57	if (new_size > text_asize) {
7a88488b RZ	58	new_size += START_STRSIZE - 1;
7a88488b RZ	59	new_size &= -START_STRSIZE;
d717f24d	60	text = xrealloc(text, new_size);
1da177e4	61	text_asize = new_size;
1da177e4	62	}
7a88488b	63	memcpy(text + text_size, str, size);
1da177e4	64	text_size += size;
7a88488b	65	text[text_size] = 0;
1da177e4 LT	66	}
1da177e4 LT	67
65166571	68	static void alloc_string(const char *str, int size)
1da177e4	69	{
177acf78	70	text = xmalloc(size + 1);
1da177e4 LT	71	memcpy(text, str, size);
	72	text[size] = 0;
	73	}
c2264564 AR	74
	75	static void warn_ignored_character(char chr)
	76	{
	77	fprintf(stderr,
	78	"%s:%d:warning: ignoring unsupported character '%c'\n",
77c1c0fa	79	current_file->name, yylineno, chr);
c2264564	80	}
1da177e4 LT	81	%}
1da177e4 LT	82
c2264564	83	n [A-Za-z0-9_-]
1da177e4 LT	84
	85	%%
	86	int str = 0;
	87	int ts, i;
	88
a02f0570 RZ	89	[ \t]#.\n \|
a02f0570 RZ	90	[ \t]*\n {
a02f0570 RZ	91	return T_EOL;
a02f0570 RZ	92	}
1da177e4	93	[ \t]#.
1da177e4 LT	94	. {
	95	unput(yytext[0]);
	96	BEGIN(COMMAND);
	97	}
	98
	99
	100	<COMMAND>{
1da177e4	101	{n}+ {
61f956f5	102	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
a02f0570	103	current_pos.file = current_file;
18492685	104	current_pos.lineno = yylineno;
7a88488b	105	if (id && id->flags & TF_COMMAND) {
9de07153	106	BEGIN(PARAM);
765f4cde	107	yylval.id = id;
7a88488b RZ	108	return id->token;
7a88488b RZ	109	}
1da177e4	110	alloc_string(yytext, yyleng);
765f4cde	111	yylval.string = text;
9ced3bdd	112	return T_VARIABLE;
1da177e4	113	}
82bc8bd8 MY	114	({n}\|$)+ {
	115	/* this token includes at least one '$' */
	116	yylval.string = expand_token(yytext, yyleng);
	117	if (strlen(yylval.string))
	118	return T_VARIABLE;
	119	free(yylval.string);
	120	}
1175c025 MY	121	"=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
1175c025 MY	122	":=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
ed2a22f2	123	"+=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
9ced3bdd	124	[[:blank:]]+
c2264564	125	. warn_ignored_character(*yytext);
a02f0570 RZ	126	\n {
a02f0570 RZ	127	BEGIN(INITIAL);
a02f0570 RZ	128	return T_EOL;
a02f0570 RZ	129	}
1da177e4 LT	130	}
1da177e4 LT	131
9ced3bdd MY	132	<ASSIGN_VAL>{
	133	[^[:blank:]\n]+.* {
	134	alloc_string(yytext, yyleng);
	135	yylval.string = text;
	136	return T_ASSIGN_VAL;
	137	}
	138	\n { BEGIN(INITIAL); return T_EOL; }
	139	.
	140	}
	141
1da177e4 LT	142	<PARAM>{
	143	"&&" return T_AND;
	144	"\|\|" return T_OR;
	145	"(" return T_OPEN_PAREN;
	146	")" return T_CLOSE_PAREN;
	147	"!" return T_NOT;
	148	"=" return T_EQUAL;
	149	"!=" return T_UNEQUAL;
31847b67 JB	150	"<=" return T_LESS_EQUAL;
	151	">=" return T_GREATER_EQUAL;
	152	"<" return T_LESS;
	153	">" return T_GREATER;
1da177e4 LT	154	\"\|\' {
	155	str = yytext[0];
	156	new_string();
	157	BEGIN(STRING);
	158	}
18492685	159	\n BEGIN(INITIAL); return T_EOL;
c2264564	160	({n}\|[/.])+ {
61f956f5	161	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
3370f9f0	162	if (id && id->flags & TF_PARAM) {
765f4cde	163	yylval.id = id;
7a88488b	164	return id->token;
3370f9f0	165	}
1da177e4	166	alloc_string(yytext, yyleng);
765f4cde	167	yylval.string = text;
1da177e4 LT	168	return T_WORD;
1da177e4 LT	169	}
104daea1 MY	170	({n}\|[/.$])+ {
	171	/* this token includes at least one '$' */
	172	yylval.string = expand_token(yytext, yyleng);
	173	if (strlen(yylval.string))
	174	return T_WORD;
	175	free(yylval.string);
	176	}
1da177e4	177	#.* /* comment */
18492685	178	\\\n ;
2e0d737f	179	[[:blank:]]+
c2264564	180	. warn_ignored_character(*yytext);
1da177e4 LT	181	<<EOF>> {
	182	BEGIN(INITIAL);
	183	}
	184	}
	185
	186	<STRING>{
104daea1	187	"$".* append_expanded_string(yytext);
104daea1	188	[^$'"\\\n]+ {
1da177e4 LT	189	append_string(yytext, yyleng);
1da177e4 LT	190	}
1da177e4 LT	191	\\.? {
	192	append_string(yytext + 1, yyleng - 1);
	193	}
	194	\'\|\" {
	195	if (str == yytext[0]) {
	196	BEGIN(PARAM);
765f4cde	197	yylval.string = text;
1da177e4 LT	198	return T_WORD_QUOTE;
	199	} else
	200	append_string(yytext, 1);
	201	}
	202	\n {
9e3e10c7 MY	203	fprintf(stderr,
	204	"%s:%d:warning: multi-line strings not supported\n",
	205	zconf_curname(), zconf_lineno());
21c5ecf6	206	unput('\n');
1da177e4	207	BEGIN(INITIAL);
21c5ecf6 MY	208	yylval.string = text;
21c5ecf6 MY	209	return T_WORD_QUOTE;
1da177e4 LT	210	}
	211	<<EOF>> {
	212	BEGIN(INITIAL);
fbac5977 MY	213	yylval.string = text;
fbac5977 MY	214	return T_WORD_QUOTE;
1da177e4 LT	215	}
	216	}
	217
	218	<HELP>{
	219	[ \t]+ {
	220	ts = 0;
	221	for (i = 0; i < yyleng; i++) {
	222	if (yytext[i] == '\t')
	223	ts = (ts & ~7) + 8;
	224	else
	225	ts++;
	226	}
	227	last_ts = ts;
	228	if (first_ts) {
	229	if (ts < first_ts) {
	230	zconf_endhelp();
	231	return T_HELPTEXT;
	232	}
	233	ts -= first_ts;
	234	while (ts > 8) {
	235	append_string(" ", 8);
	236	ts -= 8;
	237	}
	238	append_string(" ", ts);
	239	}
	240	}
	241	[ \t]*\n/[^ \t\n] {
1da177e4 LT	242	zconf_endhelp();
	243	return T_HELPTEXT;
	244	}
	245	[ \t]*\n {
1da177e4 LT	246	append_string("\n", 1);
	247	}
	248	[^ \t\n].* {
f7a4b4cd EG	249	while (yyleng) {
	250	if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
	251	break;
	252	yyleng--;
	253	}
1da177e4 LT	254	append_string(yytext, yyleng);
	255	if (!first_ts)
	256	first_ts = last_ts;
	257	}
	258	<<EOF>> {
	259	zconf_endhelp();
	260	return T_HELPTEXT;
	261	}
	262	}
	263
	264	<<EOF>> {
a02f0570	265	if (current_file) {
1da177e4	266	zconf_endfile();
a02f0570	267	return T_EOL;
1da177e4 LT	268	}
	269	fclose(yyin);
	270	yyterminate();
	271	}
	272
	273	%%
cc66bca7 MY	274
	275	/* second stage lexer */
	276	int yylex(void)
	277	{
	278	int token;
	279
	280	repeat:
	281	token = yylex1();
	282
	283	/* Do not pass unneeded T_EOL to the parser. */
	284	if ((prev_token == T_EOL \|\| prev_token == T_HELPTEXT) && token == T_EOL)
	285	goto repeat;
	286
	287	prev_token = token;
	288
	289	return token;
	290	}
	291
104daea1 MY	292	static char expand_token(const char in, size_t n)
	293	{
	294	char *out;
	295	int c;
	296	char c2;
	297	const char rest, end;
	298
	299	new_string();
	300	append_string(in, n);
	301
	302	/* get the whole line because we do not know the end of token. */
	303	while ((c = input()) != EOF) {
	304	if (c == '\n') {
	305	unput(c);
	306	break;
	307	}
	308	c2 = c;
	309	append_string(&c2, 1);
	310	}
	311
	312	rest = text;
	313	out = expand_one_token(&rest);
	314
	315	/* push back unused characters to the input stream */
	316	end = rest + strlen(rest);
	317	while (end > rest)
	318	unput(*--end);
	319
	320	free(text);
	321
	322	return out;
	323	}
	324
	325	static void append_expanded_string(const char *str)
	326	{
	327	const char *end;
	328	char *res;
	329
	330	str++;
	331
	332	res = expand_dollar(&str);
	333
	334	/* push back unused characters to the input stream */
	335	end = str + strlen(str);
	336	while (end > str)
	337	unput(*--end);
	338
	339	append_string(res, strlen(res));
	340
	341	free(res);
	342	}
	343
1da177e4 LT	344	void zconf_starthelp(void)
	345	{
	346	new_string();
	347	last_ts = first_ts = 0;
	348	BEGIN(HELP);
	349	}
	350
	351	static void zconf_endhelp(void)
	352	{
765f4cde	353	yylval.string = text;
1da177e4 LT	354	BEGIN(INITIAL);
	355	}
	356
	357
	358	/*
	359	* Try to open specified file with following names:
	360	* ./name
	361	* $(srctree)/name
	362	* The latter is used when srctree is separate from objtree
	363	* when compiling the kernel.
	364	* Return NULL if file is not found.
	365	*/
	366	FILE zconf_fopen(const char name)
	367	{
	368	char *env, fullname[PATH_MAX+1];
	369	FILE *f;
	370
	371	f = fopen(name, "r");
11de39e2	372	if (!f && name != NULL && name[0] != '/') {
1da177e4 LT	373	env = getenv(SRCTREE);
	374	if (env) {
	375	sprintf(fullname, "%s/%s", env, name);
	376	f = fopen(fullname, "r");
	377	}
	378	}
	379	return f;
	380	}
	381
	382	void zconf_initscan(const char *name)
	383	{
	384	yyin = zconf_fopen(name);
	385	if (!yyin) {
9e3e10c7	386	fprintf(stderr, "can't find file %s\n", name);
1da177e4 LT	387	exit(1);
	388	}
	389
177acf78	390	current_buf = xmalloc(sizeof(*current_buf));
1da177e4 LT	391	memset(current_buf, 0, sizeof(*current_buf));
	392
	393	current_file = file_lookup(name);
18492685	394	yylineno = 1;
1da177e4 LT	395	}
	396
	397	void zconf_nextfile(const char *name)
	398	{
f094f8a1	399	struct file *iter;
1da177e4	400	struct file *file = file_lookup(name);
177acf78	401	struct buffer buf = xmalloc(sizeof(buf));
1da177e4 LT	402	memset(buf, 0, sizeof(*buf));
	403
	404	current_buf->state = YY_CURRENT_BUFFER;
e82dae90	405	yyin = zconf_fopen(file->name);
1da177e4	406	if (!yyin) {
9e3e10c7 MY	407	fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
9e3e10c7 MY	408	zconf_curname(), zconf_lineno(), file->name);
1da177e4 LT	409	exit(1);
	410	}
	411	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	412	buf->parent = current_buf;
	413	current_buf = buf;
	414
18492685	415	current_file->lineno = yylineno;
379a8eb8 MY	416	file->parent = current_file;
	417
	418	for (iter = current_file; iter; iter = iter->parent) {
	419	if (!strcmp(iter->name, file->name)) {
9e3e10c7	420	fprintf(stderr,
32a94b8b MY	421	"Recursive inclusion detected.\n"
32a94b8b MY	422	"Inclusion path:\n"
379a8eb8 MY	423	" current file : %s\n", file->name);
379a8eb8 MY	424	iter = file;
5ae6fcc4	425	do {
f094f8a1	426	iter = iter->parent;
32a94b8b	427	fprintf(stderr, " included from: %s:%d\n",
5ae6fcc4	428	iter->name, iter->lineno - 1);
379a8eb8	429	} while (strcmp(iter->name, file->name));
f094f8a1 YM	430	exit(1);
f094f8a1 YM	431	}
1da177e4	432	}
379a8eb8	433
18492685	434	yylineno = 1;
1da177e4 LT	435	current_file = file;
	436	}
	437
a02f0570	438	static void zconf_endfile(void)
1da177e4 LT	439	{
	440	struct buffer *parent;
	441
1da177e4	442	current_file = current_file->parent;
18492685 MY	443	if (current_file)
18492685 MY	444	yylineno = current_file->lineno;
1da177e4 LT	445
	446	parent = current_buf->parent;
	447	if (parent) {
	448	fclose(yyin);
	449	yy_delete_buffer(YY_CURRENT_BUFFER);
	450	yy_switch_to_buffer(parent->state);
	451	}
	452	free(current_buf);
	453	current_buf = parent;
1da177e4 LT	454	}
	455
	456	int zconf_lineno(void)
	457	{
a02f0570	458	return current_pos.lineno;
1da177e4 LT	459	}
1da177e4 LT	460
2e7a0918	461	const char *zconf_curname(void)
1da177e4	462	{
a02f0570	463	return current_pos.file ? current_pos.file->name : "<none>";
1da177e4	464	}