[mirror_ubuntu-zesty-kernel.git] / tools / perf / util / parse-events.l


%option reentrant
%option bison-bridge
%option prefix="parse_events_"
%option stack
%option bison-locations
%option yylineno

%{
#include <errno.h>
#include "../perf.h"
#include "parse-events.h"
#include "parse-events-bison.h"

char *parse_events_get_text(yyscan_t yyscanner);
YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);

static int __value(YYSTYPE *yylval, char *str, int base, int token)
{
	u64 num;

	errno = 0;
	num = strtoull(str, NULL, base);
	if (errno)
		return PE_ERROR;

	yylval->num = num;
	return token;
}

static int value(yyscan_t scanner, int base)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	return __value(yylval, text, base, PE_VALUE);
}

static int raw(yyscan_t scanner)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	return __value(yylval, text + 1, 16, PE_RAW);
}

static int str(yyscan_t scanner, int token)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	yylval->str = strdup(text);
	return token;
}

/*
 * This function is called when the parser gets two kind of input:
 *
 * 	@cfg1 or @cfg2=config
 *
 * The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
 * bison.  In the latter case it is necessary to keep the string intact so that
 * the PMU kernel driver can determine what configurable is associated to
 * 'config'.
 */
static int drv_str(yyscan_t scanner, int token)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	/* Strip off the '@' */
	yylval->str = strdup(text + 1);
	return token;
}

#define REWIND(__alloc)				\
do {								\
	YYSTYPE *__yylval = parse_events_get_lval(yyscanner);	\
	char *text = parse_events_get_text(yyscanner);		\
								\
	if (__alloc)						\
		__yylval->str = strdup(text);			\
								\
	yycolumn -= strlen(text);				\
	yyless(0);						\
} while (0)

static int pmu_str_check(yyscan_t scanner)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	yylval->str = strdup(text);
	switch (perf_pmu__parse_check(text)) {
		case PMU_EVENT_SYMBOL_PREFIX:
			return PE_PMU_EVENT_PRE;
		case PMU_EVENT_SYMBOL_SUFFIX:
			return PE_PMU_EVENT_SUF;
		case PMU_EVENT_SYMBOL:
			return PE_KERNEL_PMU_EVENT;
		default:
			return PE_NAME;
	}
}

static int sym(yyscan_t scanner, int type, int config)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);

	yylval->num = (type << 16) + config;
	return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
}

static int term(yyscan_t scanner, int type)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);

	yylval->num = type;
	return PE_TERM;
}

#define YY_USER_ACTION					\
do {							\
	yylloc->last_column  = yylloc->first_column;	\
	yylloc->first_column = yycolumn;		\
	yycolumn += yyleng;				\
} while (0);

%}

%x mem
%s config
%x event
%x array

group		[^,{}/]*[{][^}]*[}][^,{}/]*
event_pmu	[^,{}/]+[/][^/]*[/][^,{}/]*
event		[^,{}/]+
bpf_object	[^,{}]+\.(o|bpf)
bpf_source	[^,{}]+\.c

num_dec		[0-9]+
num_hex		0x[a-fA-F0-9]+
num_raw_hex	[a-fA-F0-9]+
name		[a-zA-Z_*?][a-zA-Z0-9_*?.]*
name_minus	[a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
drv_cfg_term	[a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
/* If you add a modifier you need to update check_modifier() */
modifier_event	[ukhpPGHSDI]+
modifier_bp	[rwx]{1,3}

%%

%{
	{
		int start_token;

		start_token = parse_events_get_extra(yyscanner);

		if (start_token == PE_START_TERMS)
			BEGIN(config);
		else if (start_token == PE_START_EVENTS)
			BEGIN(event);

		if (start_token) {
			parse_events_set_extra(NULL, yyscanner);
			/*
			 * The flex parser does not init locations variable
			 * via the scan_string interface, so we need do the
			 * init in here.
			 */
			yycolumn = 0;
			return start_token;
		}
         }
%}

<event>{

{group}		{
			BEGIN(INITIAL);
			REWIND(0);
		}

{event_pmu}	|
{bpf_object}	|
{bpf_source}	|
{event}		{
			BEGIN(INITIAL);
			REWIND(1);
			return PE_EVENT_NAME;
		}

<<EOF>>		{
			BEGIN(INITIAL);
			REWIND(0);
		}

}

<array>{
"]"			{ BEGIN(config); return ']'; }
{num_dec}		{ return value(yyscanner, 10); }
{num_hex}		{ return value(yyscanner, 16); }
,			{ return ','; }
"\.\.\."		{ return PE_ARRAY_RANGE; }
}

<config>{
	/*
	 * Please update config_term_names when new static term is added.
	 */
config			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
config1			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
config2			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
name			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
period			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
freq			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
branch_type		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
time			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
call-graph		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
stack-size		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
max-stack		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
inherit			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
no-inherit		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
overwrite		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
no-overwrite		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
,			{ return ','; }
"/"			{ BEGIN(INITIAL); return '/'; }
{name_minus}		{ return str(yyscanner, PE_NAME); }
\[all\]			{ return PE_ARRAY_ALL; }
"["			{ BEGIN(array); return '['; }
@{drv_cfg_term}		{ return drv_str(yyscanner, PE_DRV_CFG_TERM); }
}

<mem>{
{modifier_bp}		{ return str(yyscanner, PE_MODIFIER_BP); }
:			{ return ':'; }
"/"			{ return '/'; }
{num_dec}		{ return value(yyscanner, 10); }
{num_hex}		{ return value(yyscanner, 16); }
	/*
	 * We need to separate 'mem:' scanner part, in order to get specific
	 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
	 * and we'd need to parse it manually. During the escape from <mem>
	 * state we need to put the escaping char back, so we dont miss it.
	 */
.			{ unput(*yytext); BEGIN(INITIAL); }
	/*
	 * We destroy the scanner after reaching EOF,
	 * but anyway just to be sure get back to INIT state.
	 */
<<EOF>>			{ BEGIN(INITIAL); }
}

cpu-cycles|cycles				{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
stalled-cycles-frontend|idle-cycles-frontend	{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
stalled-cycles-backend|idle-cycles-backend	{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
instructions					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
cache-references				{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
cache-misses					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
branch-instructions|branches			{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
branch-misses					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
bus-cycles					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
ref-cycles					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
cpu-clock					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
task-clock					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
page-faults|faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
minor-faults					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
major-faults					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
context-switches|cs				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
cpu-migrations|migrations			{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
alignment-faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
emulation-faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
dummy						{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
bpf-output					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }

	/*
	 * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
	 * Because the prefix cycles is mixed up with cpu-cycles.
	 * loads and stores are mixed up with cache event
	 */
cycles-ct					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
cycles-t					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
mem-loads					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
mem-stores					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
topdown-[a-z-]+					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }

L1-dcache|l1-d|l1d|L1-data		|
L1-icache|l1-i|l1i|L1-instruction	|
LLC|L2					|
dTLB|d-tlb|Data-TLB			|
iTLB|i-tlb|Instruction-TLB		|
branch|branches|bpu|btb|bpc		|
node					{ return str(yyscanner, PE_NAME_CACHE_TYPE); }

load|loads|read				|
store|stores|write			|
prefetch|prefetches			|
speculative-read|speculative-load	|
refs|Reference|ops|access		|
misses|miss				{ return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }

mem:			{ BEGIN(mem); return PE_PREFIX_MEM; }
r{num_raw_hex}		{ return raw(yyscanner); }
{num_dec}		{ return value(yyscanner, 10); }
{num_hex}		{ return value(yyscanner, 16); }

{modifier_event}	{ return str(yyscanner, PE_MODIFIER_EVENT); }
{bpf_object}		{ return str(yyscanner, PE_BPF_OBJECT); }
{bpf_source}		{ return str(yyscanner, PE_BPF_SOURCE); }
{name}			{ return pmu_str_check(yyscanner); }
"/"			{ BEGIN(config); return '/'; }
-			{ return '-'; }
,			{ BEGIN(event); return ','; }
:			{ return ':'; }
"{"			{ BEGIN(event); return '{'; }
"}"			{ return '}'; }
=			{ return '='; }
\n			{ }
.			{ }

%%

int parse_events_wrap(void *scanner __maybe_unused)
{
	return 1;
}
Commit	Line	Data
89812fc8	1
ac20de6f ZY	2	%option reentrant
ac20de6f ZY	3	%option bison-bridge
89812fc8	4	%option prefix="parse_events_"
08d2f762	5	%option stack
6297d423 JO	6	%option bison-locations
6297d423 JO	7	%option yylineno
89812fc8 JO	8
	9	%{
	10	#include <errno.h>
	11	#include "../perf.h"
8f707d84	12	#include "parse-events.h"
e571e029	13	#include "parse-events-bison.h"
89812fc8	14
ac20de6f ZY	15	char *parse_events_get_text(yyscan_t yyscanner);
	16	YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
	17
	18	static int __value(YYSTYPE yylval, char str, int base, int token)
89812fc8	19	{
b527bab5	20	u64 num;
89812fc8 JO	21
89812fc8 JO	22	errno = 0;
b527bab5	23	num = strtoull(str, NULL, base);
89812fc8 JO	24	if (errno)
	25	return PE_ERROR;
	26
ac20de6f	27	yylval->num = num;
89812fc8 JO	28	return token;
	29	}
	30
ac20de6f	31	static int value(yyscan_t scanner, int base)
89812fc8	32	{
ac20de6f ZY	33	YYSTYPE *yylval = parse_events_get_lval(scanner);
	34	char *text = parse_events_get_text(scanner);
	35
	36	return __value(yylval, text, base, PE_VALUE);
89812fc8 JO	37	}
89812fc8 JO	38
ac20de6f	39	static int raw(yyscan_t scanner)
89812fc8	40	{
ac20de6f ZY	41	YYSTYPE *yylval = parse_events_get_lval(scanner);
	42	char *text = parse_events_get_text(scanner);
	43
	44	return __value(yylval, text + 1, 16, PE_RAW);
89812fc8 JO	45	}
89812fc8 JO	46
ac20de6f	47	static int str(yyscan_t scanner, int token)
89812fc8	48	{
ac20de6f ZY	49	YYSTYPE *yylval = parse_events_get_lval(scanner);
	50	char *text = parse_events_get_text(scanner);
	51
	52	yylval->str = strdup(text);
89812fc8 JO	53	return token;
	54	}
	55
dd60fba7 MP	56	/*
	57	* This function is called when the parser gets two kind of input:
	58	*
	59	* @cfg1 or @cfg2=config
	60	*
	61	* The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
	62	* bison. In the latter case it is necessary to keep the string intact so that
	63	* the PMU kernel driver can determine what configurable is associated to
	64	* 'config'.
	65	*/
	66	static int drv_str(yyscan_t scanner, int token)
	67	{
	68	YYSTYPE *yylval = parse_events_get_lval(scanner);
	69	char *text = parse_events_get_text(scanner);
	70
	71	/* Strip off the '@' */
	72	yylval->str = strdup(text + 1);
	73	return token;
	74	}
	75
6297d423 JO	76	#define REWIND(__alloc) \
	77	do { \
	78	YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
	79	char *text = parse_events_get_text(yyscanner); \
	80	\
	81	if (__alloc) \
	82	__yylval->str = strdup(text); \
	83	\
	84	yycolumn -= strlen(text); \
	85	yyless(0); \
	86	} while (0)
	87
ba32a451 KL	88	static int pmu_str_check(yyscan_t scanner)
	89	{
	90	YYSTYPE *yylval = parse_events_get_lval(scanner);
	91	char *text = parse_events_get_text(scanner);
	92
	93	yylval->str = strdup(text);
	94	switch (perf_pmu__parse_check(text)) {
	95	case PMU_EVENT_SYMBOL_PREFIX:
	96	return PE_PMU_EVENT_PRE;
	97	case PMU_EVENT_SYMBOL_SUFFIX:
	98	return PE_PMU_EVENT_SUF;
	99	case PMU_EVENT_SYMBOL:
	100	return PE_KERNEL_PMU_EVENT;
	101	default:
	102	return PE_NAME;
	103	}
	104	}
	105
ac20de6f	106	static int sym(yyscan_t scanner, int type, int config)
89812fc8	107	{
ac20de6f ZY	108	YYSTYPE *yylval = parse_events_get_lval(scanner);
	109
	110	yylval->num = (type << 16) + config;
cf3506dc	111	return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
89812fc8 JO	112	}
89812fc8 JO	113
ac20de6f	114	static int term(yyscan_t scanner, int type)
8f707d84	115	{
ac20de6f ZY	116	YYSTYPE *yylval = parse_events_get_lval(scanner);
	117
	118	yylval->num = type;
8f707d84 JO	119	return PE_TERM;
	120	}
	121
6297d423 JO	122	#define YY_USER_ACTION \
	123	do { \
	124	yylloc->last_column = yylloc->first_column; \
	125	yylloc->first_column = yycolumn; \
	126	yycolumn += yyleng; \
	127	} while (0);
	128
89812fc8 JO	129	%}
89812fc8 JO	130
08d2f762	131	%x mem
ac2ba9f3 RR	132	%s config
ac2ba9f3 RR	133	%x event
e571e029	134	%x array
ac2ba9f3 RR	135
	136	group [^,{}/][{][^}][}][^,{}/]*
	137	event_pmu [^,{}/]+[/][^/][/][^,{}/]
	138	event [^,{}/]+
2d470b62 WN	139	bpf_object [^,{}]+\.(o\|bpf)
2d470b62 WN	140	bpf_source [^,{}]+\.c
08d2f762	141
89812fc8 JO	142	num_dec [0-9]+
	143	num_hex 0x[a-fA-F0-9]+
	144	num_raw_hex [a-fA-F0-9]+
5b021ddf	145	name [a-zA-Z_?][a-zA-Z0-9_?.]*
a34f3be7	146	name_minus [a-zA-Z_?][a-zA-Z0-9\-_?.:]*
dd60fba7	147	drv_cfg_term [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
e9a7c414	148	/* If you add a modifier you need to update check_modifier() */
7f94af7a	149	modifier_event [ukhpPGHSDI]+
7582732f	150	modifier_bp [rwx]{1,3}
89812fc8 JO	151
89812fc8 JO	152	%%
90e2b22d JO	153
	154	%{
	155	{
	156	int start_token;
	157
ac2ba9f3 RR	158	start_token = parse_events_get_extra(yyscanner);
	159
	160	if (start_token == PE_START_TERMS)
	161	BEGIN(config);
	162	else if (start_token == PE_START_EVENTS)
	163	BEGIN(event);
	164
90e2b22d JO	165	if (start_token) {
90e2b22d JO	166	parse_events_set_extra(NULL, yyscanner);
6297d423 JO	167	/*
	168	* The flex parser does not init locations variable
	169	* via the scan_string interface, so we need do the
	170	* init in here.
	171	*/
	172	yycolumn = 0;
90e2b22d JO	173	return start_token;
	174	}
	175	}
	176	%}
	177
ac2ba9f3 RR	178	<event>{
	179
	180	{group} {
6297d423 JO	181	BEGIN(INITIAL);
6297d423 JO	182	REWIND(0);
ac2ba9f3 RR	183	}
	184
	185	{event_pmu} \|
84c86ca1	186	{bpf_object} \|
d509db04	187	{bpf_source} \|
ac2ba9f3	188	{event} {
6297d423 JO	189	BEGIN(INITIAL);
6297d423 JO	190	REWIND(1);
ac2ba9f3 RR	191	return PE_EVENT_NAME;
	192	}
	193
ac2ba9f3	194	<<EOF>> {
6297d423 JO	195	BEGIN(INITIAL);
6297d423 JO	196	REWIND(0);
ac2ba9f3 RR	197	}
	198
	199	}
	200
e571e029 WN	201	<array>{
	202	"]" { BEGIN(config); return ']'; }
	203	{num_dec} { return value(yyscanner, 10); }
	204	{num_hex} { return value(yyscanner, 16); }
	205	, { return ','; }
	206	"\.\.\." { return PE_ARRAY_RANGE; }
	207	}
	208
82004223	209	<config>{
e64b020b	210	/*
17cb5f84	211	* Please update config_term_names when new static term is added.
e64b020b	212	*/
82004223 JO	213	config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
	214	config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
	215	config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
	216	name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
	217	period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
09af2a55	218	freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
82004223	219	branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
32067712	220	time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
d457c963 KL	221	call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
d457c963 KL	222	stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
792d48b4	223	max-stack { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
374ce938 WN	224	inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
374ce938 WN	225	no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
626a6b78 WN	226	overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
626a6b78 WN	227	no-overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
82004223 JO	228	, { return ','; }
	229	"/" { BEGIN(INITIAL); return '/'; }
	230	{name_minus} { return str(yyscanner, PE_NAME); }
e571e029 WN	231	\[all\] { return PE_ARRAY_ALL; }
e571e029 WN	232	"[" { BEGIN(array); return '['; }
dd60fba7	233	@{drv_cfg_term} { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
82004223 JO	234	}
	235
	236	<mem>{
	237	{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
	238	: { return ':'; }
3741eb9f	239	"/" { return '/'; }
82004223 JO	240	{num_dec} { return value(yyscanner, 10); }
	241	{num_hex} { return value(yyscanner, 16); }
	242	/*
	243	* We need to separate 'mem:' scanner part, in order to get specific
	244	* modifier bits parsed out. Otherwise we would need to handle PE_NAME
	245	* and we'd need to parse it manually. During the escape from <mem>
	246	* state we need to put the escaping char back, so we dont miss it.
	247	*/
	248	. { unput(*yytext); BEGIN(INITIAL); }
	249	/*
	250	* We destroy the scanner after reaching EOF,
	251	* but anyway just to be sure get back to INIT state.
	252	*/
	253	<<EOF>> { BEGIN(INITIAL); }
	254	}
	255
ac20de6f ZY	256	cpu-cycles\|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
	257	stalled-cycles-frontend\|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
	258	stalled-cycles-backend\|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
	259	instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
	260	cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
	261	cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
	262	branch-instructions\|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
	263	branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
	264	bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
	265	ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
	266	cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
	267	task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
	268	page-faults\|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
	269	minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
	270	major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
	271	context-switches\|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
	272	cpu-migrations\|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
	273	alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
	274	emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
d22d1a2a	275	dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
03e0a7df	276	bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
89812fc8	277
ba32a451 KL	278	/*
	279	* We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
	280	* Because the prefix cycles is mixed up with cpu-cycles.
	281	* loads and stores are mixed up with cache event
	282	*/
	283	cycles-ct { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	284	cycles-t { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	285	mem-loads { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	286	mem-stores { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
44b1e60a	287	topdown-[a-z-]+ { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
ba32a451	288
89812fc8 JO	289	L1-dcache\|l1-d\|l1d\|L1-data \|
	290	L1-icache\|l1-i\|l1i\|L1-instruction \|
	291	LLC\|L2 \|
	292	dTLB\|d-tlb\|Data-TLB \|
	293	iTLB\|i-tlb\|Instruction-TLB \|
	294	branch\|branches\|bpu\|btb\|bpc \|
ac20de6f	295	node { return str(yyscanner, PE_NAME_CACHE_TYPE); }
89812fc8 JO	296
	297	load\|loads\|read \|
	298	store\|stores\|write \|
	299	prefetch\|prefetches \|
	300	speculative-read\|speculative-load \|
	301	refs\|Reference\|ops\|access \|
ac20de6f	302	misses\|miss { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
89812fc8	303
08d2f762	304	mem: { BEGIN(mem); return PE_PREFIX_MEM; }
ac20de6f ZY	305	r{num_raw_hex} { return raw(yyscanner); }
	306	{num_dec} { return value(yyscanner, 10); }
	307	{num_hex} { return value(yyscanner, 16); }
89812fc8	308
ac20de6f	309	{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
84c86ca1	310	{bpf_object} { return str(yyscanner, PE_BPF_OBJECT); }
d509db04	311	{bpf_source} { return str(yyscanner, PE_BPF_SOURCE); }
ba32a451	312	{name} { return pmu_str_check(yyscanner); }
ac2ba9f3	313	"/" { BEGIN(config); return '/'; }
89812fc8	314	- { return '-'; }
ac2ba9f3	315	, { BEGIN(event); return ','; }
89812fc8	316	: { return ':'; }
ac2ba9f3	317	"{" { BEGIN(event); return '{'; }
89efb029	318	"}" { return '}'; }
89812fc8	319	= { return '='; }
8c5f0a84	320	\n { }
82004223	321	. { }
08d2f762	322
89812fc8 JO	323	%%
89812fc8 JO	324
1d037ca1	325	int parse_events_wrap(void *scanner __maybe_unused)
89812fc8 JO	326	{
	327	return 1;
	328	}