| | 1 | /* SPDX-License-Identifier: GPL-2.0 */ |
| | 2 | #ifdef CONFIG_PPC64 |
| | 3 | #define PROVIDE32(x) PROVIDE(__unused__##x) |
| | 4 | #else |
| | 5 | #define PROVIDE32(x) PROVIDE(x) |
| | 6 | #endif |
| | 7 | |
| | 8 | #define BSS_FIRST_SECTIONS *(.bss.prominit) |
| | 9 | |
| | 10 | #include <asm/page.h> |
| | 11 | #include <asm-generic/vmlinux.lds.h> |
| | 12 | #include <asm/cache.h> |
| | 13 | #include <asm/thread_info.h> |
| | 14 | |
| | 15 | #define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT) |
| | 16 | #define ETEXT_ALIGN_SIZE (1 << CONFIG_ETEXT_SHIFT) |
| | 17 | |
| | 18 | ENTRY(_stext) |
| | 19 | |
| | 20 | PHDRS { |
| | 21 | kernel PT_LOAD FLAGS(7); /* RWX */ |
| | 22 | notes PT_NOTE FLAGS(0); |
| | 23 | dummy PT_NOTE FLAGS(0); |
| | 24 | |
| | 25 | /* binutils < 2.18 has a bug that makes it misbehave when taking an |
| | 26 | ELF file with all segments at load address 0 as input. This |
| | 27 | happens when running "strip" on vmlinux, because of the AT() magic |
| | 28 | in this linker script. People using GCC >= 4.2 won't run into |
| | 29 | this problem, because the "build-id" support will put some data |
| | 30 | into the "notes" segment (at a non-zero load address). |
| | 31 | |
| | 32 | To work around this, we force some data into both the "dummy" |
| | 33 | segment and the kernel segment, so the dummy segment will get a |
| | 34 | non-zero load address. It's not enough to always create the |
| | 35 | "notes" segment, since if nothing gets assigned to it, its load |
| | 36 | address will be zero. */ |
| | 37 | } |
| | 38 | |
| | 39 | #ifdef CONFIG_PPC64 |
| | 40 | OUTPUT_ARCH(powerpc:common64) |
| | 41 | jiffies = jiffies_64; |
| | 42 | #else |
| | 43 | OUTPUT_ARCH(powerpc:common) |
| | 44 | jiffies = jiffies_64 + 4; |
| | 45 | #endif |
| | 46 | SECTIONS |
| | 47 | { |
| | 48 | . = KERNELBASE; |
| | 49 | |
| | 50 | /* |
| | 51 | * Text, read only data and other permanent read-only sections |
| | 52 | */ |
| | 53 | |
| | 54 | _text = .; |
| | 55 | _stext = .; |
| | 56 | |
| | 57 | /* |
| | 58 | * Head text. |
| | 59 | * This needs to be in its own output section to avoid ld placing |
| | 60 | * branch trampoline stubs randomly throughout the fixed sections, |
| | 61 | * which it will do (even if the branch comes from another section) |
| | 62 | * in order to optimize stub generation. |
| | 63 | */ |
| | 64 | .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { |
| | 65 | #ifdef CONFIG_PPC64 |
| | 66 | KEEP(*(.head.text.first_256B)); |
| | 67 | #ifdef CONFIG_PPC_BOOK3E |
| | 68 | #else |
| | 69 | KEEP(*(.head.text.real_vectors)); |
| | 70 | *(.head.text.real_trampolines); |
| | 71 | KEEP(*(.head.text.virt_vectors)); |
| | 72 | *(.head.text.virt_trampolines); |
| | 73 | # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV) |
| | 74 | KEEP(*(.head.data.fwnmi_page)); |
| | 75 | # endif |
| | 76 | #endif |
| | 77 | #else /* !CONFIG_PPC64 */ |
| | 78 | HEAD_TEXT |
| | 79 | #endif |
| | 80 | } :kernel |
| | 81 | |
| | 82 | __head_end = .; |
| | 83 | |
| | 84 | #ifdef CONFIG_PPC64 |
| | 85 | /* |
| | 86 | * ALIGN(0) overrides the default output section alignment because |
| | 87 | * this needs to start right after .head.text in order for fixed |
| | 88 | * section placement to work. |
| | 89 | */ |
| | 90 | .text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) { |
| | 91 | #ifdef CONFIG_LD_HEAD_STUB_CATCH |
| | 92 | KEEP(*(.linker_stub_catch)); |
| | 93 | . = . ; |
| | 94 | #endif |
| | 95 | |
| | 96 | #else |
| | 97 | .text : AT(ADDR(.text) - LOAD_OFFSET) { |
| | 98 | ALIGN_FUNCTION(); |
| | 99 | #endif |
| | 100 | /* careful! __ftr_alt_* sections need to be close to .text */ |
| | 101 | *(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text); |
| | 102 | #ifdef CONFIG_PPC64 |
| | 103 | *(.tramp.ftrace.text); |
| | 104 | #endif |
| | 105 | NOINSTR_TEXT |
| | 106 | SCHED_TEXT |
| | 107 | CPUIDLE_TEXT |
| | 108 | LOCK_TEXT |
| | 109 | KPROBES_TEXT |
| | 110 | IRQENTRY_TEXT |
| | 111 | SOFTIRQENTRY_TEXT |
| | 112 | /* |
| | 113 | * -Os builds call FP save/restore functions. The powerpc64 |
| | 114 | * linker generates those on demand in the .sfpr section. |
| | 115 | * .sfpr gets placed at the beginning of a group of input |
| | 116 | * sections, which can break start-of-text offset if it is |
| | 117 | * included with the main text sections, so put it by itself. |
| | 118 | */ |
| | 119 | *(.sfpr); |
| | 120 | MEM_KEEP(init.text) |
| | 121 | MEM_KEEP(exit.text) |
| | 122 | |
| | 123 | #ifdef CONFIG_PPC32 |
| | 124 | *(.got1) |
| | 125 | __got2_start = .; |
| | 126 | *(.got2) |
| | 127 | __got2_end = .; |
| | 128 | #endif /* CONFIG_PPC32 */ |
| | 129 | |
| | 130 | } :kernel |
| | 131 | |
| | 132 | . = ALIGN(ETEXT_ALIGN_SIZE); |
| | 133 | _etext = .; |
| | 134 | PROVIDE32 (etext = .); |
| | 135 | |
| | 136 | /* Read-only data */ |
| | 137 | RO_DATA(PAGE_SIZE) |
| | 138 | |
| | 139 | #ifdef CONFIG_PPC64 |
| | 140 | . = ALIGN(8); |
| | 141 | __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) { |
| | 142 | __start___stf_entry_barrier_fixup = .; |
| | 143 | *(__stf_entry_barrier_fixup) |
| | 144 | __stop___stf_entry_barrier_fixup = .; |
| | 145 | } |
| | 146 | |
| | 147 | . = ALIGN(8); |
| | 148 | __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) { |
| | 149 | __start___uaccess_flush_fixup = .; |
| | 150 | *(__uaccess_flush_fixup) |
| | 151 | __stop___uaccess_flush_fixup = .; |
| | 152 | } |
| | 153 | |
| | 154 | . = ALIGN(8); |
| | 155 | __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) { |
| | 156 | __start___entry_flush_fixup = .; |
| | 157 | *(__entry_flush_fixup) |
| | 158 | __stop___entry_flush_fixup = .; |
| | 159 | } |
| | 160 | |
| | 161 | . = ALIGN(8); |
| | 162 | __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) { |
| | 163 | __start___stf_exit_barrier_fixup = .; |
| | 164 | *(__stf_exit_barrier_fixup) |
| | 165 | __stop___stf_exit_barrier_fixup = .; |
| | 166 | } |
| | 167 | |
| | 168 | . = ALIGN(8); |
| | 169 | __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) { |
| | 170 | __start___rfi_flush_fixup = .; |
| | 171 | *(__rfi_flush_fixup) |
| | 172 | __stop___rfi_flush_fixup = .; |
| | 173 | } |
| | 174 | #endif /* CONFIG_PPC64 */ |
| | 175 | |
| | 176 | #ifdef CONFIG_PPC_BARRIER_NOSPEC |
| | 177 | . = ALIGN(8); |
| | 178 | __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) { |
| | 179 | __start___barrier_nospec_fixup = .; |
| | 180 | *(__barrier_nospec_fixup) |
| | 181 | __stop___barrier_nospec_fixup = .; |
| | 182 | } |
| | 183 | #endif /* CONFIG_PPC_BARRIER_NOSPEC */ |
| | 184 | |
| | 185 | #ifdef CONFIG_PPC_FSL_BOOK3E |
| | 186 | . = ALIGN(8); |
| | 187 | __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) { |
| | 188 | __start__btb_flush_fixup = .; |
| | 189 | *(__btb_flush_fixup) |
| | 190 | __stop__btb_flush_fixup = .; |
| | 191 | } |
| | 192 | #endif |
| | 193 | EXCEPTION_TABLE(0) |
| | 194 | |
| | 195 | NOTES :kernel :notes |
| | 196 | |
| | 197 | /* The dummy segment contents for the bug workaround mentioned above |
| | 198 | near PHDRS. */ |
| | 199 | .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) { |
| | 200 | LONG(0) |
| | 201 | LONG(0) |
| | 202 | LONG(0) |
| | 203 | } :kernel :dummy |
| | 204 | |
| | 205 | /* |
| | 206 | * Init sections discarded at runtime |
| | 207 | */ |
| | 208 | . = ALIGN(STRICT_ALIGN_SIZE); |
| | 209 | __init_begin = .; |
| | 210 | . = ALIGN(PAGE_SIZE); |
| | 211 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { |
| | 212 | _sinittext = .; |
| | 213 | INIT_TEXT |
| | 214 | |
| | 215 | /* |
| | 216 | *.init.text might be RO so we must ensure this section ends on |
| | 217 | * a page boundary. |
| | 218 | */ |
| | 219 | . = ALIGN(PAGE_SIZE); |
| | 220 | _einittext = .; |
| | 221 | #ifdef CONFIG_PPC64 |
| | 222 | *(.tramp.ftrace.init); |
| | 223 | #endif |
| | 224 | } :kernel |
| | 225 | |
| | 226 | /* .exit.text is discarded at runtime, not link time, |
| | 227 | * to deal with references from __bug_table |
| | 228 | */ |
| | 229 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { |
| | 230 | EXIT_TEXT |
| | 231 | } |
| | 232 | |
| | 233 | . = ALIGN(PAGE_SIZE); |
| | 234 | |
| | 235 | INIT_DATA_SECTION(16) |
| | 236 | |
| | 237 | . = ALIGN(8); |
| | 238 | __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) { |
| | 239 | __start___ftr_fixup = .; |
| | 240 | KEEP(*(__ftr_fixup)) |
| | 241 | __stop___ftr_fixup = .; |
| | 242 | } |
| | 243 | . = ALIGN(8); |
| | 244 | __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) { |
| | 245 | __start___mmu_ftr_fixup = .; |
| | 246 | KEEP(*(__mmu_ftr_fixup)) |
| | 247 | __stop___mmu_ftr_fixup = .; |
| | 248 | } |
| | 249 | . = ALIGN(8); |
| | 250 | __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) { |
| | 251 | __start___lwsync_fixup = .; |
| | 252 | KEEP(*(__lwsync_fixup)) |
| | 253 | __stop___lwsync_fixup = .; |
| | 254 | } |
| | 255 | #ifdef CONFIG_PPC64 |
| | 256 | . = ALIGN(8); |
| | 257 | __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) { |
| | 258 | __start___fw_ftr_fixup = .; |
| | 259 | KEEP(*(__fw_ftr_fixup)) |
| | 260 | __stop___fw_ftr_fixup = .; |
| | 261 | } |
| | 262 | #endif |
| | 263 | |
| | 264 | PERCPU_SECTION(L1_CACHE_BYTES) |
| | 265 | |
| | 266 | . = ALIGN(8); |
| | 267 | .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) { |
| | 268 | __machine_desc_start = . ; |
| | 269 | KEEP(*(.machine.desc)) |
| | 270 | __machine_desc_end = . ; |
| | 271 | } |
| | 272 | #ifdef CONFIG_RELOCATABLE |
| | 273 | . = ALIGN(8); |
| | 274 | .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET) |
| | 275 | { |
| | 276 | #ifdef CONFIG_PPC32 |
| | 277 | __dynamic_symtab = .; |
| | 278 | #endif |
| | 279 | *(.dynsym) |
| | 280 | } |
| | 281 | .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) } |
| | 282 | .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET) |
| | 283 | { |
| | 284 | __dynamic_start = .; |
| | 285 | *(.dynamic) |
| | 286 | } |
| | 287 | .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) } |
| | 288 | .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) } |
| | 289 | .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET) |
| | 290 | { |
| | 291 | __rela_dyn_start = .; |
| | 292 | *(.rela*) |
| | 293 | } |
| | 294 | #endif |
| | 295 | /* .exit.data is discarded at runtime, not link time, |
| | 296 | * to deal with references from .exit.text |
| | 297 | */ |
| | 298 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { |
| | 299 | EXIT_DATA |
| | 300 | } |
| | 301 | |
| | 302 | /* freed after init ends here */ |
| | 303 | . = ALIGN(PAGE_SIZE); |
| | 304 | __init_end = .; |
| | 305 | |
| | 306 | /* |
| | 307 | * And now the various read/write data |
| | 308 | */ |
| | 309 | |
| | 310 | . = ALIGN(PAGE_SIZE); |
| | 311 | _sdata = .; |
| | 312 | |
| | 313 | #ifdef CONFIG_PPC32 |
| | 314 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
| | 315 | DATA_DATA |
| | 316 | #ifdef CONFIG_UBSAN |
| | 317 | *(.data..Lubsan_data*) |
| | 318 | *(.data..Lubsan_type*) |
| | 319 | #endif |
| | 320 | *(.data.rel*) |
| | 321 | *(SDATA_MAIN) |
| | 322 | *(.sdata2) |
| | 323 | *(.got.plt) *(.got) |
| | 324 | *(.plt) |
| | 325 | *(.branch_lt) |
| | 326 | } |
| | 327 | #else |
| | 328 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
| | 329 | DATA_DATA |
| | 330 | *(.data.rel*) |
| | 331 | *(.toc1) |
| | 332 | *(.branch_lt) |
| | 333 | } |
| | 334 | |
| | 335 | .opd : AT(ADDR(.opd) - LOAD_OFFSET) { |
| | 336 | __start_opd = .; |
| | 337 | KEEP(*(.opd)) |
| | 338 | __end_opd = .; |
| | 339 | } |
| | 340 | |
| | 341 | . = ALIGN(256); |
| | 342 | .got : AT(ADDR(.got) - LOAD_OFFSET) { |
| | 343 | __toc_start = .; |
| | 344 | #ifndef CONFIG_RELOCATABLE |
| | 345 | __prom_init_toc_start = .; |
| | 346 | arch/powerpc/kernel/prom_init.o*(.toc .got) |
| | 347 | __prom_init_toc_end = .; |
| | 348 | #endif |
| | 349 | *(.got) |
| | 350 | *(.toc) |
| | 351 | } |
| | 352 | #endif |
| | 353 | |
| | 354 | /* The initial task and kernel stack */ |
| | 355 | INIT_TASK_DATA_SECTION(THREAD_SIZE) |
| | 356 | |
| | 357 | .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) { |
| | 358 | PAGE_ALIGNED_DATA(PAGE_SIZE) |
| | 359 | } |
| | 360 | |
| | 361 | .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) { |
| | 362 | CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES) |
| | 363 | } |
| | 364 | |
| | 365 | .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) { |
| | 366 | READ_MOSTLY_DATA(L1_CACHE_BYTES) |
| | 367 | } |
| | 368 | |
| | 369 | . = ALIGN(PAGE_SIZE); |
| | 370 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { |
| | 371 | NOSAVE_DATA |
| | 372 | } |
| | 373 | |
| | 374 | BUG_TABLE |
| | 375 | |
| | 376 | . = ALIGN(PAGE_SIZE); |
| | 377 | _edata = .; |
| | 378 | PROVIDE32 (edata = .); |
| | 379 | |
| | 380 | /* |
| | 381 | * And finally the bss |
| | 382 | */ |
| | 383 | |
| | 384 | BSS_SECTION(0, 0, 0) |
| | 385 | |
| | 386 | . = ALIGN(PAGE_SIZE); |
| | 387 | _end = . ; |
| | 388 | PROVIDE32 (end = .); |
| | 389 | |
| | 390 | STABS_DEBUG |
| | 391 | |
| | 392 | DWARF_DEBUG |
| | 393 | |
| | 394 | DISCARDS |
| | 395 | /DISCARD/ : { |
| | 396 | *(*.EMB.apuinfo) |
| | 397 | *(.glink .iplt .plt .rela* .comment) |
| | 398 | *(.gnu.version*) |
| | 399 | *(.gnu.attributes) |
| | 400 | *(.eh_frame) |
| | 401 | } |
| | 402 | } |
projects / mirror_ubuntu-focal-kernel.git / blame_incremental