]>
Commit | Line | Data |
---|---|---|
87d546d8 TG |
1 | dnl # |
2 | dnl # Default ZFS kernel configuration | |
3 | dnl # | |
4 | AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [ | |
5 | ZFS_AC_KERNEL | |
6 | ZFS_AC_SPL | |
7 | ZFS_AC_TEST_MODULE | |
8 | ZFS_AC_KERNEL_CONFIG | |
9 | ZFS_AC_KERNEL_DECLARE_EVENT_CLASS | |
10 | ZFS_AC_KERNEL_CURRENT_BIO_TAIL | |
11 | ZFS_AC_KERNEL_SUBMIT_BIO | |
12 | ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS | |
13 | ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID | |
14 | ZFS_AC_KERNEL_TYPE_FMODE_T | |
15 | ZFS_AC_KERNEL_KOBJ_NAME_LEN | |
16 | ZFS_AC_KERNEL_3ARG_BLKDEV_GET | |
17 | ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH | |
18 | ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE | |
19 | ZFS_AC_KERNEL_LOOKUP_BDEV | |
20 | ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS | |
21 | ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE | |
22 | ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE | |
23 | ZFS_AC_KERNEL_BIO_BVEC_ITER | |
24 | ZFS_AC_KERNEL_BIO_FAILFAST_DTD | |
25 | ZFS_AC_KERNEL_REQ_FAILFAST_MASK | |
26 | ZFS_AC_KERNEL_REQ_OP_DISCARD | |
27 | ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE | |
28 | ZFS_AC_KERNEL_REQ_OP_FLUSH | |
29 | ZFS_AC_KERNEL_BIO_BI_OPF | |
30 | ZFS_AC_KERNEL_BIO_END_IO_T_ARGS | |
31 | ZFS_AC_KERNEL_BIO_RW_BARRIER | |
32 | ZFS_AC_KERNEL_BIO_RW_DISCARD | |
33 | ZFS_AC_KERNEL_BLK_QUEUE_FLUSH | |
34 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS | |
35 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS | |
36 | ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG | |
37 | ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG | |
38 | ZFS_AC_KERNEL_GET_DISK_RO | |
39 | ZFS_AC_KERNEL_GET_GENDISK | |
40 | ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS | |
41 | ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL | |
42 | ZFS_AC_KERNEL_DISCARD_GRANULARITY | |
43 | ZFS_AC_KERNEL_CONST_XATTR_HANDLER | |
44 | ZFS_AC_KERNEL_XATTR_HANDLER_NAME | |
45 | ZFS_AC_KERNEL_XATTR_HANDLER_GET | |
46 | ZFS_AC_KERNEL_XATTR_HANDLER_SET | |
47 | ZFS_AC_KERNEL_XATTR_HANDLER_LIST | |
48 | ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE | |
49 | ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS | |
50 | ZFS_AC_KERNEL_POSIX_ACL_RELEASE | |
51 | ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE | |
52 | ZFS_AC_KERNEL_POSIX_ACL_CHMOD | |
53 | ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T | |
54 | ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS | |
55 | ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION | |
56 | ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA | |
57 | ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL | |
58 | ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS | |
59 | ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL | |
60 | ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL | |
3e990ae0 | 61 | ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR |
87d546d8 TG |
62 | ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE |
63 | ZFS_AC_KERNEL_SHOW_OPTIONS | |
64 | ZFS_AC_KERNEL_FILE_INODE | |
65 | ZFS_AC_KERNEL_FSYNC | |
66 | ZFS_AC_KERNEL_EVICT_INODE | |
67 | ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS | |
68 | ZFS_AC_KERNEL_NR_CACHED_OBJECTS | |
69 | ZFS_AC_KERNEL_FREE_CACHED_OBJECTS | |
70 | ZFS_AC_KERNEL_FALLOCATE | |
71 | ZFS_AC_KERNEL_AIO_FSYNC | |
72 | ZFS_AC_KERNEL_MKDIR_UMODE_T | |
73 | ZFS_AC_KERNEL_LOOKUP_NAMEIDATA | |
74 | ZFS_AC_KERNEL_CREATE_NAMEIDATA | |
75 | ZFS_AC_KERNEL_GET_LINK | |
76 | ZFS_AC_KERNEL_PUT_LINK | |
77 | ZFS_AC_KERNEL_TRUNCATE_RANGE | |
78 | ZFS_AC_KERNEL_AUTOMOUNT | |
79 | ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE | |
80 | ZFS_AC_KERNEL_COMMIT_METADATA | |
81 | ZFS_AC_KERNEL_CLEAR_INODE | |
82 | ZFS_AC_KERNEL_SETATTR_PREPARE | |
83 | ZFS_AC_KERNEL_INSERT_INODE_LOCKED | |
84 | ZFS_AC_KERNEL_D_MAKE_ROOT | |
85 | ZFS_AC_KERNEL_D_OBTAIN_ALIAS | |
86 | ZFS_AC_KERNEL_D_PRUNE_ALIASES | |
87 | ZFS_AC_KERNEL_D_SET_D_OP | |
88 | ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA | |
89 | ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS | |
90 | ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE | |
91 | ZFS_AC_KERNEL_TRUNCATE_SETSIZE | |
92 | ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY | |
93 | ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY | |
94 | ZFS_AC_KERNEL_MOUNT_NODEV | |
95 | ZFS_AC_KERNEL_SHRINK | |
96 | ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID | |
97 | ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD | |
98 | ZFS_AC_KERNEL_S_D_OP | |
99 | ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER | |
100 | ZFS_AC_KERNEL_SET_NLINK | |
101 | ZFS_AC_KERNEL_ELEVATOR_CHANGE | |
102 | ZFS_AC_KERNEL_5ARG_SGET | |
103 | ZFS_AC_KERNEL_LSEEK_EXECUTE | |
104 | ZFS_AC_KERNEL_VFS_ITERATE | |
105 | ZFS_AC_KERNEL_VFS_RW_ITERATE | |
106 | ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS | |
107 | ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS | |
108 | ZFS_AC_KERNEL_FOLLOW_DOWN_ONE | |
109 | ZFS_AC_KERNEL_MAKE_REQUEST_FN | |
110 | ZFS_AC_KERNEL_GENERIC_IO_ACCT | |
111 | ZFS_AC_KERNEL_RENAME_WANTS_FLAGS | |
112 | ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR | |
113 | ||
114 | AS_IF([test "$LINUX_OBJ" != "$LINUX"], [ | |
115 | KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ" | |
116 | ]) | |
117 | AC_SUBST(KERNELMAKE_PARAMS) | |
118 | ||
119 | ||
120 | dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other | |
121 | dnl # compiler options are added by the kernel build system. | |
122 | KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE" | |
123 | KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE" | |
124 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL" | |
125 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\"" | |
126 | ||
127 | AC_SUBST(KERNELCPPFLAGS) | |
128 | ]) | |
129 | ||
130 | dnl # | |
131 | dnl # Detect name used for Module.symvers file in kernel | |
132 | dnl # | |
133 | AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [ | |
134 | modpost=$LINUX/scripts/Makefile.modpost | |
135 | AC_MSG_CHECKING([kernel file name for module symbols]) | |
136 | AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [ | |
137 | AS_IF([grep -q Modules.symvers $modpost], [ | |
138 | LINUX_SYMBOLS=Modules.symvers | |
139 | ], [ | |
140 | LINUX_SYMBOLS=Module.symvers | |
141 | ]) | |
142 | ||
143 | AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [ | |
144 | AC_MSG_ERROR([ | |
145 | *** Please make sure the kernel devel package for your distribution | |
146 | *** is installed. If you are building with a custom kernel, make sure the | |
147 | *** kernel is configured, built, and the '--with-linux=PATH' configure | |
148 | *** option refers to the location of the kernel source.]) | |
149 | ]) | |
150 | ], [ | |
151 | LINUX_SYMBOLS=NONE | |
152 | ]) | |
153 | AC_MSG_RESULT($LINUX_SYMBOLS) | |
154 | AC_SUBST(LINUX_SYMBOLS) | |
155 | ]) | |
156 | ||
157 | dnl # | |
158 | dnl # Detect the kernel to be built against | |
159 | dnl # | |
160 | AC_DEFUN([ZFS_AC_KERNEL], [ | |
161 | AC_ARG_WITH([linux], | |
162 | AS_HELP_STRING([--with-linux=PATH], | |
163 | [Path to kernel source]), | |
164 | [kernelsrc="$withval"]) | |
165 | ||
166 | AC_ARG_WITH(linux-obj, | |
167 | AS_HELP_STRING([--with-linux-obj=PATH], | |
168 | [Path to kernel build objects]), | |
169 | [kernelbuild="$withval"]) | |
170 | ||
171 | AC_MSG_CHECKING([kernel source directory]) | |
172 | AS_IF([test -z "$kernelsrc"], [ | |
173 | AS_IF([test -e "/lib/modules/$(uname -r)/source"], [ | |
174 | headersdir="/lib/modules/$(uname -r)/source" | |
175 | sourcelink=$(readlink -f "$headersdir") | |
176 | ], [test -e "/lib/modules/$(uname -r)/build"], [ | |
177 | headersdir="/lib/modules/$(uname -r)/build" | |
178 | sourcelink=$(readlink -f "$headersdir") | |
179 | ], [ | |
180 | sourcelink=$(ls -1d /usr/src/kernels/* \ | |
181 | /usr/src/linux-* \ | |
182 | 2>/dev/null | grep -v obj | tail -1) | |
183 | ]) | |
184 | ||
185 | AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [ | |
186 | kernelsrc=`readlink -f ${sourcelink}` | |
187 | ], [ | |
188 | kernelsrc="[Not found]" | |
189 | ]) | |
190 | ], [ | |
191 | AS_IF([test "$kernelsrc" = "NONE"], [ | |
192 | kernsrcver=NONE | |
193 | ]) | |
194 | ]) | |
195 | ||
196 | AC_MSG_RESULT([$kernelsrc]) | |
197 | AS_IF([test ! -d "$kernelsrc"], [ | |
198 | AC_MSG_ERROR([ | |
199 | *** Please make sure the kernel devel package for your distribution | |
200 | *** is installed and then try again. If that fails, you can specify the | |
201 | *** location of the kernel source with the '--with-linux=PATH' option.]) | |
202 | ]) | |
203 | ||
204 | AC_MSG_CHECKING([kernel build directory]) | |
205 | AS_IF([test -z "$kernelbuild"], [ | |
206 | AS_IF([test -e "/lib/modules/$(uname -r)/build"], [ | |
207 | kernelbuild=`readlink -f /lib/modules/$(uname -r)/build` | |
208 | ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [ | |
209 | kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu} | |
210 | ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [ | |
211 | kernelbuild=${kernelsrc}-obj/${target_cpu}/default | |
212 | ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [ | |
213 | kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu} | |
214 | ], [ | |
215 | kernelbuild=${kernelsrc} | |
216 | ]) | |
217 | ]) | |
218 | AC_MSG_RESULT([$kernelbuild]) | |
219 | ||
220 | AC_MSG_CHECKING([kernel source version]) | |
221 | utsrelease1=$kernelbuild/include/linux/version.h | |
222 | utsrelease2=$kernelbuild/include/linux/utsrelease.h | |
223 | utsrelease3=$kernelbuild/include/generated/utsrelease.h | |
224 | AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [ | |
225 | utsrelease=linux/version.h | |
226 | ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [ | |
227 | utsrelease=linux/utsrelease.h | |
228 | ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [ | |
229 | utsrelease=generated/utsrelease.h | |
230 | ]) | |
231 | ||
232 | AS_IF([test "$utsrelease"], [ | |
233 | kernsrcver=`(echo "#include <$utsrelease>"; | |
234 | echo "kernsrcver=UTS_RELEASE") | | |
235 | cpp -I $kernelbuild/include | | |
236 | grep "^kernsrcver=" | cut -d \" -f 2` | |
237 | ||
238 | AS_IF([test -z "$kernsrcver"], [ | |
239 | AC_MSG_RESULT([Not found]) | |
240 | AC_MSG_ERROR([*** Cannot determine kernel version.]) | |
241 | ]) | |
242 | ], [ | |
243 | AC_MSG_RESULT([Not found]) | |
244 | if test "x$enable_linux_builtin" != xyes; then | |
245 | AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.]) | |
246 | else | |
247 | AC_MSG_ERROR([ | |
248 | *** Cannot find UTS_RELEASE definition. | |
249 | *** Please run 'make prepare' inside the kernel source tree.]) | |
250 | fi | |
251 | ]) | |
252 | ||
253 | AC_MSG_RESULT([$kernsrcver]) | |
254 | ||
255 | LINUX=${kernelsrc} | |
256 | LINUX_OBJ=${kernelbuild} | |
257 | LINUX_VERSION=${kernsrcver} | |
258 | ||
259 | AC_SUBST(LINUX) | |
260 | AC_SUBST(LINUX_OBJ) | |
261 | AC_SUBST(LINUX_VERSION) | |
262 | ||
263 | ZFS_AC_MODULE_SYMVERS | |
264 | ]) | |
265 | ||
266 | ||
267 | dnl # | |
268 | dnl # Detect the SPL module to be built against | |
269 | dnl # | |
270 | AC_DEFUN([ZFS_AC_SPL], [ | |
271 | AC_ARG_WITH([spl], | |
272 | AS_HELP_STRING([--with-spl=PATH], | |
273 | [Path to spl source]), | |
274 | [splsrc="$withval"]) | |
275 | ||
276 | AC_ARG_WITH([spl-obj], | |
277 | AS_HELP_STRING([--with-spl-obj=PATH], | |
278 | [Path to spl build objects]), | |
279 | [splbuild="$withval"]) | |
280 | ||
281 | AC_ARG_WITH([spl-timeout], | |
282 | AS_HELP_STRING([--with-spl-timeout=SECS], | |
283 | [Wait SECS for SPL header and symver file @<:@default=0@:>@]), | |
284 | [timeout="$withval"], [timeout=0]) | |
285 | ||
286 | dnl # | |
287 | dnl # The existence of spl.release.in is used to identify a valid | |
288 | dnl # source directory. In order of preference: | |
289 | dnl # | |
290 | splsrc0="/var/lib/dkms/spl/${VERSION}/build" | |
291 | splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}" | |
292 | splsrc2="/usr/local/src/spl-${VERSION}" | |
293 | splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}" | |
294 | splsrc4="/usr/src/spl-${VERSION}" | |
295 | splsrc5="../spl/" | |
296 | splsrc6="$LINUX" | |
297 | ||
298 | AC_MSG_CHECKING([spl source directory]) | |
299 | AS_IF([test -z "${splsrc}"], [ | |
300 | AS_IF([ test -e "${splsrc0}/spl.release.in"], [ | |
301 | splsrc=${splsrc0} | |
302 | ], [ test -e "${splsrc1}/spl.release.in"], [ | |
303 | splsrc=${splsrc1} | |
304 | ], [ test -e "${splsrc2}/spl.release.in"], [ | |
305 | splsrc=${splsrc2} | |
306 | ], [ test -e "${splsrc3}/spl.release.in"], [ | |
307 | splsrc=$(readlink -f "${splsrc3}") | |
308 | ], [ test -e "${splsrc4}/spl.release.in" ], [ | |
309 | splsrc=${splsrc4} | |
310 | ], [ test -e "${splsrc5}/spl.release.in"], [ | |
311 | splsrc=$(readlink -f "${splsrc5}") | |
312 | ], [ test -e "${splsrc6}/spl.release.in" ], [ | |
313 | splsrc=${splsrc6} | |
314 | ], [ | |
315 | splsrc="[Not found]" | |
316 | ]) | |
317 | ], [ | |
318 | AS_IF([test "$splsrc" = "NONE"], [ | |
319 | splbuild=NONE | |
320 | splsrcver=NONE | |
321 | ]) | |
322 | ]) | |
323 | ||
324 | AC_MSG_RESULT([$splsrc]) | |
325 | AS_IF([ test ! -e "$splsrc/spl.release.in"], [ | |
326 | AC_MSG_ERROR([ | |
327 | *** Please make sure the kmod spl devel package for your distribution | |
328 | *** is installed then try again. If that fails you can specify the | |
329 | *** location of the spl source with the '--with-spl=PATH' option.]) | |
330 | ]) | |
331 | ||
332 | dnl # | |
333 | dnl # The existence of the spl_config.h is used to identify a valid | |
334 | dnl # spl object directory. In many cases the object and source | |
335 | dnl # directory are the same, however the objects may also reside | |
336 | dnl # is a subdirectory named after the kernel version. | |
337 | dnl # | |
338 | dnl # This file is supposed to be available after DKMS finishes | |
339 | dnl # building the SPL kernel module for the target kernel. The | |
340 | dnl # '--with-spl-timeout' option can be passed to pause here, | |
341 | dnl # waiting for the file to appear from a concurrently building | |
342 | dnl # SPL package. | |
343 | dnl # | |
344 | AC_MSG_CHECKING([spl build directory]) | |
345 | while true; do | |
346 | AS_IF([test -z "$splbuild"], [ | |
347 | AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [ | |
348 | splbuild="${splsrc}/${LINUX_VERSION}" | |
349 | ], [ test -e "${splsrc}/spl_config.h" ], [ | |
350 | splbuild="${splsrc}" | |
351 | ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [ | |
352 | splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,') | |
353 | ], [ | |
354 | splbuild="[Not found]" | |
355 | ]) | |
356 | ]) | |
357 | AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [ | |
358 | break; | |
359 | ], [ | |
360 | sleep 1 | |
361 | timeout=$((timeout-1)) | |
362 | ]) | |
363 | done | |
364 | ||
365 | AC_MSG_RESULT([$splbuild]) | |
366 | AS_IF([ ! test -e "$splbuild/spl_config.h"], [ | |
367 | AC_MSG_ERROR([ | |
368 | *** Please make sure the kmod spl devel <kernel> package for your | |
369 | *** distribution is installed then try again. If that fails you | |
370 | *** can specify the location of the spl objects with the | |
371 | *** '--with-spl-obj=PATH' option.]) | |
372 | ]) | |
373 | ||
374 | AC_MSG_CHECKING([spl source version]) | |
375 | AS_IF([test -r $splbuild/spl_config.h && | |
376 | fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [ | |
377 | ||
378 | splsrcver=`(echo "#include <spl_config.h>"; | |
379 | echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") | | |
380 | cpp -I $splbuild | | |
381 | grep "^splsrcver=" | tr -d \" | cut -d= -f2` | |
382 | ]) | |
383 | ||
384 | AS_IF([test -z "$splsrcver"], [ | |
385 | AC_MSG_RESULT([Not found]) | |
386 | AC_MSG_ERROR([ | |
387 | *** Cannot determine the version of the spl source. | |
388 | *** Please prepare the spl source before running this script]) | |
389 | ]) | |
390 | ||
391 | AC_MSG_RESULT([$splsrcver]) | |
392 | ||
393 | SPL=${splsrc} | |
394 | SPL_OBJ=${splbuild} | |
395 | SPL_VERSION=${splsrcver} | |
396 | ||
397 | AC_SUBST(SPL) | |
398 | AC_SUBST(SPL_OBJ) | |
399 | AC_SUBST(SPL_VERSION) | |
400 | ||
401 | dnl # | |
402 | dnl # Detect the name used for the SPL Module.symvers file. If one | |
403 | dnl # does not exist this is likely because the SPL has been configured | |
404 | dnl # but not built. The '--with-spl-timeout' option can be passed | |
405 | dnl # to pause here, waiting for the file to appear from a concurrently | |
406 | dnl # building SPL package. If the file does not appear in time, a good | |
407 | dnl # guess is made as to what this file will be named based on what it | |
408 | dnl # is named in the kernel build products. This file will first be | |
409 | dnl # used at link time so if the guess is wrong the build will fail | |
410 | dnl # then. This unfortunately means the ZFS package does not contain a | |
411 | dnl # reliable mechanism to detect symbols exported by the SPL at | |
412 | dnl # configure time. | |
413 | dnl # | |
414 | AC_MSG_CHECKING([spl file name for module symbols]) | |
415 | SPL_SYMBOLS=NONE | |
416 | ||
417 | while true; do | |
418 | AS_IF([test -r $SPL_OBJ/Module.symvers], [ | |
419 | SPL_SYMBOLS=Module.symvers | |
420 | ], [test -r $SPL_OBJ/Modules.symvers], [ | |
421 | SPL_SYMBOLS=Modules.symvers | |
422 | ], [test -r $SPL_OBJ/module/Module.symvers], [ | |
423 | SPL_SYMBOLS=Module.symvers | |
424 | ], [test -r $SPL_OBJ/module/Modules.symvers], [ | |
425 | SPL_SYMBOLS=Modules.symvers | |
426 | ]) | |
427 | ||
428 | AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [ | |
429 | break; | |
430 | ], [ | |
431 | sleep 1 | |
432 | timeout=$((timeout-1)) | |
433 | ]) | |
434 | done | |
435 | ||
436 | AS_IF([test "$SPL_SYMBOLS" = NONE], [ | |
437 | SPL_SYMBOLS=$LINUX_SYMBOLS | |
438 | ]) | |
439 | ||
440 | AC_MSG_RESULT([$SPL_SYMBOLS]) | |
441 | AC_SUBST(SPL_SYMBOLS) | |
442 | ]) | |
443 | ||
444 | dnl # | |
445 | dnl # Basic toolchain sanity check. | |
446 | dnl # | |
447 | AC_DEFUN([ZFS_AC_TEST_MODULE], [ | |
448 | AC_MSG_CHECKING([whether modules can be built]) | |
449 | ZFS_LINUX_TRY_COMPILE([],[],[ | |
450 | AC_MSG_RESULT([yes]) | |
451 | ],[ | |
452 | AC_MSG_RESULT([no]) | |
453 | if test "x$enable_linux_builtin" != xyes; then | |
454 | AC_MSG_ERROR([*** Unable to build an empty module.]) | |
455 | else | |
456 | AC_MSG_ERROR([ | |
457 | *** Unable to build an empty module. | |
458 | *** Please run 'make scripts' inside the kernel source tree.]) | |
459 | fi | |
460 | ]) | |
461 | ]) | |
462 | ||
463 | dnl # | |
464 | dnl # Certain kernel build options are not supported. These must be | |
465 | dnl # detected at configure time and cause a build failure. Otherwise | |
466 | dnl # modules may be successfully built that behave incorrectly. | |
467 | dnl # | |
468 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [ | |
469 | AS_IF([test "x$cross_compiling" != xyes], [ | |
470 | AC_RUN_IFELSE([ | |
471 | AC_LANG_PROGRAM([ | |
472 | #include "$LINUX/include/linux/license.h" | |
473 | ], [ | |
474 | return !license_is_gpl_compatible("$ZFS_META_LICENSE"); | |
475 | ]) | |
476 | ], [ | |
477 | AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1], | |
478 | [Define to 1 if GPL-only symbols can be used]) | |
479 | ], [ | |
480 | ]) | |
481 | ]) | |
482 | ||
483 | ZFS_AC_KERNEL_CONFIG_THREAD_SIZE | |
484 | ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC | |
485 | ]) | |
486 | ||
487 | dnl # | |
488 | dnl # Check configured THREAD_SIZE | |
489 | dnl # | |
490 | dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64 | |
491 | dnl # the default thread stack size was increased to 16K from 8K. Therefore, | |
492 | dnl # on newer kernels and some architectures stack usage optimizations can be | |
493 | dnl # conditionally applied to improve performance without negatively impacting | |
494 | dnl # stability. | |
495 | dnl # | |
496 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [ | |
497 | AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks]) | |
498 | ZFS_LINUX_TRY_COMPILE([ | |
499 | #include <linux/module.h> | |
500 | ],[ | |
501 | #if (THREAD_SIZE < 16384) | |
502 | #error "THREAD_SIZE is less than 16K" | |
503 | #endif | |
504 | ],[ | |
505 | AC_MSG_RESULT([yes]) | |
506 | AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks]) | |
507 | ],[ | |
508 | AC_MSG_RESULT([no]) | |
509 | ]) | |
510 | ]) | |
511 | ||
512 | dnl # | |
513 | dnl # Check CONFIG_DEBUG_LOCK_ALLOC | |
514 | dnl # | |
515 | dnl # This is typically only set for debug kernels because it comes with | |
516 | dnl # a performance penalty. However, when it is set it maps the non-GPL | |
517 | dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol. | |
518 | dnl # This will cause a failure at link time which we'd rather know about | |
519 | dnl # at compile time. | |
520 | dnl # | |
521 | dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol | |
522 | dnl # with the upstream community we add a check to detect this case. | |
523 | dnl # | |
524 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [ | |
525 | ||
526 | ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [ | |
527 | AC_MSG_CHECKING([whether mutex_lock() is GPL-only]) | |
528 | tmp_flags="$EXTRA_KCFLAGS" | |
529 | ZFS_LINUX_TRY_COMPILE([ | |
530 | #include <linux/module.h> | |
531 | #include <linux/mutex.h> | |
532 | ||
533 | MODULE_LICENSE("$ZFS_META_LICENSE"); | |
534 | ],[ | |
535 | struct mutex lock; | |
536 | ||
537 | mutex_init(&lock); | |
538 | mutex_lock(&lock); | |
539 | mutex_unlock(&lock); | |
540 | ],[ | |
541 | AC_MSG_RESULT(no) | |
542 | ],[ | |
543 | AC_MSG_RESULT(yes) | |
544 | AC_MSG_ERROR([ | |
545 | *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible | |
546 | *** with the CDDL license and will prevent the module linking stage | |
547 | *** from succeeding. You must rebuild your kernel without this | |
548 | *** option enabled.]) | |
549 | ]) | |
550 | EXTRA_KCFLAGS="$tmp_flags" | |
551 | ], []) | |
552 | ]) | |
553 | ||
554 | dnl # | |
555 | dnl # ZFS_LINUX_CONFTEST_H | |
556 | dnl # | |
557 | AC_DEFUN([ZFS_LINUX_CONFTEST_H], [ | |
558 | cat - <<_ACEOF >conftest.h | |
559 | $1 | |
560 | _ACEOF | |
561 | ]) | |
562 | ||
563 | dnl # | |
564 | dnl # ZFS_LINUX_CONFTEST_C | |
565 | dnl # | |
566 | AC_DEFUN([ZFS_LINUX_CONFTEST_C], [ | |
567 | cat confdefs.h - <<_ACEOF >conftest.c | |
568 | $1 | |
569 | _ACEOF | |
570 | ]) | |
571 | ||
572 | dnl # | |
573 | dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY]) | |
574 | dnl # | |
575 | m4_define([ZFS_LANG_PROGRAM], [ | |
576 | $1 | |
577 | int | |
578 | main (void) | |
579 | { | |
580 | dnl Do *not* indent the following line: there may be CPP directives. | |
581 | dnl Don't move the `;' right after for the same reason. | |
582 | $2 | |
583 | ; | |
584 | return 0; | |
585 | } | |
586 | ]) | |
587 | ||
588 | dnl # | |
589 | dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE | |
590 | dnl # | |
591 | AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [ | |
592 | m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])]) | |
593 | m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])]) | |
594 | rm -Rf build && mkdir -p build && touch build/conftest.mod.c | |
595 | echo "obj-m := conftest.o" >build/Makefile | |
596 | modpost_flag='' | |
597 | test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage | |
598 | AS_IF( | |
599 | [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])], | |
600 | [$4], | |
601 | [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])] | |
602 | ) | |
603 | rm -Rf build | |
604 | ]) | |
605 | ||
606 | dnl # | |
607 | dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE | |
608 | dnl # | |
609 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE], | |
610 | [ZFS_LINUX_COMPILE_IFELSE( | |
611 | [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])], | |
612 | [modules], | |
613 | [test -s build/conftest.o], | |
614 | [$3], [$4]) | |
615 | ]) | |
616 | ||
617 | dnl # | |
618 | dnl # ZFS_LINUX_CONFIG | |
619 | dnl # | |
620 | AC_DEFUN([ZFS_LINUX_CONFIG], | |
621 | [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1]) | |
622 | ZFS_LINUX_TRY_COMPILE([ | |
623 | #include <linux/module.h> | |
624 | ],[ | |
625 | #ifndef CONFIG_$1 | |
626 | #error CONFIG_$1 not #defined | |
627 | #endif | |
628 | ],[ | |
629 | AC_MSG_RESULT([yes]) | |
630 | $2 | |
631 | ],[ | |
632 | AC_MSG_RESULT([no]) | |
633 | $3 | |
634 | ]) | |
635 | ]) | |
636 | ||
637 | dnl # | |
638 | dnl # ZFS_CHECK_SYMBOL_EXPORT | |
639 | dnl # check symbol exported or not | |
640 | dnl # | |
641 | AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [ | |
642 | grep -q -E '[[[:space:]]]$1[[[:space:]]]' \ | |
643 | $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null | |
644 | rc=$? | |
645 | if test $rc -ne 0; then | |
646 | export=0 | |
647 | for file in $2; do | |
648 | grep -q -E "EXPORT_SYMBOL.*($1)" \ | |
649 | "$LINUX/$file" 2>/dev/null | |
650 | rc=$? | |
651 | if test $rc -eq 0; then | |
652 | export=1 | |
653 | break; | |
654 | fi | |
655 | done | |
656 | if test $export -eq 0; then : | |
657 | $4 | |
658 | else : | |
659 | $3 | |
660 | fi | |
661 | else : | |
662 | $3 | |
663 | fi | |
664 | ]) | |
665 | ||
666 | dnl # | |
667 | dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL | |
668 | dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT | |
669 | dnl # is called if not compiling for builtin | |
670 | dnl # | |
671 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [ | |
672 | ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1]) | |
673 | if test $rc -ne 0; then : | |
674 | $6 | |
675 | else | |
676 | if test "x$enable_linux_builtin" != xyes; then | |
677 | ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1]) | |
678 | fi | |
679 | if test $rc -ne 0; then : | |
680 | $6 | |
681 | else : | |
682 | $5 | |
683 | fi | |
684 | fi | |
685 | ]) | |
686 | ||
687 | dnl # | |
688 | dnl # ZFS_LINUX_TRY_COMPILE_HEADER | |
689 | dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are | |
690 | dnl # provided via the fifth parameter | |
691 | dnl # | |
692 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], | |
693 | [ZFS_LINUX_COMPILE_IFELSE( | |
694 | [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])], | |
695 | [modules], | |
696 | [test -s build/conftest.o], | |
697 | [$3], [$4], [$5]) | |
698 | ]) |