[mirror_ubuntu-bionic-kernel.git] / scripts / kconfig / zconf.y

%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <ctype.h>
#include <stdarg.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <stdbool.h>

#include "lkc.h"

#define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)

#define PRINTD		0x0001
#define DEBUG_PARSE	0x0002

int cdebug = PRINTD;

extern int zconflex(void);
static void zconfprint(const char *err, ...);
static void zconf_error(const char *err, ...);
static void zconferror(const char *err);
static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);

struct symbol *symbol_hash[SYMBOL_HASHSIZE];

static struct menu *current_menu, *current_entry;

%}
%expect 32

%union
{
	char *string;
	struct file *file;
	struct symbol *symbol;
	struct expr *expr;
	struct menu *menu;
	const struct kconf_id *id;
}

%token <id>T_MAINMENU
%token <id>T_MENU
%token <id>T_ENDMENU
%token <id>T_SOURCE
%token <id>T_CHOICE
%token <id>T_ENDCHOICE
%token <id>T_COMMENT
%token <id>T_CONFIG
%token <id>T_MENUCONFIG
%token <id>T_HELP
%token <string> T_HELPTEXT
%token <id>T_IF
%token <id>T_ENDIF
%token <id>T_DEPENDS
%token <id>T_OPTIONAL
%token <id>T_PROMPT
%token <id>T_TYPE
%token <id>T_DEFAULT
%token <id>T_SELECT
%token <id>T_IMPLY
%token <id>T_RANGE
%token <id>T_VISIBLE
%token <id>T_OPTION
%token <id>T_ON
%token <string> T_WORD
%token <string> T_WORD_QUOTE
%token T_UNEQUAL
%token T_LESS
%token T_LESS_EQUAL
%token T_GREATER
%token T_GREATER_EQUAL
%token T_CLOSE_PAREN
%token T_OPEN_PAREN
%token T_EOL

%left T_OR
%left T_AND
%left T_EQUAL T_UNEQUAL
%left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
%nonassoc T_NOT

%type <string> prompt
%type <symbol> symbol
%type <expr> expr
%type <expr> if_expr
%type <id> end
%type <id> option_name
%type <menu> if_entry menu_entry choice_entry
%type <string> symbol_option_arg word_opt

%destructor {
	fprintf(stderr, "%s:%d: missing end statement for this entry\n",
		$$->file->name, $$->lineno);
	if (current_menu == $$)
		menu_end_menu();
} if_entry menu_entry choice_entry

%{
/* Include zconf_id.c here so it can see the token constants. */
#include "kconf_id.c"
%}

%%
input: nl start | start;

start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;

/* mainmenu entry */

mainmenu_stmt: T_MAINMENU prompt nl
{
	menu_add_prompt(P_MENU, $2, NULL);
};

/* Default main menu, if there's no mainmenu entry */

no_mainmenu_stmt: /* empty */
{
	/*
	 * Hack: Keep the main menu title on the heap so we can safely free it
	 * later regardless of whether it comes from the 'prompt' in
	 * mainmenu_stmt or here
	 */
	menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
};


stmt_list:
	  /* empty */
	| stmt_list common_stmt
	| stmt_list choice_stmt
	| stmt_list menu_stmt
	| stmt_list end			{ zconf_error("unexpected end statement"); }
	| stmt_list T_WORD error T_EOL	{ zconf_error("unknown statement \"%s\"", $2); }
	| stmt_list option_name error T_EOL
{
	zconf_error("unexpected option \"%s\"", $2->name);
}
	| stmt_list error T_EOL		{ zconf_error("invalid statement"); }
;

option_name:
	T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
;

common_stmt:
	  T_EOL
	| if_stmt
	| comment_stmt
	| config_stmt
	| menuconfig_stmt
	| source_stmt
;

option_error:
	  T_WORD error T_EOL		{ zconf_error("unknown option \"%s\"", $1); }
	| error T_EOL			{ zconf_error("invalid option"); }
;


/* config/menuconfig entry */

config_entry_start: T_CONFIG T_WORD T_EOL
{
	struct symbol *sym = sym_lookup($2, 0);
	sym->flags |= SYMBOL_OPTIONAL;
	menu_add_entry(sym);
	printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
};

config_stmt: config_entry_start config_option_list
{
	menu_end_entry();
	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
};

menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
{
	struct symbol *sym = sym_lookup($2, 0);
	sym->flags |= SYMBOL_OPTIONAL;
	menu_add_entry(sym);
	printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
};

menuconfig_stmt: menuconfig_entry_start config_option_list
{
	if (current_entry->prompt)
		current_entry->prompt->type = P_MENU;
	else
		zconfprint("warning: menuconfig statement without prompt");
	menu_end_entry();
	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
};

config_option_list:
	  /* empty */
	| config_option_list config_option
	| config_option_list symbol_option
	| config_option_list depends
	| config_option_list help
	| config_option_list option_error
	| config_option_list T_EOL
;

config_option: T_TYPE prompt_stmt_opt T_EOL
{
	menu_set_type($1->stype);
	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
		zconf_curname(), zconf_lineno(),
		$1->stype);
};

config_option: T_PROMPT prompt if_expr T_EOL
{
	menu_add_prompt(P_PROMPT, $2, $3);
	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
};

config_option: T_DEFAULT expr if_expr T_EOL
{
	menu_add_expr(P_DEFAULT, $2, $3);
	if ($1->stype != S_UNKNOWN)
		menu_set_type($1->stype);
	printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
		zconf_curname(), zconf_lineno(),
		$1->stype);
};

config_option: T_SELECT T_WORD if_expr T_EOL
{
	menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
	printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
};

config_option: T_IMPLY T_WORD if_expr T_EOL
{
	menu_add_symbol(P_IMPLY, sym_lookup($2, 0), $3);
	printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
};

config_option: T_RANGE symbol symbol if_expr T_EOL
{
	menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
	printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
};

symbol_option: T_OPTION symbol_option_list T_EOL
;

symbol_option_list:
	  /* empty */
	| symbol_option_list T_WORD symbol_option_arg
{
	const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
	if (id && id->flags & TF_OPTION)
		menu_add_option(id->token, $3);
	else
		zconfprint("warning: ignoring unknown option %s", $2);
	free($2);
};

symbol_option_arg:
	  /* empty */		{ $$ = NULL; }
	| T_EQUAL prompt	{ $$ = $2; }
;

/* choice entry */

choice: T_CHOICE word_opt T_EOL
{
	struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
	sym->flags |= SYMBOL_AUTO;
	menu_add_entry(sym);
	menu_add_expr(P_CHOICE, NULL, NULL);
	printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
};

choice_entry: choice choice_option_list
{
	$$ = menu_add_menu();
};

choice_end: end
{
	if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
	}
};

choice_stmt: choice_entry choice_block choice_end
;

choice_option_list:
	  /* empty */
	| choice_option_list choice_option
	| choice_option_list depends
	| choice_option_list help
	| choice_option_list T_EOL
	| choice_option_list option_error
;

choice_option: T_PROMPT prompt if_expr T_EOL
{
	menu_add_prompt(P_PROMPT, $2, $3);
	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
};

choice_option: T_TYPE prompt_stmt_opt T_EOL
{
	if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
		menu_set_type($1->stype);
		printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
			zconf_curname(), zconf_lineno(),
			$1->stype);
	} else
		YYERROR;
};

choice_option: T_OPTIONAL T_EOL
{
	current_entry->sym->flags |= SYMBOL_OPTIONAL;
	printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
};

choice_option: T_DEFAULT T_WORD if_expr T_EOL
{
	if ($1->stype == S_UNKNOWN) {
		menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
		printd(DEBUG_PARSE, "%s:%d:default\n",
			zconf_curname(), zconf_lineno());
	} else
		YYERROR;
};

choice_block:
	  /* empty */
	| choice_block common_stmt
;

/* if entry */

if_entry: T_IF expr nl
{
	printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
	menu_add_entry(NULL);
	menu_add_dep($2);
	$$ = menu_add_menu();
};

if_end: end
{
	if (zconf_endtoken($1, T_IF, T_ENDIF)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
	}
};

if_stmt: if_entry if_block if_end
;

if_block:
	  /* empty */
	| if_block common_stmt
	| if_block menu_stmt
	| if_block choice_stmt
;

/* menu entry */

menu: T_MENU prompt T_EOL
{
	menu_add_entry(NULL);
	menu_add_prompt(P_MENU, $2, NULL);
	printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
};

menu_entry: menu visibility_list depends_list
{
	$$ = menu_add_menu();
};

menu_end: end
{
	if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
	}
};

menu_stmt: menu_entry menu_block menu_end
;

menu_block:
	  /* empty */
	| menu_block common_stmt
	| menu_block menu_stmt
	| menu_block choice_stmt
;

source_stmt: T_SOURCE prompt T_EOL
{
	printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
	zconf_nextfile($2);
};

/* comment entry */

comment: T_COMMENT prompt T_EOL
{
	menu_add_entry(NULL);
	menu_add_prompt(P_COMMENT, $2, NULL);
	printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
};

comment_stmt: comment depends_list
{
	menu_end_entry();
};

/* help option */

help_start: T_HELP T_EOL
{
	printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
	zconf_starthelp();
};

help: help_start T_HELPTEXT
{
	current_entry->help = $2;
};

/* depends option */

depends_list:
	  /* empty */
	| depends_list depends
	| depends_list T_EOL
	| depends_list option_error
;

depends: T_DEPENDS T_ON expr T_EOL
{
	menu_add_dep($3);
	printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
};

/* visibility option */

visibility_list:
	  /* empty */
	| visibility_list visible
	| visibility_list T_EOL
;

visible: T_VISIBLE if_expr
{
	menu_add_visibility($2);
};

/* prompt statement */

prompt_stmt_opt:
	  /* empty */
	| prompt if_expr
{
	menu_add_prompt(P_PROMPT, $1, $2);
};

prompt:	  T_WORD
	| T_WORD_QUOTE
;

end:	  T_ENDMENU T_EOL	{ $$ = $1; }
	| T_ENDCHOICE T_EOL	{ $$ = $1; }
	| T_ENDIF T_EOL		{ $$ = $1; }
;

nl:
	  T_EOL
	| nl T_EOL
;

if_expr:  /* empty */			{ $$ = NULL; }
	| T_IF expr			{ $$ = $2; }
;

expr:	  symbol				{ $$ = expr_alloc_symbol($1); }
	| symbol T_LESS symbol			{ $$ = expr_alloc_comp(E_LTH, $1, $3); }
	| symbol T_LESS_EQUAL symbol		{ $$ = expr_alloc_comp(E_LEQ, $1, $3); }
	| symbol T_GREATER symbol		{ $$ = expr_alloc_comp(E_GTH, $1, $3); }
	| symbol T_GREATER_EQUAL symbol		{ $$ = expr_alloc_comp(E_GEQ, $1, $3); }
	| symbol T_EQUAL symbol			{ $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
	| symbol T_UNEQUAL symbol		{ $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
	| T_OPEN_PAREN expr T_CLOSE_PAREN	{ $$ = $2; }
	| T_NOT expr				{ $$ = expr_alloc_one(E_NOT, $2); }
	| expr T_OR expr			{ $$ = expr_alloc_two(E_OR, $1, $3); }
	| expr T_AND expr			{ $$ = expr_alloc_two(E_AND, $1, $3); }
;

symbol:	  T_WORD	{ $$ = sym_lookup($1, 0); free($1); }
	| T_WORD_QUOTE	{ $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
;

word_opt: /* empty */			{ $$ = NULL; }
	| T_WORD

%%

void conf_parse(const char *name)
{
	const char *tmp;
	struct symbol *sym;
	int i;

	zconf_initscan(name);

	sym_init();
	_menu_init();

	if (getenv("ZCONF_DEBUG"))
		zconfdebug = 1;
	zconfparse();
	if (zconfnerrs)
		exit(1);
	if (!modules_sym)
		modules_sym = sym_find( "n" );

	tmp = rootmenu.prompt->text;
	rootmenu.prompt->text = _(rootmenu.prompt->text);
	rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
	free((char*)tmp);

	menu_finalize(&rootmenu);
	for_all_symbols(i, sym) {
		if (sym_check_deps(sym))
			zconfnerrs++;
	}
	if (zconfnerrs)
		exit(1);
	sym_set_change_count(1);
}

static const char *zconf_tokenname(int token)
{
	switch (token) {
	case T_MENU:		return "menu";
	case T_ENDMENU:		return "endmenu";
	case T_CHOICE:		return "choice";
	case T_ENDCHOICE:	return "endchoice";
	case T_IF:		return "if";
	case T_ENDIF:		return "endif";
	case T_DEPENDS:		return "depends";
	case T_VISIBLE:		return "visible";
	}
	return "<token>";
}

static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
{
	if (id->token != endtoken) {
		zconf_error("unexpected '%s' within %s block",
			id->name, zconf_tokenname(starttoken));
		zconfnerrs++;
		return false;
	}
	if (current_menu->file != current_file) {
		zconf_error("'%s' in different file than '%s'",
			id->name, zconf_tokenname(starttoken));
		fprintf(stderr, "%s:%d: location of the '%s'\n",
			current_menu->file->name, current_menu->lineno,
			zconf_tokenname(starttoken));
		zconfnerrs++;
		return false;
	}
	return true;
}

static void zconfprint(const char *err, ...)
{
	va_list ap;

	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	va_start(ap, err);
	vfprintf(stderr, err, ap);
	va_end(ap);
	fprintf(stderr, "\n");
}

static void zconf_error(const char *err, ...)
{
	va_list ap;

	zconfnerrs++;
	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	va_start(ap, err);
	vfprintf(stderr, err, ap);
	va_end(ap);
	fprintf(stderr, "\n");
}

static void zconferror(const char *err)
{
	fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
}

static void print_quoted_string(FILE *out, const char *str)
{
	const char *p;
	int len;

	putc('"', out);
	while ((p = strchr(str, '"'))) {
		len = p - str;
		if (len)
			fprintf(out, "%.*s", len, str);
		fputs("\\\"", out);
		str = p + 1;
	}
	fputs(str, out);
	putc('"', out);
}

static void print_symbol(FILE *out, struct menu *menu)
{
	struct symbol *sym = menu->sym;
	struct property *prop;

	if (sym_is_choice(sym))
		fprintf(out, "\nchoice\n");
	else
		fprintf(out, "\nconfig %s\n", sym->name);
	switch (sym->type) {
	case S_BOOLEAN:
		fputs("  boolean\n", out);
		break;
	case S_TRISTATE:
		fputs("  tristate\n", out);
		break;
	case S_STRING:
		fputs("  string\n", out);
		break;
	case S_INT:
		fputs("  integer\n", out);
		break;
	case S_HEX:
		fputs("  hex\n", out);
		break;
	default:
		fputs("  ???\n", out);
		break;
	}
	for (prop = sym->prop; prop; prop = prop->next) {
		if (prop->menu != menu)
			continue;
		switch (prop->type) {
		case P_PROMPT:
			fputs("  prompt ", out);
			print_quoted_string(out, prop->text);
			if (!expr_is_yes(prop->visible.expr)) {
				fputs(" if ", out);
				expr_fprint(prop->visible.expr, out);
			}
			fputc('\n', out);
			break;
		case P_DEFAULT:
			fputs( "  default ", out);
			expr_fprint(prop->expr, out);
			if (!expr_is_yes(prop->visible.expr)) {
				fputs(" if ", out);
				expr_fprint(prop->visible.expr, out);
			}
			fputc('\n', out);
			break;
		case P_CHOICE:
			fputs("  #choice value\n", out);
			break;
		case P_SELECT:
			fputs( "  select ", out);
			expr_fprint(prop->expr, out);
			fputc('\n', out);
			break;
		case P_IMPLY:
			fputs( "  imply ", out);
			expr_fprint(prop->expr, out);
			fputc('\n', out);
			break;
		case P_RANGE:
			fputs( "  range ", out);
			expr_fprint(prop->expr, out);
			fputc('\n', out);
			break;
		case P_MENU:
			fputs( "  menu ", out);
			print_quoted_string(out, prop->text);
			fputc('\n', out);
			break;
		default:
			fprintf(out, "  unknown prop %d!\n", prop->type);
			break;
		}
	}
	if (menu->help) {
		int len = strlen(menu->help);
		while (menu->help[--len] == '\n')
			menu->help[len] = 0;
		fprintf(out, "  help\n%s\n", menu->help);
	}
}

void zconfdump(FILE *out)
{
	struct property *prop;
	struct symbol *sym;
	struct menu *menu;

	menu = rootmenu.list;
	while (menu) {
		if ((sym = menu->sym))
			print_symbol(out, menu);
		else if ((prop = menu->prompt)) {
			switch (prop->type) {
			case P_COMMENT:
				fputs("\ncomment ", out);
				print_quoted_string(out, prop->text);
				fputs("\n", out);
				break;
			case P_MENU:
				fputs("\nmenu ", out);
				print_quoted_string(out, prop->text);
				fputs("\n", out);
				break;
			default:
				;
			}
			if (!expr_is_yes(prop->visible.expr)) {
				fputs("  depends ", out);
				expr_fprint(prop->visible.expr, out);
				fputc('\n', out);
			}
		}

		if (menu->list)
			menu = menu->list;
		else if (menu->next)
			menu = menu->next;
		else while ((menu = menu->parent)) {
			if (menu->prompt && menu->prompt->type == P_MENU)
				fputs("\nendmenu\n", out);
			if (menu->next) {
				menu = menu->next;
				break;
			}
		}
	}
}

#include "zconf.lex.c"
#include "util.c"
#include "confdata.c"
#include "expr.c"
#include "symbol.c"
#include "menu.c"
Commit	Line	Data
1da177e4 LT	1	%{
	2	/*
	3	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	4	* Released under the terms of the GNU GPL v2.0.
	5	*/
	6
	7	#include <ctype.h>
	8	#include <stdarg.h>
	9	#include <stdio.h>
	10	#include <stdlib.h>
	11	#include <string.h>
	12	#include <stdbool.h>
	13
7a88488b RZ	14	#include "lkc.h"
7a88488b RZ	15
1da177e4 LT	16	#define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
	17
	18	#define PRINTD 0x0001
	19	#define DEBUG_PARSE 0x0002
	20
	21	int cdebug = PRINTD;
	22
	23	extern int zconflex(void);
	24	static void zconfprint(const char *err, ...);
a02f0570	25	static void zconf_error(const char *err, ...);
1da177e4	26	static void zconferror(const char *err);
61f956f5	27	static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
1da177e4	28
e66f25d7	29	struct symbol *symbol_hash[SYMBOL_HASHSIZE];
1da177e4 LT	30
	31	static struct menu current_menu, current_entry;
	32
1da177e4	33	%}
237e3ad0	34	%expect 32
1da177e4 LT	35
	36	%union
	37	{
1da177e4	38	char *string;
a02f0570	39	struct file *file;
1da177e4 LT	40	struct symbol *symbol;
	41	struct expr *expr;
	42	struct menu *menu;
61f956f5	43	const struct kconf_id *id;
1da177e4 LT	44	}
1da177e4 LT	45
3370f9f0 RZ	46	%token <id>T_MAINMENU
	47	%token <id>T_MENU
	48	%token <id>T_ENDMENU
	49	%token <id>T_SOURCE
	50	%token <id>T_CHOICE
	51	%token <id>T_ENDCHOICE
	52	%token <id>T_COMMENT
	53	%token <id>T_CONFIG
	54	%token <id>T_MENUCONFIG
	55	%token <id>T_HELP
1da177e4	56	%token <string> T_HELPTEXT
3370f9f0 RZ	57	%token <id>T_IF
	58	%token <id>T_ENDIF
	59	%token <id>T_DEPENDS
3370f9f0 RZ	60	%token <id>T_OPTIONAL
	61	%token <id>T_PROMPT
	62	%token <id>T_TYPE
	63	%token <id>T_DEFAULT
	64	%token <id>T_SELECT
237e3ad0	65	%token <id>T_IMPLY
3370f9f0	66	%token <id>T_RANGE
86e187ff	67	%token <id>T_VISIBLE
f6a88aa8	68	%token <id>T_OPTION
3370f9f0	69	%token <id>T_ON
1da177e4 LT	70	%token <string> T_WORD
	71	%token <string> T_WORD_QUOTE
	72	%token T_UNEQUAL
31847b67 JB	73	%token T_LESS
	74	%token T_LESS_EQUAL
	75	%token T_GREATER
	76	%token T_GREATER_EQUAL
1da177e4 LT	77	%token T_CLOSE_PAREN
1da177e4 LT	78	%token T_OPEN_PAREN
3370f9f0	79	%token T_EOL
1da177e4 LT	80
	81	%left T_OR
	82	%left T_AND
	83	%left T_EQUAL T_UNEQUAL
31847b67	84	%left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
1da177e4 LT	85	%nonassoc T_NOT
	86
	87	%type <string> prompt
1da177e4 LT	88	%type <symbol> symbol
	89	%type <expr> expr
	90	%type <expr> if_expr
a02f0570 RZ	91	%type <id> end
	92	%type <id> option_name
	93	%type <menu> if_entry menu_entry choice_entry
5a1aa8a1	94	%type <string> symbol_option_arg word_opt
a02f0570 RZ	95
	96	%destructor {
	97	fprintf(stderr, "%s:%d: missing end statement for this entry\n",
	98	$$->file->name, $$->lineno);
	99	if (current_menu == $$)
	100	menu_end_menu();
	101	} if_entry menu_entry choice_entry
1da177e4	102
1456edbb	103	%{
bb3290d9 LT	104	/* Include zconf_id.c here so it can see the token constants. */
bb3290d9 LT	105	#include "kconf_id.c"
1456edbb JT	106	%}
1456edbb JT	107
1da177e4	108	%%
8ea13e2c AL	109	input: nl start \| start;
8ea13e2c AL	110
e07a0a2c UM	111	start: mainmenu_stmt stmt_list \| no_mainmenu_stmt stmt_list;
	112
	113	/* mainmenu entry */
	114
	115	mainmenu_stmt: T_MAINMENU prompt nl
	116	{
	117	menu_add_prompt(P_MENU, $2, NULL);
	118	};
	119
	120	/* Default main menu, if there's no mainmenu entry */
	121
	122	no_mainmenu_stmt: /* empty */
	123	{
	124	/*
	125	* Hack: Keep the main menu title on the heap so we can safely free it
	126	* later regardless of whether it comes from the 'prompt' in
	127	* mainmenu_stmt or here
	128	*/
	129	menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
	130	};
	131
a02f0570 RZ	132
	133	stmt_list:
	134	/* empty */
	135	\| stmt_list common_stmt
	136	\| stmt_list choice_stmt
	137	\| stmt_list menu_stmt
a02f0570 RZ	138	\| stmt_list end { zconf_error("unexpected end statement"); }
	139	\| stmt_list T_WORD error T_EOL { zconf_error("unknown statement \"%s\"", $2); }
	140	\| stmt_list option_name error T_EOL
	141	{
bb3290d9	142	zconf_error("unexpected option \"%s\"", $2->name);
a02f0570 RZ	143	}
a02f0570 RZ	144	\| stmt_list error T_EOL { zconf_error("invalid statement"); }
1da177e4 LT	145	;
1da177e4 LT	146
a02f0570	147	option_name:
237e3ad0	148	T_DEPENDS \| T_PROMPT \| T_TYPE \| T_SELECT \| T_IMPLY \| T_OPTIONAL \| T_RANGE \| T_DEFAULT \| T_VISIBLE
1da177e4 LT	149	;
1da177e4 LT	150
a02f0570 RZ	151	common_stmt:
	152	T_EOL
	153	\| if_stmt
1da177e4 LT	154	\| comment_stmt
	155	\| config_stmt
	156	\| menuconfig_stmt
	157	\| source_stmt
a02f0570 RZ	158	;
	159
	160	option_error:
	161	T_WORD error T_EOL { zconf_error("unknown option \"%s\"", $1); }
	162	\| error T_EOL { zconf_error("invalid option"); }
1da177e4 LT	163	;
	164
	165
	166	/* config/menuconfig entry */
	167
	168	config_entry_start: T_CONFIG T_WORD T_EOL
	169	{
	170	struct symbol *sym = sym_lookup($2, 0);
	171	sym->flags \|= SYMBOL_OPTIONAL;
	172	menu_add_entry(sym);
	173	printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
	174	};
	175
	176	config_stmt: config_entry_start config_option_list
	177	{
	178	menu_end_entry();
	179	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
	180	};
	181
	182	menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
	183	{
	184	struct symbol *sym = sym_lookup($2, 0);
	185	sym->flags \|= SYMBOL_OPTIONAL;
	186	menu_add_entry(sym);
	187	printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
	188	};
	189
	190	menuconfig_stmt: menuconfig_entry_start config_option_list
	191	{
	192	if (current_entry->prompt)
	193	current_entry->prompt->type = P_MENU;
	194	else
	195	zconfprint("warning: menuconfig statement without prompt");
	196	menu_end_entry();
	197	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
	198	};
	199
	200	config_option_list:
	201	/* empty */
	202	\| config_option_list config_option
f6a88aa8	203	\| config_option_list symbol_option
1da177e4 LT	204	\| config_option_list depends
1da177e4 LT	205	\| config_option_list help
a02f0570	206	\| config_option_list option_error
1da177e4 LT	207	\| config_option_list T_EOL
	208	;
	209
3370f9f0	210	config_option: T_TYPE prompt_stmt_opt T_EOL
1da177e4	211	{
3370f9f0 RZ	212	menu_set_type($1->stype);
	213	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
	214	zconf_curname(), zconf_lineno(),
	215	$1->stype);
1da177e4 LT	216	};
	217
	218	config_option: T_PROMPT prompt if_expr T_EOL
	219	{
	220	menu_add_prompt(P_PROMPT, $2, $3);
	221	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
	222	};
	223
	224	config_option: T_DEFAULT expr if_expr T_EOL
	225	{
	226	menu_add_expr(P_DEFAULT, $2, $3);
3370f9f0 RZ	227	if ($1->stype != S_UNKNOWN)
	228	menu_set_type($1->stype);
	229	printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
	230	zconf_curname(), zconf_lineno(),
	231	$1->stype);
1da177e4 LT	232	};
	233
	234	config_option: T_SELECT T_WORD if_expr T_EOL
	235	{
	236	menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
	237	printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
	238	};
	239
237e3ad0 NP	240	config_option: T_IMPLY T_WORD if_expr T_EOL
	241	{
	242	menu_add_symbol(P_IMPLY, sym_lookup($2, 0), $3);
	243	printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
	244	};
	245
1da177e4 LT	246	config_option: T_RANGE symbol symbol if_expr T_EOL
	247	{
	248	menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
	249	printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
	250	};
	251
f6a88aa8 RZ	252	symbol_option: T_OPTION symbol_option_list T_EOL
	253	;
	254
	255	symbol_option_list:
	256	/* empty */
	257	\| symbol_option_list T_WORD symbol_option_arg
	258	{
61f956f5	259	const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
f6a88aa8 RZ	260	if (id && id->flags & TF_OPTION)
	261	menu_add_option(id->token, $3);
	262	else
	263	zconfprint("warning: ignoring unknown option %s", $2);
	264	free($2);
	265	};
	266
	267	symbol_option_arg:
	268	/* empty */ { $$ = NULL; }
	269	\| T_EQUAL prompt { $$ = $2; }
	270	;
	271
1da177e4 LT	272	/* choice entry */
1da177e4 LT	273
5a1aa8a1	274	choice: T_CHOICE word_opt T_EOL
1da177e4	275	{
5a1aa8a1 RZ	276	struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
5a1aa8a1 RZ	277	sym->flags \|= SYMBOL_AUTO;
1da177e4 LT	278	menu_add_entry(sym);
	279	menu_add_expr(P_CHOICE, NULL, NULL);
	280	printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
	281	};
	282
	283	choice_entry: choice choice_option_list
	284	{
a02f0570	285	$$ = menu_add_menu();
1da177e4 LT	286	};
	287
	288	choice_end: end
	289	{
	290	if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
	291	menu_end_menu();
	292	printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
	293	}
	294	};
	295
a02f0570 RZ	296	choice_stmt: choice_entry choice_block choice_end
a02f0570 RZ	297	;
1da177e4 LT	298
	299	choice_option_list:
	300	/* empty */
	301	\| choice_option_list choice_option
	302	\| choice_option_list depends
	303	\| choice_option_list help
	304	\| choice_option_list T_EOL
a02f0570	305	\| choice_option_list option_error
1da177e4 LT	306	;
	307
	308	choice_option: T_PROMPT prompt if_expr T_EOL
	309	{
	310	menu_add_prompt(P_PROMPT, $2, $3);
	311	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
	312	};
	313
3370f9f0	314	choice_option: T_TYPE prompt_stmt_opt T_EOL
1da177e4	315	{
3370f9f0 RZ	316	if ($1->stype == S_BOOLEAN \|\| $1->stype == S_TRISTATE) {
	317	menu_set_type($1->stype);
	318	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
	319	zconf_curname(), zconf_lineno(),
	320	$1->stype);
	321	} else
	322	YYERROR;
1da177e4 LT	323	};
	324
	325	choice_option: T_OPTIONAL T_EOL
	326	{
	327	current_entry->sym->flags \|= SYMBOL_OPTIONAL;
	328	printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
	329	};
	330
	331	choice_option: T_DEFAULT T_WORD if_expr T_EOL
	332	{
3370f9f0 RZ	333	if ($1->stype == S_UNKNOWN) {
	334	menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
	335	printd(DEBUG_PARSE, "%s:%d:default\n",
	336	zconf_curname(), zconf_lineno());
	337	} else
	338	YYERROR;
1da177e4 LT	339	};
	340
	341	choice_block:
	342	/* empty */
a02f0570	343	\| choice_block common_stmt
1da177e4 LT	344	;
	345
	346	/* if entry */
	347
a02f0570	348	if_entry: T_IF expr nl
1da177e4 LT	349	{
	350	printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
	351	menu_add_entry(NULL);
	352	menu_add_dep($2);
a02f0570	353	$$ = menu_add_menu();
1da177e4 LT	354	};
	355
	356	if_end: end
	357	{
	358	if (zconf_endtoken($1, T_IF, T_ENDIF)) {
	359	menu_end_menu();
	360	printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
	361	}
	362	};
	363
a02f0570 RZ	364	if_stmt: if_entry if_block if_end
a02f0570 RZ	365	;
1da177e4 LT	366
	367	if_block:
	368	/* empty */
a02f0570	369	\| if_block common_stmt
1da177e4 LT	370	\| if_block menu_stmt
	371	\| if_block choice_stmt
	372	;
	373
	374	/* menu entry */
	375
	376	menu: T_MENU prompt T_EOL
	377	{
	378	menu_add_entry(NULL);
fb7f6ff6	379	menu_add_prompt(P_MENU, $2, NULL);
1da177e4 LT	380	printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
	381	};
	382
86e187ff	383	menu_entry: menu visibility_list depends_list
1da177e4	384	{
a02f0570	385	$$ = menu_add_menu();
1da177e4 LT	386	};
	387
	388	menu_end: end
	389	{
	390	if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
	391	menu_end_menu();
	392	printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
	393	}
	394	};
	395
a02f0570 RZ	396	menu_stmt: menu_entry menu_block menu_end
a02f0570 RZ	397	;
1da177e4 LT	398
	399	menu_block:
	400	/* empty */
a02f0570	401	\| menu_block common_stmt
1da177e4 LT	402	\| menu_block menu_stmt
1da177e4 LT	403	\| menu_block choice_stmt
1da177e4 LT	404	;
1da177e4 LT	405
a02f0570	406	source_stmt: T_SOURCE prompt T_EOL
1da177e4	407	{
1da177e4	408	printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
a02f0570	409	zconf_nextfile($2);
1da177e4 LT	410	};
	411
	412	/* comment entry */
	413
	414	comment: T_COMMENT prompt T_EOL
	415	{
	416	menu_add_entry(NULL);
fb7f6ff6	417	menu_add_prompt(P_COMMENT, $2, NULL);
1da177e4 LT	418	printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
	419	};
	420
	421	comment_stmt: comment depends_list
	422	{
	423	menu_end_entry();
	424	};
	425
	426	/* help option */
	427
	428	help_start: T_HELP T_EOL
	429	{
	430	printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
	431	zconf_starthelp();
	432	};
	433
	434	help: help_start T_HELPTEXT
	435	{
03d29122	436	current_entry->help = $2;
1da177e4 LT	437	};
	438
	439	/* depends option */
	440
a02f0570 RZ	441	depends_list:
	442	/* empty */
	443	\| depends_list depends
	444	\| depends_list T_EOL
	445	\| depends_list option_error
1da177e4 LT	446	;
	447
	448	depends: T_DEPENDS T_ON expr T_EOL
	449	{
	450	menu_add_dep($3);
	451	printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
1da177e4 LT	452	};
1da177e4 LT	453
86e187ff AL	454	/* visibility option */
	455
	456	visibility_list:
	457	/* empty */
	458	\| visibility_list visible
	459	\| visibility_list T_EOL
	460	;
	461
	462	visible: T_VISIBLE if_expr
	463	{
	464	menu_add_visibility($2);
	465	};
	466
1da177e4 LT	467	/* prompt statement */
	468
	469	prompt_stmt_opt:
	470	/* empty */
	471	\| prompt if_expr
	472	{
fb7f6ff6	473	menu_add_prompt(P_PROMPT, $1, $2);
1da177e4 LT	474	};
	475
	476	prompt: T_WORD
	477	\| T_WORD_QUOTE
	478	;
	479
a02f0570 RZ	480	end: T_ENDMENU T_EOL { $$ = $1; }
	481	\| T_ENDCHOICE T_EOL { $$ = $1; }
	482	\| T_ENDIF T_EOL { $$ = $1; }
1da177e4 LT	483	;
1da177e4 LT	484
a02f0570 RZ	485	nl:
	486	T_EOL
	487	\| nl T_EOL
	488	;
1da177e4 LT	489
	490	if_expr: /* empty */ { $$ = NULL; }
	491	\| T_IF expr { $$ = $2; }
	492	;
	493
	494	expr: symbol { $$ = expr_alloc_symbol($1); }
31847b67 JB	495	\| symbol T_LESS symbol { $$ = expr_alloc_comp(E_LTH, $1, $3); }
	496	\| symbol T_LESS_EQUAL symbol { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
	497	\| symbol T_GREATER symbol { $$ = expr_alloc_comp(E_GTH, $1, $3); }
	498	\| symbol T_GREATER_EQUAL symbol { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
1da177e4 LT	499	\| symbol T_EQUAL symbol { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
	500	\| symbol T_UNEQUAL symbol { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
	501	\| T_OPEN_PAREN expr T_CLOSE_PAREN { $$ = $2; }
	502	\| T_NOT expr { $$ = expr_alloc_one(E_NOT, $2); }
	503	\| expr T_OR expr { $$ = expr_alloc_two(E_OR, $1, $3); }
	504	\| expr T_AND expr { $$ = expr_alloc_two(E_AND, $1, $3); }
	505	;
	506
	507	symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); }
5a1aa8a1	508	\| T_WORD_QUOTE { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
1da177e4 LT	509	;
1da177e4 LT	510
5a1aa8a1 RZ	511	word_opt: /* empty */ { $$ = NULL; }
	512	\| T_WORD
	513
1da177e4 LT	514	%%
	515
	516	void conf_parse(const char *name)
	517	{
e07a0a2c	518	const char *tmp;
1da177e4 LT	519	struct symbol *sym;
	520	int i;
	521
	522	zconf_initscan(name);
	523
	524	sym_init();
692d97c3	525	_menu_init();
1da177e4	526
a02f0570 RZ	527	if (getenv("ZCONF_DEBUG"))
a02f0570 RZ	528	zconfdebug = 1;
1da177e4 LT	529	zconfparse();
	530	if (zconfnerrs)
	531	exit(1);
6902dccf YM	532	if (!modules_sym)
6902dccf YM	533	modules_sym = sym_find( "n" );
f6ce00b8	534
e07a0a2c	535	tmp = rootmenu.prompt->text;
f6ce00b8 AL	536	rootmenu.prompt->text = _(rootmenu.prompt->text);
f6ce00b8 AL	537	rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
e07a0a2c	538	free((char*)tmp);
f6ce00b8	539
1da177e4 LT	540	menu_finalize(&rootmenu);
1da177e4 LT	541	for_all_symbols(i, sym) {
5447d34b SR	542	if (sym_check_deps(sym))
5447d34b SR	543	zconfnerrs++;
bb66fc67	544	}
5447d34b SR	545	if (zconfnerrs)
5447d34b SR	546	exit(1);
bfc10001	547	sym_set_change_count(1);
1da177e4 LT	548	}
1da177e4 LT	549
65166571	550	static const char *zconf_tokenname(int token)
1da177e4 LT	551	{
	552	switch (token) {
	553	case T_MENU: return "menu";
	554	case T_ENDMENU: return "endmenu";
	555	case T_CHOICE: return "choice";
	556	case T_ENDCHOICE: return "endchoice";
	557	case T_IF: return "if";
	558	case T_ENDIF: return "endif";
a02f0570	559	case T_DEPENDS: return "depends";
86e187ff	560	case T_VISIBLE: return "visible";
1da177e4 LT	561	}
	562	return "<token>";
	563	}
	564
61f956f5	565	static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
1da177e4	566	{
a02f0570 RZ	567	if (id->token != endtoken) {
a02f0570 RZ	568	zconf_error("unexpected '%s' within %s block",
bb3290d9	569	id->name, zconf_tokenname(starttoken));
1da177e4 LT	570	zconfnerrs++;
	571	return false;
	572	}
	573	if (current_menu->file != current_file) {
a02f0570	574	zconf_error("'%s' in different file than '%s'",
bb3290d9	575	id->name, zconf_tokenname(starttoken));
a02f0570 RZ	576	fprintf(stderr, "%s:%d: location of the '%s'\n",
	577	current_menu->file->name, current_menu->lineno,
	578	zconf_tokenname(starttoken));
1da177e4 LT	579	zconfnerrs++;
	580	return false;
	581	}
	582	return true;
	583	}
	584
	585	static void zconfprint(const char *err, ...)
	586	{
	587	va_list ap;
	588
a02f0570 RZ	589	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	590	va_start(ap, err);
	591	vfprintf(stderr, err, ap);
	592	va_end(ap);
	593	fprintf(stderr, "\n");
	594	}
	595
	596	static void zconf_error(const char *err, ...)
	597	{
	598	va_list ap;
	599
	600	zconfnerrs++;
	601	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
1da177e4 LT	602	va_start(ap, err);
	603	vfprintf(stderr, err, ap);
	604	va_end(ap);
	605	fprintf(stderr, "\n");
	606	}
	607
	608	static void zconferror(const char *err)
	609	{
	610	fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
	611	}
	612
65166571	613	static void print_quoted_string(FILE out, const char str)
1da177e4 LT	614	{
	615	const char *p;
	616	int len;
	617
	618	putc('"', out);
	619	while ((p = strchr(str, '"'))) {
	620	len = p - str;
	621	if (len)
	622	fprintf(out, "%.*s", len, str);
	623	fputs("\\\"", out);
	624	str = p + 1;
	625	}
	626	fputs(str, out);
	627	putc('"', out);
	628	}
	629
65166571	630	static void print_symbol(FILE out, struct menu menu)
1da177e4 LT	631	{
	632	struct symbol *sym = menu->sym;
	633	struct property *prop;
	634
	635	if (sym_is_choice(sym))
c6ccc30f	636	fprintf(out, "\nchoice\n");
1da177e4	637	else
c6ccc30f	638	fprintf(out, "\nconfig %s\n", sym->name);
1da177e4 LT	639	switch (sym->type) {
	640	case S_BOOLEAN:
	641	fputs(" boolean\n", out);
	642	break;
	643	case S_TRISTATE:
	644	fputs(" tristate\n", out);
	645	break;
	646	case S_STRING:
	647	fputs(" string\n", out);
	648	break;
	649	case S_INT:
	650	fputs(" integer\n", out);
	651	break;
	652	case S_HEX:
	653	fputs(" hex\n", out);
	654	break;
	655	default:
	656	fputs(" ???\n", out);
	657	break;
	658	}
	659	for (prop = sym->prop; prop; prop = prop->next) {
	660	if (prop->menu != menu)
	661	continue;
	662	switch (prop->type) {
	663	case P_PROMPT:
	664	fputs(" prompt ", out);
	665	print_quoted_string(out, prop->text);
	666	if (!expr_is_yes(prop->visible.expr)) {
	667	fputs(" if ", out);
	668	expr_fprint(prop->visible.expr, out);
	669	}
	670	fputc('\n', out);
	671	break;
	672	case P_DEFAULT:
	673	fputs( " default ", out);
	674	expr_fprint(prop->expr, out);
	675	if (!expr_is_yes(prop->visible.expr)) {
	676	fputs(" if ", out);
	677	expr_fprint(prop->visible.expr, out);
	678	}
	679	fputc('\n', out);
	680	break;
	681	case P_CHOICE:
	682	fputs(" #choice value\n", out);
	683	break;
c6ccc30f LZ	684	case P_SELECT:
	685	fputs( " select ", out);
	686	expr_fprint(prop->expr, out);
	687	fputc('\n', out);
	688	break;
237e3ad0 NP	689	case P_IMPLY:
	690	fputs( " imply ", out);
	691	expr_fprint(prop->expr, out);
	692	fputc('\n', out);
	693	break;
c6ccc30f LZ	694	case P_RANGE:
	695	fputs( " range ", out);
	696	expr_fprint(prop->expr, out);
	697	fputc('\n', out);
	698	break;
	699	case P_MENU:
	700	fputs( " menu ", out);
	701	print_quoted_string(out, prop->text);
	702	fputc('\n', out);
	703	break;
1da177e4 LT	704	default:
	705	fprintf(out, " unknown prop %d!\n", prop->type);
	706	break;
	707	}
	708	}
03d29122 SR	709	if (menu->help) {
	710	int len = strlen(menu->help);
	711	while (menu->help[--len] == '\n')
	712	menu->help[len] = 0;
	713	fprintf(out, " help\n%s\n", menu->help);
1da177e4	714	}
1da177e4 LT	715	}
	716
	717	void zconfdump(FILE *out)
	718	{
	719	struct property *prop;
	720	struct symbol *sym;
	721	struct menu *menu;
	722
	723	menu = rootmenu.list;
	724	while (menu) {
	725	if ((sym = menu->sym))
	726	print_symbol(out, menu);
	727	else if ((prop = menu->prompt)) {
	728	switch (prop->type) {
	729	case P_COMMENT:
	730	fputs("\ncomment ", out);
	731	print_quoted_string(out, prop->text);
	732	fputs("\n", out);
	733	break;
	734	case P_MENU:
	735	fputs("\nmenu ", out);
	736	print_quoted_string(out, prop->text);
	737	fputs("\n", out);
	738	break;
	739	default:
	740	;
	741	}
	742	if (!expr_is_yes(prop->visible.expr)) {
	743	fputs(" depends ", out);
	744	expr_fprint(prop->visible.expr, out);
	745	fputc('\n', out);
	746	}
1da177e4 LT	747	}
	748
	749	if (menu->list)
	750	menu = menu->list;
	751	else if (menu->next)
	752	menu = menu->next;
	753	else while ((menu = menu->parent)) {
	754	if (menu->prompt && menu->prompt->type == P_MENU)
	755	fputs("\nendmenu\n", out);
	756	if (menu->next) {
	757	menu = menu->next;
	758	break;
	759	}
	760	}
	761	}
	762	}
	763
378dbb2c	764	#include "zconf.lex.c"
1da177e4 LT	765	#include "util.c"
	766	#include "confdata.c"
	767	#include "expr.c"
	768	#include "symbol.c"
	769	#include "menu.c"