]>
Commit | Line | Data |
---|---|---|
1 | # -*- autoconf -*- | |
2 | ||
3 | # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc. | |
4 | # | |
5 | # Licensed under the Apache License, Version 2.0 (the "License"); | |
6 | # you may not use this file except in compliance with the License. | |
7 | # You may obtain a copy of the License at: | |
8 | # | |
9 | # http://www.apache.org/licenses/LICENSE-2.0 | |
10 | # | |
11 | # Unless required by applicable law or agreed to in writing, software | |
12 | # distributed under the License is distributed on an "AS IS" BASIS, | |
13 | # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. | |
14 | # See the License for the specific language governing permissions and | |
15 | # limitations under the License. | |
16 | ||
17 | dnl OVS_ENABLE_WERROR | |
18 | AC_DEFUN([OVS_ENABLE_WERROR], | |
19 | [AC_ARG_ENABLE( | |
20 | [Werror], | |
21 | [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])], | |
22 | [], [enable_Werror=no]) | |
23 | AC_CONFIG_COMMANDS_PRE( | |
24 | [if test "X$enable_Werror" = Xyes; then | |
25 | OVS_CFLAGS="$OVS_CFLAGS -Werror" | |
26 | fi])]) | |
27 | ||
28 | dnl OVS_CHECK_LINUX | |
29 | dnl | |
30 | dnl Configure linux kernel source tree | |
31 | AC_DEFUN([OVS_CHECK_LINUX], [ | |
32 | AC_ARG_WITH([linux], | |
33 | [AC_HELP_STRING([--with-linux=/path/to/linux], | |
34 | [Specify the Linux kernel build directory])]) | |
35 | AC_ARG_WITH([linux-source], | |
36 | [AC_HELP_STRING([--with-linux-source=/path/to/linux-source], | |
37 | [Specify the Linux kernel source directory | |
38 | (usually figured out automatically from build | |
39 | directory)])]) | |
40 | ||
41 | # Deprecated equivalents to --with-linux, --with-linux-source. | |
42 | AC_ARG_WITH([l26]) | |
43 | AC_ARG_WITH([l26-source]) | |
44 | ||
45 | if test X"$with_linux" != X; then | |
46 | KBUILD=$with_linux | |
47 | elif test X"$with_l26" != X; then | |
48 | KBUILD=$with_l26 | |
49 | AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead]) | |
50 | else | |
51 | KBUILD= | |
52 | fi | |
53 | ||
54 | if test X"$KBUILD" != X; then | |
55 | if test X"$with_linux_source" != X; then | |
56 | KSRC=$with_linux_source | |
57 | elif test X"$with_l26_source" != X; then | |
58 | KSRC=$with_l26_source | |
59 | AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead]) | |
60 | else | |
61 | KSRC= | |
62 | fi | |
63 | elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then | |
64 | AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory]) | |
65 | fi | |
66 | ||
67 | if test -n "$KBUILD"; then | |
68 | KBUILD=`eval echo "$KBUILD"` | |
69 | case $KBUILD in | |
70 | /*) ;; | |
71 | *) KBUILD=`pwd`/$KBUILD ;; | |
72 | esac | |
73 | ||
74 | # The build directory is what the user provided. | |
75 | # Make sure that it exists. | |
76 | AC_MSG_CHECKING([for Linux build directory]) | |
77 | if test -d "$KBUILD"; then | |
78 | AC_MSG_RESULT([$KBUILD]) | |
79 | AC_SUBST(KBUILD) | |
80 | else | |
81 | AC_MSG_RESULT([no]) | |
82 | AC_ERROR([source dir $KBUILD doesn't exist]) | |
83 | fi | |
84 | ||
85 | # Debian breaks kernel headers into "source" header and "build" headers. | |
86 | # We want the source headers, but $KBUILD gives us the "build" headers. | |
87 | # Use heuristics to find the source headers. | |
88 | AC_MSG_CHECKING([for Linux source directory]) | |
89 | if test -n "$KSRC"; then | |
90 | KSRC=`eval echo "$KSRC"` | |
91 | case $KSRC in | |
92 | /*) ;; | |
93 | *) KSRC=`pwd`/$KSRC ;; | |
94 | esac | |
95 | if test ! -e $KSRC/include/linux/kernel.h; then | |
96 | AC_MSG_ERROR([$KSRC is not a kernel source directory]) | |
97 | fi | |
98 | else | |
99 | KSRC=$KBUILD | |
100 | if test ! -e $KSRC/include/linux/kernel.h; then | |
101 | # Debian kernel build Makefiles tend to include a line of the form: | |
102 | # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486 | |
103 | # First try to extract the source directory from this line. | |
104 | KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile` | |
105 | if test ! -e "$KSRC"/include/linux/kernel.h; then | |
106 | # Didn't work. Fall back to name-based heuristics that used to work. | |
107 | case `echo "$KBUILD" | sed 's,/*$,,'` in # ( | |
108 | */build) | |
109 | KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'` | |
110 | ;; # ( | |
111 | *) | |
112 | KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'` | |
113 | ;; | |
114 | esac | |
115 | fi | |
116 | fi | |
117 | if test ! -e "$KSRC"/include/linux/kernel.h; then | |
118 | AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)]) | |
119 | fi | |
120 | fi | |
121 | AC_MSG_RESULT([$KSRC]) | |
122 | ||
123 | AC_MSG_CHECKING([for kernel version]) | |
124 | version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"` | |
125 | patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"` | |
126 | sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"` | |
127 | if test X"$version" = X || test X"$patchlevel" = X; then | |
128 | AC_ERROR([cannot determine kernel version]) | |
129 | elif test X"$sublevel" = X; then | |
130 | kversion=$version.$patchlevel | |
131 | else | |
132 | kversion=$version.$patchlevel.$sublevel | |
133 | fi | |
134 | AC_MSG_RESULT([$kversion]) | |
135 | ||
136 | if test "$version" -ge 4; then | |
137 | if test "$version" = 4 && test "$patchlevel" -le 11; then | |
138 | : # Linux 4.x | |
139 | else | |
140 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.11.x is not supported (please refer to the FAQ for advice)]) | |
141 | fi | |
142 | elif test "$version" = 3 && test "$patchlevel" -ge 10; then | |
143 | : # Linux 3.x | |
144 | else | |
145 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required]) | |
146 | fi | |
147 | if (test ! -e "$KBUILD"/include/linux/version.h && \ | |
148 | test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \ | |
149 | (test ! -e "$KBUILD"/include/linux/autoconf.h && \ | |
150 | test ! -e "$KBUILD"/include/generated/autoconf.h); then | |
151 | AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured]) | |
152 | fi | |
153 | OVS_CHECK_LINUX_COMPAT | |
154 | fi | |
155 | AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD") | |
156 | ]) | |
157 | ||
158 | dnl OVS_CHECK_LINUX_TC | |
159 | dnl | |
160 | dnl Configure Linux tc compat. | |
161 | AC_DEFUN([OVS_CHECK_LINUX_TC], [ | |
162 | AC_COMPILE_IFELSE([ | |
163 | AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [ | |
164 | int x = TCA_ACT_COOKIE; | |
165 | ])], | |
166 | [AC_DEFINE([HAVE_TCA_ACT_COOKIE], [1], | |
167 | [Define to 1 if TCA_ACT_COOKIE is avaiable.])]) | |
168 | ||
169 | AC_COMPILE_IFELSE([ | |
170 | AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [ | |
171 | int x = TCA_VLAN_PUSH_VLAN_PRIORITY; | |
172 | ])], | |
173 | [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1], | |
174 | [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])]) | |
175 | ||
176 | AC_COMPILE_IFELSE([ | |
177 | AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [ | |
178 | int x = TCA_TUNNEL_KEY_ENC_DST_PORT; | |
179 | ])], | |
180 | [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1], | |
181 | [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])]) | |
182 | ]) | |
183 | ||
184 | dnl OVS_CHECK_DPDK | |
185 | dnl | |
186 | dnl Configure DPDK source tree | |
187 | AC_DEFUN([OVS_CHECK_DPDK], [ | |
188 | AC_ARG_WITH([dpdk], | |
189 | [AC_HELP_STRING([--with-dpdk=/path/to/dpdk], | |
190 | [Specify the DPDK build directory])], | |
191 | [have_dpdk=true]) | |
192 | ||
193 | AC_MSG_CHECKING([whether dpdk datapath is enabled]) | |
194 | if test "$have_dpdk" != true || test "$with_dpdk" = no; then | |
195 | AC_MSG_RESULT([no]) | |
196 | DPDKLIB_FOUND=false | |
197 | else | |
198 | AC_MSG_RESULT([yes]) | |
199 | case "$with_dpdk" in | |
200 | yes) | |
201 | DPDK_AUTO_DISCOVER="true" | |
202 | DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk" | |
203 | ;; | |
204 | *) | |
205 | DPDK_AUTO_DISCOVER="false" | |
206 | DPDK_INCLUDE="$with_dpdk/include" | |
207 | # If 'with_dpdk' is passed install directory, point to headers | |
208 | # installed in $DESTDIR/$prefix/include/dpdk | |
209 | AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [], | |
210 | [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h], | |
211 | [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])]) | |
212 | DPDK_LIB_DIR="$with_dpdk/lib" | |
213 | ;; | |
214 | esac | |
215 | ||
216 | DPDK_LIB="-ldpdk" | |
217 | DPDK_EXTRA_LIB="" | |
218 | ||
219 | ovs_save_CFLAGS="$CFLAGS" | |
220 | ovs_save_LDFLAGS="$LDFLAGS" | |
221 | CFLAGS="$CFLAGS -I$DPDK_INCLUDE" | |
222 | if test "$DPDK_AUTO_DISCOVER" = "false"; then | |
223 | LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}" | |
224 | fi | |
225 | ||
226 | AC_COMPILE_IFELSE([ | |
227 | AC_LANG_PROGRAM( | |
228 | [ | |
229 | #include <rte_config.h> | |
230 | #if RTE_LIBRTE_VHOST_NUMA | |
231 | #error | |
232 | #endif | |
233 | ], []) | |
234 | ], [], | |
235 | [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])]) | |
236 | DPDK_EXTRA_LIB="-lnuma" | |
237 | AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])]) | |
238 | ||
239 | AC_COMPILE_IFELSE([ | |
240 | AC_LANG_PROGRAM( | |
241 | [ | |
242 | #include <rte_config.h> | |
243 | #if RTE_LIBRTE_PMD_PCAP | |
244 | #error | |
245 | #endif | |
246 | ], []) | |
247 | ], [], | |
248 | [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])]) | |
249 | DPDK_EXTRA_LIB="-lpcap" | |
250 | AC_COMPILE_IFELSE([ | |
251 | AC_LANG_PROGRAM( | |
252 | [ | |
253 | #include <rte_config.h> | |
254 | #if RTE_LIBRTE_PDUMP | |
255 | #error | |
256 | #endif | |
257 | ], []) | |
258 | ], [], | |
259 | [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])]) | |
260 | ]) | |
261 | ||
262 | # On some systems we have to add -ldl to link with dpdk | |
263 | # | |
264 | # This code, at first, tries to link without -ldl (""), | |
265 | # then adds it and tries again. | |
266 | # Before each attempt the search cache must be unset, | |
267 | # otherwise autoconf will stick with the old result | |
268 | ||
269 | DPDKLIB_FOUND=false | |
270 | save_LIBS=$LIBS | |
271 | for extras in "" "-ldl"; do | |
272 | LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB" | |
273 | AC_LINK_IFELSE( | |
274 | [AC_LANG_PROGRAM([#include <rte_config.h> | |
275 | #include <rte_eal.h>], | |
276 | [int rte_argc; char ** rte_argv; | |
277 | rte_eal_init(rte_argc, rte_argv);])], | |
278 | [DPDKLIB_FOUND=true]) | |
279 | if $DPDKLIB_FOUND; then | |
280 | break | |
281 | fi | |
282 | done | |
283 | ||
284 | # If linking unsuccessful | |
285 | if test "$DPDKLIB_FOUND" = "false" ; then | |
286 | if $DPDK_AUTO_DISCOVER; then | |
287 | AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location]) | |
288 | else | |
289 | AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR]) | |
290 | fi | |
291 | fi | |
292 | CFLAGS="$ovs_save_CFLAGS" | |
293 | LDFLAGS="$ovs_save_LDFLAGS" | |
294 | if test "$DPDK_AUTO_DISCOVER" = "false"; then | |
295 | OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR" | |
296 | fi | |
297 | OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE" | |
298 | OVS_ENABLE_OPTION([-mssse3]) | |
299 | ||
300 | # DPDK pmd drivers are not linked unless --whole-archive is used. | |
301 | # | |
302 | # This happens because the rest of the DPDK code doesn't use any symbol in | |
303 | # the pmd driver objects, and the drivers register themselves using an | |
304 | # __attribute__((constructor)) function. | |
305 | # | |
306 | # These options are specified inside a single -Wl directive to prevent | |
307 | # autotools from reordering them. | |
308 | DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive | |
309 | AC_SUBST([DPDK_vswitchd_LDFLAGS]) | |
310 | AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.]) | |
311 | fi | |
312 | ||
313 | AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true) | |
314 | ]) | |
315 | ||
316 | dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH]) | |
317 | dnl | |
318 | dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH. | |
319 | dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with | |
320 | dnl <REGEX> translated to uppercase. | |
321 | AC_DEFUN([OVS_GREP_IFELSE], [ | |
322 | AC_MSG_CHECKING([whether $2 matches in $1]) | |
323 | if test -f $1; then | |
324 | grep '$2' $1 >/dev/null 2>&1 | |
325 | status=$? | |
326 | case $status in | |
327 | 0) | |
328 | AC_MSG_RESULT([yes]) | |
329 | m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3]) | |
330 | ;; | |
331 | 1) | |
332 | AC_MSG_RESULT([no]) | |
333 | $4 | |
334 | ;; | |
335 | *) | |
336 | AC_MSG_ERROR([grep exited with status $status]) | |
337 | ;; | |
338 | esac | |
339 | else | |
340 | AC_MSG_RESULT([file not found]) | |
341 | $4 | |
342 | fi | |
343 | ]) | |
344 | ||
345 | dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH]) | |
346 | dnl | |
347 | dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the | |
348 | dnl structure definition. If this is successful, runs IF-MATCH, otherwise | |
349 | dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to | |
350 | dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX> | |
351 | dnl translated to uppercase. | |
352 | AC_DEFUN([OVS_FIND_FIELD_IFELSE], [ | |
353 | AC_MSG_CHECKING([whether $2 has member $3 in $1]) | |
354 | if test -f $1; then | |
355 | awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null | |
356 | status=$? | |
357 | case $status in | |
358 | 0) | |
359 | AC_MSG_RESULT([yes]) | |
360 | m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4]) | |
361 | ;; | |
362 | 1) | |
363 | AC_MSG_RESULT([no]) | |
364 | $5 | |
365 | ;; | |
366 | *) | |
367 | AC_MSG_ERROR([grep exited with status $status]) | |
368 | ;; | |
369 | esac | |
370 | else | |
371 | AC_MSG_RESULT([file not found]) | |
372 | $5 | |
373 | fi | |
374 | ]) | |
375 | ||
376 | dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH]) | |
377 | dnl | |
378 | dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within | |
379 | dnl the function signature starting from the line matching FUNCTION | |
380 | dnl and ending with the line containing the closing parenthesis. If | |
381 | dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH. If | |
382 | dnl IF-MATCH is empty then it defines to | |
383 | dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and | |
384 | dnl <REGEX> translated to uppercase. | |
385 | AC_DEFUN([OVS_FIND_PARAM_IFELSE], [ | |
386 | AC_MSG_CHECKING([whether $2 has parameter $3 in $1]) | |
387 | if test -f $1; then | |
388 | awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null | |
389 | status=$? | |
390 | case $status in | |
391 | 0) | |
392 | AC_MSG_RESULT([yes]) | |
393 | m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4]) | |
394 | ;; | |
395 | 1) | |
396 | AC_MSG_RESULT([no]) | |
397 | $5 | |
398 | ;; | |
399 | *) | |
400 | AC_MSG_ERROR([grep exited with status $status]) | |
401 | ;; | |
402 | esac | |
403 | else | |
404 | AC_MSG_RESULT([file not found]) | |
405 | $5 | |
406 | fi | |
407 | ]) | |
408 | ||
409 | dnl OVS_DEFINE(NAME) | |
410 | dnl | |
411 | dnl Defines NAME to 1 in kcompat.h. | |
412 | AC_DEFUN([OVS_DEFINE], [ | |
413 | echo '#define $1 1' >> datapath/linux/kcompat.h.new | |
414 | ]) | |
415 | ||
416 | dnl OVS_CHECK_LINUX_COMPAT | |
417 | dnl | |
418 | dnl Runs various Autoconf checks on the Linux kernel source in | |
419 | dnl the directory in $KBUILD. | |
420 | AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [ | |
421 | rm -f datapath/linux/kcompat.h.new | |
422 | mkdir -p datapath/linux | |
423 | : > datapath/linux/kcompat.h.new | |
424 | ||
425 | echo '#include <linux/version.h> | |
426 | #ifndef RHEL_RELEASE_CODE | |
427 | #define RHEL_RELEASE_CODE 0 | |
428 | #define RHEL_RELEASE_VERSION(a, b) 0 | |
429 | #endif' >> datapath/linux/kcompat.h.new | |
430 | ||
431 | OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,], | |
432 | [OVS_DEFINE([HAVE_CSUM_COPY_DBG])]) | |
433 | ||
434 | OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net], | |
435 | [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])]) | |
436 | OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub]) | |
437 | ||
438 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST]) | |
439 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL]) | |
440 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO]) | |
441 | ||
442 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random]) | |
443 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy]) | |
444 | ||
445 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS]) | |
446 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64]) | |
447 | OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64]) | |
448 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto]) | |
449 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside]) | |
450 | ||
451 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast]) | |
452 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset]) | |
453 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry], | |
454 | [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])]) | |
455 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net], | |
456 | [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])]) | |
457 | ||
458 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net], | |
459 | [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])]) | |
460 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net], | |
461 | [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])]) | |
462 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h], | |
463 | [ip_do_fragment], [net], | |
464 | [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])]) | |
465 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h], | |
466 | [ip_local_out], [net], | |
467 | [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])]) | |
468 | ||
469 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu]) | |
470 | ||
471 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU], | |
472 | [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])]) | |
473 | OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu]) | |
474 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const], | |
475 | [OVS_DEFINE([HAVE_INET_FRAGS_CONST])]) | |
476 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in], | |
477 | [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])]) | |
478 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting]) | |
479 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor]) | |
480 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags], | |
481 | [frags_work]) | |
482 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags], | |
483 | [rwlock]) | |
484 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue], | |
485 | [list_evictor]) | |
486 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move]) | |
487 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h], | |
488 | [sub_frag_mem_limit], [struct.netns_frags], | |
489 | [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])]) | |
490 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init], | |
491 | [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])]) | |
492 | OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif], | |
493 | [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])]) | |
494 | ||
495 | dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure. | |
496 | dnl OVS does not really need ipv6 label field, but its presence signifies that | |
497 | dnl the stack has all required ipv6 support. | |
498 | dnl OVS also does not need dst_cache But this dependency allows us to write | |
499 | dnl much cleaner code. | |
500 | ||
501 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key], | |
502 | [label], | |
503 | [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], | |
504 | [iptunnel_pull_offloads], | |
505 | [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache], | |
506 | [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])]) | |
507 | ||
508 | OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr], | |
509 | [OVS_DEFINE([MPLS_HEADER_IS_L3])]) | |
510 | OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net], | |
511 | [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])]) | |
512 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst]) | |
513 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro]) | |
514 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats]) | |
515 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu]) | |
516 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level]) | |
517 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment]) | |
518 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol]) | |
519 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink]) | |
520 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check], | |
521 | [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])]) | |
522 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port]) | |
523 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port]) | |
524 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t]) | |
525 | dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats. | |
526 | dnl So check type of tstats. | |
527 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats], | |
528 | [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])]) | |
529 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device], | |
530 | [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])]) | |
531 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload]) | |
532 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff], | |
533 | [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])]) | |
534 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum]) | |
535 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM]) | |
536 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops], | |
537 | [extended]) | |
538 | OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h], | |
539 | [netdev_master_upper_dev_link], [upper_priv], | |
540 | [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])]) | |
541 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device], | |
542 | [max_mtu]) | |
543 | ||
544 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state]) | |
545 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook]) | |
546 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops], | |
547 | [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])]) | |
548 | OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv], | |
549 | [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])]) | |
550 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops], | |
551 | [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])]) | |
552 | ||
553 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops], | |
554 | [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])]) | |
555 | ||
556 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
557 | [nf_conn], [struct timer_list[[ \t]]*timeout], | |
558 | [OVS_DEFINE([HAVE_NF_CONN_TIMER])]) | |
559 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
560 | [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])]) | |
561 | ||
562 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
563 | [nf_ct_tmpl_alloc], [nf_conntrack_zone], | |
564 | [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])]) | |
565 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
566 | [nf_ct_get_tuplepr], [struct.net], | |
567 | [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])]) | |
568 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
569 | [nf_ct_set]) | |
570 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], | |
571 | [nf_ct_is_untracked]) | |
572 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h], | |
573 | [nf_ct_zone_init]) | |
574 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], | |
575 | [nf_connlabels_get]) | |
576 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], | |
577 | [nf_connlabels_get], [int bit], | |
578 | [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])]) | |
579 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], | |
580 | [nf_conn_labels], [words]) | |
581 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add]) | |
582 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding]) | |
583 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust]) | |
584 | ||
585 | OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32]) | |
586 | OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max]) | |
587 | ||
588 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net]) | |
589 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type]) | |
590 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net], | |
591 | [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])]) | |
592 | OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t]) | |
593 | ||
594 | OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [], | |
595 | [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], | |
596 | [rcu_read_lock_held])]) | |
597 | OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held]) | |
598 | ||
599 | # Check for the proto_data_valid member in struct sk_buff. The [^@] | |
600 | # is necessary because some versions of this header remove the | |
601 | # member but retain the kerneldoc comment that describes it (which | |
602 | # starts with @). The brackets must be doubled because of m4 | |
603 | # quoting rules. | |
604 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid], | |
605 | [OVS_DEFINE([HAVE_PROTO_DATA_VALID])]) | |
606 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset]) | |
607 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol]) | |
608 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type]) | |
609 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset]) | |
610 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list]) | |
611 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash]) | |
612 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash], | |
613 | [OVS_DEFINE([HAVE_U16_RXHASH])]) | |
614 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(], | |
615 | [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])]) | |
616 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], | |
617 | [skb_copy_from_linear_data_offset]) | |
618 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], | |
619 | [skb_reset_tail_pointer]) | |
620 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head]) | |
621 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro], | |
622 | [OVS_DEFINE([HAVE_SKB_WARN_LRO])]) | |
623 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb]) | |
624 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page]) | |
625 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list]) | |
626 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc]) | |
627 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len]) | |
628 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone]) | |
629 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags]) | |
630 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(], | |
631 | [OVS_DEFINE([HAVE_SKB_GET_HASH])]) | |
632 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash]) | |
633 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(], | |
634 | [OVS_DEFINE([HAVE_SKB_ZEROCOPY])]) | |
635 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash], | |
636 | [OVS_DEFINE([HAVE_L4_RXHASH])]) | |
637 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable]) | |
638 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop]) | |
639 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop]) | |
640 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push]) | |
641 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4]) | |
642 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum]) | |
643 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum]) | |
644 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct]) | |
645 | ||
646 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool], | |
647 | [OVS_DEFINE([HAVE_BOOL_TYPE])]) | |
648 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum], | |
649 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) | |
650 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum], | |
651 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) | |
652 | ||
653 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4]) | |
654 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold]) | |
655 | ||
656 | OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk]) | |
657 | OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy]) | |
658 | ||
659 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners]) | |
660 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset]) | |
661 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops]) | |
662 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock], | |
663 | [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])]) | |
664 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse]) | |
665 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family], | |
666 | [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])]) | |
667 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h], | |
668 | [genl_notify], [net], | |
669 | [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])]) | |
670 | ||
671 | ||
672 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], | |
673 | [genl_multicast_group], [id]) | |
674 | OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr]) | |
675 | ||
676 | OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register]) | |
677 | OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads]) | |
678 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH]) | |
679 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk]) | |
680 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash]) | |
681 | OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst], | |
682 | [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])]) | |
683 | OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock], | |
684 | [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])]) | |
685 | ||
686 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit]) | |
687 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16]) | |
688 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16]) | |
689 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32]) | |
690 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64]) | |
691 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr]) | |
692 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested]) | |
693 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last]) | |
694 | OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err], | |
695 | [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])]) | |
696 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h], | |
697 | [nla_parse], [netlink_ext_ack], | |
698 | [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])]) | |
699 | ||
700 | OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum]) | |
701 | ||
702 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD], | |
703 | [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])]) | |
704 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto]) | |
705 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag]) | |
706 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol]) | |
707 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged]) | |
708 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan]) | |
709 | ||
710 | OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq]) | |
711 | ||
712 | OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata], | |
713 | [OVS_DEFINE([HAVE_VXLAN_METADATA])]) | |
714 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port], | |
715 | [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net], | |
716 | [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])]) | |
717 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check]) | |
718 | OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete]) | |
719 | OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads], | |
720 | [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])]) | |
721 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg], | |
722 | [gro_receive]) | |
723 | ||
724 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df], | |
725 | [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])]) | |
726 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN], | |
727 | [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])]) | |
728 | ||
729 | OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx]) | |
730 | OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx]) | |
731 | OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6], | |
732 | [OVS_DEFINE([HAVE_RHEL6_PER_CPU])]) | |
733 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h], | |
734 | [udp_add_offload], [net], | |
735 | [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])]) | |
736 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h], | |
737 | [nf_defrag_ipv6_enable], [net], | |
738 | [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])]) | |
739 | ||
740 | if cmp -s datapath/linux/kcompat.h.new \ | |
741 | datapath/linux/kcompat.h >/dev/null 2>&1; then | |
742 | rm datapath/linux/kcompat.h.new | |
743 | else | |
744 | mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h | |
745 | fi | |
746 | ]) | |
747 | ||
748 | dnl Checks for net/if_packet.h. | |
749 | AC_DEFUN([OVS_CHECK_IF_PACKET], | |
750 | [AC_CHECK_HEADER([net/if_packet.h], | |
751 | [HAVE_IF_PACKET=yes], | |
752 | [HAVE_IF_PACKET=no]) | |
753 | AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes]) | |
754 | if test "$HAVE_IF_PACKET" = yes; then | |
755 | AC_DEFINE([HAVE_IF_PACKET], [1], | |
756 | [Define to 1 if net/if_packet.h is available.]) | |
757 | fi]) | |
758 | ||
759 | dnl Checks for net/if_dl.h. | |
760 | dnl | |
761 | dnl (We use this as a proxy for checking whether we're building on FreeBSD | |
762 | dnl or NetBSD.) | |
763 | AC_DEFUN([OVS_CHECK_IF_DL], | |
764 | [AC_CHECK_HEADER([net/if_dl.h], | |
765 | [HAVE_IF_DL=yes], | |
766 | [HAVE_IF_DL=no]) | |
767 | AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes]) | |
768 | if test "$HAVE_IF_DL" = yes; then | |
769 | AC_DEFINE([HAVE_IF_DL], [1], | |
770 | [Define to 1 if net/if_dl.h is available.]) | |
771 | ||
772 | # On these platforms we use libpcap to access network devices. | |
773 | AC_SEARCH_LIBS([pcap_open_live], [pcap]) | |
774 | fi]) | |
775 | ||
776 | dnl Checks for buggy strtok_r. | |
777 | dnl | |
778 | dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling | |
779 | dnl with optimization that can cause segfaults: | |
780 | dnl | |
781 | dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614. | |
782 | AC_DEFUN([OVS_CHECK_STRTOK_R], | |
783 | [AC_CACHE_CHECK( | |
784 | [whether strtok_r macro segfaults on some inputs], | |
785 | [ovs_cv_strtok_r_bug], | |
786 | [AC_RUN_IFELSE( | |
787 | [AC_LANG_PROGRAM([#include <stdio.h> | |
788 | #include <string.h> | |
789 | ], | |
790 | [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8 | |
791 | /* Assume bug is present, because relatively minor | |
792 | changes in compiler settings (e.g. optimization | |
793 | level) can make it crop up. */ | |
794 | return 1; | |
795 | #else | |
796 | char string[] = ":::"; | |
797 | char *save_ptr = (char *) 0xc0ffee; | |
798 | char *token1, *token2; | |
799 | token1 = strtok_r(string, ":", &save_ptr); | |
800 | token2 = strtok_r(NULL, ":", &save_ptr); | |
801 | freopen ("/dev/null", "w", stdout); | |
802 | printf ("%s %s\n", token1, token2); | |
803 | return 0; | |
804 | #endif | |
805 | ]])], | |
806 | [ovs_cv_strtok_r_bug=no], | |
807 | [ovs_cv_strtok_r_bug=yes], | |
808 | [ovs_cv_strtok_r_bug=yes])]) | |
809 | if test $ovs_cv_strtok_r_bug = yes; then | |
810 | AC_DEFINE([HAVE_STRTOK_R_BUG], [1], | |
811 | [Define if strtok_r macro segfaults on some inputs]) | |
812 | fi | |
813 | ]) | |
814 | ||
815 | dnl ---------------------------------------------------------------------- | |
816 | dnl These macros are from GNU PSPP, with the following original license: | |
817 | dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc. | |
818 | dnl This file is free software; the Free Software Foundation | |
819 | dnl gives unlimited permission to copy and/or distribute it, | |
820 | dnl with or without modifications, as long as this notice is preserved. | |
821 | ||
822 | AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl | |
823 | m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl | |
824 | AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], | |
825 | [ovs_save_CFLAGS="$CFLAGS" | |
826 | dnl Include -Werror in the compiler options, because without -Werror | |
827 | dnl clang's GCC-compatible compiler driver does not return a failure | |
828 | dnl exit status even though it complains about options it does not | |
829 | dnl understand. | |
830 | dnl | |
831 | dnl Also, check stderr as gcc exits with status 0 for options | |
832 | dnl rejected at getopt level. | |
833 | dnl % touch /tmp/a.c | |
834 | dnl % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $? | |
835 | dnl gcc: unrecognized option '-Qunused-arguments' | |
836 | dnl 0 | |
837 | dnl % | |
838 | CFLAGS="$CFLAGS $WERROR $1" | |
839 | AC_COMPILE_IFELSE( | |
840 | [AC_LANG_SOURCE([int x;])], | |
841 | [if test -s conftest.err && grep "unrecognized option" conftest.err | |
842 | then | |
843 | ovs_cv_name[]=no | |
844 | else | |
845 | ovs_cv_name[]=yes | |
846 | fi], | |
847 | [ovs_cv_name[]=no]) | |
848 | CFLAGS="$ovs_save_CFLAGS"]) | |
849 | if test $ovs_cv_name = yes; then | |
850 | m4_if([$2], [], [:], [$2]) | |
851 | else | |
852 | m4_if([$3], [], [:], [$3]) | |
853 | fi | |
854 | ]) | |
855 | ||
856 | dnl OVS_CHECK_WERROR | |
857 | dnl | |
858 | dnl Check whether the C compiler accepts -Werror. | |
859 | dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string. | |
860 | AC_DEFUN([OVS_CHECK_WERROR], | |
861 | [WERROR= | |
862 | _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])]) | |
863 | ||
864 | dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED]) | |
865 | dnl Check whether the given C compiler OPTION is accepted. | |
866 | dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED. | |
867 | AC_DEFUN([OVS_CHECK_CC_OPTION], | |
868 | [AC_REQUIRE([OVS_CHECK_WERROR]) | |
869 | _OVS_CHECK_CC_OPTION([$1], [$2], [$3])]) | |
870 | ||
871 | dnl OVS_ENABLE_OPTION([OPTION]) | |
872 | dnl Check whether the given C compiler OPTION is accepted. | |
873 | dnl If so, add it to WARNING_FLAGS. | |
874 | dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement]) | |
875 | AC_DEFUN([OVS_ENABLE_OPTION], | |
876 | [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"]) | |
877 | AC_SUBST([WARNING_FLAGS])]) | |
878 | ||
879 | dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL]) | |
880 | dnl Check whether the given C compiler OPTION is accepted. | |
881 | dnl If so, enable the given Automake CONDITIONAL. | |
882 | ||
883 | dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED]) | |
884 | AC_DEFUN([OVS_CONDITIONAL_CC_OPTION], | |
885 | [OVS_CHECK_CC_OPTION( | |
886 | [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no]) | |
887 | AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])]) | |
888 | dnl ---------------------------------------------------------------------- | |
889 | ||
890 | dnl Check for too-old XenServer. | |
891 | AC_DEFUN([OVS_CHECK_XENSERVER_VERSION], | |
892 | [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion], | |
893 | [if test -e /etc/redhat-release; then | |
894 | ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release` | |
895 | fi | |
896 | if test -z "$ovs_cv_xsversion"; then | |
897 | ovs_cv_xsversion=none | |
898 | fi]) | |
899 | case $ovs_cv_xsversion in | |
900 | none) | |
901 | ;; | |
902 | ||
903 | [[1-9]][[0-9]]* | dnl XenServer 10 or later | |
904 | [[6-9]]* | dnl XenServer 6 or later | |
905 | 5.[[7-9]]* | dnl XenServer 5.7 or later | |
906 | 5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.1000 or later | |
907 | 5.6.[[2-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.200 or later | |
908 | 5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later | |
909 | ;; | |
910 | ||
911 | *) | |
912 | AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)]) | |
913 | ;; | |
914 | esac]) | |
915 | ||
916 | dnl OVS_CHECK_SPARSE_TARGET | |
917 | dnl | |
918 | dnl The "cgcc" script from "sparse" isn't very good at detecting the | |
919 | dnl target for which the code is being built. This helps it out. | |
920 | AC_DEFUN([OVS_CHECK_SPARSE_TARGET], | |
921 | [AC_CACHE_CHECK( | |
922 | [target hint for cgcc], | |
923 | [ac_cv_sparse_target], | |
924 | [AS_CASE([`$CC -dumpmachine 2>/dev/null`], | |
925 | [i?86-* | athlon-*], [ac_cv_sparse_target=x86], | |
926 | [x86_64-*], [ac_cv_sparse_target=x86_64], | |
927 | [ac_cv_sparse_target=other])]) | |
928 | AS_CASE([$ac_cv_sparse_target], | |
929 | [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86], | |
930 | [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64], | |
931 | [SPARSEFLAGS= CGCCFLAGS=]) | |
932 | AC_SUBST([SPARSEFLAGS]) | |
933 | AC_SUBST([CGCCFLAGS])]) | |
934 | ||
935 | dnl OVS_SPARSE_EXTRA_INCLUDES | |
936 | dnl | |
937 | dnl The cgcc script from "sparse" does not search gcc's default | |
938 | dnl search path. Get the default search path from GCC and pass | |
939 | dnl them to sparse. | |
940 | AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES], | |
941 | AC_SUBST([SPARSE_EXTRA_INCLUDES], | |
942 | [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] )) | |
943 | ||
944 | dnl OVS_ENABLE_SPARSE | |
945 | AC_DEFUN([OVS_ENABLE_SPARSE], | |
946 | [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET]) | |
947 | AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES]) | |
948 | : ${SPARSE=sparse} | |
949 | AC_SUBST([SPARSE]) | |
950 | AC_CONFIG_COMMANDS_PRE( | |
951 | [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])]) | |
952 | ||
953 | dnl OVS_PTHREAD_SET_NAME | |
954 | dnl | |
955 | dnl This checks for three known variants of pthreads functions for setting | |
956 | dnl the name of the current thread: | |
957 | dnl | |
958 | dnl glibc: int pthread_setname_np(pthread_t, const char *name); | |
959 | dnl NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg); | |
960 | dnl FreeBSD: int pthread_set_name_np(pthread_t, const char *name); | |
961 | dnl | |
962 | dnl For glibc and FreeBSD, the arguments are just a thread and its name. For | |
963 | dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to | |
964 | dnl provide to it. | |
965 | dnl | |
966 | dnl This macro defines: | |
967 | dnl | |
968 | dnl glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP | |
969 | dnl NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP | |
970 | dnl FreeBSD: HAVE_PTHREAD_SET_NAME_NP | |
971 | AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME], | |
972 | [AC_CHECK_FUNCS([pthread_set_name_np]) | |
973 | if test $ac_cv_func_pthread_set_name_np != yes; then | |
974 | AC_CACHE_CHECK( | |
975 | [for pthread_setname_np() variant], | |
976 | [ovs_cv_pthread_setname_np], | |
977 | [AC_LINK_IFELSE( | |
978 | [AC_LANG_PROGRAM([#include <pthread.h> | |
979 | ], [pthread_setname_np(pthread_self(), "name");])], | |
980 | [ovs_cv_pthread_setname_np=glibc], | |
981 | [AC_LINK_IFELSE( | |
982 | [AC_LANG_PROGRAM([#include <pthread.h> | |
983 | ], [pthread_setname_np(pthread_self(), "%s", "name");])], | |
984 | [ovs_cv_pthread_setname_np=netbsd], | |
985 | [ovs_cv_pthread_setname_np=none])])]) | |
986 | case $ovs_cv_pthread_setname_np in # ( | |
987 | glibc) | |
988 | AC_DEFINE( | |
989 | [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1], | |
990 | [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).]) | |
991 | ;; # ( | |
992 | netbsd) | |
993 | AC_DEFINE( | |
994 | [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1], | |
995 | [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).]) | |
996 | ;; | |
997 | esac | |
998 | fi]) | |
999 | ||
1000 | dnl OVS_CHECK_LINUX_HOST. | |
1001 | dnl | |
1002 | dnl Checks whether we're building for a Linux host, based on the presence of | |
1003 | dnl the __linux__ preprocessor symbol, and sets up an Automake conditional | |
1004 | dnl LINUX based on the result. | |
1005 | AC_DEFUN([OVS_CHECK_LINUX_HOST], | |
1006 | [AC_CACHE_CHECK( | |
1007 | [whether __linux__ is defined], | |
1008 | [ovs_cv_linux], | |
1009 | [AC_COMPILE_IFELSE( | |
1010 | [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])], | |
1011 | [ovs_cv_linux=true], | |
1012 | [ovs_cv_linux=false])]) | |
1013 | AM_CONDITIONAL([LINUX], [$ovs_cv_linux])]) |