]>
Commit | Line | Data |
---|---|---|
1 | ## | |
2 | ## Configure template file for FRRouting. | |
3 | ## autoconf will generate a configure script. | |
4 | ## | |
5 | ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org> | |
6 | ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st> | |
7 | ## | |
8 | AC_PREREQ([2.69]) | |
9 | ||
10 | AC_INIT([frr], [9.0-dev], [https://github.com/frrouting/frr/issues]) | |
11 | PACKAGE_URL="https://frrouting.org/" | |
12 | AC_SUBST([PACKAGE_URL]) | |
13 | PACKAGE_FULLNAME="FRRouting" | |
14 | AC_SUBST([PACKAGE_FULLNAME]) | |
15 | ||
16 | CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`" | |
17 | AC_SUBST([CONFIG_ARGS]) | |
18 | ||
19 | AC_CONFIG_SRCDIR([lib/zebra.h]) | |
20 | AC_CONFIG_MACRO_DIR([m4]) | |
21 | AC_CONFIG_AUX_DIR([m4/ac]) | |
22 | ||
23 | dnl ----------------------------------- | |
24 | dnl Get hostname and other information. | |
25 | dnl ----------------------------------- | |
26 | AC_CANONICAL_BUILD() | |
27 | AC_CANONICAL_HOST() | |
28 | ||
29 | AC_ARG_VAR([AR],[archiver command]) | |
30 | AC_ARG_VAR([LD],[linker command]) | |
31 | AC_ARG_VAR([OBJCOPY],[objcopy command]) | |
32 | AC_ARG_VAR([OBJDUMP],[objdump command]) | |
33 | AC_ARG_VAR([RANLIB],[ranlib command]) | |
34 | AC_ARG_VAR([STRIP],[strip command]) | |
35 | ||
36 | hosttools_clippy="false" | |
37 | build_clippy="true" | |
38 | ||
39 | dnl case 1: external clippy | |
40 | if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then | |
41 | if test "$enable_clippy_only" = "yes"; then | |
42 | AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy]) | |
43 | fi | |
44 | ||
45 | CLIPPY="$with_clippy" | |
46 | build_clippy="false" | |
47 | if test ! -x "$with_clippy"; then | |
48 | AC_MSG_ERROR([clippy tool ($with_clippy) is not executable]) | |
49 | fi | |
50 | ||
51 | dnl case 2: cross-compiling internal clippy | |
52 | elif test "$host" != "$build"; then | |
53 | if test "$srcdir" = "."; then | |
54 | AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option. create a separate directory and run as .../path-to-frr/configure.]) | |
55 | fi | |
56 | test -d hosttools || mkdir hosttools | |
57 | abssrc="`cd \"${srcdir}\"; pwd`" | |
58 | ||
59 | AC_MSG_NOTICE([...]) | |
60 | AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools]) | |
61 | AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary]) | |
62 | AC_MSG_NOTICE([...]) | |
63 | ||
64 | ( | |
65 | for var in $ac_precious_vars; do | |
66 | dnl special cases | |
67 | case "$var" in | |
68 | YACC|YFLAGS) continue;; | |
69 | PYTHON*) retain=true;; | |
70 | *) retain=false; | |
71 | esac | |
72 | ||
73 | eval "hostvar=\"\${HOST_$var}\"" | |
74 | eval "targetvar=\"\${$var}\"" | |
75 | if test -n "$hostvar"; then | |
76 | eval "$var='$hostvar'" | |
77 | _AS_ECHO_LOG([host $var='$hostvar']) | |
78 | elif $retain; then | |
79 | _AS_ECHO_LOG([host retain $var='$targetvar']) | |
80 | else | |
81 | eval "unset $var" | |
82 | _AS_ECHO_LOG([host unset $var]) | |
83 | fi | |
84 | done | |
85 | cd hosttools | |
86 | "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh" | |
87 | ) || exit 1 | |
88 | ||
89 | AC_MSG_NOTICE([...]) | |
90 | AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools]) | |
91 | AC_MSG_NOTICE([...]) | |
92 | ||
93 | build_clippy="false" | |
94 | hosttools_clippy="true" | |
95 | CLIPPY="hosttools/lib/clippy" | |
96 | ||
97 | dnl case 3: normal build internal clippy | |
98 | else | |
99 | CLIPPY="lib/clippy\$(EXEEXT)" | |
100 | fi | |
101 | AC_SUBST([CLIPPY]) | |
102 | AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy]) | |
103 | AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy]) | |
104 | AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"]) | |
105 | ||
106 | # Disable portability warnings -- our automake code (in particular | |
107 | # common.am) uses some constructs specific to gmake. | |
108 | AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign]) | |
109 | m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])]) | |
110 | AM_SILENT_RULES([yes]) | |
111 | AC_CONFIG_HEADERS([config.h]) | |
112 | ||
113 | AC_PATH_PROG([PERL], [perl]) | |
114 | PKG_PROG_PKG_CONFIG | |
115 | ||
116 | dnl default is to match previous behavior | |
117 | pkgsrcrcdir="" | |
118 | AC_ARG_ENABLE([pkgsrcrcdir], | |
119 | AS_HELP_STRING([--enable-pkgsrcrcdir], | |
120 | [specify directory for rc.d scripts]), | |
121 | pkgsrcrcdir="$enableval",) | |
122 | dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow | |
123 | AC_SUBST([pkgsrcrcdir]) | |
124 | AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""]) | |
125 | ||
126 | AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [ | |
127 | moduledir="$withval" | |
128 | ], [ | |
129 | moduledir="\${libdir}/frr/modules" | |
130 | ]) | |
131 | AC_SUBST([moduledir], [$moduledir]) | |
132 | ||
133 | AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [ | |
134 | scriptdir="$withval" | |
135 | ], [ | |
136 | scriptdir="\${sysconfdir}/scripts" | |
137 | ]) | |
138 | AC_SUBST([scriptdir], [$scriptdir]) | |
139 | ||
140 | AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [ | |
141 | yangmodelsdir="$withval" | |
142 | ], [ | |
143 | yangmodelsdir="\${datarootdir}/yang" | |
144 | ]) | |
145 | AC_SUBST([yangmodelsdir]) | |
146 | ||
147 | AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [ | |
148 | vici_socket="$withval" | |
149 | ], [ | |
150 | vici_socket="/var/run/charon.vici" | |
151 | ]) | |
152 | AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path]) | |
153 | ||
154 | AC_ARG_ENABLE(tcmalloc, | |
155 | AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]), | |
156 | [case "${enableval}" in | |
157 | yes) tcmalloc_enabled=true | |
158 | LIBS="$LIBS -ltcmalloc_minimal" | |
159 | ;; | |
160 | no) tcmalloc_enabled=false ;; | |
161 | *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;; | |
162 | esac],[tcmalloc_enabled=false]) | |
163 | ||
164 | ||
165 | dnl Thanks autoconf, but we don't want a default -g -O2. We have our own | |
166 | dnl flag determination logic. | |
167 | CFLAGS="${CFLAGS:-}" | |
168 | ||
169 | dnl -------------------- | |
170 | dnl Check CC and friends | |
171 | dnl -------------------- | |
172 | dnl note orig_cflags is also used further down | |
173 | orig_cflags="$CFLAGS" | |
174 | orig_cxxflags="$CXXFLAGS" | |
175 | AC_LANG([C]) | |
176 | AC_PROG_CC | |
177 | AC_PROG_CPP | |
178 | AC_PROG_CXX | |
179 | AM_PROG_CC_C_O | |
180 | dnl remove autoconf default "-g -O2" | |
181 | CFLAGS="$orig_cflags" | |
182 | CXXFLAGS="$orig_cxxflags" | |
183 | ||
184 | dnl Some special handling for ICC later on | |
185 | if test "$CC" = "icc"; then | |
186 | cc_is_icc="yes" | |
187 | fi | |
188 | ||
189 | PKG_PROG_PKG_CONFIG | |
190 | ||
191 | dnl it's 2019, sed is sed. | |
192 | SED=sed | |
193 | AC_SUBST([SED]) | |
194 | ||
195 | dnl try and enable CFLAGS that are useful for FRR | |
196 | dnl - specifically, options to control warnings | |
197 | ||
198 | AC_SUBST([AC_CFLAGS]) | |
199 | AC_USE_SYSTEM_EXTENSIONS | |
200 | AC_DEFUN([AC_C_FLAG], [{ | |
201 | m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])]) | |
202 | AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [ | |
203 | AC_LANG_PUSH([C]) | |
204 | ac_c_flag_save="$CFLAGS" | |
205 | CFLAGS="$CFLAGS $1" | |
206 | AC_COMPILE_IFELSE( | |
207 | [AC_LANG_PROGRAM([[$4]])], | |
208 | [ | |
209 | cachename=yes | |
210 | ], [ | |
211 | cachename=no | |
212 | ]) | |
213 | CFLAGS="$ac_c_flag_save" | |
214 | AC_LANG_POP([C]) | |
215 | ]) | |
216 | if test "$cachename" = "yes"; then | |
217 | m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3]) | |
218 | else | |
219 | : | |
220 | $2 | |
221 | fi | |
222 | m4_popdef([cachename]) | |
223 | }]) | |
224 | ||
225 | AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{ | |
226 | AC_LANG_PUSH([C]) | |
227 | ac_cflags_save="$CFLAGS" | |
228 | ac_libs_save="$LIBS" | |
229 | CFLAGS="$CFLAGS $1" | |
230 | LIBS="$LIBS $2" | |
231 | AC_LINK_IFELSE( | |
232 | [$3], | |
233 | [ | |
234 | CFLAGS="$ac_cflags_save" | |
235 | LIBS="$ac_libs_save" | |
236 | m4_default([$5], [ | |
237 | AC_MSG_RESULT([yes]) | |
238 | ]) | |
239 | ], [ | |
240 | CFLAGS="$ac_cflags_save" | |
241 | LIBS="$ac_libs_save" | |
242 | m4_default([$4], [ | |
243 | AC_MSG_RESULT([no]) | |
244 | ]) | |
245 | ]) | |
246 | AC_LANG_POP([C]) | |
247 | }]) | |
248 | ||
249 | dnl ICC won't bail on unknown options without -diag-error 10006 | |
250 | dnl need to do this first so we get useful results for the other options | |
251 | if test "$cc_is_icc" = "yes"; then | |
252 | AC_C_FLAG([-diag-error 10006]) | |
253 | fi | |
254 | ||
255 | dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art" | |
256 | dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11 | |
257 | m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl | |
258 | dnl autoconf < 2.70 | |
259 | AC_PROG_CC_C99 | |
260 | ||
261 | dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something | |
262 | ac_cc="$CC" | |
263 | CC="${CC% -std=gnu99}" | |
264 | CC="${CC% -std=c99}" | |
265 | ||
266 | AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"]) | |
267 | ], [ | |
268 | dnl autoconf >= 2.70 | |
269 | if test "$ac_cv_prog_cc_c11" = "no"; then | |
270 | AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.]) | |
271 | fi | |
272 | ]) | |
273 | ||
274 | dnl if the user has specified any CFLAGS, override our settings | |
275 | if test "$enable_gcov" = "yes"; then | |
276 | if test "$orig_cflags" = ""; then | |
277 | AC_C_FLAG([--coverage]) | |
278 | AC_C_FLAG([-O0]) | |
279 | fi | |
280 | ||
281 | AC_LDFLAGS="${AC_LDFLAGS} --coverage" | |
282 | fi | |
283 | ||
284 | if test "$enable_clang_coverage" = "yes"; then | |
285 | AC_C_FLAG([-fprofile-instr-generate], [ | |
286 | AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.]) | |
287 | ]) | |
288 | AC_C_FLAG([-fcoverage-mapping], [ | |
289 | AC_MSG_ERROR([$CC does not support -fcoverage-mapping.]) | |
290 | ]) | |
291 | fi | |
292 | ||
293 | AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"]) | |
294 | ||
295 | if test "$enable_scripting" = "yes"; then | |
296 | AX_PROG_LUA([5.3], [5.4], [], [ | |
297 | AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.]) | |
298 | ]) | |
299 | AX_LUA_HEADERS([], [ | |
300 | AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.]) | |
301 | ]) | |
302 | PKG_CHECK_MODULES([LUA], [lua5.3], [ | |
303 | AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting]) | |
304 | LIBS="$LIBS $LUA_LIBS" | |
305 | SCRIPTING=true | |
306 | ], [ | |
307 | AX_LUA_LIBS([ | |
308 | AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting]) | |
309 | LIBS="$LIBS $LUA_LIB" | |
310 | SCRIPTING=true | |
311 | ], [ | |
312 | SCRIPTING=false | |
313 | AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.]) | |
314 | ]) | |
315 | ]) | |
316 | fi | |
317 | ||
318 | dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make | |
319 | dnl sense to be overridden by the user | |
320 | if test "$enable_dev_build" = "yes"; then | |
321 | AC_DEFINE([DEV_BUILD], [1], [Build for development]) | |
322 | if test "$orig_cflags" = ""; then | |
323 | AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"]) | |
324 | AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"]) | |
325 | AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"]) | |
326 | fi | |
327 | else | |
328 | if test "$orig_cflags" = ""; then | |
329 | AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"]) | |
330 | AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"]) | |
331 | fi | |
332 | fi | |
333 | ||
334 | dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much | |
335 | LDFLAGS="$LDFLAGS -g" | |
336 | ||
337 | AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"]) | |
338 | ||
339 | dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD, | |
340 | dnl which just straight up breaks compiling any code. | |
341 | dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0) | |
342 | AH_VERBATIM([OpenBSD], [ | |
343 | #ifdef __OpenBSD__ | |
344 | #define __wchar_t __wchar_t_ignore | |
345 | #include <stdint.h> | |
346 | #undef __wchar_t | |
347 | #endif | |
348 | ]) | |
349 | ||
350 | dnl always want these CFLAGS | |
351 | AC_C_FLAG([-fms-extensions], [ | |
352 | AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)]) | |
353 | ]) | |
354 | AC_C_FLAG([-fno-omit-frame-pointer]) | |
355 | AC_C_FLAG([-funwind-tables]) | |
356 | AC_C_FLAG([-Wall]) | |
357 | AC_C_FLAG([-Wextra]) | |
358 | AC_C_FLAG([-Wformat-nonliteral]) | |
359 | AC_C_FLAG([-Wformat-security]) | |
360 | AC_C_FLAG([-Wswitch-enum]) | |
361 | AC_C_FLAG([-Wstrict-prototypes]) | |
362 | AC_C_FLAG([-Wmissing-prototypes]) | |
363 | AC_C_FLAG([-Wmissing-declarations]) | |
364 | AC_C_FLAG([-Wpointer-arith]) | |
365 | AC_C_FLAG([-Wbad-function-cast]) | |
366 | AC_C_FLAG([-Wwrite-strings]) | |
367 | AC_C_FLAG([-Wundef]) | |
368 | if test "$enable_gcc_ultra_verbose" = "yes" ; then | |
369 | AC_C_FLAG([-Wcast-qual]) | |
370 | AC_C_FLAG([-Wmissing-noreturn]) | |
371 | AC_C_FLAG([-Wmissing-format-attribute]) | |
372 | AC_C_FLAG([-Wunreachable-code]) | |
373 | AC_C_FLAG([-Wpacked]) | |
374 | AC_C_FLAG([-Wpadded]) | |
375 | AC_C_FLAG([-Wshadow]) | |
376 | else | |
377 | AC_C_FLAG([-Wno-unused-result]) | |
378 | fi | |
379 | AC_C_FLAG([-Wno-unused-parameter]) | |
380 | AC_C_FLAG([-Wno-missing-field-initializers]) | |
381 | ||
382 | AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"]) | |
383 | AC_SUBST([CXX_COMPAT_CFLAGS]) | |
384 | ||
385 | dnl ICC emits a broken warning for const char *x = a ? "b" : "c"; | |
386 | dnl for some reason the string consts get 'promoted' to char *, | |
387 | dnl triggering a const to non-const conversion warning. | |
388 | if test "$cc_is_icc" = "yes"; then | |
389 | AC_C_FLAG([-diag-disable 3179]) | |
390 | fi | |
391 | ||
392 | if test "$enable_werror" = "yes" ; then | |
393 | WERROR="-Werror" | |
394 | fi | |
395 | AC_SUBST([WERROR]) | |
396 | ||
397 | SAN_FLAGS="" | |
398 | if test "$enable_address_sanitizer" = "yes"; then | |
399 | AC_C_FLAG([-fsanitize=address], [ | |
400 | AC_MSG_ERROR([$CC does not support Address Sanitizer.]) | |
401 | ], [ | |
402 | SAN_FLAGS="$SAN_FLAGS -fsanitize=address" | |
403 | ]) | |
404 | fi | |
405 | if test "$enable_thread_sanitizer" = "yes"; then | |
406 | AC_C_FLAG([-fsanitize=thread], [ | |
407 | AC_MSG_ERROR([$CC does not support Thread Sanitizer.]) | |
408 | ], [ | |
409 | SAN_FLAGS="$SAN_FLAGS -fsanitize=thread" | |
410 | ]) | |
411 | fi | |
412 | if test "$enable_memory_sanitizer" = "yes"; then | |
413 | AC_C_FLAG([-fsanitize=memory -fPIE -pie], [ | |
414 | AC_MSG_ERROR([$CC does not support Memory Sanitizer.]) | |
415 | ], [ | |
416 | SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie" | |
417 | ]) | |
418 | fi | |
419 | if test "$enable_undefined_sanitizer" = "yes"; then | |
420 | AC_C_FLAG([-fsanitize=undefined], [ | |
421 | AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.]) | |
422 | ], [ | |
423 | SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined" | |
424 | ]) | |
425 | fi | |
426 | AC_SUBST([SAN_FLAGS]) | |
427 | ||
428 | dnl frr-format.so | |
429 | if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then | |
430 | AC_C_FLAG([-fplugin=${with_frr_format}], [ | |
431 | AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work]) | |
432 | ],,[ | |
433 | #ifndef _FRR_ATTRIBUTE_PRINTFRR | |
434 | #error plugin not loaded | |
435 | #endif | |
436 | #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000 | |
437 | #error plugin too old | |
438 | #endif | |
439 | ]) | |
440 | elif test "$with_frr_format" = "no"; then | |
441 | : #nothing | |
442 | else | |
443 | AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[ | |
444 | AC_C_FLAG([-fplugin=frr-format],[ | |
445 | if test "$with_frr_format" = "yes"; then | |
446 | AC_MSG_ERROR([frr-format plugin requested but not found]) | |
447 | fi | |
448 | ],,[ | |
449 | #ifndef _FRR_ATTRIBUTE_PRINTFRR | |
450 | #error plugin not loaded | |
451 | #endif | |
452 | #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000 | |
453 | #error plugin too old | |
454 | #endif | |
455 | ]) | |
456 | ],,[ | |
457 | #ifndef _FRR_ATTRIBUTE_PRINTFRR | |
458 | #error plugin not loaded | |
459 | #endif | |
460 | #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000 | |
461 | #error plugin too old | |
462 | #endif | |
463 | ]) | |
464 | fi | |
465 | ||
466 | AC_MSG_CHECKING([whether linker supports __start/stop_section symbols]) | |
467 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[ | |
468 | #include <stdio.h> | |
469 | int __attribute__((section("secttest"))) var = 1; | |
470 | extern int __start_secttest, __stop_secttest; | |
471 | ]], [[ | |
472 | void *a = &var, *b = &__start_secttest, *c = &__stop_secttest; | |
473 | printf("%p %p %p\n", a, b, c); | |
474 | ]])], [ | |
475 | AC_MSG_RESULT(yes) | |
476 | AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols]) | |
477 | ], [ | |
478 | AC_MSG_RESULT(no) | |
479 | ]) | |
480 | ||
481 | dnl ---------- | |
482 | dnl Essentials | |
483 | dnl ---------- | |
484 | ||
485 | AX_PTHREAD([ | |
486 | CC="$PTHREAD_CC" | |
487 | AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS" | |
488 | LIBS="$PTHREAD_LIBS $LIBS" | |
489 | ], [ | |
490 | AC_MSG_FAILURE([This FRR version needs pthreads]) | |
491 | ]) | |
492 | ||
493 | orig_cflags="$CFLAGS" | |
494 | CFLAGS="$CFLAGS $PTHREAD_CFLAGS" | |
495 | ||
496 | AC_SEARCH_LIBS([pthread_condattr_setclock], [], | |
497 | [frr_cv_pthread_condattr_setclock=yes], | |
498 | [frr_cv_pthread_condattr_setclock=no]) | |
499 | if test "$frr_cv_pthread_condattr_setclock" = "yes"; then | |
500 | AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock]) | |
501 | fi | |
502 | ||
503 | AC_CHECK_HEADERS([pthread_np.h],,, [ | |
504 | #include <pthread.h> | |
505 | ]) | |
506 | AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np]) | |
507 | ||
508 | CFLAGS="$orig_cflags" | |
509 | ||
510 | dnl -------------- | |
511 | dnl Check programs | |
512 | dnl -------------- | |
513 | AC_PROG_INSTALL | |
514 | AC_PROG_LN_S | |
515 | AC_CHECK_TOOL([AR], [ar]) | |
516 | ||
517 | dnl ------- | |
518 | dnl libtool | |
519 | dnl ------- | |
520 | AC_ARG_ENABLE([static-bin], | |
521 | AS_HELP_STRING([--enable-static-bin], [link binaries statically])) | |
522 | LT_INIT | |
523 | _LT_CONFIG_LIBTOOL([ | |
524 | patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \ | |
525 | AC_MSG_WARN([Could not patch libtool for static linking support. Loading modules into a statically linked daemon will fail.]) | |
526 | dnl the -i option is not POSIX sed and the BSDs implement it differently | |
527 | dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact | |
528 | sed -e 's%func_warning "relinking%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool | |
529 | sed -e 's%func_warning "remember to run%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool | |
530 | sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool | |
531 | test -f libtool.sed && rm libtool.sed | |
532 | ]) | |
533 | if test "$enable_static_bin" = "yes"; then | |
534 | AC_LDFLAGS_EXEC="-static" | |
535 | if test "$enable_static" != "yes"; then | |
536 | AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.]) | |
537 | fi | |
538 | fi | |
539 | if test "$enable_shared" != "yes"; then | |
540 | AC_MSG_ERROR([FRR cannot be built with --disable-shared. If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin]) | |
541 | fi | |
542 | AC_SUBST([AC_LDFLAGS]) | |
543 | AC_SUBST([AC_LDFLAGS_EXEC]) | |
544 | AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"]) | |
545 | ||
546 | dnl libtool, the repository of all knowledge related linkers, is too stupid to | |
547 | dnl correctly tell the linker how to build modules. | |
548 | if test -z "$module_cmds"; then | |
549 | module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`" | |
550 | fi | |
551 | if test -z "$module_expsym_cmds"; then | |
552 | module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`" | |
553 | fi | |
554 | ||
555 | AC_ARG_ENABLE([rpath], | |
556 | [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])], | |
557 | [], | |
558 | [enable_rpath=yes]) | |
559 | ||
560 | dnl $AR and $RANLIB are set by LT_INIT above | |
561 | AC_MSG_CHECKING([whether $AR supports D option]) | |
562 | if $AR crD conftest.a >/dev/null 2>/dev/null; then | |
563 | AC_MSG_RESULT([yes]) | |
564 | dnl ARFLAGS is for automake, AR_FLAGS for libtool m-( | |
565 | ARFLAGS="crD" | |
566 | AR_FLAGS="crD" | |
567 | else | |
568 | AC_MSG_RESULT([no]) | |
569 | ARFLAGS="cru" | |
570 | AR_FLAGS="cru" | |
571 | fi | |
572 | AC_SUBST([ARFLAGS]) | |
573 | AC_SUBST([AR_FLAGS]) | |
574 | ||
575 | AC_MSG_CHECKING([whether $RANLIB supports D option]) | |
576 | if $RANLIB -D conftest.a >conftest.err 2>&1; then | |
577 | if grep -q -- '-D' conftest.err; then | |
578 | AC_MSG_RESULT([no]) | |
579 | else | |
580 | AC_MSG_RESULT([yes]) | |
581 | RANLIB="$RANLIB -D" | |
582 | fi | |
583 | else | |
584 | AC_MSG_RESULT([no]) | |
585 | fi | |
586 | AC_SUBST([RANLIB]) | |
587 | ||
588 | test -f conftest.err && rm conftest.err | |
589 | test -f conftest.a && rm conftest.a | |
590 | ||
591 | dnl ---------------------- | |
592 | dnl Packages configuration | |
593 | dnl ---------------------- | |
594 | if test -f config.version; then | |
595 | . ./config.version | |
596 | elif test -f "${srcdir}/config.version"; then | |
597 | . "${srcdir}/config.version" | |
598 | fi | |
599 | AC_ARG_WITH([pkg-extra-version], | |
600 | AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [ | |
601 | if test "$withval" = "no"; then | |
602 | EXTRAVERSION= | |
603 | else | |
604 | EXTRAVERSION=$withval | |
605 | fi | |
606 | ], []) | |
607 | AC_ARG_WITH([pkg-git-version], | |
608 | AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]), | |
609 | [ test "$withval" != "no" && with_pkg_git_version="yes" ]) | |
610 | AC_ARG_WITH([clippy], | |
611 | AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program])) | |
612 | AC_ARG_WITH([vtysh_pager], | |
613 | AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]), | |
614 | VTYSH_PAGER=$withval, VTYSH_PAGER="more") | |
615 | AC_ARG_ENABLE([vtysh], | |
616 | AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR])) | |
617 | AC_ARG_ENABLE([doc], | |
618 | AS_HELP_STRING([--disable-doc], [do not build docs])) | |
619 | AC_ARG_ENABLE([doc-html], | |
620 | AS_HELP_STRING([--enable-doc-html], [build HTML docs])) | |
621 | AC_ARG_ENABLE([zebra], | |
622 | AS_HELP_STRING([--disable-zebra], [do not build zebra daemon])) | |
623 | AC_ARG_ENABLE([bgpd], | |
624 | AS_HELP_STRING([--disable-bgpd], [do not build bgpd])) | |
625 | AC_ARG_ENABLE([mgmtd], | |
626 | AS_HELP_STRING([--disable-mgmtd], [do not build mgmtd])) | |
627 | AC_ARG_ENABLE([mgmtd_local_validations], | |
628 | AS_HELP_STRING([--enable-mgmtd-local-validations], [dev: unimplemented local validation])) | |
629 | AC_ARG_ENABLE([ripd], | |
630 | AS_HELP_STRING([--disable-ripd], [do not build ripd])) | |
631 | AC_ARG_ENABLE([ripngd], | |
632 | AS_HELP_STRING([--disable-ripngd], [do not build ripngd])) | |
633 | AC_ARG_ENABLE([ospfd], | |
634 | AS_HELP_STRING([--disable-ospfd], [do not build ospfd])) | |
635 | AC_ARG_ENABLE([ospf6d], | |
636 | AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d])) | |
637 | AC_ARG_ENABLE([ldpd], | |
638 | AS_HELP_STRING([--disable-ldpd], [do not build ldpd])) | |
639 | AC_ARG_ENABLE([nhrpd], | |
640 | AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd])) | |
641 | AC_ARG_ENABLE([eigrpd], | |
642 | AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd])) | |
643 | AC_ARG_ENABLE([babeld], | |
644 | AS_HELP_STRING([--disable-babeld], [do not build babeld])) | |
645 | AC_ARG_ENABLE([watchfrr], | |
646 | AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr])) | |
647 | AC_ARG_ENABLE([isisd], | |
648 | AS_HELP_STRING([--disable-isisd], [do not build isisd])) | |
649 | AC_ARG_ENABLE([pimd], | |
650 | AS_HELP_STRING([--disable-pimd], [do not build pimd])) | |
651 | AC_ARG_ENABLE([pim6d], | |
652 | AS_HELP_STRING([--disable-pim6d], [do not build pim6d])) | |
653 | AC_ARG_ENABLE([pbrd], | |
654 | AS_HELP_STRING([--disable-pbrd], [do not build pbrd])) | |
655 | AC_ARG_ENABLE([sharpd], | |
656 | AS_HELP_STRING([--enable-sharpd], [build sharpd])) | |
657 | AC_ARG_ENABLE([staticd], | |
658 | AS_HELP_STRING([--disable-staticd], [do not build staticd])) | |
659 | AC_ARG_ENABLE([fabricd], | |
660 | AS_HELP_STRING([--disable-fabricd], [do not build fabricd])) | |
661 | AC_ARG_ENABLE([vrrpd], | |
662 | AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd])) | |
663 | AC_ARG_ENABLE([pathd], | |
664 | AS_HELP_STRING([--disable-pathd], [do not build pathd])) | |
665 | AC_ARG_ENABLE([bgp-announce], | |
666 | AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement])) | |
667 | AC_ARG_ENABLE([bgp-vnc], | |
668 | AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support])) | |
669 | AC_ARG_ENABLE([bgp-bmp], | |
670 | AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support])) | |
671 | AC_ARG_ENABLE([snmp], | |
672 | AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx])) | |
673 | AC_ARG_ENABLE([config_rollbacks], | |
674 | AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)])) | |
675 | AC_ARG_ENABLE([confd], | |
676 | AS_HELP_STRING([--enable-confd=ARG], [enable confd integration])) | |
677 | AC_ARG_ENABLE([sysrepo], | |
678 | AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration])) | |
679 | AC_ARG_ENABLE([grpc], | |
680 | AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin])) | |
681 | AC_ARG_ENABLE([zeromq], | |
682 | AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)])) | |
683 | AC_ARG_ENABLE([lttng], | |
684 | AS_HELP_STRING([--enable-lttng], [enable LTTng tracing])) | |
685 | AC_ARG_ENABLE([usdt], | |
686 | AS_HELP_STRING([--enable-usdt], [enable USDT probes])) | |
687 | AC_ARG_WITH([libpam], | |
688 | AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh])) | |
689 | AC_ARG_ENABLE([ospfapi], | |
690 | AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database])) | |
691 | AC_ARG_ENABLE([ospfclient], | |
692 | AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI, | |
693 | (this is the default if --disable-ospfapi is set)])) | |
694 | AC_ARG_WITH([log_timestamp_precision], | |
695 | AS_HELP_STRING([--with-log-timestamp-precision=ARG], [set startup log timestamp precision, ARG must be 0-12])) | |
696 | AC_ARG_ENABLE([multipath], | |
697 | AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit])) | |
698 | AC_ARG_WITH([service_timeout], | |
699 | AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit])) | |
700 | AC_ARG_ENABLE([user], | |
701 | AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)])) | |
702 | AC_ARG_ENABLE([group], | |
703 | AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)])) | |
704 | AC_ARG_ENABLE([vty_group], | |
705 | AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner])) | |
706 | AC_ARG_ENABLE([configfile_mask], | |
707 | AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files])) | |
708 | AC_ARG_ENABLE([logfile_mask], | |
709 | AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files])) | |
710 | AC_ARG_ENABLE([shell_access], | |
711 | AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh])) | |
712 | AC_ARG_ENABLE([realms], | |
713 | AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux])) | |
714 | AC_ARG_ENABLE([rtadv], | |
715 | AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature])) | |
716 | AC_ARG_ENABLE([irdp], | |
717 | AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)])) | |
718 | AC_ARG_ENABLE([capabilities], | |
719 | AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities])) | |
720 | AC_ARG_ENABLE([gcc_ultra_verbose], | |
721 | AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings])) | |
722 | AC_ARG_ENABLE([backtrace], | |
723 | AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)])) | |
724 | AC_ARG_ENABLE([time-check], | |
725 | AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages])) | |
726 | AC_ARG_ENABLE([cpu-time], | |
727 | AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering])) | |
728 | AC_ARG_ENABLE([pcreposix], | |
729 | AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions])) | |
730 | AC_ARG_ENABLE([pcre2posix], | |
731 | AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions])) | |
732 | AC_ARG_ENABLE([fpm], | |
733 | AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support])) | |
734 | AC_ARG_ENABLE([werror], | |
735 | AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)])) | |
736 | AC_ARG_ENABLE([cumulus], | |
737 | AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions])) | |
738 | AC_ARG_ENABLE([datacenter], | |
739 | AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions])) | |
740 | AC_ARG_ENABLE([rr-semantics], | |
741 | AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics])) | |
742 | AC_ARG_ENABLE([protobuf], | |
743 | AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support])) | |
744 | AC_ARG_ENABLE([oldvpn_commands], | |
745 | AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands])) | |
746 | AC_ARG_ENABLE([rpki], | |
747 | AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support])) | |
748 | AC_ARG_ENABLE([clippy-only], | |
749 | AS_HELP_STRING([--enable-clippy-only], [Only build clippy])) | |
750 | AC_ARG_ENABLE([numeric_version], | |
751 | AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)])) | |
752 | AC_ARG_ENABLE([gcov], | |
753 | AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov])) | |
754 | AC_ARG_ENABLE([clang_coverage], | |
755 | AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage])) | |
756 | AC_ARG_ENABLE([bfdd], | |
757 | AS_HELP_STRING([--disable-bfdd], [do not build bfdd])) | |
758 | AC_ARG_ENABLE([address-sanitizer], | |
759 | AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors])) | |
760 | AC_ARG_ENABLE([thread-sanitizer], | |
761 | AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races])) | |
762 | AC_ARG_ENABLE([memory-sanitizer], | |
763 | AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads])) | |
764 | AC_ARG_ENABLE([undefined-sanitizer], | |
765 | AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior])) | |
766 | AC_ARG_WITH([crypto], | |
767 | AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)])) | |
768 | AC_ARG_WITH([frr-format], | |
769 | AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin])) | |
770 | ||
771 | AC_ARG_ENABLE([version-build-config], | |
772 | AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command])) | |
773 | ||
774 | #if openssl, else use the internal | |
775 | AS_IF([test "$with_crypto" = "openssl"], [ | |
776 | AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], []) | |
777 | if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then | |
778 | AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system]) | |
779 | else | |
780 | AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support]) | |
781 | fi | |
782 | ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation]) | |
783 | ], [AC_MSG_ERROR([Unknown value for --with-crypto])] | |
784 | ) | |
785 | ||
786 | AS_IF([test "$enable_clippy_only" != "yes"], [ | |
787 | AC_CHECK_HEADERS([json-c/json.h]) | |
788 | AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm]) | |
789 | if test "$ac_cv_lib_json_c_json_object_get" = "no"; then | |
790 | AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"]) | |
791 | if test "$ac_cv_lib_json_json_object_get" = "no"; then | |
792 | AC_MSG_ERROR([libjson is needed to compile]) | |
793 | fi | |
794 | fi | |
795 | ]) | |
796 | ||
797 | AC_ARG_ENABLE([ccls], | |
798 | AS_HELP_STRING([--enable-ccls], [Write .ccls config for this build])) | |
799 | ||
800 | AC_ARG_ENABLE([dev_build], | |
801 | AS_HELP_STRING([--enable-dev-build], [build for development])) | |
802 | ||
803 | AC_ARG_ENABLE([scripting], | |
804 | AS_HELP_STRING([--enable-scripting], [Build with scripting support])) | |
805 | ||
806 | AC_ARG_ENABLE([netlink-debug], | |
807 | AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages])) | |
808 | ||
809 | if test "$enable_netlink_debug" != "no" ; then | |
810 | AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code]) | |
811 | fi | |
812 | ||
813 | AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"]) | |
814 | ||
815 | if test "$enable_time_check" != "no" ; then | |
816 | if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then | |
817 | AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check]) | |
818 | else | |
819 | AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check]) | |
820 | fi | |
821 | fi | |
822 | ||
823 | case "${enable_cpu_time}" in | |
824 | "no") | |
825 | AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering]) | |
826 | ;; | |
827 | "*") | |
828 | ;; | |
829 | esac | |
830 | ||
831 | if test "$enable_rr_semantics" != "no" ; then | |
832 | AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics]) | |
833 | fi | |
834 | ||
835 | if test "$enable_datacenter" = "yes" ; then | |
836 | AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter]) | |
837 | DFLT_NAME="datacenter" | |
838 | else | |
839 | DFLT_NAME="traditional" | |
840 | fi | |
841 | ||
842 | if test "$enable_cumulus" = "yes" ; then | |
843 | AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in]) | |
844 | fi | |
845 | ||
846 | AC_SUBST([DFLT_NAME]) | |
847 | AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set]) | |
848 | ||
849 | if test "$enable_shell_access" = "yes"; then | |
850 | AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure]) | |
851 | fi | |
852 | ||
853 | # | |
854 | # Python for clippy | |
855 | # | |
856 | ||
857 | AS_IF([test "$host" = "$build"], [ | |
858 | AM_PATH_PYTHON([3]) | |
859 | AC_CHECK_HEADER([gelf.h], [], [ | |
860 | AC_MSG_ERROR([libelf headers are required for building clippy. (Host only when cross-compiling.)]) | |
861 | ]) | |
862 | ||
863 | LIBS_save="$LIBS" | |
864 | AC_CHECK_LIB([elf], [elf_memory], [], [ | |
865 | AC_MSG_ERROR([libelf is required for building clippy. (Host only when cross-compiling.)]) | |
866 | ]) | |
867 | ||
868 | AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [ | |
869 | AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()]) | |
870 | ]) | |
871 | AC_CHECK_LIB([elf], [gelf_getnote], [ | |
872 | AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()]) | |
873 | ]) | |
874 | LIBS="$LIBS_save" | |
875 | unset LIBS_save | |
876 | ||
877 | FRR_PYTHON_DEV | |
878 | ], [ | |
879 | FRR_PYTHON | |
880 | ]) | |
881 | ||
882 | FRR_PYTHON_MODULES([pytest]) | |
883 | ||
884 | if test "$enable_doc" != "no"; then | |
885 | FRR_PYTHON_MODULES([sphinx], , [ | |
886 | if test "$enable_doc" = "yes"; then | |
887 | AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.]) | |
888 | fi | |
889 | ]) | |
890 | fi | |
891 | AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"]) | |
892 | AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"]) | |
893 | ||
894 | FRR_PYTHON_MOD_EXEC([sphinx], [--version], [ | |
895 | PYSPHINX="-m sphinx" | |
896 | ], [ | |
897 | PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'" | |
898 | ]) | |
899 | AC_SUBST([PYSPHINX]) | |
900 | ||
901 | # | |
902 | # Logic for old vpn commands support. | |
903 | # | |
904 | if test "$enable_oldvpn_commands" = "yes"; then | |
905 | AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands]) | |
906 | fi | |
907 | ||
908 | AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements]) | |
909 | if test "$enable_rtadv" != "no"; then | |
910 | AC_MSG_RESULT([yes]) | |
911 | AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support]) | |
912 | else | |
913 | AC_MSG_RESULT([no]) | |
914 | fi | |
915 | ||
916 | if test "$enable_user" = "no"; then | |
917 | enable_user="" | |
918 | else | |
919 | if test "$enable_user" = "yes" || test "$enable_user" = ""; then | |
920 | enable_user="frr" | |
921 | fi | |
922 | AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User]) | |
923 | fi | |
924 | ||
925 | if test "$enable_group" = "no"; then | |
926 | enable_group="" | |
927 | else | |
928 | if test "$enable_group" = "yes" || test "$enable_group" = ""; then | |
929 | enable_group="frr" | |
930 | fi | |
931 | AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group]) | |
932 | fi | |
933 | ||
934 | if test "$enable_vty_group" = "yes" ; then | |
935 | AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes]) | |
936 | elif test "$enable_vty_group" != ""; then | |
937 | if test "$enable_vty_group" != "no"; then | |
938 | AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group]) | |
939 | fi | |
940 | fi | |
941 | AC_SUBST([enable_user]) | |
942 | AC_SUBST([enable_group]) | |
943 | AC_SUBST([enable_vty_group]) | |
944 | ||
945 | enable_configfile_mask=${enable_configfile_mask:-0600} | |
946 | AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files]) | |
947 | AC_SUBST([enable_configfile_mask]) | |
948 | ||
949 | enable_logfile_mask=${enable_logfile_mask:-0600} | |
950 | AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files]) | |
951 | ||
952 | MPATH_NUM=16 | |
953 | ||
954 | case "${enable_multipath}" in | |
955 | 0) | |
956 | MPATH_NUM=64 | |
957 | ;; | |
958 | [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]]) | |
959 | MPATH_NUM="${enable_multipath}" | |
960 | ;; | |
961 | "") | |
962 | ;; | |
963 | *) | |
964 | AC_MSG_FAILURE([Please specify digit to enable multipath ARG]) | |
965 | ;; | |
966 | esac | |
967 | ||
968 | AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route]) | |
969 | ||
970 | case "${with_log_timestamp_precision}" in | |
971 | [[0-9]|1[012]]) | |
972 | ;; | |
973 | "") | |
974 | ;; | |
975 | *) | |
976 | AC_MSG_FAILURE([Please specify a number from 0-12 for log precision ARG]) | |
977 | ;; | |
978 | esac | |
979 | with_log_timestamp_precision=${with_log_timestamp_precision:-0} | |
980 | AC_DEFINE_UNQUOTED([LOG_TIMESTAMP_PRECISION], [${with_log_timestamp_precision}], [Startup zlog timestamp precision]) | |
981 | ||
982 | AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use]) | |
983 | ||
984 | TIMEOUT_MIN=2 | |
985 | case "${with_service_timeout}" in | |
986 | [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]]) | |
987 | TIMEOUT_MIN="${with_service_timeout}" | |
988 | ;; | |
989 | 0|"") | |
990 | ;; | |
991 | *) | |
992 | AC_MSG_FAILURE([Please specify digit for timeout ARG]) | |
993 | ;; | |
994 | esac | |
995 | AC_SUBST([TIMEOUT_MIN]) | |
996 | ||
997 | dnl -------------------- | |
998 | dnl Enable code coverage | |
999 | dnl -------------------- | |
1000 | AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"]) | |
1001 | ||
1002 | dnl ------------------------------------ | |
1003 | dnl Alpine only accepts numeric versions | |
1004 | dnl ------------------------------------ | |
1005 | if test "$enable_numeric_version" != "" ; then | |
1006 | VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`" | |
1007 | PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`" | |
1008 | fi | |
1009 | ||
1010 | dnl ----------------------------------- | |
1011 | dnl Add extra version string to package | |
1012 | dnl name, string and version fields. | |
1013 | dnl ----------------------------------- | |
1014 | if test "$EXTRAVERSION" != "" ; then | |
1015 | VERSION="${VERSION}${EXTRAVERSION}" | |
1016 | PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}" | |
1017 | AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"]) | |
1018 | PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}" | |
1019 | fi | |
1020 | AC_SUBST([EXTRAVERSION]) | |
1021 | ||
1022 | if test "$with_pkg_git_version" = "yes"; then | |
1023 | if test -e "${srcdir}/.git"; then | |
1024 | AC_DEFINE([GIT_VERSION], [1], [include git version info]) | |
1025 | else with_pkg_git_version="no" | |
1026 | AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout]) | |
1027 | fi | |
1028 | fi | |
1029 | AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"]) | |
1030 | ||
1031 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [:]) | |
1032 | if test "$OBJCOPY" != ":"; then | |
1033 | AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [ | |
1034 | frr_cv_interp="" | |
1035 | AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [ | |
1036 | if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then | |
1037 | frr_cv_interp="`xargs -0 echo < conftest.interp`" | |
1038 | fi | |
1039 | test -f conftest.interp && rm conftest.interp | |
1040 | ]) | |
1041 | ]) | |
1042 | fi | |
1043 | if test -n "$frr_cv_interp"; then | |
1044 | AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value]) | |
1045 | fi | |
1046 | ||
1047 | dnl ------------------------- | |
1048 | dnl Check other header files. | |
1049 | dnl ------------------------- | |
1050 | AC_CHECK_HEADERS([stropts.h sys/ksym.h \ | |
1051 | linux/version.h asm/types.h endian.h sys/endian.h]) | |
1052 | ||
1053 | ac_stdatomic_ok=false | |
1054 | AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs]) | |
1055 | AC_CHECK_HEADER([stdatomic.h],[ | |
1056 | ||
1057 | AC_MSG_CHECKING([whether _Atomic qualifier works]) | |
1058 | AC_LINK_IFELSE([AC_LANG_SOURCE([[ | |
1059 | #include <stdatomic.h> | |
1060 | int main(int argc, char **argv) { | |
1061 | _Atomic int i = 0; | |
1062 | return i; | |
1063 | } | |
1064 | ]])], [ | |
1065 | AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h]) | |
1066 | AC_MSG_RESULT([yes]) | |
1067 | ac_stdatomic_ok=true | |
1068 | ], [ | |
1069 | AC_MSG_RESULT([no]) | |
1070 | ]) | |
1071 | ]) | |
1072 | ||
1073 | AS_IF([$ac_stdatomic_ok], [true], [ | |
1074 | AC_MSG_CHECKING([for __atomic_* builtins]) | |
1075 | AC_LINK_IFELSE([AC_LANG_SOURCE([[ | |
1076 | int main(int argc, char **argv) { | |
1077 | volatile int i = 1; | |
1078 | __atomic_store_n (&i, 0, __ATOMIC_RELEASE); | |
1079 | return __atomic_load_n (&i, __ATOMIC_ACQUIRE); | |
1080 | } | |
1081 | ]])], [ | |
1082 | AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins]) | |
1083 | AC_MSG_RESULT([yes]) | |
1084 | ], [ | |
1085 | AC_MSG_RESULT([no]) | |
1086 | ||
1087 | dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work | |
1088 | AC_MSG_CHECKING([for __sync_* builtins]) | |
1089 | AC_LINK_IFELSE([AC_LANG_SOURCE([[ | |
1090 | int main(int argc, char **argv) { | |
1091 | volatile int i = 1; | |
1092 | __sync_fetch_and_sub (&i, 1); | |
1093 | return __sync_val_compare_and_swap (&i, 0, 1); | |
1094 | } | |
1095 | ]])], [ | |
1096 | AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins]) | |
1097 | AC_MSG_RESULT([yes]) | |
1098 | ||
1099 | AC_MSG_CHECKING([for __sync_swap builtin]) | |
1100 | AC_LINK_IFELSE([AC_LANG_SOURCE([[ | |
1101 | int main(int argc, char **argv) { | |
1102 | volatile int i = 1; | |
1103 | return __sync_swap (&i, 2); | |
1104 | } | |
1105 | ]])], [ | |
1106 | AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin]) | |
1107 | AC_MSG_RESULT([yes]) | |
1108 | ], [ | |
1109 | AC_MSG_RESULT([no]) | |
1110 | ]) | |
1111 | ||
1112 | ], [ | |
1113 | AC_MSG_RESULT([no]) | |
1114 | AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins]) | |
1115 | ]) | |
1116 | ]) | |
1117 | ]) | |
1118 | ||
1119 | needsync=true | |
1120 | ||
1121 | AS_IF([$needsync], [ | |
1122 | dnl Linux | |
1123 | AC_MSG_CHECKING([for Linux futex() support]) | |
1124 | AC_LINK_IFELSE([AC_LANG_PROGRAM([ | |
1125 | #ifndef _GNU_SOURCE | |
1126 | #define _GNU_SOURCE | |
1127 | #endif | |
1128 | #include <unistd.h> | |
1129 | #include <limits.h> | |
1130 | #include <sys/time.h> | |
1131 | #include <sys/syscall.h> | |
1132 | #include <linux/futex.h> | |
1133 | ||
1134 | int main(void); | |
1135 | ], | |
1136 | [ | |
1137 | { | |
1138 | return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0); | |
1139 | } | |
1140 | ])], [ | |
1141 | AC_MSG_RESULT([yes]) | |
1142 | AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support) | |
1143 | needsync=false | |
1144 | ], [ | |
1145 | AC_MSG_RESULT([no]) | |
1146 | ]) | |
1147 | ]) | |
1148 | ||
1149 | AS_IF([$needsync], [ | |
1150 | dnl FreeBSD | |
1151 | AC_MSG_CHECKING([for FreeBSD _umtx_op() support]) | |
1152 | AC_LINK_IFELSE([AC_LANG_PROGRAM([ | |
1153 | #include <errno.h> | |
1154 | #include <stdlib.h> | |
1155 | #include <sys/types.h> | |
1156 | #include <sys/umtx.h> | |
1157 | int main(void); | |
1158 | ], | |
1159 | [ | |
1160 | { | |
1161 | return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL); | |
1162 | } | |
1163 | ])], [ | |
1164 | AC_MSG_RESULT([yes]) | |
1165 | AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support) | |
1166 | needsync=false | |
1167 | ], [ | |
1168 | AC_MSG_RESULT([no]) | |
1169 | ]) | |
1170 | ]) | |
1171 | ||
1172 | AS_IF([$needsync], [ | |
1173 | dnl OpenBSD patch (not upstream at the time of writing this) | |
1174 | dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2 | |
1175 | AC_MSG_CHECKING([for OpenBSD futex() support]) | |
1176 | AC_LINK_IFELSE([AC_LANG_PROGRAM([ | |
1177 | #include <sys/futex.h> | |
1178 | int main(void); | |
1179 | ], | |
1180 | [ | |
1181 | { | |
1182 | return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0); | |
1183 | } | |
1184 | ])], [ | |
1185 | AC_MSG_RESULT([yes]) | |
1186 | AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support) | |
1187 | needsync=false | |
1188 | ], [ | |
1189 | AC_MSG_RESULT([no]) | |
1190 | ]) | |
1191 | ]) | |
1192 | ||
1193 | dnl Utility macro to avoid retyping includes all the time | |
1194 | m4_define([FRR_INCLUDES], | |
1195 | [#ifdef SUNOS_5 | |
1196 | #define _POSIX_C_SOURCE 200809L | |
1197 | #define __EXTENSIONS__ | |
1198 | #endif | |
1199 | #include <stdio.h> | |
1200 | #include <stdlib.h> | |
1201 | #include <stddef.h> | |
1202 | #include <sys/types.h> | |
1203 | /* sys/conf.h depends on param.h on FBSD at least */ | |
1204 | #include <sys/param.h> | |
1205 | /* Required for MAXSIG */ | |
1206 | #include <signal.h> | |
1207 | #include <sys/socket.h> | |
1208 | #ifdef __APPLE__ | |
1209 | # define __APPLE_USE_RFC_3542 | |
1210 | #endif | |
1211 | #include <netinet/in.h> | |
1212 | #include <sys/time.h> | |
1213 | #include <time.h> | |
1214 | #include <net/if.h> | |
1215 | ])dnl | |
1216 | ||
1217 | dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and | |
1218 | dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence | |
1219 | dnl an additional round for it. | |
1220 | ||
1221 | AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES]) | |
1222 | ||
1223 | m4_define([FRR_INCLUDES], | |
1224 | FRR_INCLUDES | |
1225 | [#ifdef HAVE_NET_IF_VAR_H | |
1226 | # include <net/if_var.h> | |
1227 | #endif | |
1228 | ])dnl | |
1229 | ||
1230 | AC_CHECK_HEADERS([netinet/in_var.h \ | |
1231 | net/if_dl.h net/netopt.h \ | |
1232 | inet/nd.h netinet/ip_icmp.h \ | |
1233 | sys/sysctl.h sys/sockio.h sys/conf.h], | |
1234 | [], [], [FRR_INCLUDES]) | |
1235 | ||
1236 | AC_CHECK_HEADERS([ucontext.h], [], [], | |
1237 | [#ifndef __USE_GNU | |
1238 | #define __USE_GNU | |
1239 | #endif /* __USE_GNU */ | |
1240 | FRR_INCLUDES | |
1241 | ]) | |
1242 | ||
1243 | m4_define([UCONTEXT_INCLUDES], | |
1244 | [#include <ucontext.h>])dnl | |
1245 | ||
1246 | AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs], | |
1247 | [], [], [UCONTEXT_INCLUDES]) | |
1248 | AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs], | |
1249 | [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip], | |
1250 | [], [], [UCONTEXT_INCLUDES])], | |
1251 | [], [UCONTEXT_INCLUDES]) | |
1252 | AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs], | |
1253 | [], [], [UCONTEXT_INCLUDES]) | |
1254 | ||
1255 | m4_define([FRR_INCLUDES], | |
1256 | FRR_INCLUDES | |
1257 | [ | |
1258 | #include <sys/un.h> | |
1259 | #include <netinet/in_systm.h> | |
1260 | #ifdef HAVE_NETINET_IN_VAR_H | |
1261 | # include <netinet/in_var.h> | |
1262 | #endif | |
1263 | #ifdef HAVE_NET_IF_DL_H | |
1264 | # include <net/if_dl.h> | |
1265 | #endif | |
1266 | #ifdef HAVE_NET_NETOPT_H | |
1267 | # include <net/netopt.h> | |
1268 | #endif | |
1269 | #include <net/route.h> | |
1270 | #ifdef HAVE_INET_ND_H | |
1271 | # include <inet/nd.h> | |
1272 | #endif | |
1273 | #include <arpa/inet.h> | |
1274 | /* Required for IDRP */ | |
1275 | #ifdef HAVE_NETINET_IP_ICMP_H | |
1276 | # include <netinet/ip_icmp.h> | |
1277 | #endif | |
1278 | ])dnl | |
1279 | ||
1280 | dnl V6 headers are checked below, after we check for v6 | |
1281 | ||
1282 | is_linux=false | |
1283 | ||
1284 | AC_MSG_CHECKING([which operating system interface to use]) | |
1285 | case "$host_os" in | |
1286 | sunos* | solaris2*) | |
1287 | AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5]) | |
1288 | ;; | |
1289 | linux*) | |
1290 | AC_MSG_RESULT([Linux]) | |
1291 | ||
1292 | AC_DEFINE([GNU_LINUX], [1], [GNU Linux]) | |
1293 | AC_DEFINE([HAVE_NETLINK], [1], [netlink]) | |
1294 | AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack]) | |
1295 | ||
1296 | dnl Linux has a compilation problem with mixing | |
1297 | dnl netinet/in.h and linux/in6.h they are not | |
1298 | dnl compatible. There has been discussion on | |
1299 | dnl how to fix it but no real progress on implementation | |
1300 | dnl when they fix it, remove this | |
1301 | AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count]) | |
1302 | ||
1303 | is_linux=true | |
1304 | ;; | |
1305 | openbsd*) | |
1306 | AC_MSG_RESULT([OpenBSD]) | |
1307 | ||
1308 | AC_DEFINE([OPEN_BSD], [1], [OpenBSD]) | |
1309 | AC_DEFINE([KAME], [1], [KAME IPv6]) | |
1310 | AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding]) | |
1311 | ;; | |
1312 | *) | |
1313 | AC_MSG_RESULT([BSD]) | |
1314 | ||
1315 | AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST]) | |
1316 | AC_DEFINE([KAME], [1], [KAME IPv6]) | |
1317 | AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding]) | |
1318 | ;; | |
1319 | esac | |
1320 | AM_CONDITIONAL([LINUX], [${is_linux}]) | |
1321 | ||
1322 | AC_SYS_LARGEFILE | |
1323 | ||
1324 | dnl ------------------------ | |
1325 | dnl Integrated REALMS option | |
1326 | dnl ------------------------ | |
1327 | if test "$enable_realms" = "yes"; then | |
1328 | case "$host_os" in | |
1329 | linux*) | |
1330 | AC_DEFINE([SUPPORT_REALMS], [1], [Realms support]) | |
1331 | ;; | |
1332 | *) | |
1333 | echo "Sorry, only Linux has REALMS support" | |
1334 | exit 1 | |
1335 | ;; | |
1336 | esac | |
1337 | fi | |
1338 | ||
1339 | dnl --------------- | |
1340 | dnl other functions | |
1341 | dnl --------------- | |
1342 | AC_CHECK_FUNCS([ \ | |
1343 | strlcat strlcpy \ | |
1344 | getgrouplist \ | |
1345 | openat \ | |
1346 | unlinkat \ | |
1347 | posix_fallocate \ | |
1348 | sendmmsg \ | |
1349 | explicit_bzero \ | |
1350 | ]) | |
1351 | ||
1352 | AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES) | |
1353 | ||
1354 | dnl ########################################################################## | |
1355 | dnl LARGE if block spans a lot of "configure"! | |
1356 | if test "$enable_clippy_only" != "yes"; then | |
1357 | dnl ########################################################################## | |
1358 | ||
1359 | # | |
1360 | # Logic for protobuf support. | |
1361 | # | |
1362 | PROTO3=false | |
1363 | # Enable Protobuf by default at all times. | |
1364 | # Check for protoc & protoc-c | |
1365 | # protoc is not required, it's only for a "be nice" helper target | |
1366 | AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false]) | |
1367 | ||
1368 | AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false]) | |
1369 | if test "$PROTOC_C" = "/bin/false"; then | |
1370 | AC_MSG_FAILURE([protobuf requested but protoc-c not found. Install protobuf-c.]) | |
1371 | fi | |
1372 | ||
1373 | PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 1.1.0],, [ | |
1374 | AC_MSG_FAILURE([minimum version (1.1.0) of libprotobuf-c not found. Install minimum required version of protobuf-c.]) | |
1375 | ]) | |
1376 | ||
1377 | if test "$enable_protobuf3" = "yes"; then | |
1378 | PROTO3=true | |
1379 | AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], | |
1380 | [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE, | |
1381 | AC_DEFINE([HAVE_PROTOBUF_VERSION_3], | |
1382 | [1], [Have Protobuf version 3]), | |
1383 | [PROTO3=false], | |
1384 | [#include <google/protobuf-c/protobuf-c.h>])], | |
1385 | [PROTO3=false && AC_MSG_FAILURE([protobuf3 requested but protobuf-c.h not found. Install protobuf-c.])]) | |
1386 | fi | |
1387 | ||
1388 | AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf]) | |
1389 | # | |
1390 | # End of logic for protobuf support. | |
1391 | # | |
1392 | ||
1393 | ||
1394 | dnl --------------------- | |
1395 | dnl Integrated VTY option | |
1396 | dnl --------------------- | |
1397 | case "${enable_vtysh}" in | |
1398 | "no") | |
1399 | VTYSH="";; | |
1400 | *) | |
1401 | VTYSH="vtysh"; | |
1402 | AC_DEFINE([VTYSH], [1], [VTY shell]) | |
1403 | ||
1404 | prev_libs="$LIBS" | |
1405 | AC_CHECK_LIB([readline], [readline], [ | |
1406 | LIBREADLINE="-lreadline" | |
1407 | ], [ | |
1408 | dnl readline failed - it might be incorrectly linked and missing its | |
1409 | dnl termcap/tinfo/curses dependency. see if we can fix that... | |
1410 | AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [ | |
1411 | LIBREADLINE="$ac_cv_search_tputs" | |
1412 | ], [ | |
1413 | AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies]) | |
1414 | ]) | |
1415 | ||
1416 | dnl re-try with the lib we found above | |
1417 | unset ac_cv_lib_readline_main | |
1418 | AC_CHECK_LIB([readline], [main], [ | |
1419 | LIBREADLINE="-lreadline $LIBREADLINE" | |
1420 | ], [ | |
1421 | AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies]) | |
1422 | ], [$LIBREADLINE]) | |
1423 | ], []) | |
1424 | LIBS="$LIBS -lreadline" | |
1425 | AC_CHECK_FUNCS([rl_clear_visible_line]) | |
1426 | LIBS="$prev_libs" | |
1427 | ||
1428 | AC_CHECK_HEADER([readline/history.h]) | |
1429 | if test "$ac_cv_header_readline_history_h" = "no"; then | |
1430 | AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.]) | |
1431 | fi | |
1432 | AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE]) | |
1433 | if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then | |
1434 | AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline]) | |
1435 | fi | |
1436 | AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE]) | |
1437 | if test "$frr_cv_append_history" = "yes"; then | |
1438 | AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history]) | |
1439 | fi | |
1440 | ;; | |
1441 | esac | |
1442 | AC_SUBST([LIBREADLINE]) | |
1443 | ||
1444 | dnl ---------- | |
1445 | dnl PAM module | |
1446 | dnl | |
1447 | dnl FRR detects the PAM library it is built against by checking for a | |
1448 | dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h | |
1449 | dnl is known to #include pam_appl.h, the standard header of a PAM library, and | |
1450 | dnl openpam.h doesn't do that, although depends on the header too. Hence a | |
1451 | dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection | |
1452 | dnl of OpenPAM. | |
1453 | dnl ---------- | |
1454 | if test "$with_libpam" = "yes"; then | |
1455 | AC_CHECK_HEADER([security/pam_misc.h], | |
1456 | [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h]) | |
1457 | AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv]) | |
1458 | pam_conv_func="misc_conv" | |
1459 | ], | |
1460 | [], FRR_INCLUDES) | |
1461 | AC_CHECK_HEADER([security/openpam.h], | |
1462 | [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h]) | |
1463 | AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv]) | |
1464 | pam_conv_func="openpam_ttyconv" | |
1465 | ], | |
1466 | [], FRR_INCLUDES[#include <security/pam_appl.h>]) | |
1467 | if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then | |
1468 | AC_MSG_WARN([*** pam support will not be built ***]) | |
1469 | with_libpam="no" | |
1470 | fi | |
1471 | fi | |
1472 | ||
1473 | if test "$with_libpam" = "yes"; then | |
1474 | dnl took this test from proftpds configure.in and suited to our needs | |
1475 | dnl ------------------------------------------------------------------------- | |
1476 | dnl | |
1477 | dnl This next check looks funky due to a linker problem with some versions | |
1478 | dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library | |
1479 | dnl omitted requiring libdl linking information. PAM-0.72 or better ships | |
1480 | dnl with RedHat 6.2 and Debian 2.2 or better. | |
1481 | AC_CHECK_LIB([pam], [pam_start], | |
1482 | [AC_CHECK_LIB([pam], [$pam_conv_func], | |
1483 | [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication]) | |
1484 | LIBPAM="-lpam"], | |
1485 | [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication]) | |
1486 | LIBPAM="-lpam -lpam_misc"] | |
1487 | ) | |
1488 | ], | |
1489 | ||
1490 | [AC_CHECK_LIB([pam], [pam_end], | |
1491 | [AC_CHECK_LIB([pam], [$pam_conv_func], | |
1492 | [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication]) | |
1493 | LIBPAM="-lpam -ldl"], | |
1494 | [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication]) | |
1495 | LIBPAM="-lpam -ldl -lpam_misc"] | |
1496 | ) | |
1497 | ],AC_MSG_WARN([*** pam support will not be built ***]), | |
1498 | [-ldl]) | |
1499 | ] | |
1500 | ) | |
1501 | fi | |
1502 | AC_SUBST([LIBPAM]) | |
1503 | ||
1504 | dnl ------------------------------- | |
1505 | dnl bgpd needs pow() and hence libm | |
1506 | dnl ------------------------------- | |
1507 | TMPLIBS="$LIBS" | |
1508 | LIBS="" | |
1509 | AC_SEARCH_LIBS([pow], [m], [ | |
1510 | LIBM="$LIBS" | |
1511 | ], [ | |
1512 | AC_MSG_WARN([Unable to find working pow function - bgpd may not link]) | |
1513 | ]) | |
1514 | LIBS="$TMPLIBS" | |
1515 | AC_SUBST([LIBM]) | |
1516 | ||
1517 | AC_CHECK_FUNCS([ppoll], [ | |
1518 | AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()]) | |
1519 | ]) | |
1520 | AC_CHECK_FUNCS([pollts], [ | |
1521 | AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()]) | |
1522 | ]) | |
1523 | ||
1524 | AC_CHECK_HEADER([asm-generic/unistd.h], | |
1525 | [AC_CHECK_DECL(__NR_setns, | |
1526 | AC_DEFINE([HAVE_NETNS], [1], [Have netns]),, | |
1527 | FRR_INCLUDES [#include <asm-generic/unistd.h> | |
1528 | ]) | |
1529 | AC_CHECK_FUNCS([setns])] | |
1530 | ) | |
1531 | ||
1532 | dnl -------------------------- | |
1533 | dnl Determine IS-IS I/O method | |
1534 | dnl -------------------------- | |
1535 | AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket]) | |
1536 | AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi]) | |
1537 | AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf]) | |
1538 | AC_CHECK_HEADER([net/bpf.h]) | |
1539 | AC_CHECK_HEADER([sys/dlpi.h]) | |
1540 | AC_MSG_CHECKING([zebra IS-IS I/O method]) | |
1541 | ||
1542 | case "$host_os" in | |
1543 | linux*) | |
1544 | AC_MSG_RESULT([pfpacket]) | |
1545 | ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET" | |
1546 | ;; | |
1547 | *) | |
1548 | if test "$ac_cv_header_net_bpf_h" = "no"; then | |
1549 | if test "$ac_cv_header_sys_dlpi_h" = "no"; then | |
1550 | AC_MSG_RESULT([none]) | |
1551 | if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then | |
1552 | AC_MSG_FAILURE([IS-IS support requested but no packet backend found]) | |
1553 | fi | |
1554 | AC_MSG_WARN([*** IS-IS support will not be built ***]) | |
1555 | enable_isisd="no" | |
1556 | enable_fabricd="no" | |
1557 | else | |
1558 | AC_MSG_RESULT([DLPI]) | |
1559 | fi | |
1560 | ISIS_METHOD_MACRO="ISIS_METHOD_DLPI" | |
1561 | else | |
1562 | AC_MSG_RESULT([BPF]) | |
1563 | ISIS_METHOD_MACRO="ISIS_METHOD_BPF" | |
1564 | fi | |
1565 | ;; | |
1566 | esac | |
1567 | AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants]) | |
1568 | ||
1569 | dnl --------------------------------------------------------------- | |
1570 | dnl figure out how to specify an interface in multicast sockets API | |
1571 | dnl --------------------------------------------------------------- | |
1572 | AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES) | |
1573 | ||
1574 | AC_CHECK_HEADERS([linux/mroute.h], [], [],[ | |
1575 | #include <sys/socket.h> | |
1576 | #include <netinet/in.h> | |
1577 | #define _LINUX_IN_H /* For Linux <= 2.6.25 */ | |
1578 | #include <linux/types.h> | |
1579 | ]) | |
1580 | ||
1581 | AC_CHECK_HEADERS([linux/mroute6.h], [], [],[ | |
1582 | #include <sys/socket.h> | |
1583 | #include <netinet/in.h> | |
1584 | #define _LINUX_IN_H /* For Linux <= 2.6.25 */ | |
1585 | #include <linux/types.h> | |
1586 | ]) | |
1587 | ||
1588 | m4_define([FRR_INCLUDES], | |
1589 | FRR_INCLUDES | |
1590 | [#ifdef HAVE_LINUX_MROUTE_H | |
1591 | # include <linux/mroute.h> | |
1592 | #endif | |
1593 | ])dnl | |
1594 | ||
1595 | AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[ | |
1596 | #include <sys/socket.h> | |
1597 | #include <sys/types.h> | |
1598 | #include <netinet/in.h> | |
1599 | #include <net/route.h> | |
1600 | ]) | |
1601 | ||
1602 | m4_define([FRR_INCLUDES], | |
1603 | FRR_INCLUDES | |
1604 | [#ifdef HAVE_NETINET_IP_MROUTE_H | |
1605 | # include <netinet/ip_mroute.h> | |
1606 | #endif | |
1607 | ])dnl | |
1608 | ||
1609 | AC_MSG_CHECKING([for RFC3678 protocol-independed API]) | |
1610 | AC_COMPILE_IFELSE( | |
1611 | [ AC_LANG_PROGRAM([[ | |
1612 | #include <sys/types.h> | |
1613 | #include <netinet/in.h> | |
1614 | ]], [[ | |
1615 | struct group_req gr; | |
1616 | int sock; | |
1617 | setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr)); | |
1618 | ]]) | |
1619 | ],[ | |
1620 | AC_MSG_RESULT([yes]) | |
1621 | AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API]) | |
1622 | ],[ | |
1623 | AC_MSG_RESULT(no) | |
1624 | ]) | |
1625 | ||
1626 | dnl --------------------------------------------------------------- | |
1627 | dnl figure out how to check link-state | |
1628 | dnl --------------------------------------------------------------- | |
1629 | AC_CHECK_HEADER([net/if_media.h], | |
1630 | [m4_define([LINK_DETECT_INCLUDES], | |
1631 | FRR_INCLUDES | |
1632 | [#include <net/if_media.h> | |
1633 | ]) | |
1634 | AC_CHECK_MEMBERS([struct ifmediareq.ifm_status], | |
1635 | AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]), | |
1636 | [], LINK_DETECT_INCLUDES)], | |
1637 | [], | |
1638 | FRR_INCLUDES) | |
1639 | ||
1640 | dnl --------------------------------------------------------------- | |
1641 | dnl Additional, newer way to check link-state using ifi_link_state. | |
1642 | dnl Not available in all BSD's when ifmediareq available | |
1643 | dnl --------------------------------------------------------------- | |
1644 | AC_CHECK_MEMBERS([struct if_data.ifi_link_state], | |
1645 | AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]), | |
1646 | [], FRR_INCLUDES) | |
1647 | ||
1648 | dnl ------------------------ | |
1649 | dnl TCP_MD5SIG socket option | |
1650 | dnl ------------------------ | |
1651 | ||
1652 | AC_CHECK_HEADER([netinet/tcp.h], | |
1653 | [m4_define([MD5_INCLUDES], | |
1654 | FRR_INCLUDES | |
1655 | [#include <netinet/tcp.h> | |
1656 | ]) | |
1657 | AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)], | |
1658 | [], | |
1659 | FRR_INCLUDES) | |
1660 | if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then | |
1661 | AC_CHECK_HEADER([linux/tcp.h], | |
1662 | [m4_define([MD5_INCLUDES], | |
1663 | FRR_INCLUDES | |
1664 | [#include <linux/tcp.h> | |
1665 | ]) | |
1666 | AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)]) | |
1667 | fi | |
1668 | ||
1669 | LIBS_save="$LIBS" | |
1670 | AC_CHECK_LIB([crypt], [crypt], [], [ | |
1671 | AC_CHECK_LIB([crypto], [DES_crypt]) | |
1672 | ]) | |
1673 | LIBCRYPT="$LIBS" | |
1674 | LIBCRYPT="${LIBCRYPT%$LIBS_save}" | |
1675 | LIBCRYPT="${LIBCRYPT#$LIBS_save}" | |
1676 | AC_SUBST([LIBCRYPT]) | |
1677 | LIBS="$LIBS_save" | |
1678 | unset LIBS_save | |
1679 | ||
1680 | AC_CHECK_LIB([resolv], [res_init]) | |
1681 | ||
1682 | dnl --------------------------- | |
1683 | dnl check system has PCRE regexp | |
1684 | dnl --------------------------- | |
1685 | if test "$enable_pcreposix" = "yes"; then | |
1686 | AC_CHECK_LIB([pcreposix], [regexec], [], [ | |
1687 | AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix]) | |
1688 | ]) | |
1689 | fi | |
1690 | AC_SUBST([HAVE_LIBPCREPOSIX]) | |
1691 | ||
1692 | dnl --------------------------- | |
1693 | dnl check system has PCRE2 regexp | |
1694 | dnl --------------------------- | |
1695 | if test "$enable_pcre2posix" = "yes"; then | |
1696 | AC_CHECK_LIB([pcre2-posix], [regexec], [], [ | |
1697 | AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix]) | |
1698 | ]) | |
1699 | fi | |
1700 | AC_SUBST([HAVE_LIBPCRE2_POSIX]) | |
1701 | ||
1702 | dnl ########################################################################## | |
1703 | dnl test "$enable_clippy_only" != "yes" | |
1704 | fi | |
1705 | dnl END OF LARGE if block | |
1706 | dnl ########################################################################## | |
1707 | ||
1708 | dnl ------------------ | |
1709 | dnl check C-Ares library | |
1710 | dnl ------------------ | |
1711 | PKG_CHECK_MODULES([CARES], [libcares], [ | |
1712 | c_ares_found=true | |
1713 | ],[ | |
1714 | c_ares_found=false | |
1715 | ]) | |
1716 | AM_CONDITIONAL([CARES], [$c_ares_found]) | |
1717 | ||
1718 | ||
1719 | dnl ---------------------------------------------------------------------------- | |
1720 | dnl figure out if domainname is available in the utsname struct (GNU extension). | |
1721 | dnl ---------------------------------------------------------------------------- | |
1722 | AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>]) | |
1723 | ||
1724 | dnl ------------------ | |
1725 | dnl IPv6 header checks | |
1726 | dnl ------------------ | |
1727 | AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \ | |
1728 | netinet6/in6_var.h netinet6/nd6.h], [], [], | |
1729 | FRR_INCLUDES) | |
1730 | ||
1731 | m4_define([FRR_INCLUDES],dnl | |
1732 | FRR_INCLUDES | |
1733 | [#ifdef HAVE_NETINET6_IN6_H | |
1734 | #include <netinet6/in6.h> | |
1735 | #endif | |
1736 | #ifdef HAVE_NETINET_IN6_VAR_H | |
1737 | #include <netinet/in6_var.h> | |
1738 | #endif | |
1739 | #include <netinet/icmp6.h> | |
1740 | #ifdef HAVE_NETINET6_IN6_VAR_H | |
1741 | # include <netinet6/in6_var.h> | |
1742 | #endif | |
1743 | #ifdef HAVE_NETINET6_ND6_H | |
1744 | # include <netinet6/nd6.h> | |
1745 | #endif | |
1746 | ])dnl | |
1747 | ||
1748 | dnl -------------------- | |
1749 | dnl Daemon disable check | |
1750 | dnl -------------------- | |
1751 | ||
1752 | AS_IF([test "$enable_bgpd" != "no"], [ | |
1753 | AC_DEFINE([HAVE_BGPD], [1], [bgpd]) | |
1754 | ]) | |
1755 | ||
1756 | AS_IF([test "$enable_mgmtd" != "no"], [ | |
1757 | ||
1758 | AC_DEFINE([HAVE_MGMTD], [1], [mgmtd]) | |
1759 | ||
1760 | # Enable MGMTD local validations | |
1761 | AS_IF([test "$enable_mgmtd_local_validations" == "yes"], [ | |
1762 | AC_DEFINE([MGMTD_LOCAL_VALIDATIONS_ENABLED], [1], [Enable mgmtd local validations.]) | |
1763 | ]) | |
1764 | ]) | |
1765 | ||
1766 | AS_IF([test "$enable_ripd" != "no"], [ | |
1767 | AC_DEFINE([HAVE_RIPD], [1], [ripd]) | |
1768 | ]) | |
1769 | ||
1770 | AS_IF([test "$enable_ripngd" != "no"], [ | |
1771 | AC_DEFINE([HAVE_RIPNGD], [1], [ripngd]) | |
1772 | ]) | |
1773 | ||
1774 | AS_IF([test "$enable_ospfd" != "no"], [ | |
1775 | AC_DEFINE([HAVE_OSPFD], [1], [ospfd]) | |
1776 | ]) | |
1777 | ||
1778 | AS_IF([test "$enable_ospf6d" != "no"], [ | |
1779 | AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d]) | |
1780 | ]) | |
1781 | ||
1782 | AS_IF([test "$enable_ldpd" != "no"], [ | |
1783 | AC_DEFINE([HAVE_LDPD], [1], [ldpd]) | |
1784 | ]) | |
1785 | ||
1786 | AS_IF([test "$enable_nhrpd" != "no"], [ | |
1787 | AC_DEFINE([HAVE_NHRPD], [1], [nhrpd]) | |
1788 | ]) | |
1789 | ||
1790 | AS_IF([test "$enable_eigrpd" != "no"], [ | |
1791 | AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd]) | |
1792 | ]) | |
1793 | ||
1794 | AS_IF([test "$enable_babeld" != "no"], [ | |
1795 | AC_DEFINE([HAVE_BABELD], [1], [babeld]) | |
1796 | ]) | |
1797 | ||
1798 | AS_IF([test "$enable_isisd" != "no"], [ | |
1799 | AC_DEFINE([HAVE_ISISD], [1], [isisd]) | |
1800 | ]) | |
1801 | ||
1802 | AS_IF([test "$enable_pimd" != "no"], [ | |
1803 | AC_DEFINE([HAVE_PIMD], [1], [pimd]) | |
1804 | ]) | |
1805 | ||
1806 | AS_IF([test "$enable_pim6d" != "no"], [ | |
1807 | AC_DEFINE([HAVE_PIM6D], [1], [pim6d]) | |
1808 | ]) | |
1809 | ||
1810 | AS_IF([test "$enable_pbrd" != "no"], [ | |
1811 | AC_DEFINE([HAVE_PBRD], [1], [pbrd]) | |
1812 | ]) | |
1813 | ||
1814 | AS_IF([test "$enable_sharpd" = "yes"], [ | |
1815 | AC_DEFINE([HAVE_SHARPD], [1], [sharpd]) | |
1816 | ]) | |
1817 | ||
1818 | AS_IF([test "$enable_staticd" != "no"], [ | |
1819 | AC_DEFINE([HAVE_STATICD], [1], [staticd]) | |
1820 | ]) | |
1821 | ||
1822 | AS_IF([test "$enable_fabricd" != "no"], [ | |
1823 | AC_DEFINE([HAVE_FABRICD], [1], [fabricd]) | |
1824 | ]) | |
1825 | ||
1826 | AS_IF([test "$enable_vrrpd" != "no"], [ | |
1827 | AC_DEFINE([HAVE_VRRPD], [1], [vrrpd]) | |
1828 | ]) | |
1829 | ||
1830 | if test "$enable_bfdd" = "no"; then | |
1831 | AC_DEFINE([HAVE_BFDD], [0], [bfdd]) | |
1832 | BFDD="" | |
1833 | else | |
1834 | AC_DEFINE([HAVE_BFDD], [1], [bfdd]) | |
1835 | BFDD="bfdd" | |
1836 | ||
1837 | case $host_os in | |
1838 | linux*) | |
1839 | AC_DEFINE([BFD_LINUX], [1], [bfdd]) | |
1840 | ;; | |
1841 | ||
1842 | *) | |
1843 | AC_DEFINE([BFD_BSD], [1], [bfdd]) | |
1844 | ;; | |
1845 | esac | |
1846 | fi | |
1847 | ||
1848 | AS_IF([test "$enable_pathd" != "no"], [ | |
1849 | AC_DEFINE([HAVE_PATHD], [1], [pathd]) | |
1850 | ]) | |
1851 | ||
1852 | if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then | |
1853 | AC_MSG_ERROR(["you must use json-c library to use bfdd"]) | |
1854 | fi | |
1855 | ||
1856 | NHRPD="" | |
1857 | case "$host_os" in | |
1858 | linux*) | |
1859 | case "${enable_nhrpd}" in | |
1860 | no) | |
1861 | ;; | |
1862 | yes) | |
1863 | if test "$enable_clippy_only" != "yes"; then | |
1864 | if test "$c_ares_found" != "true" ; then | |
1865 | AC_MSG_ERROR([nhrpd requires libcares. Please install c-ares and its -dev headers.]) | |
1866 | fi | |
1867 | fi | |
1868 | NHRPD="nhrpd" | |
1869 | ;; | |
1870 | *) | |
1871 | if test "$c_ares_found" = "true" ; then | |
1872 | NHRPD="nhrpd" | |
1873 | fi | |
1874 | ;; | |
1875 | esac | |
1876 | ;; | |
1877 | *) | |
1878 | if test "$enable_nhrpd" = "yes"; then | |
1879 | AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.]) | |
1880 | fi | |
1881 | ;; | |
1882 | esac | |
1883 | ||
1884 | if test "$enable_watchfrr" = "no";then | |
1885 | WATCHFRR="" | |
1886 | else | |
1887 | WATCHFRR="watchfrr" | |
1888 | fi | |
1889 | ||
1890 | OSPFCLIENT="" | |
1891 | if test "$enable_ospfapi" != "no";then | |
1892 | AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI]) | |
1893 | ||
1894 | if test "$enable_ospfclient" != "no";then | |
1895 | OSPFCLIENT="ospfclient" | |
1896 | fi | |
1897 | fi | |
1898 | ||
1899 | if test "$enable_bgp_announce" = "no";then | |
1900 | AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra]) | |
1901 | else | |
1902 | AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra]) | |
1903 | fi | |
1904 | ||
1905 | if test "$enable_bgp_vnc" != "no";then | |
1906 | AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support]) | |
1907 | fi | |
1908 | ||
1909 | bgpd_bmp=false | |
1910 | case "${enable_bgp_bmp}" in | |
1911 | no) | |
1912 | ;; | |
1913 | yes) | |
1914 | if test "$c_ares_found" != "true" ; then | |
1915 | AC_MSG_ERROR([BMP support requires libcares. Please install c-ares and its -dev headers.]) | |
1916 | fi | |
1917 | bgpd_bmp=true | |
1918 | ;; | |
1919 | *) | |
1920 | if test "$c_ares_found" = "true" ; then | |
1921 | bgpd_bmp=true | |
1922 | fi | |
1923 | ;; | |
1924 | esac | |
1925 | ||
1926 | if test "$enable_version_build_config" != "no";then | |
1927 | AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version]) | |
1928 | fi | |
1929 | ||
1930 | dnl ########################################################################## | |
1931 | dnl LARGE if block | |
1932 | if test "$enable_clippy_only" != "yes"; then | |
1933 | dnl ########################################################################## | |
1934 | ||
1935 | dnl ------------------ | |
1936 | dnl check Net-SNMP library | |
1937 | dnl ------------------ | |
1938 | if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then | |
1939 | AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no]) | |
1940 | if test "$NETSNMP_CONFIG" = "no"; then | |
1941 | AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config]) | |
1942 | fi | |
1943 | SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`" | |
1944 | SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`" | |
1945 | # net-snmp lists all of its own dependencies. we absolutely do not want that | |
1946 | # among other things we avoid a GPL vs. OpenSSL license conflict here | |
1947 | for removelib in crypto ssl sensors pci wrap; do | |
1948 | SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`" | |
1949 | done | |
1950 | AC_MSG_CHECKING([whether we can link to Net-SNMP]) | |
1951 | AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([ | |
1952 | int main(void); | |
1953 | ], | |
1954 | [ | |
1955 | { | |
1956 | return 0; | |
1957 | } | |
1958 | ])], [ | |
1959 | AC_MSG_RESULT([no]) | |
1960 | AC_MSG_ERROR([--enable-snmp given but not usable])]) | |
1961 | case "${enable_snmp}" in | |
1962 | yes) | |
1963 | SNMP_METHOD=agentx | |
1964 | ;; | |
1965 | agentx) | |
1966 | SNMP_METHOD="${enable_snmp}" | |
1967 | ;; | |
1968 | *) | |
1969 | AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx]) | |
1970 | ;; | |
1971 | esac | |
1972 | AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd]) | |
1973 | AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd]) | |
1974 | fi | |
1975 | AC_SUBST([SNMP_LIBS]) | |
1976 | AC_SUBST([SNMP_CFLAGS]) | |
1977 | ||
1978 | dnl --------------- | |
1979 | dnl libyang | |
1980 | dnl --------------- | |
1981 | PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [ | |
1982 | AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.]) | |
1983 | ]) | |
1984 | ac_cflags_save="$CFLAGS" | |
1985 | CFLAGS="$CFLAGS $LIBYANG_CFLAGS" | |
1986 | AC_CHECK_MEMBER([struct lyd_node.priv], [], [ | |
1987 | AC_MSG_ERROR([m4_normalize([ | |
1988 | libyang needs to be compiled with ENABLE_LYD_PRIV=ON. | |
1989 | Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html]) | |
1990 | ]) | |
1991 | ], [[#include <libyang/libyang.h>]]) | |
1992 | CFLAGS="$ac_cflags_save" | |
1993 | ||
1994 | dnl --------------- | |
1995 | dnl configuration rollbacks | |
1996 | dnl --------------- | |
1997 | SQLITE3=false | |
1998 | if test "$enable_config_rollbacks" = "yes"; then | |
1999 | PKG_CHECK_MODULES([SQLITE3], [sqlite3], [ | |
2000 | AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks]) | |
2001 | AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database]) | |
2002 | SQLITE3=true | |
2003 | ], [ | |
2004 | AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.]) | |
2005 | ]) | |
2006 | fi | |
2007 | ||
2008 | dnl --------------- | |
2009 | dnl confd | |
2010 | dnl --------------- | |
2011 | if test "$enable_confd" != "" -a "$enable_confd" != "no"; then | |
2012 | AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin") | |
2013 | if test "$CONFD" = "/bin/false"; then | |
2014 | AC_MSG_ERROR([confd was not found on your system.])] | |
2015 | fi | |
2016 | AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin") | |
2017 | CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib" | |
2018 | AC_SUBST([CONFD_CFLAGS]) | |
2019 | CONFD_LIBS="-lconfd" | |
2020 | AC_SUBST([CONFD_LIBS]) | |
2021 | AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration]) | |
2022 | fi | |
2023 | ||
2024 | dnl --------------- | |
2025 | dnl sysrepo | |
2026 | dnl --------------- | |
2027 | if test "$enable_sysrepo" = "yes"; then | |
2028 | PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42], | |
2029 | [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration]) | |
2030 | SYSREPO=true], | |
2031 | [SYSREPO=false | |
2032 | AC_MSG_ERROR([sysrepo was not found on your system.])] | |
2033 | ) | |
2034 | fi | |
2035 | ||
2036 | dnl --------------- | |
2037 | dnl gRPC | |
2038 | dnl --------------- | |
2039 | if test "$enable_grpc" = "yes"; then | |
2040 | AC_LANG_PUSH([C++]) | |
2041 | AX_CXX_COMPILE_STDCXX([11], [ext]) | |
2042 | PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [ | |
2043 | AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false]) | |
2044 | if test "$PROTOC" = "/bin/false"; then | |
2045 | AC_MSG_FAILURE([grpc requested but protoc not found.]) | |
2046 | fi | |
2047 | ||
2048 | AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin]) | |
2049 | GRPC=true | |
2050 | ], [ | |
2051 | GRPC=false | |
2052 | AC_MSG_ERROR([grpc/grpc++ were not found on your system.]) | |
2053 | ]) | |
2054 | AC_LANG_POP([C++]) | |
2055 | fi | |
2056 | ||
2057 | dnl --------- | |
2058 | dnl DPDK | |
2059 | dnl --------- | |
2060 | if test "$enable_dp_dpdk" = "yes"; then | |
2061 | PKG_CHECK_MODULES([DPDK], [libdpdk], [ | |
2062 | AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend]) | |
2063 | DPDK=true | |
2064 | ], [ | |
2065 | AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found]) | |
2066 | ]) | |
2067 | fi | |
2068 | ||
2069 | dnl ----- | |
2070 | dnl LTTng | |
2071 | dnl ----- | |
2072 | if test "$enable_lttng" = "yes"; then | |
2073 | PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [ | |
2074 | AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support]) | |
2075 | LTTNG=true | |
2076 | ], [ | |
2077 | AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found]) | |
2078 | ]) | |
2079 | fi | |
2080 | ||
2081 | dnl ---- | |
2082 | dnl USDT | |
2083 | dnl ---- | |
2084 | if test "$enable_usdt" = "yes"; then | |
2085 | AC_CHECK_HEADERS([sys/sdt.h], [ | |
2086 | AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes]) | |
2087 | USDT=true | |
2088 | ], [ | |
2089 | AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found]) | |
2090 | ]) | |
2091 | fi | |
2092 | ||
2093 | dnl ------ | |
2094 | dnl ZeroMQ | |
2095 | dnl ------ | |
2096 | if test "$enable_zeromq" != "no"; then | |
2097 | PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [ | |
2098 | AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support]) | |
2099 | ZEROMQ=true | |
2100 | ], [ | |
2101 | if test "$enable_zeromq" = "yes"; then | |
2102 | AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found]) | |
2103 | fi | |
2104 | ]) | |
2105 | fi | |
2106 | ||
2107 | dnl ------------------------------------ | |
2108 | dnl Enable RPKI and add librtr to libs | |
2109 | dnl ------------------------------------ | |
2110 | if test "$enable_rpki" = "yes"; then | |
2111 | PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0], | |
2112 | [RPKI=true], | |
2113 | [RPKI=false | |
2114 | AC_MSG_ERROR([rtrlib was not found on your system or is too old.])] | |
2115 | ) | |
2116 | fi | |
2117 | ||
2118 | dnl ------------------------------------ | |
2119 | dnl pimd and pim6d not supported on OpenBSD and MacOS | |
2120 | dnl ------------------------------------ | |
2121 | if test "$enable_pimd" != "no"; then | |
2122 | AC_MSG_CHECKING([for pimd OS support]) | |
2123 | case "$host_os" in | |
2124 | darwin*) | |
2125 | AC_MSG_RESULT([no]) | |
2126 | enable_pimd="no" | |
2127 | ;; | |
2128 | openbsd*) | |
2129 | AC_MSG_RESULT([no]) | |
2130 | enable_pimd="no" | |
2131 | ;; | |
2132 | *) | |
2133 | AC_MSG_RESULT([yes]) | |
2134 | ;; | |
2135 | esac | |
2136 | fi | |
2137 | ||
2138 | if test "$enable_pim6d" != "no"; then | |
2139 | AC_MSG_CHECKING([for pim6d OS support]) | |
2140 | case "$host_os" in | |
2141 | linux*) | |
2142 | AC_MSG_RESULT([yes]) | |
2143 | ;; | |
2144 | *) | |
2145 | AC_MSG_RESULT([no]) | |
2146 | enable_pim6d="no" | |
2147 | ;; | |
2148 | esac | |
2149 | fi | |
2150 | ||
2151 | dnl ------------------------------------- | |
2152 | dnl VRRP is only supported on linux | |
2153 | dnl ------------------------------------- | |
2154 | if test "$enable_vrrpd" != "no"; then | |
2155 | AC_MSG_CHECKING([for VRRP OS support]) | |
2156 | case "$host_os" in | |
2157 | linux*) | |
2158 | AC_MSG_RESULT([yes]) | |
2159 | ;; | |
2160 | *) | |
2161 | AC_MSG_RESULT([no]) | |
2162 | enable_vrrpd="no" | |
2163 | ;; | |
2164 | esac | |
2165 | fi | |
2166 | ||
2167 | dnl ------------------------------------------ | |
2168 | dnl Check whether rtrlib was build with ssh support | |
2169 | dnl ------------------------------------------ | |
2170 | AC_MSG_CHECKING([whether the RTR Library is compiled with SSH]) | |
2171 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]], | |
2172 | [[struct tr_ssh_config config;]])], | |
2173 | [AC_MSG_RESULT([yes]) | |
2174 | AC_DEFINE([FOUND_SSH], [1], [found_ssh])], | |
2175 | AC_MSG_RESULT([no]) | |
2176 | ) | |
2177 | ||
2178 | dnl --------------- | |
2179 | dnl dlopen & dlinfo | |
2180 | dnl --------------- | |
2181 | LIBS_save="$LIBS" | |
2182 | AC_SEARCH_LIBS([dlopen], [dl dld], [], [ | |
2183 | AC_MSG_ERROR([unable to find the dlopen()]) | |
2184 | ]) | |
2185 | ||
2186 | AC_CHECK_HEADERS([link.h]) | |
2187 | ||
2188 | AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [ | |
2189 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[ | |
2190 | #include <stdlib.h> | |
2191 | #ifdef HAVE_LINK_H | |
2192 | #include <link.h> | |
2193 | #endif | |
2194 | #include <dlfcn.h> | |
2195 | ]], [[ | |
2196 | char origin[1]; | |
2197 | dlinfo (NULL, RTLD_DI_ORIGIN, &origin); | |
2198 | ]])], [ | |
2199 | frr_cv_rtld_di_origin=yes | |
2200 | ], [ | |
2201 | frr_cv_rtld_di_origin=no | |
2202 | ]) | |
2203 | ]) | |
2204 | if test "$frr_cv_rtld_di_origin" = "yes"; then | |
2205 | AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN]) | |
2206 | fi | |
2207 | ||
2208 | AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [ | |
2209 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[ | |
2210 | #include <stdlib.h> | |
2211 | #ifdef HAVE_LINK_H | |
2212 | #include <link.h> | |
2213 | #endif | |
2214 | #include <dlfcn.h> | |
2215 | ]], [[ | |
2216 | struct link_map *lm = NULL; | |
2217 | dlinfo (NULL, RTLD_DI_LINKMAP, &lm); | |
2218 | ]])], [ | |
2219 | frr_cv_rtld_di_linkmap=yes | |
2220 | ], [ | |
2221 | frr_cv_rtld_di_linkmap=no | |
2222 | ]) | |
2223 | ]) | |
2224 | if test "$frr_cv_rtld_di_linkmap" = "yes"; then | |
2225 | AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP]) | |
2226 | fi | |
2227 | ||
2228 | LIBDL="$LIBS" | |
2229 | LIBDL="${LIBDL%$LIBS_save}" | |
2230 | LIBDL="${LIBDL#$LIBS_save}" | |
2231 | AC_SUBST([LIBDL]) | |
2232 | LIBS="$LIBS_save" | |
2233 | unset LIBS_save | |
2234 | ||
2235 | dnl ########################################################################## | |
2236 | dnl test "$enable_clippy_only" != "yes" | |
2237 | fi | |
2238 | dnl END OF LARGE if block | |
2239 | dnl ########################################################################## | |
2240 | ||
2241 | dnl --------------------------- | |
2242 | dnl sockaddr and netinet checks | |
2243 | dnl --------------------------- | |
2244 | AC_CHECK_TYPES([ | |
2245 | struct sockaddr_dl, | |
2246 | struct vifctl, struct mfcctl, struct sioc_sg_req, | |
2247 | vifi_t, struct sioc_vif_req, struct igmpmsg, | |
2248 | struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq, | |
2249 | struct nd_opt_adv_interval, | |
2250 | struct nd_opt_homeagent_info, struct nd_opt_adv_interval, | |
2251 | struct nd_opt_rdnss, struct nd_opt_dnssl], | |
2252 | [], [], FRR_INCLUDES) | |
2253 | ||
2254 | AC_CHECK_MEMBERS([struct sockaddr.sa_len, | |
2255 | struct sockaddr_in.sin_len, struct sockaddr_un.sun_len, | |
2256 | struct sockaddr_dl.sdl_len, | |
2257 | struct if6_aliasreq.ifra_lifetime, | |
2258 | struct nd_opt_adv_interval.nd_opt_ai_type], | |
2259 | [], [], FRR_INCLUDES) | |
2260 | ||
2261 | dnl --------------------------- | |
2262 | dnl IRDP/pktinfo/icmphdr checks | |
2263 | dnl --------------------------- | |
2264 | ||
2265 | AC_CHECK_TYPES([struct in_pktinfo], [ | |
2266 | AC_CHECK_TYPES([struct icmphdr], [ | |
2267 | IRDP=true | |
2268 | ], [ | |
2269 | IRDP=false | |
2270 | ], [FRR_INCLUDES]) | |
2271 | ], [ | |
2272 | IRDP=false | |
2273 | ], [FRR_INCLUDES]) | |
2274 | ||
2275 | case "${enable_irdp}" in | |
2276 | yes) | |
2277 | $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!']) | |
2278 | ;; | |
2279 | no) | |
2280 | IRDP=false | |
2281 | ;; | |
2282 | esac | |
2283 | ||
2284 | ||
2285 | dnl ----------------------- | |
2286 | dnl checking for IP_PKTINFO | |
2287 | dnl ----------------------- | |
2288 | AC_MSG_CHECKING([for IP_PKTINFO]) | |
2289 | AC_COMPILE_IFELSE( | |
2290 | [ AC_LANG_PROGRAM([[ | |
2291 | #include <netdb.h> | |
2292 | ]], [[ | |
2293 | int opt = IP_PKTINFO; | |
2294 | ]]) | |
2295 | ],[ | |
2296 | AC_MSG_RESULT([yes]) | |
2297 | AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO]) | |
2298 | ],[ | |
2299 | AC_MSG_RESULT([no]) | |
2300 | ]) | |
2301 | ||
2302 | dnl --------------------------- | |
2303 | dnl checking for IP_RECVDSTADDR | |
2304 | dnl --------------------------- | |
2305 | AC_MSG_CHECKING([for IP_RECVDSTADDR]) | |
2306 | AC_COMPILE_IFELSE( | |
2307 | [ AC_LANG_PROGRAM([[ | |
2308 | #include <netinet/in.h> | |
2309 | ]], [[ | |
2310 | int opt = IP_RECVDSTADDR; | |
2311 | ]]) | |
2312 | ],[ | |
2313 | AC_MSG_RESULT([yes]) | |
2314 | AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR]) | |
2315 | ],[ | |
2316 | AC_MSG_RESULT([no]) | |
2317 | ]) | |
2318 | ||
2319 | dnl ---------------------- | |
2320 | dnl checking for IP_RECVIF | |
2321 | dnl ---------------------- | |
2322 | AC_MSG_CHECKING([for IP_RECVIF]) | |
2323 | AC_COMPILE_IFELSE( | |
2324 | [ AC_LANG_PROGRAM([[ | |
2325 | #include <netinet/in.h> | |
2326 | ]], [[ | |
2327 | int opt = IP_RECVIF; | |
2328 | ]]) | |
2329 | ],[ | |
2330 | AC_MSG_RESULT([yes]) | |
2331 | AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF]) | |
2332 | ],[ | |
2333 | AC_MSG_RESULT([no]) | |
2334 | ]) | |
2335 | ||
2336 | dnl ---------------------- | |
2337 | dnl checking for SO_BINDANY | |
2338 | dnl ---------------------- | |
2339 | AC_MSG_CHECKING([for SO_BINDANY]) | |
2340 | AC_COMPILE_IFELSE( | |
2341 | [ AC_LANG_PROGRAM([[ | |
2342 | #include <sys/socket.h> | |
2343 | ]], [[ | |
2344 | int opt = SO_BINDANY; | |
2345 | ]]) | |
2346 | ],[ | |
2347 | AC_MSG_RESULT([yes]) | |
2348 | AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY]) | |
2349 | ],[ | |
2350 | AC_MSG_RESULT([no]) | |
2351 | ]) | |
2352 | ||
2353 | dnl ---------------------- | |
2354 | dnl checking for IP_FREEBIND | |
2355 | dnl ---------------------- | |
2356 | AC_MSG_CHECKING([for IP_FREEBIND]) | |
2357 | AC_COMPILE_IFELSE( | |
2358 | [ AC_LANG_PROGRAM([[ | |
2359 | #include <netinet/in.h> | |
2360 | ]], [[ | |
2361 | int opt = IP_FREEBIND; | |
2362 | ]]) | |
2363 | ],[ | |
2364 | AC_MSG_RESULT([yes]) | |
2365 | AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND]) | |
2366 | ],[ | |
2367 | AC_MSG_RESULT([no]) | |
2368 | ]) | |
2369 | ||
2370 | dnl -------------------------------------- | |
2371 | dnl checking for be32dec existence or not | |
2372 | dnl -------------------------------------- | |
2373 | AC_CHECK_DECLS([be32enc, be32dec], [], [], [ | |
2374 | #ifdef HAVE_SYS_ENDIAN_H | |
2375 | #include <sys/endian.h> | |
2376 | #endif | |
2377 | #ifdef HAVE_ENDIAN_H | |
2378 | #include <endian.h> | |
2379 | #endif | |
2380 | ]) | |
2381 | ||
2382 | dnl -------------------------------------- | |
2383 | dnl checking for clock_time monotonic struct and call | |
2384 | dnl -------------------------------------- | |
2385 | AC_CHECK_DECL([CLOCK_MONOTONIC], | |
2386 | [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"]) | |
2387 | AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock]) | |
2388 | ], [AC_MSG_RESULT([no])], [FRR_INCLUDES]) | |
2389 | ||
2390 | AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [ | |
2391 | AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock]) | |
2392 | ], [AC_MSG_RESULT([no])], [FRR_INCLUDES]) | |
2393 | ||
2394 | AC_SEARCH_LIBS([clock_nanosleep], [rt], [ | |
2395 | AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()]) | |
2396 | ]) | |
2397 | ||
2398 | dnl -------------------------------------- | |
2399 | dnl checking for flex and bison | |
2400 | dnl -------------------------------------- | |
2401 | ||
2402 | dnl autoconf 2.69 AC_PROG_LEX has no parameters | |
2403 | dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params | |
2404 | m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl | |
2405 | dnl autoconf < 2.70 | |
2406 | AC_PROG_LEX | |
2407 | ], [ | |
2408 | dnl autoconf >= 2.70 | |
2409 | AC_PROG_LEX([noyywrap]) | |
2410 | ]) | |
2411 | ||
2412 | AC_MSG_CHECKING([version of flex]) | |
2413 | frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)" | |
2414 | frr_ac_flex_version="${frr_ac_flex_version##* }" | |
2415 | AC_MSG_RESULT([$frr_ac_flex_version]) | |
2416 | AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [ | |
2417 | LEX="$SHELL $missing_dir/missing flex" | |
2418 | if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then | |
2419 | AC_MSG_WARN([using pregenerated flex output files]) | |
2420 | else | |
2421 | AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)]) | |
2422 | fi | |
2423 | AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy]) | |
2424 | AC_SUBST([LEXLIB], ['']) | |
2425 | ]) | |
2426 | ||
2427 | AC_PROG_YACC | |
2428 | dnl thanks GNU bison for this b*llshit... | |
2429 | AC_MSG_CHECKING([version of bison]) | |
2430 | frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)" | |
2431 | frr_ac_bison_version="${frr_ac_bison_version##* }" | |
2432 | frr_ac_bison_missing="false" | |
2433 | case "x${frr_ac_bison_version}x" in | |
2434 | x2.7*) | |
2435 | BISON_OPENBRACE='"' | |
2436 | BISON_CLOSEBRACE='"' | |
2437 | BISON_VERBOSE='' | |
2438 | AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older]) | |
2439 | ;; | |
2440 | x2.*|x1.*) | |
2441 | AC_MSG_RESULT([$frr_ac_bison_version]) | |
2442 | AC_MSG_WARN([installed bison is too old. Please install GNU bison 2.7.x or newer.]) | |
2443 | frr_ac_bison_missing="true" | |
2444 | ;; | |
2445 | x) | |
2446 | AC_MSG_RESULT([none]) | |
2447 | AC_MSG_WARN([could not determine bison version. Please install GNU bison 2.7.x or newer.]) | |
2448 | frr_ac_bison_missing="true" | |
2449 | ;; | |
2450 | x3.[012][^0-9]*) | |
2451 | BISON_OPENBRACE='{' | |
2452 | BISON_CLOSEBRACE='}' | |
2453 | BISON_VERBOSE='-Dparse.error=verbose' | |
2454 | AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2]) | |
2455 | ;; | |
2456 | *) | |
2457 | BISON_OPENBRACE='{' | |
2458 | BISON_CLOSEBRACE='}' | |
2459 | BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc' | |
2460 | AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer]) | |
2461 | ;; | |
2462 | esac | |
2463 | AC_SUBST([BISON_OPENBRACE]) | |
2464 | AC_SUBST([BISON_CLOSEBRACE]) | |
2465 | AC_SUBST([BISON_VERBOSE]) | |
2466 | ||
2467 | if $frr_ac_bison_missing; then | |
2468 | YACC="$SHELL $missing_dir/missing bison -y" | |
2469 | if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then | |
2470 | AC_MSG_WARN([using pregenerated bison output files]) | |
2471 | else | |
2472 | AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)]) | |
2473 | fi | |
2474 | fi | |
2475 | ||
2476 | dnl ------------------- | |
2477 | dnl capabilities checks | |
2478 | dnl ------------------- | |
2479 | if test "$enable_capabilities" != "no"; then | |
2480 | AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available]) | |
2481 | AC_COMPILE_IFELSE( | |
2482 | [ AC_LANG_PROGRAM([[ | |
2483 | #include <sys/prctl.h> | |
2484 | ]], [[ | |
2485 | prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0); | |
2486 | ]]) | |
2487 | ],[AC_MSG_RESULT([yes]) | |
2488 | AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl]) | |
2489 | frr_ac_keepcaps="yes" | |
2490 | ],[AC_MSG_RESULT(no) | |
2491 | ]) | |
2492 | if test "$frr_ac_keepcaps" = "yes"; then | |
2493 | AC_CHECK_HEADERS([sys/capability.h]) | |
2494 | fi | |
2495 | if test "$ac_cv_header_sys_capability_h" = "yes"; then | |
2496 | AC_CHECK_LIB([cap], [cap_init], | |
2497 | [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities]) | |
2498 | LIBCAP="-lcap" | |
2499 | frr_ac_lcaps="yes"] | |
2500 | ) | |
2501 | fi | |
2502 | if test "$frr_ac_scaps" = "yes" \ | |
2503 | -o "$frr_ac_lcaps" = "yes"; then | |
2504 | AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities]) | |
2505 | fi | |
2506 | ||
2507 | case "$host_os" in | |
2508 | linux*) | |
2509 | if test "$enable_clippy_only" != "yes"; then | |
2510 | if test "$frr_ac_lcaps" != "yes"; then | |
2511 | AC_MSG_ERROR([libcap and/or its headers were not found. Running FRR without libcap support built in causes a huge performance penalty.]) | |
2512 | fi | |
2513 | fi | |
2514 | ;; | |
2515 | esac | |
2516 | else | |
2517 | case "$host_os" in | |
2518 | linux*) | |
2519 | AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.]) | |
2520 | ;; | |
2521 | esac | |
2522 | fi | |
2523 | AC_SUBST([LIBCAP]) | |
2524 | ||
2525 | dnl --------------------------- | |
2526 | dnl check for glibc 'backtrace' | |
2527 | dnl --------------------------- | |
2528 | if test "$enable_backtrace" != "no" ; then | |
2529 | backtrace_ok=no | |
2530 | PKG_CHECK_MODULES([UNWIND], [libunwind], [ | |
2531 | AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind]) | |
2532 | backtrace_ok=yes | |
2533 | ], [ | |
2534 | true | |
2535 | ]) | |
2536 | ||
2537 | if test "$backtrace_ok" = "no"; then | |
2538 | AC_CHECK_HEADER([unwind.h], [ | |
2539 | AC_SEARCH_LIBS([unw_getcontext], [unwind], [ | |
2540 | AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind]) | |
2541 | backtrace_ok=yes | |
2542 | ]) | |
2543 | ]) | |
2544 | fi | |
2545 | ||
2546 | if test "$backtrace_ok" = "no"; then | |
2547 | AC_CHECK_HEADER([execinfo.h], [ | |
2548 | AC_SEARCH_LIBS([backtrace], [execinfo], [ | |
2549 | AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace]) | |
2550 | backtrace_ok=yes | |
2551 | ],, [-lm]) | |
2552 | ]) | |
2553 | fi | |
2554 | ||
2555 | if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then | |
2556 | dnl user explicitly requested backtrace but we failed to find support | |
2557 | AC_MSG_FAILURE([failed to find backtrace or libunwind support]) | |
2558 | fi | |
2559 | fi | |
2560 | ||
2561 | dnl ----------------------------------------- | |
2562 | dnl check for malloc mallinfo struct and call | |
2563 | dnl this must try and link using LIBS, in | |
2564 | dnl order to check no alternative allocator | |
2565 | dnl has been specified, which might not provide | |
2566 | dnl mallinfo | |
2567 | dnl ----------------------------------------- | |
2568 | AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES]) | |
2569 | ||
2570 | AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [ | |
2571 | AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [ | |
2572 | #ifdef HAVE_MALLOC_H | |
2573 | #include <malloc.h> | |
2574 | #endif | |
2575 | #ifdef HAVE_MALLOC_NP_H | |
2576 | #include <malloc_np.h> | |
2577 | #endif | |
2578 | #ifdef HAVE_MALLOC_MALLOC_H | |
2579 | #include <malloc/malloc.h> | |
2580 | #endif | |
2581 | ]], [[ | |
2582 | struct mallinfo ac_x; ac_x = mallinfo (); | |
2583 | ]])], [ | |
2584 | frr_cv_mallinfo=yes | |
2585 | ], [ | |
2586 | frr_cv_mallinfo=no | |
2587 | ]) | |
2588 | ]) | |
2589 | if test "$frr_cv_mallinfo" = "yes"; then | |
2590 | AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo]) | |
2591 | fi | |
2592 | ||
2593 | AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [ | |
2594 | AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [ | |
2595 | #ifdef HAVE_MALLOC_H | |
2596 | #include <malloc.h> | |
2597 | #endif | |
2598 | #ifdef HAVE_MALLOC_NP_H | |
2599 | #include <malloc_np.h> | |
2600 | #endif | |
2601 | #ifdef HAVE_MALLOC_MALLOC_H | |
2602 | #include <malloc/malloc.h> | |
2603 | #endif | |
2604 | ]], [[ | |
2605 | struct mallinfo2 ac_x; ac_x = mallinfo2 (); | |
2606 | ]])], [ | |
2607 | frr_cv_mallinfo2=yes | |
2608 | ], [ | |
2609 | frr_cv_mallinfo2=no | |
2610 | ]) | |
2611 | ]) | |
2612 | if test "$frr_cv_mallinfo2" = "yes"; then | |
2613 | AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2]) | |
2614 | fi | |
2615 | ||
2616 | AC_MSG_CHECKING([whether malloc_usable_size is available]) | |
2617 | AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [ | |
2618 | #ifdef HAVE_MALLOC_H | |
2619 | #include <malloc.h> | |
2620 | #endif | |
2621 | #ifdef HAVE_MALLOC_MALLOC_H | |
2622 | #include <malloc/malloc.h> | |
2623 | #endif | |
2624 | ]], [[ | |
2625 | size_t ac_x; ac_x = malloc_usable_size(NULL); | |
2626 | ]])], [ | |
2627 | AC_MSG_RESULT([yes]) | |
2628 | AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size]) | |
2629 | ], [ | |
2630 | AC_MSG_RESULT([no]) | |
2631 | ||
2632 | AC_MSG_CHECKING([whether malloc_size is available]) | |
2633 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[ | |
2634 | #ifdef HAVE_MALLOC_H | |
2635 | #include <malloc.h> | |
2636 | #endif | |
2637 | #ifdef HAVE_MALLOC_MALLOC_H | |
2638 | #include <malloc/malloc.h> | |
2639 | #endif | |
2640 | ]], [[ | |
2641 | size_t ac_x; ac_x = malloc_size(NULL); | |
2642 | ]])], [ | |
2643 | AC_MSG_RESULT([yes]) | |
2644 | AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size]) | |
2645 | ], [ | |
2646 | AC_MSG_RESULT([no]) | |
2647 | ]) | |
2648 | ]) | |
2649 | ||
2650 | dnl ---------- | |
2651 | dnl configure date | |
2652 | dnl ---------- | |
2653 | dev_version=`echo $VERSION | grep dev` | |
2654 | #don't expire deprecated code in non 'dev' branch | |
2655 | if test "$dev_version" = ""; then | |
2656 | CONFDATE=0 | |
2657 | else | |
2658 | CONFDATE=`date '+%Y%m%d'` | |
2659 | fi | |
2660 | AC_SUBST([CONFDATE]) | |
2661 | ||
2662 | dnl ------------------------------ | |
2663 | dnl set paths for state directory | |
2664 | dnl ------------------------------ | |
2665 | AC_MSG_CHECKING([directory to use for state file]) | |
2666 | if test "$prefix" = "NONE"; then | |
2667 | frr_statedir_prefix=""; | |
2668 | else | |
2669 | frr_statedir_prefix=${prefix} | |
2670 | fi | |
2671 | if test "$localstatedir" = '${prefix}/var'; then | |
2672 | for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl | |
2673 | ${frr_statedir_prefix}/var/adm dnl | |
2674 | ${frr_statedir_prefix}/etc dnl | |
2675 | /var/run dnl | |
2676 | /var/adm dnl | |
2677 | /etc dnl | |
2678 | /dev/null; | |
2679 | do | |
2680 | test -d $FRR_STATE_DIR && break | |
2681 | done | |
2682 | frr_statedir=$FRR_STATE_DIR | |
2683 | else | |
2684 | frr_statedir=${localstatedir} | |
2685 | fi | |
2686 | if test "$frr_statedir" = "/dev/null"; then | |
2687 | AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!]) | |
2688 | fi | |
2689 | AC_MSG_RESULT([${frr_statedir}]) | |
2690 | AC_SUBST([frr_statedir]) | |
2691 | ||
2692 | AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket]) | |
2693 | AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket]) | |
2694 | AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket]) | |
2695 | AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information]) | |
2696 | AC_DEFINE_UNQUOTED([MGMTD_FE_SERVER_PATH], ["$frr_statedir/mgmtd_fe.sock"], [mgmtd frontend server socket]) | |
2697 | AC_DEFINE_UNQUOTED([MGMTD_BE_SERVER_PATH], ["$frr_statedir/mgmtd_be.sock"], [mgmtd backend server socket]) | |
2698 | AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information]) | |
2699 | AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information]) | |
2700 | AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information]) | |
2701 | AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory]) | |
2702 | AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory]) | |
2703 | ||
2704 | dnl autoconf does this, but it does it too late... | |
2705 | test "$prefix" = "NONE" && prefix=$ac_default_prefix | |
2706 | test "$exec_prefix" = "NONE" && exec_prefix='${prefix}' | |
2707 | ||
2708 | dnl get the full path, recursing through variables... | |
2709 | vtysh_bin="$bindir/vtysh" | |
2710 | for I in 1 2 3 4 5 6 7 8 9 10; do | |
2711 | eval vtysh_bin="\"$vtysh_bin\"" | |
2712 | done | |
2713 | AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary]) | |
2714 | AC_SUBST([vtysh_bin]) | |
2715 | ||
2716 | CFG_SYSCONF="$sysconfdir" | |
2717 | CFG_SBIN="$sbindir" | |
2718 | CFG_BIN="$bindir" | |
2719 | CFG_STATE="$frr_statedir" | |
2720 | CFG_MODULE="$moduledir" | |
2721 | CFG_YANGMODELS="$yangmodelsdir" | |
2722 | CFG_SCRIPT="$scriptdir" | |
2723 | for I in 1 2 3 4 5 6 7 8 9 10; do | |
2724 | eval CFG_SYSCONF="\"$CFG_SYSCONF\"" | |
2725 | eval CFG_SBIN="\"$CFG_SBIN\"" | |
2726 | eval CFG_BIN="\"$CFG_BIN\"" | |
2727 | eval CFG_STATE="\"$CFG_STATE\"" | |
2728 | eval CFG_MODULE="\"$CFG_MODULE\"" | |
2729 | eval CFG_YANGMODELS="\"$CFG_YANGMODELS\"" | |
2730 | eval CFG_SCRIPT="\"$CFG_SCRIPT\"" | |
2731 | done | |
2732 | AC_SUBST([CFG_SYSCONF]) | |
2733 | AC_SUBST([CFG_SBIN]) | |
2734 | AC_SUBST([CFG_BIN]) | |
2735 | AC_SUBST([CFG_STATE]) | |
2736 | AC_SUBST([CFG_MODULE]) | |
2737 | AC_SUBST([CFG_SCRIPT]) | |
2738 | AC_SUBST([CFG_YANGMODELS]) | |
2739 | AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules]) | |
2740 | AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts]) | |
2741 | AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models]) | |
2742 | AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh]) | |
2743 | ||
2744 | dnl various features | |
2745 | AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"]) | |
2746 | AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"]) | |
2747 | AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp]) | |
2748 | dnl northbound | |
2749 | AM_CONDITIONAL([SQLITE3], [$SQLITE3]) | |
2750 | AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""]) | |
2751 | AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"]) | |
2752 | AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"]) | |
2753 | AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"]) | |
2754 | dnl plugins | |
2755 | AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"]) | |
2756 | AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"]) | |
2757 | AM_CONDITIONAL([IRDP], [$IRDP]) | |
2758 | AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"]) | |
2759 | AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" != "no"]) | |
2760 | AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3]) | |
2761 | ||
2762 | dnl PCEP plugin | |
2763 | AS_IF([test "$enable_pathd" != "no"], [ | |
2764 | AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"]) | |
2765 | AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "]) | |
2766 | ]) | |
2767 | AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no]) | |
2768 | AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes]) | |
2769 | AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes) | |
2770 | AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"]) | |
2771 | ||
2772 | dnl daemons | |
2773 | AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"]) | |
2774 | AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"]) | |
2775 | AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"]) | |
2776 | AM_CONDITIONAL([MGMTD], [test "$enable_mgmtd" != "no"]) | |
2777 | AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"]) | |
2778 | AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"]) | |
2779 | AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"]) | |
2780 | AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"]) | |
2781 | AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"]) | |
2782 | AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"]) | |
2783 | AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"]) | |
2784 | AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"]) | |
2785 | AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"]) | |
2786 | AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"]) | |
2787 | AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"]) | |
2788 | AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"]) | |
2789 | AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"]) | |
2790 | AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" != "no"]) | |
2791 | AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"]) | |
2792 | AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"]) | |
2793 | AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"]) | |
2794 | AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"]) | |
2795 | AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"]) | |
2796 | AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"]) | |
2797 | AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"]) | |
2798 | AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"]) | |
2799 | ||
2800 | AC_CONFIG_FILES([Makefile],[ | |
2801 | test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build" | |
2802 | ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1 | |
2803 | ], [ | |
2804 | PYTHON="$PYTHON" | |
2805 | enable_dev_build="$enable_dev_build" | |
2806 | ]) | |
2807 | ||
2808 | AC_CONFIG_FILES([ | |
2809 | config.version | |
2810 | redhat/frr.spec | |
2811 | alpine/APKBUILD | |
2812 | snapcraft/snapcraft.yaml | |
2813 | lib/version.h | |
2814 | tests/lib/cli/test_cli.refout pkgsrc/mgmtd.sh | |
2815 | pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh | |
2816 | pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh | |
2817 | pkgsrc/eigrpd.sh]) | |
2818 | ||
2819 | AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr]) | |
2820 | AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh]) | |
2821 | AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh]) | |
2822 | AC_CONFIG_FILES([tools/frrcommon.sh]) | |
2823 | AC_CONFIG_FILES([tools/frr.service]) | |
2824 | AC_CONFIG_FILES([tools/frr@.service]) | |
2825 | ||
2826 | # dnl write out a ccls file with our compile configuration | |
2827 | # dnl have to add -Wno-unused-function otherwise foobar_cmd_magic causes | |
2828 | # dnl all DEFPY(), et al., macros to flag as errors. | |
2829 | AS_IF([test "$enable_ccls" = "yes"], [ | |
2830 | AC_CONFIG_COMMANDS([gen-dot-ccls], [ | |
2831 | cat > "${srcdir}/.ccls" <<EOF | |
2832 | clang | |
2833 | -DHAVE_CONFIG_H | |
2834 | -I. | |
2835 | -I./include | |
2836 | -I./lib | |
2837 | -I./lib/assert | |
2838 | -DSYSCONFDIR="${ac_frr_sysconfdir}" | |
2839 | -DCONFDATE=${ac_frr_confdate} | |
2840 | EOF | |
2841 | if test "$ac_abs_top_builddir" != "$ac_abs_top_srcdir"; then | |
2842 | echo "-I${ac_abs_top_builddir}" >> "${srcdir}/.ccls" | |
2843 | fi | |
2844 | if test -n "$FRR_ALL_CCLS_FLAGS"; then | |
2845 | echo ${FRR_ALL_CCLS_FLAGS} | tr ' ' '\n' >> "${srcdir}/.ccls" | |
2846 | fi | |
2847 | if test -n "$FRR_ALL_CCLS_CFLAGS"; then | |
2848 | cat >> "${srcdir}/.ccls" <<EOF | |
2849 | %c $(echo ${FRR_ALL_CCLS_CFLAGS} | sed -e 's/ */\n%c /g') | |
2850 | %c -Wno-unused-function | |
2851 | EOF | |
2852 | fi | |
2853 | ], [ | |
2854 | FRR_ALL_CCLS_FLAGS="$(echo ${LIBYANG_CFLAGS} ${LUA_INCLUDE} ${SQLITE3_CFLAGS} | sed -e 's/ */ /g')" | |
2855 | FRR_ALL_CCLS_CFLAGS="$(echo ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS} | sed -e 's/ */ /g')" | |
2856 | ac_frr_confdate="${CONFDATE}" | |
2857 | ac_frr_sysconfdir="${sysconfdir}/" | |
2858 | ]) | |
2859 | ]) | |
2860 | ||
2861 | ||
2862 | AS_IF([test "$with_pkg_git_version" = "yes"], [ | |
2863 | AC_CONFIG_COMMANDS([lib/gitversion.h], [ | |
2864 | dst="${ac_abs_top_builddir}/lib/gitversion.h" | |
2865 | ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \ | |
2866 | "${ac_abs_top_srcdir}" \ | |
2867 | > "${dst}.tmp" | |
2868 | test -f "$dst" \ | |
2869 | && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \ | |
2870 | && rm "${dst}.tmp" \ | |
2871 | || mv "${dst}.tmp" "${dst}" | |
2872 | ], [ | |
2873 | PERL="$PERL" | |
2874 | ]) | |
2875 | ]) | |
2876 | ||
2877 | ## Hack, but working solution to avoid rebuilding of frr.info. | |
2878 | ## It's already in CVS until texinfo 4.7 is more common. | |
2879 | AC_OUTPUT | |
2880 | ||
2881 | if test "$enable_rpath" = "yes" ; then | |
2882 | true | |
2883 | else | |
2884 | # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath | |
2885 | sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool | |
2886 | sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool > libtool.sed && cat libtool.sed > libtool | |
2887 | test -f libtool.sed && rm libtool.sed | |
2888 | fi | |
2889 | ||
2890 | echo " | |
2891 | FRRouting configuration | |
2892 | ------------------------------ | |
2893 | FRR version : ${PACKAGE_VERSION} | |
2894 | host operating system : ${host_os} | |
2895 | source code location : ${srcdir} | |
2896 | compiler : ${CC} | |
2897 | compiler flags : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS} | |
2898 | make : ${MAKE-make} | |
2899 | linker flags : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM} | |
2900 | state file directory : ${frr_statedir} | |
2901 | config file directory : `eval echo \`echo ${sysconfdir}\`` | |
2902 | module directory : ${CFG_MODULE} | |
2903 | script directory : ${CFG_SCRIPT} | |
2904 | user to run as : ${enable_user} | |
2905 | group to run as : ${enable_group} | |
2906 | group for vty sockets : ${enable_vty_group} | |
2907 | config file mask : ${enable_configfile_mask} | |
2908 | log file mask : ${enable_logfile_mask} | |
2909 | zebra protobuf enabled : ${enable_protobuf:-no} | |
2910 | vici socket path : ${vici_socket} | |
2911 | ||
2912 | The above user and group must have read/write access to the state file | |
2913 | directory and to the config files in the config file directory." | |
2914 | ||
2915 | if test -n "$enable_datacenter"; then | |
2916 | AC_MSG_WARN([The --enable-datacenter compile time option is deprecated. Please modify the init script to pass -F datacenter to the daemons instead.]) | |
2917 | fi | |
2918 | if test -n "$enable_time_check"; then | |
2919 | AC_MSG_WARN([The --enable-time-check compile time option is deprecated. Please use the service cputime-stats configuration option instead.]) | |
2920 | fi | |
2921 | if test -n "$enable_cpu_time"; then | |
2922 | AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated. Please use the service cputime-warning NNN configuration option instead.]) | |
2923 | fi | |
2924 | ||
2925 | if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then | |
2926 | AC_MSG_WARN([sphinx is missing but required to build documentation]) | |
2927 | fi | |
2928 | if test "$frr_py_mod_pytest" = "false"; then | |
2929 | AC_MSG_WARN([pytest is missing, unit tests cannot be performed]) | |
2930 | fi |