| | 1 | # -*- autoconf -*- |
| | 2 | |
| | 3 | # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc. |
| | 4 | # |
| | 5 | # Licensed under the Apache License, Version 2.0 (the "License"); |
| | 6 | # you may not use this file except in compliance with the License. |
| | 7 | # You may obtain a copy of the License at: |
| | 8 | # |
| | 9 | # http://www.apache.org/licenses/LICENSE-2.0 |
| | 10 | # |
| | 11 | # Unless required by applicable law or agreed to in writing, software |
| | 12 | # distributed under the License is distributed on an "AS IS" BASIS, |
| | 13 | # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| | 14 | # See the License for the specific language governing permissions and |
| | 15 | # limitations under the License. |
| | 16 | |
| | 17 | dnl OVS_ENABLE_WERROR |
| | 18 | AC_DEFUN([OVS_ENABLE_WERROR], |
| | 19 | [AC_ARG_ENABLE( |
| | 20 | [Werror], |
| | 21 | [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])], |
| | 22 | [], [enable_Werror=no]) |
| | 23 | AC_CONFIG_COMMANDS_PRE( |
| | 24 | [if test "X$enable_Werror" = Xyes; then |
| | 25 | OVS_CFLAGS="$OVS_CFLAGS -Werror" |
| | 26 | fi]) |
| | 27 | |
| | 28 | # Unless --enable-Werror is specified, report but do not fail the build |
| | 29 | # for errors reported by flake8. |
| | 30 | if test "X$enable_Werror" = Xyes; then |
| | 31 | FLAKE8_WERROR= |
| | 32 | else |
| | 33 | FLAKE8_WERROR=- |
| | 34 | fi |
| | 35 | AC_SUBST([FLAKE8_WERROR])]) |
| | 36 | |
| | 37 | dnl OVS_CHECK_LINUX |
| | 38 | dnl |
| | 39 | dnl Configure linux kernel source tree |
| | 40 | AC_DEFUN([OVS_CHECK_LINUX], [ |
| | 41 | AC_ARG_WITH([linux], |
| | 42 | [AC_HELP_STRING([--with-linux=/path/to/linux], |
| | 43 | [Specify the Linux kernel build directory])]) |
| | 44 | AC_ARG_WITH([linux-source], |
| | 45 | [AC_HELP_STRING([--with-linux-source=/path/to/linux-source], |
| | 46 | [Specify the Linux kernel source directory |
| | 47 | (usually figured out automatically from build |
| | 48 | directory)])]) |
| | 49 | |
| | 50 | # Deprecated equivalents to --with-linux, --with-linux-source. |
| | 51 | AC_ARG_WITH([l26]) |
| | 52 | AC_ARG_WITH([l26-source]) |
| | 53 | |
| | 54 | if test X"$with_linux" != X; then |
| | 55 | KBUILD=$with_linux |
| | 56 | elif test X"$with_l26" != X; then |
| | 57 | KBUILD=$with_l26 |
| | 58 | AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead]) |
| | 59 | else |
| | 60 | KBUILD= |
| | 61 | fi |
| | 62 | |
| | 63 | if test X"$KBUILD" != X; then |
| | 64 | if test X"$with_linux_source" != X; then |
| | 65 | KSRC=$with_linux_source |
| | 66 | elif test X"$with_l26_source" != X; then |
| | 67 | KSRC=$with_l26_source |
| | 68 | AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead]) |
| | 69 | else |
| | 70 | KSRC= |
| | 71 | fi |
| | 72 | elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then |
| | 73 | AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory]) |
| | 74 | fi |
| | 75 | |
| | 76 | if test -n "$KBUILD"; then |
| | 77 | KBUILD=`eval echo "$KBUILD"` |
| | 78 | case $KBUILD in |
| | 79 | /*) ;; |
| | 80 | *) KBUILD=`pwd`/$KBUILD ;; |
| | 81 | esac |
| | 82 | |
| | 83 | # The build directory is what the user provided. |
| | 84 | # Make sure that it exists. |
| | 85 | AC_MSG_CHECKING([for Linux build directory]) |
| | 86 | if test -d "$KBUILD"; then |
| | 87 | AC_MSG_RESULT([$KBUILD]) |
| | 88 | AC_SUBST(KBUILD) |
| | 89 | else |
| | 90 | AC_MSG_RESULT([no]) |
| | 91 | AC_ERROR([source dir $KBUILD doesn't exist]) |
| | 92 | fi |
| | 93 | |
| | 94 | # Debian breaks kernel headers into "source" header and "build" headers. |
| | 95 | # We want the source headers, but $KBUILD gives us the "build" headers. |
| | 96 | # Use heuristics to find the source headers. |
| | 97 | AC_MSG_CHECKING([for Linux source directory]) |
| | 98 | if test -n "$KSRC"; then |
| | 99 | KSRC=`eval echo "$KSRC"` |
| | 100 | case $KSRC in |
| | 101 | /*) ;; |
| | 102 | *) KSRC=`pwd`/$KSRC ;; |
| | 103 | esac |
| | 104 | if test ! -e $KSRC/include/linux/kernel.h; then |
| | 105 | AC_MSG_ERROR([$KSRC is not a kernel source directory]) |
| | 106 | fi |
| | 107 | else |
| | 108 | KSRC=$KBUILD |
| | 109 | if test ! -e $KSRC/include/linux/kernel.h; then |
| | 110 | # Debian kernel build Makefiles tend to include a line of the form: |
| | 111 | # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486 |
| | 112 | # First try to extract the source directory from this line. |
| | 113 | KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile` |
| | 114 | if test ! -e "$KSRC"/include/linux/kernel.h; then |
| | 115 | # Didn't work. Fall back to name-based heuristics that used to work. |
| | 116 | case `echo "$KBUILD" | sed 's,/*$,,'` in # ( |
| | 117 | */build) |
| | 118 | KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'` |
| | 119 | ;; # ( |
| | 120 | *) |
| | 121 | KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'` |
| | 122 | ;; |
| | 123 | esac |
| | 124 | fi |
| | 125 | fi |
| | 126 | if test ! -e "$KSRC"/include/linux/kernel.h; then |
| | 127 | AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)]) |
| | 128 | fi |
| | 129 | fi |
| | 130 | AC_MSG_RESULT([$KSRC]) |
| | 131 | |
| | 132 | AC_MSG_CHECKING([for kernel version]) |
| | 133 | version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"` |
| | 134 | patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"` |
| | 135 | sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"` |
| | 136 | if test X"$version" = X || test X"$patchlevel" = X; then |
| | 137 | AC_ERROR([cannot determine kernel version]) |
| | 138 | elif test X"$sublevel" = X; then |
| | 139 | kversion=$version.$patchlevel |
| | 140 | else |
| | 141 | kversion=$version.$patchlevel.$sublevel |
| | 142 | fi |
| | 143 | AC_MSG_RESULT([$kversion]) |
| | 144 | |
| | 145 | if test "$version" -ge 4; then |
| | 146 | if test "$version" = 4 && test "$patchlevel" -le 11; then |
| | 147 | : # Linux 4.x |
| | 148 | else |
| | 149 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.11.x is not supported (please refer to the FAQ for advice)]) |
| | 150 | fi |
| | 151 | elif test "$version" = 3 && test "$patchlevel" -ge 10; then |
| | 152 | : # Linux 3.x |
| | 153 | else |
| | 154 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required]) |
| | 155 | fi |
| | 156 | if (test ! -e "$KBUILD"/include/linux/version.h && \ |
| | 157 | test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \ |
| | 158 | (test ! -e "$KBUILD"/include/linux/autoconf.h && \ |
| | 159 | test ! -e "$KBUILD"/include/generated/autoconf.h); then |
| | 160 | AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured]) |
| | 161 | fi |
| | 162 | OVS_CHECK_LINUX_COMPAT |
| | 163 | fi |
| | 164 | AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD") |
| | 165 | ]) |
| | 166 | |
| | 167 | dnl OVS_CHECK_LINUX_TC |
| | 168 | dnl |
| | 169 | dnl Configure Linux tc compat. |
| | 170 | AC_DEFUN([OVS_CHECK_LINUX_TC], [ |
| | 171 | AC_COMPILE_IFELSE([ |
| | 172 | AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [ |
| | 173 | int x = TCA_ACT_COOKIE; |
| | 174 | ])], |
| | 175 | [AC_DEFINE([HAVE_TCA_ACT_COOKIE], [1], |
| | 176 | [Define to 1 if TCA_ACT_COOKIE is avaiable.])]) |
| | 177 | |
| | 178 | AC_COMPILE_IFELSE([ |
| | 179 | AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [ |
| | 180 | int x = TCA_VLAN_PUSH_VLAN_PRIORITY; |
| | 181 | ])], |
| | 182 | [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1], |
| | 183 | [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])]) |
| | 184 | |
| | 185 | AC_COMPILE_IFELSE([ |
| | 186 | AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [ |
| | 187 | int x = TCA_TUNNEL_KEY_ENC_DST_PORT; |
| | 188 | ])], |
| | 189 | [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1], |
| | 190 | [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])]) |
| | 191 | ]) |
| | 192 | |
| | 193 | dnl OVS_CHECK_DPDK |
| | 194 | dnl |
| | 195 | dnl Configure DPDK source tree |
| | 196 | AC_DEFUN([OVS_CHECK_DPDK], [ |
| | 197 | AC_ARG_WITH([dpdk], |
| | 198 | [AC_HELP_STRING([--with-dpdk=/path/to/dpdk], |
| | 199 | [Specify the DPDK build directory])], |
| | 200 | [have_dpdk=true]) |
| | 201 | |
| | 202 | AC_MSG_CHECKING([whether dpdk datapath is enabled]) |
| | 203 | if test "$have_dpdk" != true || test "$with_dpdk" = no; then |
| | 204 | AC_MSG_RESULT([no]) |
| | 205 | DPDKLIB_FOUND=false |
| | 206 | else |
| | 207 | AC_MSG_RESULT([yes]) |
| | 208 | case "$with_dpdk" in |
| | 209 | yes) |
| | 210 | DPDK_AUTO_DISCOVER="true" |
| | 211 | DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk" |
| | 212 | ;; |
| | 213 | *) |
| | 214 | DPDK_AUTO_DISCOVER="false" |
| | 215 | DPDK_INCLUDE="$with_dpdk/include" |
| | 216 | # If 'with_dpdk' is passed install directory, point to headers |
| | 217 | # installed in $DESTDIR/$prefix/include/dpdk |
| | 218 | if test ! -e "$DPDK_INCLUDE/rte_config.h" && \ |
| | 219 | test -e "$DPDK_INCLUDE/dpdk/rte_config.h"; then |
| | 220 | DPDK_INCLUDE=$DPDK_INCLUDE/dpdk |
| | 221 | fi |
| | 222 | DPDK_LIB_DIR="$with_dpdk/lib" |
| | 223 | ;; |
| | 224 | esac |
| | 225 | |
| | 226 | DPDK_LIB="-ldpdk" |
| | 227 | DPDK_EXTRA_LIB="" |
| | 228 | |
| | 229 | ovs_save_CFLAGS="$CFLAGS" |
| | 230 | ovs_save_LDFLAGS="$LDFLAGS" |
| | 231 | CFLAGS="$CFLAGS -I$DPDK_INCLUDE" |
| | 232 | if test "$DPDK_AUTO_DISCOVER" = "false"; then |
| | 233 | LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}" |
| | 234 | fi |
| | 235 | |
| | 236 | AC_COMPILE_IFELSE([ |
| | 237 | AC_LANG_PROGRAM( |
| | 238 | [ |
| | 239 | #include <rte_config.h> |
| | 240 | #if RTE_LIBRTE_VHOST_NUMA |
| | 241 | #error |
| | 242 | #endif |
| | 243 | ], []) |
| | 244 | ], [], |
| | 245 | [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])]) |
| | 246 | DPDK_EXTRA_LIB="-lnuma" |
| | 247 | AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])]) |
| | 248 | |
| | 249 | AC_COMPILE_IFELSE([ |
| | 250 | AC_LANG_PROGRAM( |
| | 251 | [ |
| | 252 | #include <rte_config.h> |
| | 253 | #if RTE_LIBRTE_PMD_PCAP |
| | 254 | #error |
| | 255 | #endif |
| | 256 | ], []) |
| | 257 | ], [], |
| | 258 | [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])]) |
| | 259 | DPDK_EXTRA_LIB="-lpcap" |
| | 260 | AC_COMPILE_IFELSE([ |
| | 261 | AC_LANG_PROGRAM( |
| | 262 | [ |
| | 263 | #include <rte_config.h> |
| | 264 | #if RTE_LIBRTE_PDUMP |
| | 265 | #error |
| | 266 | #endif |
| | 267 | ], []) |
| | 268 | ], [], |
| | 269 | [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])]) |
| | 270 | ]) |
| | 271 | |
| | 272 | # On some systems we have to add -ldl to link with dpdk |
| | 273 | # |
| | 274 | # This code, at first, tries to link without -ldl (""), |
| | 275 | # then adds it and tries again. |
| | 276 | # Before each attempt the search cache must be unset, |
| | 277 | # otherwise autoconf will stick with the old result |
| | 278 | |
| | 279 | DPDKLIB_FOUND=false |
| | 280 | save_LIBS=$LIBS |
| | 281 | for extras in "" "-ldl"; do |
| | 282 | LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB" |
| | 283 | AC_LINK_IFELSE( |
| | 284 | [AC_LANG_PROGRAM([#include <rte_config.h> |
| | 285 | #include <rte_eal.h>], |
| | 286 | [int rte_argc; char ** rte_argv; |
| | 287 | rte_eal_init(rte_argc, rte_argv);])], |
| | 288 | [DPDKLIB_FOUND=true]) |
| | 289 | if $DPDKLIB_FOUND; then |
| | 290 | break |
| | 291 | fi |
| | 292 | done |
| | 293 | |
| | 294 | # If linking unsuccessful |
| | 295 | if test "$DPDKLIB_FOUND" = "false" ; then |
| | 296 | if $DPDK_AUTO_DISCOVER; then |
| | 297 | AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location]) |
| | 298 | else |
| | 299 | AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR]) |
| | 300 | fi |
| | 301 | fi |
| | 302 | CFLAGS="$ovs_save_CFLAGS" |
| | 303 | LDFLAGS="$ovs_save_LDFLAGS" |
| | 304 | if test "$DPDK_AUTO_DISCOVER" = "false"; then |
| | 305 | OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR" |
| | 306 | fi |
| | 307 | OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE" |
| | 308 | OVS_ENABLE_OPTION([-mssse3]) |
| | 309 | |
| | 310 | # DPDK pmd drivers are not linked unless --whole-archive is used. |
| | 311 | # |
| | 312 | # This happens because the rest of the DPDK code doesn't use any symbol in |
| | 313 | # the pmd driver objects, and the drivers register themselves using an |
| | 314 | # __attribute__((constructor)) function. |
| | 315 | # |
| | 316 | # These options are specified inside a single -Wl directive to prevent |
| | 317 | # autotools from reordering them. |
| | 318 | DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive |
| | 319 | AC_SUBST([DPDK_vswitchd_LDFLAGS]) |
| | 320 | AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.]) |
| | 321 | fi |
| | 322 | |
| | 323 | AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true) |
| | 324 | ]) |
| | 325 | |
| | 326 | dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH]) |
| | 327 | dnl |
| | 328 | dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH. |
| | 329 | dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with |
| | 330 | dnl <REGEX> translated to uppercase. |
| | 331 | AC_DEFUN([OVS_GREP_IFELSE], [ |
| | 332 | AC_MSG_CHECKING([whether $2 matches in $1]) |
| | 333 | if test -f $1; then |
| | 334 | grep '$2' $1 >/dev/null 2>&1 |
| | 335 | status=$? |
| | 336 | case $status in |
| | 337 | 0) |
| | 338 | AC_MSG_RESULT([yes]) |
| | 339 | m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3]) |
| | 340 | ;; |
| | 341 | 1) |
| | 342 | AC_MSG_RESULT([no]) |
| | 343 | $4 |
| | 344 | ;; |
| | 345 | *) |
| | 346 | AC_MSG_ERROR([grep exited with status $status]) |
| | 347 | ;; |
| | 348 | esac |
| | 349 | else |
| | 350 | AC_MSG_RESULT([file not found]) |
| | 351 | $4 |
| | 352 | fi |
| | 353 | ]) |
| | 354 | |
| | 355 | dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH]) |
| | 356 | dnl |
| | 357 | dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the |
| | 358 | dnl structure definition. If this is successful, runs IF-MATCH, otherwise |
| | 359 | dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to |
| | 360 | dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX> |
| | 361 | dnl translated to uppercase. |
| | 362 | AC_DEFUN([OVS_FIND_FIELD_IFELSE], [ |
| | 363 | AC_MSG_CHECKING([whether $2 has member $3 in $1]) |
| | 364 | if test -f $1; then |
| | 365 | awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null |
| | 366 | status=$? |
| | 367 | case $status in |
| | 368 | 0) |
| | 369 | AC_MSG_RESULT([yes]) |
| | 370 | m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4]) |
| | 371 | ;; |
| | 372 | 1) |
| | 373 | AC_MSG_RESULT([no]) |
| | 374 | $5 |
| | 375 | ;; |
| | 376 | *) |
| | 377 | AC_MSG_ERROR([grep exited with status $status]) |
| | 378 | ;; |
| | 379 | esac |
| | 380 | else |
| | 381 | AC_MSG_RESULT([file not found]) |
| | 382 | $5 |
| | 383 | fi |
| | 384 | ]) |
| | 385 | |
| | 386 | dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH]) |
| | 387 | dnl |
| | 388 | dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within |
| | 389 | dnl the function signature starting from the line matching FUNCTION |
| | 390 | dnl and ending with the line containing the closing parenthesis. If |
| | 391 | dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH. If |
| | 392 | dnl IF-MATCH is empty then it defines to |
| | 393 | dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and |
| | 394 | dnl <REGEX> translated to uppercase. |
| | 395 | AC_DEFUN([OVS_FIND_PARAM_IFELSE], [ |
| | 396 | AC_MSG_CHECKING([whether $2 has parameter $3 in $1]) |
| | 397 | if test -f $1; then |
| | 398 | awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null |
| | 399 | status=$? |
| | 400 | case $status in |
| | 401 | 0) |
| | 402 | AC_MSG_RESULT([yes]) |
| | 403 | m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4]) |
| | 404 | ;; |
| | 405 | 1) |
| | 406 | AC_MSG_RESULT([no]) |
| | 407 | $5 |
| | 408 | ;; |
| | 409 | *) |
| | 410 | AC_MSG_ERROR([grep exited with status $status]) |
| | 411 | ;; |
| | 412 | esac |
| | 413 | else |
| | 414 | AC_MSG_RESULT([file not found]) |
| | 415 | $5 |
| | 416 | fi |
| | 417 | ]) |
| | 418 | |
| | 419 | dnl OVS_DEFINE(NAME) |
| | 420 | dnl |
| | 421 | dnl Defines NAME to 1 in kcompat.h. |
| | 422 | AC_DEFUN([OVS_DEFINE], [ |
| | 423 | echo '#define $1 1' >> datapath/linux/kcompat.h.new |
| | 424 | ]) |
| | 425 | |
| | 426 | dnl OVS_CHECK_LINUX_COMPAT |
| | 427 | dnl |
| | 428 | dnl Runs various Autoconf checks on the Linux kernel source in |
| | 429 | dnl the directory in $KBUILD. |
| | 430 | AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [ |
| | 431 | rm -f datapath/linux/kcompat.h.new |
| | 432 | mkdir -p datapath/linux |
| | 433 | : > datapath/linux/kcompat.h.new |
| | 434 | |
| | 435 | echo '#include <linux/version.h> |
| | 436 | #ifndef RHEL_RELEASE_CODE |
| | 437 | #define RHEL_RELEASE_CODE 0 |
| | 438 | #define RHEL_RELEASE_VERSION(a, b) 0 |
| | 439 | #endif' >> datapath/linux/kcompat.h.new |
| | 440 | |
| | 441 | OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,], |
| | 442 | [OVS_DEFINE([HAVE_CSUM_COPY_DBG])]) |
| | 443 | |
| | 444 | OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net], |
| | 445 | [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])]) |
| | 446 | OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub]) |
| | 447 | |
| | 448 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST]) |
| | 449 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL]) |
| | 450 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO]) |
| | 451 | |
| | 452 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random]) |
| | 453 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy]) |
| | 454 | |
| | 455 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS]) |
| | 456 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64]) |
| | 457 | OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64]) |
| | 458 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto]) |
| | 459 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside]) |
| | 460 | |
| | 461 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast]) |
| | 462 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset]) |
| | 463 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry], |
| | 464 | [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])]) |
| | 465 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net], |
| | 466 | [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])]) |
| | 467 | |
| | 468 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net], |
| | 469 | [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])]) |
| | 470 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net], |
| | 471 | [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])]) |
| | 472 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h], |
| | 473 | [ip_do_fragment], [net], |
| | 474 | [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])]) |
| | 475 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h], |
| | 476 | [ip_local_out], [net], |
| | 477 | [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])]) |
| | 478 | |
| | 479 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu]) |
| | 480 | |
| | 481 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU], |
| | 482 | [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])]) |
| | 483 | OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu]) |
| | 484 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const], |
| | 485 | [OVS_DEFINE([HAVE_INET_FRAGS_CONST])]) |
| | 486 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in], |
| | 487 | [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])]) |
| | 488 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting]) |
| | 489 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor]) |
| | 490 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags], |
| | 491 | [frags_work]) |
| | 492 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags], |
| | 493 | [rwlock]) |
| | 494 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue], |
| | 495 | [list_evictor]) |
| | 496 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move]) |
| | 497 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h], |
| | 498 | [sub_frag_mem_limit], [struct.netns_frags], |
| | 499 | [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])]) |
| | 500 | OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init], |
| | 501 | [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])]) |
| | 502 | OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif], |
| | 503 | [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])]) |
| | 504 | |
| | 505 | dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure. |
| | 506 | dnl OVS does not really need ipv6 label field, but its presence signifies that |
| | 507 | dnl the stack has all required ipv6 support. |
| | 508 | dnl OVS also does not need dst_cache But this dependency allows us to write |
| | 509 | dnl much cleaner code. |
| | 510 | |
| | 511 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key], |
| | 512 | [label], |
| | 513 | [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], |
| | 514 | [iptunnel_pull_offloads], |
| | 515 | [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache], |
| | 516 | [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])]) |
| | 517 | |
| | 518 | OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr], |
| | 519 | [OVS_DEFINE([MPLS_HEADER_IS_L3])]) |
| | 520 | OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net], |
| | 521 | [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])]) |
| | 522 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst]) |
| | 523 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro]) |
| | 524 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats]) |
| | 525 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu]) |
| | 526 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level]) |
| | 527 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment]) |
| | 528 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol]) |
| | 529 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink]) |
| | 530 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check], |
| | 531 | [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])]) |
| | 532 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port]) |
| | 533 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port]) |
| | 534 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t]) |
| | 535 | dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats. |
| | 536 | dnl So check type of tstats. |
| | 537 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats], |
| | 538 | [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])]) |
| | 539 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device], |
| | 540 | [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])]) |
| | 541 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload]) |
| | 542 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff], |
| | 543 | [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])]) |
| | 544 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum]) |
| | 545 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM]) |
| | 546 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops], |
| | 547 | [extended]) |
| | 548 | OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h], |
| | 549 | [netdev_master_upper_dev_link], [upper_priv], |
| | 550 | [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])]) |
| | 551 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device], |
| | 552 | [max_mtu]) |
| | 553 | |
| | 554 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state]) |
| | 555 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook]) |
| | 556 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops], |
| | 557 | [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])]) |
| | 558 | OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv], |
| | 559 | [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])]) |
| | 560 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops], |
| | 561 | [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])]) |
| | 562 | |
| | 563 | OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops], |
| | 564 | [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])]) |
| | 565 | |
| | 566 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 567 | [nf_conn], [struct timer_list[[ \t]]*timeout], |
| | 568 | [OVS_DEFINE([HAVE_NF_CONN_TIMER])]) |
| | 569 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 570 | [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])]) |
| | 571 | |
| | 572 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 573 | [nf_ct_tmpl_alloc], [nf_conntrack_zone], |
| | 574 | [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])]) |
| | 575 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 576 | [nf_ct_get_tuplepr], [struct.net], |
| | 577 | [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])]) |
| | 578 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 579 | [nf_ct_set]) |
| | 580 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h], |
| | 581 | [nf_ct_is_untracked]) |
| | 582 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h], |
| | 583 | [nf_ct_zone_init]) |
| | 584 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], |
| | 585 | [nf_connlabels_get]) |
| | 586 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], |
| | 587 | [nf_connlabels_get], [int bit], |
| | 588 | [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])]) |
| | 589 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h], |
| | 590 | [nf_conn_labels], [words]) |
| | 591 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add]) |
| | 592 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding]) |
| | 593 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust]) |
| | 594 | |
| | 595 | OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32]) |
| | 596 | OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max]) |
| | 597 | |
| | 598 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net]) |
| | 599 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type]) |
| | 600 | OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net], |
| | 601 | [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])]) |
| | 602 | OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t]) |
| | 603 | |
| | 604 | OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [], |
| | 605 | [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], |
| | 606 | [rcu_read_lock_held])]) |
| | 607 | OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held]) |
| | 608 | |
| | 609 | # Check for the proto_data_valid member in struct sk_buff. The [^@] |
| | 610 | # is necessary because some versions of this header remove the |
| | 611 | # member but retain the kerneldoc comment that describes it (which |
| | 612 | # starts with @). The brackets must be doubled because of m4 |
| | 613 | # quoting rules. |
| | 614 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid], |
| | 615 | [OVS_DEFINE([HAVE_PROTO_DATA_VALID])]) |
| | 616 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset]) |
| | 617 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol]) |
| | 618 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type]) |
| | 619 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset]) |
| | 620 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list]) |
| | 621 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash]) |
| | 622 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash], |
| | 623 | [OVS_DEFINE([HAVE_U16_RXHASH])]) |
| | 624 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(], |
| | 625 | [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])]) |
| | 626 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], |
| | 627 | [skb_copy_from_linear_data_offset]) |
| | 628 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], |
| | 629 | [skb_reset_tail_pointer]) |
| | 630 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head]) |
| | 631 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro], |
| | 632 | [OVS_DEFINE([HAVE_SKB_WARN_LRO])]) |
| | 633 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb]) |
| | 634 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page]) |
| | 635 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list]) |
| | 636 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc]) |
| | 637 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len]) |
| | 638 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone]) |
| | 639 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags]) |
| | 640 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(], |
| | 641 | [OVS_DEFINE([HAVE_SKB_GET_HASH])]) |
| | 642 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash]) |
| | 643 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(], |
| | 644 | [OVS_DEFINE([HAVE_SKB_ZEROCOPY])]) |
| | 645 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash], |
| | 646 | [OVS_DEFINE([HAVE_L4_RXHASH])]) |
| | 647 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable]) |
| | 648 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop]) |
| | 649 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop]) |
| | 650 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push]) |
| | 651 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4]) |
| | 652 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum]) |
| | 653 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum]) |
| | 654 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct]) |
| | 655 | |
| | 656 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool], |
| | 657 | [OVS_DEFINE([HAVE_BOOL_TYPE])]) |
| | 658 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum], |
| | 659 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) |
| | 660 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum], |
| | 661 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) |
| | 662 | |
| | 663 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4]) |
| | 664 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold]) |
| | 665 | |
| | 666 | OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk]) |
| | 667 | OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy]) |
| | 668 | |
| | 669 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners]) |
| | 670 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset]) |
| | 671 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops]) |
| | 672 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock], |
| | 673 | [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])]) |
| | 674 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse]) |
| | 675 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family], |
| | 676 | [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])]) |
| | 677 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h], |
| | 678 | [genl_notify], [net], |
| | 679 | [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])]) |
| | 680 | |
| | 681 | |
| | 682 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], |
| | 683 | [genl_multicast_group], [id]) |
| | 684 | OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr]) |
| | 685 | |
| | 686 | OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register]) |
| | 687 | OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads]) |
| | 688 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH]) |
| | 689 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk]) |
| | 690 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash]) |
| | 691 | OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst], |
| | 692 | [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])]) |
| | 693 | OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock], |
| | 694 | [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])]) |
| | 695 | |
| | 696 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit]) |
| | 697 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16]) |
| | 698 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16]) |
| | 699 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32]) |
| | 700 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64]) |
| | 701 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr]) |
| | 702 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested]) |
| | 703 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last]) |
| | 704 | OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err], |
| | 705 | [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])]) |
| | 706 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h], |
| | 707 | [nla_parse], [netlink_ext_ack], |
| | 708 | [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])]) |
| | 709 | |
| | 710 | OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum]) |
| | 711 | |
| | 712 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD], |
| | 713 | [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])]) |
| | 714 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto]) |
| | 715 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag]) |
| | 716 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol]) |
| | 717 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged]) |
| | 718 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan]) |
| | 719 | |
| | 720 | OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq]) |
| | 721 | |
| | 722 | OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata], |
| | 723 | [OVS_DEFINE([HAVE_VXLAN_METADATA])]) |
| | 724 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port], |
| | 725 | [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net], |
| | 726 | [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])]) |
| | 727 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check]) |
| | 728 | OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete]) |
| | 729 | OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads], |
| | 730 | [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])]) |
| | 731 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg], |
| | 732 | [gro_receive]) |
| | 733 | |
| | 734 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df], |
| | 735 | [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])]) |
| | 736 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN], |
| | 737 | [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])]) |
| | 738 | |
| | 739 | OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx]) |
| | 740 | OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx]) |
| | 741 | OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6], |
| | 742 | [OVS_DEFINE([HAVE_RHEL6_PER_CPU])]) |
| | 743 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h], |
| | 744 | [udp_add_offload], [net], |
| | 745 | [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])]) |
| | 746 | OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h], |
| | 747 | [nf_defrag_ipv6_enable], [net], |
| | 748 | [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])]) |
| | 749 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list], |
| | 750 | [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])]) |
| | 751 | OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h], |
| | 752 | [nf_conntrack_helper_put]) |
| | 753 | |
| | 754 | if cmp -s datapath/linux/kcompat.h.new \ |
| | 755 | datapath/linux/kcompat.h >/dev/null 2>&1; then |
| | 756 | rm datapath/linux/kcompat.h.new |
| | 757 | else |
| | 758 | mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h |
| | 759 | fi |
| | 760 | ]) |
| | 761 | |
| | 762 | dnl Checks for net/if_packet.h. |
| | 763 | AC_DEFUN([OVS_CHECK_IF_PACKET], |
| | 764 | [AC_CHECK_HEADER([net/if_packet.h], |
| | 765 | [HAVE_IF_PACKET=yes], |
| | 766 | [HAVE_IF_PACKET=no]) |
| | 767 | AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes]) |
| | 768 | if test "$HAVE_IF_PACKET" = yes; then |
| | 769 | AC_DEFINE([HAVE_IF_PACKET], [1], |
| | 770 | [Define to 1 if net/if_packet.h is available.]) |
| | 771 | fi]) |
| | 772 | |
| | 773 | dnl Checks for net/if_dl.h. |
| | 774 | dnl |
| | 775 | dnl (We use this as a proxy for checking whether we're building on FreeBSD |
| | 776 | dnl or NetBSD.) |
| | 777 | AC_DEFUN([OVS_CHECK_IF_DL], |
| | 778 | [AC_CHECK_HEADER([net/if_dl.h], |
| | 779 | [HAVE_IF_DL=yes], |
| | 780 | [HAVE_IF_DL=no]) |
| | 781 | AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes]) |
| | 782 | if test "$HAVE_IF_DL" = yes; then |
| | 783 | AC_DEFINE([HAVE_IF_DL], [1], |
| | 784 | [Define to 1 if net/if_dl.h is available.]) |
| | 785 | |
| | 786 | # On these platforms we use libpcap to access network devices. |
| | 787 | AC_SEARCH_LIBS([pcap_open_live], [pcap]) |
| | 788 | fi]) |
| | 789 | |
| | 790 | dnl Checks for buggy strtok_r. |
| | 791 | dnl |
| | 792 | dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling |
| | 793 | dnl with optimization that can cause segfaults: |
| | 794 | dnl |
| | 795 | dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614. |
| | 796 | AC_DEFUN([OVS_CHECK_STRTOK_R], |
| | 797 | [AC_CACHE_CHECK( |
| | 798 | [whether strtok_r macro segfaults on some inputs], |
| | 799 | [ovs_cv_strtok_r_bug], |
| | 800 | [AC_RUN_IFELSE( |
| | 801 | [AC_LANG_PROGRAM([#include <stdio.h> |
| | 802 | #include <string.h> |
| | 803 | ], |
| | 804 | [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8 |
| | 805 | /* Assume bug is present, because relatively minor |
| | 806 | changes in compiler settings (e.g. optimization |
| | 807 | level) can make it crop up. */ |
| | 808 | return 1; |
| | 809 | #else |
| | 810 | char string[] = ":::"; |
| | 811 | char *save_ptr = (char *) 0xc0ffee; |
| | 812 | char *token1, *token2; |
| | 813 | token1 = strtok_r(string, ":", &save_ptr); |
| | 814 | token2 = strtok_r(NULL, ":", &save_ptr); |
| | 815 | freopen ("/dev/null", "w", stdout); |
| | 816 | printf ("%s %s\n", token1, token2); |
| | 817 | return 0; |
| | 818 | #endif |
| | 819 | ]])], |
| | 820 | [ovs_cv_strtok_r_bug=no], |
| | 821 | [ovs_cv_strtok_r_bug=yes], |
| | 822 | [ovs_cv_strtok_r_bug=yes])]) |
| | 823 | if test $ovs_cv_strtok_r_bug = yes; then |
| | 824 | AC_DEFINE([HAVE_STRTOK_R_BUG], [1], |
| | 825 | [Define if strtok_r macro segfaults on some inputs]) |
| | 826 | fi |
| | 827 | ]) |
| | 828 | |
| | 829 | dnl ---------------------------------------------------------------------- |
| | 830 | dnl These macros are from GNU PSPP, with the following original license: |
| | 831 | dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc. |
| | 832 | dnl This file is free software; the Free Software Foundation |
| | 833 | dnl gives unlimited permission to copy and/or distribute it, |
| | 834 | dnl with or without modifications, as long as this notice is preserved. |
| | 835 | |
| | 836 | AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl |
| | 837 | m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl |
| | 838 | AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], |
| | 839 | [ovs_save_CFLAGS="$CFLAGS" |
| | 840 | dnl Include -Werror in the compiler options, because without -Werror |
| | 841 | dnl clang's GCC-compatible compiler driver does not return a failure |
| | 842 | dnl exit status even though it complains about options it does not |
| | 843 | dnl understand. |
| | 844 | dnl |
| | 845 | dnl Also, check stderr as gcc exits with status 0 for options |
| | 846 | dnl rejected at getopt level. |
| | 847 | dnl % touch /tmp/a.c |
| | 848 | dnl % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $? |
| | 849 | dnl gcc: unrecognized option '-Qunused-arguments' |
| | 850 | dnl 0 |
| | 851 | dnl % |
| | 852 | CFLAGS="$CFLAGS $WERROR $1" |
| | 853 | AC_COMPILE_IFELSE( |
| | 854 | [AC_LANG_SOURCE([int x;])], |
| | 855 | [if test -s conftest.err && grep "unrecognized option" conftest.err |
| | 856 | then |
| | 857 | ovs_cv_name[]=no |
| | 858 | else |
| | 859 | ovs_cv_name[]=yes |
| | 860 | fi], |
| | 861 | [ovs_cv_name[]=no]) |
| | 862 | CFLAGS="$ovs_save_CFLAGS"]) |
| | 863 | if test $ovs_cv_name = yes; then |
| | 864 | m4_if([$2], [], [:], [$2]) |
| | 865 | else |
| | 866 | m4_if([$3], [], [:], [$3]) |
| | 867 | fi |
| | 868 | ]) |
| | 869 | |
| | 870 | dnl OVS_CHECK_WERROR |
| | 871 | dnl |
| | 872 | dnl Check whether the C compiler accepts -Werror. |
| | 873 | dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string. |
| | 874 | AC_DEFUN([OVS_CHECK_WERROR], |
| | 875 | [WERROR= |
| | 876 | _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])]) |
| | 877 | |
| | 878 | dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED]) |
| | 879 | dnl Check whether the given C compiler OPTION is accepted. |
| | 880 | dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED. |
| | 881 | AC_DEFUN([OVS_CHECK_CC_OPTION], |
| | 882 | [AC_REQUIRE([OVS_CHECK_WERROR]) |
| | 883 | _OVS_CHECK_CC_OPTION([$1], [$2], [$3])]) |
| | 884 | |
| | 885 | dnl OVS_ENABLE_OPTION([OPTION]) |
| | 886 | dnl Check whether the given C compiler OPTION is accepted. |
| | 887 | dnl If so, add it to WARNING_FLAGS. |
| | 888 | dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement]) |
| | 889 | AC_DEFUN([OVS_ENABLE_OPTION], |
| | 890 | [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"]) |
| | 891 | AC_SUBST([WARNING_FLAGS])]) |
| | 892 | |
| | 893 | dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL]) |
| | 894 | dnl Check whether the given C compiler OPTION is accepted. |
| | 895 | dnl If so, enable the given Automake CONDITIONAL. |
| | 896 | |
| | 897 | dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED]) |
| | 898 | AC_DEFUN([OVS_CONDITIONAL_CC_OPTION], |
| | 899 | [OVS_CHECK_CC_OPTION( |
| | 900 | [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no]) |
| | 901 | AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])]) |
| | 902 | dnl ---------------------------------------------------------------------- |
| | 903 | |
| | 904 | dnl Check for too-old XenServer. |
| | 905 | AC_DEFUN([OVS_CHECK_XENSERVER_VERSION], |
| | 906 | [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion], |
| | 907 | [if test -e /etc/redhat-release; then |
| | 908 | ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release` |
| | 909 | fi |
| | 910 | if test -z "$ovs_cv_xsversion"; then |
| | 911 | ovs_cv_xsversion=none |
| | 912 | fi]) |
| | 913 | case $ovs_cv_xsversion in |
| | 914 | none) |
| | 915 | ;; |
| | 916 | |
| | 917 | [[1-9]][[0-9]]* | dnl XenServer 10 or later |
| | 918 | [[6-9]]* | dnl XenServer 6 or later |
| | 919 | 5.[[7-9]]* | dnl XenServer 5.7 or later |
| | 920 | 5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.1000 or later |
| | 921 | 5.6.[[2-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.200 or later |
| | 922 | 5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later |
| | 923 | ;; |
| | 924 | |
| | 925 | *) |
| | 926 | AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)]) |
| | 927 | ;; |
| | 928 | esac]) |
| | 929 | |
| | 930 | dnl OVS_CHECK_SPARSE_TARGET |
| | 931 | dnl |
| | 932 | dnl The "cgcc" script from "sparse" isn't very good at detecting the |
| | 933 | dnl target for which the code is being built. This helps it out. |
| | 934 | AC_DEFUN([OVS_CHECK_SPARSE_TARGET], |
| | 935 | [AC_CACHE_CHECK( |
| | 936 | [target hint for cgcc], |
| | 937 | [ac_cv_sparse_target], |
| | 938 | [AS_CASE([`$CC -dumpmachine 2>/dev/null`], |
| | 939 | [i?86-* | athlon-*], [ac_cv_sparse_target=x86], |
| | 940 | [x86_64-*], [ac_cv_sparse_target=x86_64], |
| | 941 | [ac_cv_sparse_target=other])]) |
| | 942 | AS_CASE([$ac_cv_sparse_target], |
| | 943 | [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86], |
| | 944 | [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64], |
| | 945 | [SPARSEFLAGS= CGCCFLAGS=]) |
| | 946 | AC_SUBST([SPARSEFLAGS]) |
| | 947 | AC_SUBST([CGCCFLAGS])]) |
| | 948 | |
| | 949 | dnl OVS_SPARSE_EXTRA_INCLUDES |
| | 950 | dnl |
| | 951 | dnl The cgcc script from "sparse" does not search gcc's default |
| | 952 | dnl search path. Get the default search path from GCC and pass |
| | 953 | dnl them to sparse. |
| | 954 | AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES], |
| | 955 | AC_SUBST([SPARSE_EXTRA_INCLUDES], |
| | 956 | [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] )) |
| | 957 | |
| | 958 | dnl OVS_ENABLE_SPARSE |
| | 959 | AC_DEFUN([OVS_ENABLE_SPARSE], |
| | 960 | [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET]) |
| | 961 | AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES]) |
| | 962 | : ${SPARSE=sparse} |
| | 963 | AC_SUBST([SPARSE]) |
| | 964 | AC_CONFIG_COMMANDS_PRE( |
| | 965 | [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])]) |
| | 966 | |
| | 967 | dnl OVS_CTAGS_IDENTIFIERS |
| | 968 | dnl |
| | 969 | dnl ctags ignores symbols with extras identifiers. This builds a list of |
| | 970 | dnl specially handled identifiers to be ignored. |
| | 971 | AC_DEFUN([OVS_CTAGS_IDENTIFIERS], |
| | 972 | AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST], |
| | 973 | [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h | tr \\\n ' ' ; printf '"'`] )) |
| | 974 | |
| | 975 | dnl OVS_PTHREAD_SET_NAME |
| | 976 | dnl |
| | 977 | dnl This checks for three known variants of pthreads functions for setting |
| | 978 | dnl the name of the current thread: |
| | 979 | dnl |
| | 980 | dnl glibc: int pthread_setname_np(pthread_t, const char *name); |
| | 981 | dnl NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg); |
| | 982 | dnl FreeBSD: int pthread_set_name_np(pthread_t, const char *name); |
| | 983 | dnl |
| | 984 | dnl For glibc and FreeBSD, the arguments are just a thread and its name. For |
| | 985 | dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to |
| | 986 | dnl provide to it. |
| | 987 | dnl |
| | 988 | dnl This macro defines: |
| | 989 | dnl |
| | 990 | dnl glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP |
| | 991 | dnl NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP |
| | 992 | dnl FreeBSD: HAVE_PTHREAD_SET_NAME_NP |
| | 993 | AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME], |
| | 994 | [AC_CHECK_FUNCS([pthread_set_name_np]) |
| | 995 | if test $ac_cv_func_pthread_set_name_np != yes; then |
| | 996 | AC_CACHE_CHECK( |
| | 997 | [for pthread_setname_np() variant], |
| | 998 | [ovs_cv_pthread_setname_np], |
| | 999 | [AC_LINK_IFELSE( |
| | 1000 | [AC_LANG_PROGRAM([#include <pthread.h> |
| | 1001 | ], [pthread_setname_np(pthread_self(), "name");])], |
| | 1002 | [ovs_cv_pthread_setname_np=glibc], |
| | 1003 | [AC_LINK_IFELSE( |
| | 1004 | [AC_LANG_PROGRAM([#include <pthread.h> |
| | 1005 | ], [pthread_setname_np(pthread_self(), "%s", "name");])], |
| | 1006 | [ovs_cv_pthread_setname_np=netbsd], |
| | 1007 | [ovs_cv_pthread_setname_np=none])])]) |
| | 1008 | case $ovs_cv_pthread_setname_np in # ( |
| | 1009 | glibc) |
| | 1010 | AC_DEFINE( |
| | 1011 | [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1], |
| | 1012 | [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).]) |
| | 1013 | ;; # ( |
| | 1014 | netbsd) |
| | 1015 | AC_DEFINE( |
| | 1016 | [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1], |
| | 1017 | [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).]) |
| | 1018 | ;; |
| | 1019 | esac |
| | 1020 | fi]) |
| | 1021 | |
| | 1022 | dnl OVS_CHECK_LINUX_HOST. |
| | 1023 | dnl |
| | 1024 | dnl Checks whether we're building for a Linux host, based on the presence of |
| | 1025 | dnl the __linux__ preprocessor symbol, and sets up an Automake conditional |
| | 1026 | dnl LINUX based on the result. |
| | 1027 | AC_DEFUN([OVS_CHECK_LINUX_HOST], |
| | 1028 | [AC_CACHE_CHECK( |
| | 1029 | [whether __linux__ is defined], |
| | 1030 | [ovs_cv_linux], |
| | 1031 | [AC_COMPILE_IFELSE( |
| | 1032 | [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])], |
| | 1033 | [ovs_cv_linux=true], |
| | 1034 | [ovs_cv_linux=false])]) |
| | 1035 | AM_CONDITIONAL([LINUX], [$ovs_cv_linux])]) |
projects / mirror_ovs.git / blame_incremental