[mirror_ubuntu-bionic-kernel.git] / scripts / kconfig / zconf.y

%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <ctype.h>
#include <stdarg.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <stdbool.h>

#include "lkc.h"

#define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)

#define PRINTD		0x0001
#define DEBUG_PARSE	0x0002

int cdebug = PRINTD;

extern int zconflex(void);
static void zconfprint(const char *err, ...);
static void zconf_error(const char *err, ...);
static void zconferror(const char *err);
static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);

struct symbol *symbol_hash[SYMBOL_HASHSIZE];

static struct menu *current_menu, *current_entry;

%}
%expect 30

%union
{
	char *string;
	struct file *file;
	struct symbol *symbol;
	struct expr *expr;
	struct menu *menu;
	const struct kconf_id *id;
}

%token <id>T_MAINMENU
%token <id>T_MENU
%token <id>T_ENDMENU
%token <id>T_SOURCE
%token <id>T_CHOICE
%token <id>T_ENDCHOICE
%token <id>T_COMMENT
%token <id>T_CONFIG
%token <id>T_MENUCONFIG
%token <id>T_HELP
%token <string> T_HELPTEXT
%token <id>T_IF
%token <id>T_ENDIF
%token <id>T_DEPENDS
%token <id>T_OPTIONAL
%token <id>T_PROMPT
%token <id>T_TYPE
%token <id>T_DEFAULT
%token <id>T_SELECT
%token <id>T_RANGE
%token <id>T_VISIBLE
%token <id>T_OPTION
%token <id>T_ON
%token <string> T_WORD
%token <string> T_WORD_QUOTE
%token T_UNEQUAL
%token T_CLOSE_PAREN
%token T_OPEN_PAREN
%token T_EOL

%left T_OR
%left T_AND
%left T_EQUAL T_UNEQUAL
%nonassoc T_NOT

%type <string> prompt
%type <symbol> symbol
%type <expr> expr
%type <expr> if_expr
%type <id> end
%type <id> option_name
%type <menu> if_entry menu_entry choice_entry
%type <string> symbol_option_arg word_opt

%destructor {
	fprintf(stderr, "%s:%d: missing end statement for this entry\n",
		$$->file->name, $$->lineno);
	if (current_menu == $$)
		menu_end_menu();
} if_entry menu_entry choice_entry

%{
/* Include zconf.hash.c here so it can see the token constants. */
#include "zconf.hash.c"
%}

%%
input: nl start | start;

start: mainmenu_stmt stmt_list | stmt_list;

stmt_list:
	  /* empty */
	| stmt_list common_stmt
	| stmt_list choice_stmt
	| stmt_list menu_stmt
	| stmt_list end			{ zconf_error("unexpected end statement"); }
	| stmt_list T_WORD error T_EOL	{ zconf_error("unknown statement \"%s\"", $2); }
	| stmt_list option_name error T_EOL
{
	zconf_error("unexpected option \"%s\"", kconf_id_strings + $2->name);
}
	| stmt_list error T_EOL		{ zconf_error("invalid statement"); }
;

option_name:
	T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
;

common_stmt:
	  T_EOL
	| if_stmt
	| comment_stmt
	| config_stmt
	| menuconfig_stmt
	| source_stmt
;

option_error:
	  T_WORD error T_EOL		{ zconf_error("unknown option \"%s\"", $1); }
	| error T_EOL			{ zconf_error("invalid option"); }
;


/* config/menuconfig entry */

config_entry_start: T_CONFIG T_WORD T_EOL
{
	struct symbol *sym = sym_lookup($2, 0);
	sym->flags |= SYMBOL_OPTIONAL;
	menu_add_entry(sym);
	printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
};

config_stmt: config_entry_start config_option_list
{
	menu_end_entry();
	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
};

menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
{
	struct symbol *sym = sym_lookup($2, 0);
	sym->flags |= SYMBOL_OPTIONAL;
	menu_add_entry(sym);
	printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
};

menuconfig_stmt: menuconfig_entry_start config_option_list
{
	if (current_entry->prompt)
		current_entry->prompt->type = P_MENU;
	else
		zconfprint("warning: menuconfig statement without prompt");
	menu_end_entry();
	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
};

config_option_list:
	  /* empty */
	| config_option_list config_option
	| config_option_list symbol_option
	| config_option_list depends
	| config_option_list help
	| config_option_list option_error
	| config_option_list T_EOL
;

config_option: T_TYPE prompt_stmt_opt T_EOL
{
	menu_set_type($1->stype);
	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
		zconf_curname(), zconf_lineno(),
		$1->stype);
};

config_option: T_PROMPT prompt if_expr T_EOL
{
	menu_add_prompt(P_PROMPT, $2, $3);
	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
};

config_option: T_DEFAULT expr if_expr T_EOL
{
	menu_add_expr(P_DEFAULT, $2, $3);
	if ($1->stype != S_UNKNOWN)
		menu_set_type($1->stype);
	printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
		zconf_curname(), zconf_lineno(),
		$1->stype);
};

config_option: T_SELECT T_WORD if_expr T_EOL
{
	menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
	printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
};

config_option: T_RANGE symbol symbol if_expr T_EOL
{
	menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
	printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
};

symbol_option: T_OPTION symbol_option_list T_EOL
;

symbol_option_list:
	  /* empty */
	| symbol_option_list T_WORD symbol_option_arg
{
	const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
	if (id && id->flags & TF_OPTION)
		menu_add_option(id->token, $3);
	else
		zconfprint("warning: ignoring unknown option %s", $2);
	free($2);
};

symbol_option_arg:
	  /* empty */		{ $$ = NULL; }
	| T_EQUAL prompt	{ $$ = $2; }
;

/* choice entry */

choice: T_CHOICE word_opt T_EOL
{
	struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
	sym->flags |= SYMBOL_AUTO;
	menu_add_entry(sym);
	menu_add_expr(P_CHOICE, NULL, NULL);
	printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
};

choice_entry: choice choice_option_list
{
	$$ = menu_add_menu();
};

choice_end: end
{
	if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
	}
};

choice_stmt: choice_entry choice_block choice_end
;

choice_option_list:
	  /* empty */
	| choice_option_list choice_option
	| choice_option_list depends
	| choice_option_list help
	| choice_option_list T_EOL
	| choice_option_list option_error
;

choice_option: T_PROMPT prompt if_expr T_EOL
{
	menu_add_prompt(P_PROMPT, $2, $3);
	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
};

choice_option: T_TYPE prompt_stmt_opt T_EOL
{
	if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
		menu_set_type($1->stype);
		printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
			zconf_curname(), zconf_lineno(),
			$1->stype);
	} else
		YYERROR;
};

choice_option: T_OPTIONAL T_EOL
{
	current_entry->sym->flags |= SYMBOL_OPTIONAL;
	printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
};

choice_option: T_DEFAULT T_WORD if_expr T_EOL
{
	if ($1->stype == S_UNKNOWN) {
		menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
		printd(DEBUG_PARSE, "%s:%d:default\n",
			zconf_curname(), zconf_lineno());
	} else
		YYERROR;
};

choice_block:
	  /* empty */
	| choice_block common_stmt
;

/* if entry */

if_entry: T_IF expr nl
{
	printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
	menu_add_entry(NULL);
	menu_add_dep($2);
	$$ = menu_add_menu();
};

if_end: end
{
	if (zconf_endtoken($1, T_IF, T_ENDIF)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
	}
};

if_stmt: if_entry if_block if_end
;

if_block:
	  /* empty */
	| if_block common_stmt
	| if_block menu_stmt
	| if_block choice_stmt
;

/* mainmenu entry */

mainmenu_stmt: T_MAINMENU prompt nl
{
	menu_add_prompt(P_MENU, $2, NULL);
};

/* menu entry */

menu: T_MENU prompt T_EOL
{
	menu_add_entry(NULL);
	menu_add_prompt(P_MENU, $2, NULL);
	printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
};

menu_entry: menu visibility_list depends_list
{
	$$ = menu_add_menu();
};

menu_end: end
{
	if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
		menu_end_menu();
		printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
	}
};

menu_stmt: menu_entry menu_block menu_end
;

menu_block:
	  /* empty */
	| menu_block common_stmt
	| menu_block menu_stmt
	| menu_block choice_stmt
;

source_stmt: T_SOURCE prompt T_EOL
{
	printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
	zconf_nextfile($2);
};

/* comment entry */

comment: T_COMMENT prompt T_EOL
{
	menu_add_entry(NULL);
	menu_add_prompt(P_COMMENT, $2, NULL);
	printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
};

comment_stmt: comment depends_list
{
	menu_end_entry();
};

/* help option */

help_start: T_HELP T_EOL
{
	printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
	zconf_starthelp();
};

help: help_start T_HELPTEXT
{
	current_entry->help = $2;
};

/* depends option */

depends_list:
	  /* empty */
	| depends_list depends
	| depends_list T_EOL
	| depends_list option_error
;

depends: T_DEPENDS T_ON expr T_EOL
{
	menu_add_dep($3);
	printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
};

/* visibility option */

visibility_list:
	  /* empty */
	| visibility_list visible
	| visibility_list T_EOL
;

visible: T_VISIBLE if_expr
{
	menu_add_visibility($2);
};

/* prompt statement */

prompt_stmt_opt:
	  /* empty */
	| prompt if_expr
{
	menu_add_prompt(P_PROMPT, $1, $2);
};

prompt:	  T_WORD
	| T_WORD_QUOTE
;

end:	  T_ENDMENU T_EOL	{ $$ = $1; }
	| T_ENDCHOICE T_EOL	{ $$ = $1; }
	| T_ENDIF T_EOL		{ $$ = $1; }
;

nl:
	  T_EOL
	| nl T_EOL
;

if_expr:  /* empty */			{ $$ = NULL; }
	| T_IF expr			{ $$ = $2; }
;

expr:	  symbol				{ $$ = expr_alloc_symbol($1); }
	| symbol T_EQUAL symbol			{ $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
	| symbol T_UNEQUAL symbol		{ $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
	| T_OPEN_PAREN expr T_CLOSE_PAREN	{ $$ = $2; }
	| T_NOT expr				{ $$ = expr_alloc_one(E_NOT, $2); }
	| expr T_OR expr			{ $$ = expr_alloc_two(E_OR, $1, $3); }
	| expr T_AND expr			{ $$ = expr_alloc_two(E_AND, $1, $3); }
;

symbol:	  T_WORD	{ $$ = sym_lookup($1, 0); free($1); }
	| T_WORD_QUOTE	{ $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
;

word_opt: /* empty */			{ $$ = NULL; }
	| T_WORD

%%

void conf_parse(const char *name)
{
	struct symbol *sym;
	int i;

	zconf_initscan(name);

	sym_init();
	_menu_init();
	modules_sym = sym_lookup(NULL, 0);
	modules_sym->type = S_BOOLEAN;
	modules_sym->flags |= SYMBOL_AUTO;
	rootmenu.prompt = menu_add_prompt(P_MENU, "Linux Kernel Configuration", NULL);

	if (getenv("ZCONF_DEBUG"))
		zconfdebug = 1;
	zconfparse();
	if (zconfnerrs)
		exit(1);
	if (!modules_sym->prop) {
		struct property *prop;

		prop = prop_alloc(P_DEFAULT, modules_sym);
		prop->expr = expr_alloc_symbol(sym_lookup("MODULES", 0));
	}

	rootmenu.prompt->text = _(rootmenu.prompt->text);
	rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);

	menu_finalize(&rootmenu);
	for_all_symbols(i, sym) {
		if (sym_check_deps(sym))
			zconfnerrs++;
        }
	if (zconfnerrs)
		exit(1);
	sym_set_change_count(1);
}

static const char *zconf_tokenname(int token)
{
	switch (token) {
	case T_MENU:		return "menu";
	case T_ENDMENU:		return "endmenu";
	case T_CHOICE:		return "choice";
	case T_ENDCHOICE:	return "endchoice";
	case T_IF:		return "if";
	case T_ENDIF:		return "endif";
	case T_DEPENDS:		return "depends";
	case T_VISIBLE:		return "visible";
	}
	return "<token>";
}

static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
{
	if (id->token != endtoken) {
		zconf_error("unexpected '%s' within %s block",
			kconf_id_strings + id->name, zconf_tokenname(starttoken));
		zconfnerrs++;
		return false;
	}
	if (current_menu->file != current_file) {
		zconf_error("'%s' in different file than '%s'",
			kconf_id_strings + id->name, zconf_tokenname(starttoken));
		fprintf(stderr, "%s:%d: location of the '%s'\n",
			current_menu->file->name, current_menu->lineno,
			zconf_tokenname(starttoken));
		zconfnerrs++;
		return false;
	}
	return true;
}

static void zconfprint(const char *err, ...)
{
	va_list ap;

	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	va_start(ap, err);
	vfprintf(stderr, err, ap);
	va_end(ap);
	fprintf(stderr, "\n");
}

static void zconf_error(const char *err, ...)
{
	va_list ap;

	zconfnerrs++;
	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	va_start(ap, err);
	vfprintf(stderr, err, ap);
	va_end(ap);
	fprintf(stderr, "\n");
}

static void zconferror(const char *err)
{
	fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
}

static void print_quoted_string(FILE *out, const char *str)
{
	const char *p;
	int len;

	putc('"', out);
	while ((p = strchr(str, '"'))) {
		len = p - str;
		if (len)
			fprintf(out, "%.*s", len, str);
		fputs("\\\"", out);
		str = p + 1;
	}
	fputs(str, out);
	putc('"', out);
}

static void print_symbol(FILE *out, struct menu *menu)
{
	struct symbol *sym = menu->sym;
	struct property *prop;

	if (sym_is_choice(sym))
		fprintf(out, "\nchoice\n");
	else
		fprintf(out, "\nconfig %s\n", sym->name);
	switch (sym->type) {
	case S_BOOLEAN:
		fputs("  boolean\n", out);
		break;
	case S_TRISTATE:
		fputs("  tristate\n", out);
		break;
	case S_STRING:
		fputs("  string\n", out);
		break;
	case S_INT:
		fputs("  integer\n", out);
		break;
	case S_HEX:
		fputs("  hex\n", out);
		break;
	default:
		fputs("  ???\n", out);
		break;
	}
	for (prop = sym->prop; prop; prop = prop->next) {
		if (prop->menu != menu)
			continue;
		switch (prop->type) {
		case P_PROMPT:
			fputs("  prompt ", out);
			print_quoted_string(out, prop->text);
			if (!expr_is_yes(prop->visible.expr)) {
				fputs(" if ", out);
				expr_fprint(prop->visible.expr, out);
			}
			fputc('\n', out);
			break;
		case P_DEFAULT:
			fputs( "  default ", out);
			expr_fprint(prop->expr, out);
			if (!expr_is_yes(prop->visible.expr)) {
				fputs(" if ", out);
				expr_fprint(prop->visible.expr, out);
			}
			fputc('\n', out);
			break;
		case P_CHOICE:
			fputs("  #choice value\n", out);
			break;
		case P_SELECT:
			fputs( "  select ", out);
			expr_fprint(prop->expr, out);
			fputc('\n', out);
			break;
		case P_RANGE:
			fputs( "  range ", out);
			expr_fprint(prop->expr, out);
			fputc('\n', out);
			break;
		case P_MENU:
			fputs( "  menu ", out);
			print_quoted_string(out, prop->text);
			fputc('\n', out);
			break;
		default:
			fprintf(out, "  unknown prop %d!\n", prop->type);
			break;
		}
	}
	if (menu->help) {
		int len = strlen(menu->help);
		while (menu->help[--len] == '\n')
			menu->help[len] = 0;
		fprintf(out, "  help\n%s\n", menu->help);
	}
}

void zconfdump(FILE *out)
{
	struct property *prop;
	struct symbol *sym;
	struct menu *menu;

	menu = rootmenu.list;
	while (menu) {
		if ((sym = menu->sym))
			print_symbol(out, menu);
		else if ((prop = menu->prompt)) {
			switch (prop->type) {
			case P_COMMENT:
				fputs("\ncomment ", out);
				print_quoted_string(out, prop->text);
				fputs("\n", out);
				break;
			case P_MENU:
				fputs("\nmenu ", out);
				print_quoted_string(out, prop->text);
				fputs("\n", out);
				break;
			default:
				;
			}
			if (!expr_is_yes(prop->visible.expr)) {
				fputs("  depends ", out);
				expr_fprint(prop->visible.expr, out);
				fputc('\n', out);
			}
		}

		if (menu->list)
			menu = menu->list;
		else if (menu->next)
			menu = menu->next;
		else while ((menu = menu->parent)) {
			if (menu->prompt && menu->prompt->type == P_MENU)
				fputs("\nendmenu\n", out);
			if (menu->next) {
				menu = menu->next;
				break;
			}
		}
	}
}

#include "zconf.lex.c"
#include "util.c"
#include "confdata.c"
#include "expr.c"
#include "symbol.c"
#include "menu.c"
Commit	Line	Data
1da177e4 LT	1	%{
	2	/*
	3	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	4	* Released under the terms of the GNU GPL v2.0.
	5	*/
	6
	7	#include <ctype.h>
	8	#include <stdarg.h>
	9	#include <stdio.h>
	10	#include <stdlib.h>
	11	#include <string.h>
	12	#include <stdbool.h>
	13
7a88488b RZ	14	#include "lkc.h"
7a88488b RZ	15
1da177e4 LT	16	#define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
	17
	18	#define PRINTD 0x0001
	19	#define DEBUG_PARSE 0x0002
	20
	21	int cdebug = PRINTD;
	22
	23	extern int zconflex(void);
	24	static void zconfprint(const char *err, ...);
a02f0570	25	static void zconf_error(const char *err, ...);
1da177e4	26	static void zconferror(const char *err);
61f956f5	27	static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
1da177e4	28
e66f25d7	29	struct symbol *symbol_hash[SYMBOL_HASHSIZE];
1da177e4 LT	30
	31	static struct menu current_menu, current_entry;
	32
1da177e4	33	%}
86e187ff	34	%expect 30
1da177e4 LT	35
	36	%union
	37	{
1da177e4	38	char *string;
a02f0570	39	struct file *file;
1da177e4 LT	40	struct symbol *symbol;
	41	struct expr *expr;
	42	struct menu *menu;
61f956f5	43	const struct kconf_id *id;
1da177e4 LT	44	}
1da177e4 LT	45
3370f9f0 RZ	46	%token <id>T_MAINMENU
	47	%token <id>T_MENU
	48	%token <id>T_ENDMENU
	49	%token <id>T_SOURCE
	50	%token <id>T_CHOICE
	51	%token <id>T_ENDCHOICE
	52	%token <id>T_COMMENT
	53	%token <id>T_CONFIG
	54	%token <id>T_MENUCONFIG
	55	%token <id>T_HELP
1da177e4	56	%token <string> T_HELPTEXT
3370f9f0 RZ	57	%token <id>T_IF
	58	%token <id>T_ENDIF
	59	%token <id>T_DEPENDS
3370f9f0 RZ	60	%token <id>T_OPTIONAL
	61	%token <id>T_PROMPT
	62	%token <id>T_TYPE
	63	%token <id>T_DEFAULT
	64	%token <id>T_SELECT
	65	%token <id>T_RANGE
86e187ff	66	%token <id>T_VISIBLE
f6a88aa8	67	%token <id>T_OPTION
3370f9f0	68	%token <id>T_ON
1da177e4 LT	69	%token <string> T_WORD
	70	%token <string> T_WORD_QUOTE
	71	%token T_UNEQUAL
1da177e4 LT	72	%token T_CLOSE_PAREN
1da177e4 LT	73	%token T_OPEN_PAREN
3370f9f0	74	%token T_EOL
1da177e4 LT	75
	76	%left T_OR
	77	%left T_AND
	78	%left T_EQUAL T_UNEQUAL
	79	%nonassoc T_NOT
	80
	81	%type <string> prompt
1da177e4 LT	82	%type <symbol> symbol
	83	%type <expr> expr
	84	%type <expr> if_expr
a02f0570 RZ	85	%type <id> end
	86	%type <id> option_name
	87	%type <menu> if_entry menu_entry choice_entry
5a1aa8a1	88	%type <string> symbol_option_arg word_opt
a02f0570 RZ	89
	90	%destructor {
	91	fprintf(stderr, "%s:%d: missing end statement for this entry\n",
	92	$$->file->name, $$->lineno);
	93	if (current_menu == $$)
	94	menu_end_menu();
	95	} if_entry menu_entry choice_entry
1da177e4	96
1456edbb JT	97	%{
	98	/* Include zconf.hash.c here so it can see the token constants. */
	99	#include "zconf.hash.c"
	100	%}
	101
1da177e4	102	%%
8ea13e2c AL	103	input: nl start \| start;
	104
	105	start: mainmenu_stmt stmt_list \| stmt_list;
a02f0570 RZ	106
	107	stmt_list:
	108	/* empty */
	109	\| stmt_list common_stmt
	110	\| stmt_list choice_stmt
	111	\| stmt_list menu_stmt
a02f0570 RZ	112	\| stmt_list end { zconf_error("unexpected end statement"); }
	113	\| stmt_list T_WORD error T_EOL { zconf_error("unknown statement \"%s\"", $2); }
	114	\| stmt_list option_name error T_EOL
	115	{
	116	zconf_error("unexpected option \"%s\"", kconf_id_strings + $2->name);
	117	}
	118	\| stmt_list error T_EOL { zconf_error("invalid statement"); }
1da177e4 LT	119	;
1da177e4 LT	120
a02f0570	121	option_name:
86e187ff	122	T_DEPENDS \| T_PROMPT \| T_TYPE \| T_SELECT \| T_OPTIONAL \| T_RANGE \| T_DEFAULT \| T_VISIBLE
1da177e4 LT	123	;
1da177e4 LT	124
a02f0570 RZ	125	common_stmt:
	126	T_EOL
	127	\| if_stmt
1da177e4 LT	128	\| comment_stmt
	129	\| config_stmt
	130	\| menuconfig_stmt
	131	\| source_stmt
a02f0570 RZ	132	;
	133
	134	option_error:
	135	T_WORD error T_EOL { zconf_error("unknown option \"%s\"", $1); }
	136	\| error T_EOL { zconf_error("invalid option"); }
1da177e4 LT	137	;
	138
	139
	140	/* config/menuconfig entry */
	141
	142	config_entry_start: T_CONFIG T_WORD T_EOL
	143	{
	144	struct symbol *sym = sym_lookup($2, 0);
	145	sym->flags \|= SYMBOL_OPTIONAL;
	146	menu_add_entry(sym);
	147	printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
	148	};
	149
	150	config_stmt: config_entry_start config_option_list
	151	{
	152	menu_end_entry();
	153	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
	154	};
	155
	156	menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
	157	{
	158	struct symbol *sym = sym_lookup($2, 0);
	159	sym->flags \|= SYMBOL_OPTIONAL;
	160	menu_add_entry(sym);
	161	printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
	162	};
	163
	164	menuconfig_stmt: menuconfig_entry_start config_option_list
	165	{
	166	if (current_entry->prompt)
	167	current_entry->prompt->type = P_MENU;
	168	else
	169	zconfprint("warning: menuconfig statement without prompt");
	170	menu_end_entry();
	171	printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
	172	};
	173
	174	config_option_list:
	175	/* empty */
	176	\| config_option_list config_option
f6a88aa8	177	\| config_option_list symbol_option
1da177e4 LT	178	\| config_option_list depends
1da177e4 LT	179	\| config_option_list help
a02f0570	180	\| config_option_list option_error
1da177e4 LT	181	\| config_option_list T_EOL
	182	;
	183
3370f9f0	184	config_option: T_TYPE prompt_stmt_opt T_EOL
1da177e4	185	{
3370f9f0 RZ	186	menu_set_type($1->stype);
	187	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
	188	zconf_curname(), zconf_lineno(),
	189	$1->stype);
1da177e4 LT	190	};
	191
	192	config_option: T_PROMPT prompt if_expr T_EOL
	193	{
	194	menu_add_prompt(P_PROMPT, $2, $3);
	195	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
	196	};
	197
	198	config_option: T_DEFAULT expr if_expr T_EOL
	199	{
	200	menu_add_expr(P_DEFAULT, $2, $3);
3370f9f0 RZ	201	if ($1->stype != S_UNKNOWN)
	202	menu_set_type($1->stype);
	203	printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
	204	zconf_curname(), zconf_lineno(),
	205	$1->stype);
1da177e4 LT	206	};
	207
	208	config_option: T_SELECT T_WORD if_expr T_EOL
	209	{
	210	menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
	211	printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
	212	};
	213
	214	config_option: T_RANGE symbol symbol if_expr T_EOL
	215	{
	216	menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
	217	printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
	218	};
	219
f6a88aa8 RZ	220	symbol_option: T_OPTION symbol_option_list T_EOL
	221	;
	222
	223	symbol_option_list:
	224	/* empty */
	225	\| symbol_option_list T_WORD symbol_option_arg
	226	{
61f956f5	227	const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
f6a88aa8 RZ	228	if (id && id->flags & TF_OPTION)
	229	menu_add_option(id->token, $3);
	230	else
	231	zconfprint("warning: ignoring unknown option %s", $2);
	232	free($2);
	233	};
	234
	235	symbol_option_arg:
	236	/* empty */ { $$ = NULL; }
	237	\| T_EQUAL prompt { $$ = $2; }
	238	;
	239
1da177e4 LT	240	/* choice entry */
1da177e4 LT	241
5a1aa8a1	242	choice: T_CHOICE word_opt T_EOL
1da177e4	243	{
5a1aa8a1 RZ	244	struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
5a1aa8a1 RZ	245	sym->flags \|= SYMBOL_AUTO;
1da177e4 LT	246	menu_add_entry(sym);
	247	menu_add_expr(P_CHOICE, NULL, NULL);
	248	printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
	249	};
	250
	251	choice_entry: choice choice_option_list
	252	{
a02f0570	253	$$ = menu_add_menu();
1da177e4 LT	254	};
	255
	256	choice_end: end
	257	{
	258	if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
	259	menu_end_menu();
	260	printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
	261	}
	262	};
	263
a02f0570 RZ	264	choice_stmt: choice_entry choice_block choice_end
a02f0570 RZ	265	;
1da177e4 LT	266
	267	choice_option_list:
	268	/* empty */
	269	\| choice_option_list choice_option
	270	\| choice_option_list depends
	271	\| choice_option_list help
	272	\| choice_option_list T_EOL
a02f0570	273	\| choice_option_list option_error
1da177e4 LT	274	;
	275
	276	choice_option: T_PROMPT prompt if_expr T_EOL
	277	{
	278	menu_add_prompt(P_PROMPT, $2, $3);
	279	printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
	280	};
	281
3370f9f0	282	choice_option: T_TYPE prompt_stmt_opt T_EOL
1da177e4	283	{
3370f9f0 RZ	284	if ($1->stype == S_BOOLEAN \|\| $1->stype == S_TRISTATE) {
	285	menu_set_type($1->stype);
	286	printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
	287	zconf_curname(), zconf_lineno(),
	288	$1->stype);
	289	} else
	290	YYERROR;
1da177e4 LT	291	};
	292
	293	choice_option: T_OPTIONAL T_EOL
	294	{
	295	current_entry->sym->flags \|= SYMBOL_OPTIONAL;
	296	printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
	297	};
	298
	299	choice_option: T_DEFAULT T_WORD if_expr T_EOL
	300	{
3370f9f0 RZ	301	if ($1->stype == S_UNKNOWN) {
	302	menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
	303	printd(DEBUG_PARSE, "%s:%d:default\n",
	304	zconf_curname(), zconf_lineno());
	305	} else
	306	YYERROR;
1da177e4 LT	307	};
	308
	309	choice_block:
	310	/* empty */
a02f0570	311	\| choice_block common_stmt
1da177e4 LT	312	;
	313
	314	/* if entry */
	315
a02f0570	316	if_entry: T_IF expr nl
1da177e4 LT	317	{
	318	printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
	319	menu_add_entry(NULL);
	320	menu_add_dep($2);
a02f0570	321	$$ = menu_add_menu();
1da177e4 LT	322	};
	323
	324	if_end: end
	325	{
	326	if (zconf_endtoken($1, T_IF, T_ENDIF)) {
	327	menu_end_menu();
	328	printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
	329	}
	330	};
	331
a02f0570 RZ	332	if_stmt: if_entry if_block if_end
a02f0570 RZ	333	;
1da177e4 LT	334
	335	if_block:
	336	/* empty */
a02f0570	337	\| if_block common_stmt
1da177e4 LT	338	\| if_block menu_stmt
	339	\| if_block choice_stmt
	340	;
	341
8ea13e2c AL	342	/* mainmenu entry */
	343
	344	mainmenu_stmt: T_MAINMENU prompt nl
	345	{
	346	menu_add_prompt(P_MENU, $2, NULL);
	347	};
	348
1da177e4 LT	349	/* menu entry */
	350
	351	menu: T_MENU prompt T_EOL
	352	{
	353	menu_add_entry(NULL);
fb7f6ff6	354	menu_add_prompt(P_MENU, $2, NULL);
1da177e4 LT	355	printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
	356	};
	357
86e187ff	358	menu_entry: menu visibility_list depends_list
1da177e4	359	{
a02f0570	360	$$ = menu_add_menu();
1da177e4 LT	361	};
	362
	363	menu_end: end
	364	{
	365	if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
	366	menu_end_menu();
	367	printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
	368	}
	369	};
	370
a02f0570 RZ	371	menu_stmt: menu_entry menu_block menu_end
a02f0570 RZ	372	;
1da177e4 LT	373
	374	menu_block:
	375	/* empty */
a02f0570	376	\| menu_block common_stmt
1da177e4 LT	377	\| menu_block menu_stmt
1da177e4 LT	378	\| menu_block choice_stmt
1da177e4 LT	379	;
1da177e4 LT	380
a02f0570	381	source_stmt: T_SOURCE prompt T_EOL
1da177e4	382	{
1da177e4	383	printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
a02f0570	384	zconf_nextfile($2);
1da177e4 LT	385	};
	386
	387	/* comment entry */
	388
	389	comment: T_COMMENT prompt T_EOL
	390	{
	391	menu_add_entry(NULL);
fb7f6ff6	392	menu_add_prompt(P_COMMENT, $2, NULL);
1da177e4 LT	393	printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
	394	};
	395
	396	comment_stmt: comment depends_list
	397	{
	398	menu_end_entry();
	399	};
	400
	401	/* help option */
	402
	403	help_start: T_HELP T_EOL
	404	{
	405	printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
	406	zconf_starthelp();
	407	};
	408
	409	help: help_start T_HELPTEXT
	410	{
03d29122	411	current_entry->help = $2;
1da177e4 LT	412	};
	413
	414	/* depends option */
	415
a02f0570 RZ	416	depends_list:
	417	/* empty */
	418	\| depends_list depends
	419	\| depends_list T_EOL
	420	\| depends_list option_error
1da177e4 LT	421	;
	422
	423	depends: T_DEPENDS T_ON expr T_EOL
	424	{
	425	menu_add_dep($3);
	426	printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
1da177e4 LT	427	};
1da177e4 LT	428
86e187ff AL	429	/* visibility option */
	430
	431	visibility_list:
	432	/* empty */
	433	\| visibility_list visible
	434	\| visibility_list T_EOL
	435	;
	436
	437	visible: T_VISIBLE if_expr
	438	{
	439	menu_add_visibility($2);
	440	};
	441
1da177e4 LT	442	/* prompt statement */
	443
	444	prompt_stmt_opt:
	445	/* empty */
	446	\| prompt if_expr
	447	{
fb7f6ff6	448	menu_add_prompt(P_PROMPT, $1, $2);
1da177e4 LT	449	};
	450
	451	prompt: T_WORD
	452	\| T_WORD_QUOTE
	453	;
	454
a02f0570 RZ	455	end: T_ENDMENU T_EOL { $$ = $1; }
	456	\| T_ENDCHOICE T_EOL { $$ = $1; }
	457	\| T_ENDIF T_EOL { $$ = $1; }
1da177e4 LT	458	;
1da177e4 LT	459
a02f0570 RZ	460	nl:
	461	T_EOL
	462	\| nl T_EOL
	463	;
1da177e4 LT	464
	465	if_expr: /* empty */ { $$ = NULL; }
	466	\| T_IF expr { $$ = $2; }
	467	;
	468
	469	expr: symbol { $$ = expr_alloc_symbol($1); }
	470	\| symbol T_EQUAL symbol { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
	471	\| symbol T_UNEQUAL symbol { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
	472	\| T_OPEN_PAREN expr T_CLOSE_PAREN { $$ = $2; }
	473	\| T_NOT expr { $$ = expr_alloc_one(E_NOT, $2); }
	474	\| expr T_OR expr { $$ = expr_alloc_two(E_OR, $1, $3); }
	475	\| expr T_AND expr { $$ = expr_alloc_two(E_AND, $1, $3); }
	476	;
	477
	478	symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); }
5a1aa8a1	479	\| T_WORD_QUOTE { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
1da177e4 LT	480	;
1da177e4 LT	481
5a1aa8a1 RZ	482	word_opt: /* empty */ { $$ = NULL; }
	483	\| T_WORD
	484
1da177e4 LT	485	%%
	486
	487	void conf_parse(const char *name)
	488	{
	489	struct symbol *sym;
	490	int i;
	491
	492	zconf_initscan(name);
	493
	494	sym_init();
692d97c3	495	_menu_init();
face4374 RZ	496	modules_sym = sym_lookup(NULL, 0);
	497	modules_sym->type = S_BOOLEAN;
	498	modules_sym->flags \|= SYMBOL_AUTO;
fb7f6ff6	499	rootmenu.prompt = menu_add_prompt(P_MENU, "Linux Kernel Configuration", NULL);
1da177e4	500
a02f0570 RZ	501	if (getenv("ZCONF_DEBUG"))
a02f0570 RZ	502	zconfdebug = 1;
1da177e4 LT	503	zconfparse();
	504	if (zconfnerrs)
	505	exit(1);
face4374 RZ	506	if (!modules_sym->prop) {
	507	struct property *prop;
	508
	509	prop = prop_alloc(P_DEFAULT, modules_sym);
	510	prop->expr = expr_alloc_symbol(sym_lookup("MODULES", 0));
	511	}
f6ce00b8 AL	512
	513	rootmenu.prompt->text = _(rootmenu.prompt->text);
	514	rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
	515
1da177e4 LT	516	menu_finalize(&rootmenu);
1da177e4 LT	517	for_all_symbols(i, sym) {
5447d34b SR	518	if (sym_check_deps(sym))
5447d34b SR	519	zconfnerrs++;
1da177e4	520	}
5447d34b SR	521	if (zconfnerrs)
5447d34b SR	522	exit(1);
bfc10001	523	sym_set_change_count(1);
1da177e4 LT	524	}
1da177e4 LT	525
65166571	526	static const char *zconf_tokenname(int token)
1da177e4 LT	527	{
	528	switch (token) {
	529	case T_MENU: return "menu";
	530	case T_ENDMENU: return "endmenu";
	531	case T_CHOICE: return "choice";
	532	case T_ENDCHOICE: return "endchoice";
	533	case T_IF: return "if";
	534	case T_ENDIF: return "endif";
a02f0570	535	case T_DEPENDS: return "depends";
86e187ff	536	case T_VISIBLE: return "visible";
1da177e4 LT	537	}
	538	return "<token>";
	539	}
	540
61f956f5	541	static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
1da177e4	542	{
a02f0570 RZ	543	if (id->token != endtoken) {
	544	zconf_error("unexpected '%s' within %s block",
	545	kconf_id_strings + id->name, zconf_tokenname(starttoken));
1da177e4 LT	546	zconfnerrs++;
	547	return false;
	548	}
	549	if (current_menu->file != current_file) {
a02f0570 RZ	550	zconf_error("'%s' in different file than '%s'",
	551	kconf_id_strings + id->name, zconf_tokenname(starttoken));
	552	fprintf(stderr, "%s:%d: location of the '%s'\n",
	553	current_menu->file->name, current_menu->lineno,
	554	zconf_tokenname(starttoken));
1da177e4 LT	555	zconfnerrs++;
	556	return false;
	557	}
	558	return true;
	559	}
	560
	561	static void zconfprint(const char *err, ...)
	562	{
	563	va_list ap;
	564
a02f0570 RZ	565	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
	566	va_start(ap, err);
	567	vfprintf(stderr, err, ap);
	568	va_end(ap);
	569	fprintf(stderr, "\n");
	570	}
	571
	572	static void zconf_error(const char *err, ...)
	573	{
	574	va_list ap;
	575
	576	zconfnerrs++;
	577	fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
1da177e4 LT	578	va_start(ap, err);
	579	vfprintf(stderr, err, ap);
	580	va_end(ap);
	581	fprintf(stderr, "\n");
	582	}
	583
	584	static void zconferror(const char *err)
	585	{
	586	fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
	587	}
	588
65166571	589	static void print_quoted_string(FILE out, const char str)
1da177e4 LT	590	{
	591	const char *p;
	592	int len;
	593
	594	putc('"', out);
	595	while ((p = strchr(str, '"'))) {
	596	len = p - str;
	597	if (len)
	598	fprintf(out, "%.*s", len, str);
	599	fputs("\\\"", out);
	600	str = p + 1;
	601	}
	602	fputs(str, out);
	603	putc('"', out);
	604	}
	605
65166571	606	static void print_symbol(FILE out, struct menu menu)
1da177e4 LT	607	{
	608	struct symbol *sym = menu->sym;
	609	struct property *prop;
	610
	611	if (sym_is_choice(sym))
c6ccc30f	612	fprintf(out, "\nchoice\n");
1da177e4	613	else
c6ccc30f	614	fprintf(out, "\nconfig %s\n", sym->name);
1da177e4 LT	615	switch (sym->type) {
	616	case S_BOOLEAN:
	617	fputs(" boolean\n", out);
	618	break;
	619	case S_TRISTATE:
	620	fputs(" tristate\n", out);
	621	break;
	622	case S_STRING:
	623	fputs(" string\n", out);
	624	break;
	625	case S_INT:
	626	fputs(" integer\n", out);
	627	break;
	628	case S_HEX:
	629	fputs(" hex\n", out);
	630	break;
	631	default:
	632	fputs(" ???\n", out);
	633	break;
	634	}
	635	for (prop = sym->prop; prop; prop = prop->next) {
	636	if (prop->menu != menu)
	637	continue;
	638	switch (prop->type) {
	639	case P_PROMPT:
	640	fputs(" prompt ", out);
	641	print_quoted_string(out, prop->text);
	642	if (!expr_is_yes(prop->visible.expr)) {
	643	fputs(" if ", out);
	644	expr_fprint(prop->visible.expr, out);
	645	}
	646	fputc('\n', out);
	647	break;
	648	case P_DEFAULT:
	649	fputs( " default ", out);
	650	expr_fprint(prop->expr, out);
	651	if (!expr_is_yes(prop->visible.expr)) {
	652	fputs(" if ", out);
	653	expr_fprint(prop->visible.expr, out);
	654	}
	655	fputc('\n', out);
	656	break;
	657	case P_CHOICE:
	658	fputs(" #choice value\n", out);
	659	break;
c6ccc30f LZ	660	case P_SELECT:
	661	fputs( " select ", out);
	662	expr_fprint(prop->expr, out);
	663	fputc('\n', out);
	664	break;
	665	case P_RANGE:
	666	fputs( " range ", out);
	667	expr_fprint(prop->expr, out);
	668	fputc('\n', out);
	669	break;
	670	case P_MENU:
	671	fputs( " menu ", out);
	672	print_quoted_string(out, prop->text);
	673	fputc('\n', out);
	674	break;
1da177e4 LT	675	default:
	676	fprintf(out, " unknown prop %d!\n", prop->type);
	677	break;
	678	}
	679	}
03d29122 SR	680	if (menu->help) {
	681	int len = strlen(menu->help);
	682	while (menu->help[--len] == '\n')
	683	menu->help[len] = 0;
	684	fprintf(out, " help\n%s\n", menu->help);
1da177e4	685	}
1da177e4 LT	686	}
	687
	688	void zconfdump(FILE *out)
	689	{
	690	struct property *prop;
	691	struct symbol *sym;
	692	struct menu *menu;
	693
	694	menu = rootmenu.list;
	695	while (menu) {
	696	if ((sym = menu->sym))
	697	print_symbol(out, menu);
	698	else if ((prop = menu->prompt)) {
	699	switch (prop->type) {
	700	case P_COMMENT:
	701	fputs("\ncomment ", out);
	702	print_quoted_string(out, prop->text);
	703	fputs("\n", out);
	704	break;
	705	case P_MENU:
	706	fputs("\nmenu ", out);
	707	print_quoted_string(out, prop->text);
	708	fputs("\n", out);
	709	break;
	710	default:
	711	;
	712	}
	713	if (!expr_is_yes(prop->visible.expr)) {
	714	fputs(" depends ", out);
	715	expr_fprint(prop->visible.expr, out);
	716	fputc('\n', out);
	717	}
1da177e4 LT	718	}
	719
	720	if (menu->list)
	721	menu = menu->list;
	722	else if (menu->next)
	723	menu = menu->next;
	724	else while ((menu = menu->parent)) {
	725	if (menu->prompt && menu->prompt->type == P_MENU)
	726	fputs("\nendmenu\n", out);
	727	if (menu->next) {
	728	menu = menu->next;
	729	break;
	730	}
	731	}
	732	}
	733	}
	734
378dbb2c	735	#include "zconf.lex.c"
1da177e4 LT	736	#include "util.c"
	737	#include "confdata.c"
	738	#include "expr.c"
	739	#include "symbol.c"
	740	#include "menu.c"