]> git.proxmox.com Git - mirror_frr.git/blame_incremental - configure.ac
projects / mirror_frr.git / blame_incremental
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (non-incremental) | history | HEAD
Merge pull request #1324 from donaldsharp/bgp_aspath
[mirror_frr.git] / configure.ac
... / ...
CommitLineData
1##
2## Configure template file for FRRouting.
3## autoconf will generate configure script.
4##
5## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
6## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
7##
8AC_PREREQ(2.60)
9
10AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
11PACKAGE_URL="https://frrouting.org/"
12AC_SUBST(PACKAGE_URL)
13PACKAGE_FULLNAME="FRRouting"
14AC_SUBST(PACKAGE_FULLNAME)
15
16CONFIG_ARGS="$ac_configure_args"
17AC_SUBST(CONFIG_ARGS)
18
19AC_CONFIG_SRCDIR(lib/zebra.h)
20AC_CONFIG_MACRO_DIR([m4])
21
22dnl -----------------------------------
23dnl Get hostname and other information.
24dnl -----------------------------------
25AC_CANONICAL_BUILD()
26AC_CANONICAL_HOST()
27
28AS_IF([test "$host" != "$build"], [
29 if test "$srcdir" = "."; then
30 AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir. create a separate directory and run as .../path-to-frr/configure.])
31 fi
32 test -d hosttools || mkdir hosttools
33 abssrc="`cd \"${srcdir}\"; pwd`"
34
35 AC_MSG_NOTICE([...])
36 AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
37 AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
38 AC_MSG_NOTICE([...])
39
40 ( CPPFLAGS="$HOST_CPPFLAGS"; \
41 CFLAGS="$HOST_CFLAGS"; \
42 LDFLAGS="$HOST_LDFLAGS"; \
43 cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
44
45 AC_MSG_NOTICE([...])
46 AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
47 AC_MSG_NOTICE([...])
48
49 build_clippy="false"
50 HOSTTOOLS="hosttools/"
51], [
52 build_clippy="true"
53 HOSTTOOLS=""
54])
55AC_SUBST(HOSTTOOLS)
56AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
57
58# Disable portability warnings -- our automake code (in particular
59# common.am) uses some constructs specific to gmake.
60AM_INIT_AUTOMAKE([1.12 -Wno-portability])
61m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
62AM_SILENT_RULES([yes])
63AC_CONFIG_HEADERS(config.h)
64
65AC_PATH_PROG(PERL, perl)
66PKG_PROG_PKG_CONFIG
67
68dnl default is to match previous behavior
69exampledir=${sysconfdir}
70AC_ARG_ENABLE([exampledir],
71 AS_HELP_STRING([--enable-exampledir],
72 [specify alternate directory for examples]),
73 exampledir="$enableval",)
74dnl XXX add --exampledir to autoconf standard directory list somehow
75AC_SUBST(exampledir)
76
77dnl default is to match previous behavior
78pkgsrcrcdir=""
79AC_ARG_ENABLE([pkgsrcrcdir],
80 AS_HELP_STRING([--enable-pkgsrcrcdir],
81 [specify directory for rc.d scripts]),
82 pkgsrcrcdir="$enableval",)
83dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
84AC_SUBST(pkgsrcrcdir)
85AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
86
87AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
88 moduledir="$withval"
89], [
90 moduledir="\${libdir}/frr/modules"
91])
92AC_SUBST([moduledir], [$moduledir])
93
94AC_ARG_ENABLE(tcmalloc,
95 AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
96[case "${enableval}" in
97 yes) tcmalloc_enabled=true
98LIBS="$LIBS -ltcmalloc_minimal"
99 ;;
100 no) tcmalloc_enabled=false ;;
101 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
102esac],[tcmalloc_enabled=false])
103
104
105dnl Thanks autoconf, but we don't want a default -g -O2. We have our own
106dnl flag determination logic.
107CFLAGS="${CFLAGS:-}"
108
109dnl --------------------
110dnl Check CC and friends
111dnl --------------------
112dnl note orig_cflags is also used further down
113orig_cflags="$CFLAGS"
114AC_LANG([C])
115AC_PROG_CC
116AC_PROG_CPP
117AM_PROG_CC_C_O
118dnl remove autoconf default "-g -O2"
119CFLAGS="$orig_cflags"
120AC_PROG_CC_C99
121dnl NB: see C11 below
122
123AC_PROG_EGREP
124PKG_PROG_PKG_CONFIG
125
126dnl autoconf 2.59 appears not to support AC_PROG_SED
127dnl AC_PROG_SED
128AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
129
130dnl try and enable CFLAGS that are useful for FRR
131dnl - specifically, options to control warnings
132
133AC_USE_SYSTEM_EXTENSIONS
134AC_DEFUN([AC_C_FLAG], [{
135 AC_LANG_PUSH(C)
136 ac_c_flag_save="$CFLAGS"
137 CFLAGS="$CFLAGS $1"
138 AC_MSG_CHECKING([[whether $CC supports $1]])
139 AC_COMPILE_IFELSE(
140 [AC_LANG_PROGRAM([[]])],
141 [
142 AC_MSG_RESULT([yes])
143 m4_if([$3], [], [], [
144 CFLAGS="$ac_c_flag_save"
145 $3
146 ])
147 ], [
148 CFLAGS="$ac_c_flag_save"
149 AC_MSG_RESULT([no])
150 $2
151 ])
152 AC_LANG_POP(C)
153 }])
154
155AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
156 AC_LANG_PUSH(C)
157 ac_cflags_save="$CFLAGS"
158 ac_libs_save="$LIBS"
159 CFLAGS="$CFLAGS $1"
160 LIBS="$LIBS $2"
161 AC_LINK_IFELSE(
162 [$3],
163 [
164 AC_MSG_RESULT([yes])
165 CFLAGS="$ac_cflags_save"
166 LIBS="$ac_libs_save"
167 $5
168 ], [
169 AC_MSG_RESULT([no])
170 CFLAGS="$ac_cflags_save"
171 LIBS="$ac_libs_save"
172 $4
173 ])
174 AC_LANG_POP(C)
175 }])
176
177dnl ICC won't bail on unknown options without -diag-error 10006
178dnl need to do this first so we get useful results for the other options
179AC_C_FLAG([-diag-error 10006])
180
181dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
182ac_cc="$CC"
183CC="${CC% -std=gnu99}"
184CC="${CC% -std=c99}"
185
186AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
187
188dnl if the user has specified any CFLAGS, override our settings
189if test "x${enable_dev_build}" = "xyes"; then
190 AC_DEFINE(DEV_BUILD,,Build for development)
191 if test "z$orig_cflags" = "z"; then
192 AC_C_FLAG([-g3])
193 AC_C_FLAG([-O0])
194 fi
195else
196 if test "z$orig_cflags" = "z"; then
197 AC_C_FLAG([-g])
198 AC_C_FLAG([-Os], [
199 AC_C_FLAG([-O2])
200 ])
201 fi
202fi
203AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
204
205dnl always want these CFLAGS
206AC_C_FLAG([-fno-omit-frame-pointer])
207AC_C_FLAG([-funwind-tables])
208AC_C_FLAG([-Wall])
209AC_C_FLAG([-Wextra])
210AC_C_FLAG([-Wmissing-prototypes])
211AC_C_FLAG([-Wmissing-declarations])
212AC_C_FLAG([-Wpointer-arith])
213AC_C_FLAG([-Wbad-function-cast])
214AC_C_FLAG([-Wwrite-strings])
215if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
216 AC_C_FLAG([-Wcast-qual])
217 AC_C_FLAG([-Wstrict-prototypes])
218 AC_C_FLAG([-Wmissing-noreturn])
219 AC_C_FLAG([-Wmissing-format-attribute])
220 AC_C_FLAG([-Wunreachable-code])
221 AC_C_FLAG([-Wpacked])
222 AC_C_FLAG([-Wpadded])
223else
224 AC_C_FLAG([-Wno-unused-result])
225fi
226AC_C_FLAG([-Wno-unused-parameter])
227AC_C_FLAG([-Wno-missing-field-initializers])
228
229dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
230dnl for some reason the string consts get 'promoted' to char *,
231dnl triggering a const to non-const conversion warning.
232AC_C_FLAG([-diag-disable 3179])
233
234if test x"${enable_werror}" = x"yes" ; then
235 WERROR="-Werror"
236fi
237AC_SUBST(WERROR)
238
239dnl need link on this one, not compile
240AC_LANG_PUSH(C)
241ac_ld_flag_save="$LDFLAGS"
242LDFLAGS="$LDFLAGS -rdynamic"
243AC_MSG_CHECKING([[whether linker supports -rdynamic]])
244AC_LINK_IFELSE(
245 [AC_LANG_PROGRAM([[]])],
246 [AC_MSG_RESULT([yes])],
247 [
248 LDFLAGS="$ac_ld_flag_save"
249 AC_MSG_RESULT([no])
250 ])
251AC_LANG_POP(C)
252
253dnl ----------
254dnl Essentials
255dnl ----------
256
257AX_PTHREAD([
258 CC="$PTHREAD_CC"
259 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
260 LIBS="$PTHREAD_LIBS $LIBS"
261], [
262 AC_MSG_FAILURE([This FRR version needs pthreads])
263])
264
265dnl --------------
266dnl Check programs
267dnl --------------
268AC_PROG_INSTALL
269AC_PROG_LN_S
270AC_PROG_MAKE_SET
271AC_CHECK_TOOL(AR, ar)
272
273dnl -----------------
274dnl System extensions
275dnl -----------------
276AC_GNU_SOURCE
277
278dnl -------
279dnl libtool
280dnl -------
281LT_INIT
282
283dnl ----------------------
284dnl Packages configuration
285dnl ----------------------
286AC_ARG_WITH(pkg-extra-version,
287 AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
288 [EXTRAVERSION=$withval],)
289AC_ARG_WITH(pkg-git-version,
290 AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
291 [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
292AC_ARG_WITH(vtysh_pager,
293 AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
294 VTYSH_PAGER=$withval, VTYSH_PAGER="more")
295AC_ARG_ENABLE(vtysh,
296 AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
297AC_ARG_ENABLE(doc,
298 AS_HELP_STRING([--disable-doc], [do not build docs]))
299AC_ARG_ENABLE(zebra,
300 AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
301AC_ARG_ENABLE(bgpd,
302 AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
303AC_ARG_ENABLE(ripd,
304 AS_HELP_STRING([--disable-ripd], [do not build ripd]))
305AC_ARG_ENABLE(ripngd,
306 AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
307AC_ARG_ENABLE(ospfd,
308 AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
309AC_ARG_ENABLE(ospf6d,
310 AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
311AC_ARG_ENABLE(ldpd,
312 AS_HELP_STRING([--enable-ldpd], [build ldpd]))
313AC_ARG_ENABLE(nhrpd,
314 AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
315AC_ARG_ENABLE(eigrpd,
316 AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
317AC_ARG_ENABLE(babeld,
318 AS_HELP_STRING([--disable-babeld], [do not build babeld]))
319AC_ARG_ENABLE(watchfrr,
320 AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
321AC_ARG_ENABLE(isisd,
322 AS_HELP_STRING([--disable-isisd], [do not build isisd]))
323AC_ARG_ENABLE(pimd,
324 AS_HELP_STRING([--disable-pimd], [do not build pimd]))
325AC_ARG_ENABLE(bgp-announce,
326 AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
327AC_ARG_ENABLE(bgp-vnc,
328 AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
329AC_ARG_WITH(rfp-path,
330 AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
331AC_ARG_ENABLE(snmp,
332 AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
333AC_ARG_ENABLE(zeromq,
334 AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
335AC_ARG_WITH(libpam,
336 AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
337AC_ARG_ENABLE(ospfapi,
338 AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
339AC_ARG_ENABLE(ospfclient,
340 AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
341 (this is the default if --disable-ospfapi is set)]))
342AC_ARG_ENABLE(multipath,
343 AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
344AC_ARG_ENABLE(user,
345 AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
346AC_ARG_ENABLE(group,
347 AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
348AC_ARG_ENABLE(vty_group,
349 AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
350AC_ARG_ENABLE(configfile_mask,
351 AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
352AC_ARG_ENABLE(logfile_mask,
353 AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
354AC_ARG_ENABLE(shell_access,
355 AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
356AC_ARG_ENABLE(rtadv,
357 AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
358AC_ARG_ENABLE(irdp,
359 AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
360AC_ARG_ENABLE(capabilities,
361 AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
362AC_ARG_ENABLE(rusage,
363 AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
364AC_ARG_ENABLE(gcc_ultra_verbose,
365 AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
366AC_ARG_ENABLE(linux24_tcp_md5,
367 AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
368AC_ARG_ENABLE(backtrace,
369 AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
370AC_ARG_ENABLE(time-check,
371 AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
372AC_ARG_ENABLE(pcreposix,
373 AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
374AC_ARG_ENABLE(fpm,
375 AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
376AC_ARG_ENABLE(systemd,
377 AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
378AC_ARG_ENABLE(werror,
379 AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
380AC_ARG_ENABLE(cumulus,
381 AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
382AC_ARG_ENABLE(datacenter,
383 AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
384AC_ARG_ENABLE(rr-semantics,
385 AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
386AC_ARG_ENABLE([protobuf],
387 AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
388AC_ARG_ENABLE([oldvpn_commands],
389 AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
390
391AC_CHECK_HEADERS(json-c/json.h)
392AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
393if test $ac_cv_lib_json_c_json_object_get = no; then
394 AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
395 if test $ac_cv_lib_json_json_object_get = no; then
396 AC_MSG_ERROR([lib json is needed to compile])
397 fi
398fi
399
400AC_ARG_ENABLE([dev_build],
401 AS_HELP_STRING([--enable-dev-build], [build for development]))
402
403if test x"${enable_time_check}" != x"no" ; then
404 if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
405 AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
406 else
407 AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
408 fi
409fi
410
411case "${enable_systemd}" in
412 "no") ;;
413 "yes")
414 AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
415 if test $ac_cv_lib_systemd_sd_notify = no; then
416 AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
417 else
418 AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
419 fi
420 ;;
421 "*") ;;
422esac
423
424if test "${enable_rr_semantics}" != "no" ; then
425 AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
426fi
427
428if test "${enable_datacenter}" = "yes" ; then
429 AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
430 DFLT_NAME="datacenter"
431else
432 DFLT_NAME="traditional"
433fi
434
435if test "${enable_cumulus}" = "yes" ; then
436 AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
437fi
438
439AC_SUBST(DFLT_NAME)
440AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
441
442if test "${enable_shell_access}" = "yes"; then
443 AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
444fi
445
446AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
447
448#
449# Python for clippy
450#
451AS_IF([test "$host" = "$build"], [
452 PYTHONCONFIG=""
453
454 # ordering:
455 # 1. try python3, but respect the user's preference on which minor ver
456 # 2. try python, which might be py3 or py2 again on the user's preference
457 # 3. try python2 (can really only be 2.7 but eh)
458 # 4. try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
459 #
460 # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
461 # (AX_PYTHON does not do what we need)
462
463 AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
464 if test -n "$PYTHONCONFIG"; then
465 PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
466 PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
467
468 AC_MSG_CHECKING([whether we found a working Python version])
469 AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
470#include <Python.h>
471#if PY_VERSION_HEX < 0x02070000
472#error python too old
473#endif
474int main(void);
475],
476[
477{
478 Py_Initialize();
479 return 0;
480}
481])], [
482 PYTHONCONFIG=""
483 unset PYTHON_LIBS
484 unset PYTHON_CFLAGS
485 ])
486 fi
487
488 if test -z "$PYTHONCONFIG"; then
489 PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
490 PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
491 PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
492 PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
493 PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
494 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
495 ])])])])])
496
497
498 AC_MSG_CHECKING([whether we found a working Python version])
499 AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
500#include <Python.h>
501#if PY_VERSION_HEX < 0x02070000
502#error python too old
503#endif
504int main(void);
505],
506[
507{
508 Py_Initialize();
509 return 0;
510}
511])], [
512 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
513 ])
514 fi
515])
516AC_SUBST(PYTHON_CFLAGS)
517AC_SUBST(PYTHON_LIBS)
518
519#
520# Logic for protobuf support.
521#
522if test "$enable_protobuf" = "yes"; then
523 have_protobuf=yes
524
525 # Check for protoc-c
526 AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
527 if test "x$PROTOC_C" = "x/bin/false"; then
528 have_protobuf=no
529 else
530 found_protobuf_c=no
531 PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
532 [found_protobuf_c=yes],
533 [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
534
535 if test "x$found_protobuf_c" = "xyes"; then
536 LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
537 CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
538 else
539 AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
540 [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
541 fi
542 fi
543fi
544
545#
546# Logic for old vpn commans support.
547#
548if test "$enable_oldvpn_commands" = "yes"; then
549 AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
550fi
551
552# Fail if the user explicity enabled protobuf support and we couldn't
553# find the compiler or libraries.
554if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
555 AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
556fi
557
558if test "x$have_protobuf" = "xyes"; then
559 AC_DEFINE(HAVE_PROTOBUF,, protobuf)
560fi
561
562AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
563
564#
565# End of logic for protobuf support.
566#
567
568if test "${enable_linux24_tcp_md5}" = "yes"; then
569 AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
570fi
571
572AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
573if test "${enable_rtadv}" != "no"; then
574 AC_MSG_RESULT(yes)
575 AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
576else
577 AC_MSG_RESULT(no)
578fi
579
580if test x"${enable_user}" = x"no"; then
581 enable_user=""
582else
583 if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
584 enable_user="frr"
585 fi
586 AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
587fi
588
589if test x"${enable_group}" = x"no"; then
590 enable_group=""
591else
592 if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
593 enable_group="frr"
594 fi
595 AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
596fi
597
598if test x"${enable_vty_group}" = x"yes" ; then
599 AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
600elif test x"${enable_vty_group}" != x""; then
601 if test x"${enable_vty_group}" != x"no"; then
602 AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
603 fi
604fi
605AC_SUBST([enable_user])
606AC_SUBST([enable_group])
607AC_SUBST([enable_vty_group])
608
609enable_configfile_mask=${enable_configfile_mask:-0600}
610AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
611
612enable_logfile_mask=${enable_logfile_mask:-0600}
613AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
614
615MPATH_NUM=1
616
617case "${enable_multipath}" in
618 0)
619 MPATH_NUM=64
620 ;;
621 [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
622 MPATH_NUM="${enable_multipath}"
623 ;;
624 "")
625 ;;
626 *)
627 AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
628 ;;
629esac
630
631AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
632
633AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
634
635dnl -----------------------------------
636dnl Add extra version string to package
637dnl name, string and version fields.
638dnl -----------------------------------
639if test "x${EXTRAVERSION}" != "x" ; then
640 VERSION="${VERSION}${EXTRAVERSION}"
641 PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
642 AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
643 PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
644fi
645
646if test "x$with_pkg_git_version" = "xyes"; then
647 if test -d "${srcdir}/.git"; then
648 AC_DEFINE(GIT_VERSION, [1], [include git version info])
649 else with_pkg_git_version="no"
650 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
651 fi
652fi
653AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
654
655dnl ------------------------------------
656dnl Check C keywords and standard types
657dnl ------------------------------------
658AC_C_CONST
659AC_C_INLINE
660AC_C_VOLATILE
661AC_HEADER_STDC
662dnl AC_TYPE_PID_T
663AC_TYPE_UID_T
664AC_TYPE_MODE_T
665AC_TYPE_SIZE_T
666AC_STRUCT_TM
667
668dnl -------------------------
669dnl Check other header files.
670dnl -------------------------
671AC_CHECK_HEADERS([stropts.h sys/ksym.h \
672 linux/version.h asm/types.h \
673 sys/cdefs.h])
674
675ac_stdatomic_ok=false
676AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
677AC_CHECK_HEADER([stdatomic.h],[
678
679 AC_MSG_CHECKING([whether _Atomic qualifier works])
680 AC_LINK_IFELSE([AC_LANG_SOURCE([[
681#include <stdatomic.h>
682int main(int argc, char **argv) {
683 _Atomic int i = 0;
684 return i;
685}
686]])], [
687 AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
688 AC_MSG_RESULT([yes])
689 ac_stdatomic_ok=true
690 ], [
691 AC_MSG_RESULT([no])
692 ])
693])
694
695AS_IF([$ac_stdatomic_ok], [true], [
696 AC_MSG_CHECKING([for __atomic_* builtins])
697 AC_LINK_IFELSE([AC_LANG_SOURCE([[
698int main(int argc, char **argv) {
699 volatile int i = 1;
700 __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
701 return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
702}
703]])], [
704 AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
705 AC_MSG_RESULT([yes])
706 ], [
707 AC_MSG_RESULT([no])
708
709 dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
710 AC_MSG_CHECKING([for __sync_* builtins])
711 AC_LINK_IFELSE([AC_LANG_SOURCE([[
712int main(int argc, char **argv) {
713 volatile int i = 1;
714 __sync_fetch_and_sub (&i, 1);
715 return __sync_val_compare_and_swap (&i, 0, 1);
716}
717]])], [
718 AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
719 AC_MSG_RESULT([yes])
720
721 AC_MSG_CHECKING([for __sync_swap builtin])
722 AC_LINK_IFELSE([AC_LANG_SOURCE([[
723int main(int argc, char **argv) {
724 volatile int i = 1;
725 return __sync_swap (&i, 2);
726}
727]])], [
728 AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
729 AC_MSG_RESULT([yes])
730 ], [
731 AC_MSG_RESULT([no])
732 ])
733
734 ], [
735 AC_MSG_RESULT([no])
736 AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
737 ])
738 ])
739])
740
741dnl Utility macro to avoid retyping includes all the time
742m4_define([FRR_INCLUDES],
743[#ifdef SUNOS_5
744#define _XPG4_2
745#define __EXTENSIONS__
746#endif
747#include <stdio.h>
748#include <stdlib.h>
749#include <stddef.h>
750#include <sys/types.h>
751/* sys/conf.h depends on param.h on FBSD at least */
752#include <sys/param.h>
753/* Required for MAXSIG */
754#include <signal.h>
755#include <sys/socket.h>
756#ifdef __APPLE__
757# define __APPLE_USE_RFC_3542
758#endif
759#include <netinet/in.h>
760#include <sys/time.h>
761#include <time.h>
762#include <net/if.h>
763])dnl
764
765dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
766dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
767dnl an additional round for it.
768
769AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
770
771m4_define([FRR_INCLUDES],
772FRR_INCLUDES
773[#if HAVE_NET_IF_VAR_H
774# include <net/if_var.h>
775#endif
776])dnl
777
778AC_CHECK_HEADERS([netinet/in_var.h \
779 net/if_dl.h net/netopt.h \
780 inet/nd.h netinet/ip_icmp.h \
781 sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
782 [], [], FRR_INCLUDES)
783
784AC_CHECK_HEADERS([ucontext.h], [], [],
785[#ifndef __USE_GNU
786#define __USE_GNU
787#endif /* __USE_GNU */
788FRR_INCLUDES
789])
790
791m4_define([UCONTEXT_INCLUDES],
792[#include <ucontext.h>])dnl
793
794AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
795 [], [], [UCONTEXT_INCLUDES])
796AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
797 [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
798 [], [], [UCONTEXT_INCLUDES])],
799 [], [UCONTEXT_INCLUDES])
800AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
801 [], [], [UCONTEXT_INCLUDES])
802
803m4_define([FRR_INCLUDES],
804FRR_INCLUDES
805[
806#include <sys/un.h>
807#include <netinet/in_systm.h>
808#if HAVE_NETINET_IN_VAR_H
809# include <netinet/in_var.h>
810#endif
811#if HAVE_NET_IF_DL_H
812# include <net/if_dl.h>
813#endif
814#if HAVE_NET_NETOPT_H
815# include <net/netopt.h>
816#endif
817#include <net/route.h>
818#if HAVE_INET_ND_H
819# include <inet/nd.h>
820#endif
821#include <arpa/inet.h>
822/* Required for IDRP */
823#if HAVE_NETINET_IP_ICMP_H
824# include <netinet/ip_icmp.h>
825#endif
826])dnl
827
828dnl V6 headers are checked below, after we check for v6
829
830AC_MSG_CHECKING([which operating system interface to use])
831case "$host_os" in
832 sunos* | solaris2*)
833 AC_MSG_RESULT([Solaris])
834
835 AC_DEFINE(SUNOS_5, 1, [SunOS 5])
836 AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
837
838 AC_CHECK_LIB(socket, main)
839 AC_CHECK_LIB(nsl, main)
840 AC_CHECK_LIB(umem, main)
841 AC_CHECK_FUNCS([printstack], [
842 AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
843 AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
844 ])
845 CURSES=-lcurses
846 SOLARIS="solaris"
847 ;;
848 linux*)
849 AC_MSG_RESULT([Linux])
850
851 AC_DEFINE(GNU_LINUX,,GNU Linux)
852 AC_DEFINE(HAVE_NETLINK,,netlink)
853 AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
854
855 dnl Linux has a compilation problem with mixing
856 dnl netinet/in.h and linux/in6.h they are not
857 dnl compatible. There has been discussion on
858 dnl how to fix it but no real progress on implementation
859 dnl when they fix it, remove this
860 AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
861
862 AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
863 ;;
864 openbsd*)
865 AC_MSG_RESULT([OpenBSD])
866
867 AC_DEFINE(OPEN_BSD,,OpenBSD)
868 AC_DEFINE(KAME,1,KAME IPv6)
869
870 if test "x${enable_pimd}" != "xno"; then
871 case "$host_os" in
872 openbsd6.0)
873 ;;
874 openbsd[6-9]*)
875 AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
876 ;;
877 esac
878 fi
879 ;;
880 *)
881 AC_MSG_RESULT([BSD])
882
883 AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
884 AC_DEFINE(KAME,1,KAME IPv6)
885 ;;
886esac
887AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
888
889AC_SYS_LARGEFILE
890
891dnl ---------------------
892dnl Integrated VTY option
893dnl ---------------------
894case "${enable_vtysh}" in
895 "no") VTYSH="";;
896 *) VTYSH="vtysh";
897 AC_DEFINE(VTYSH,,VTY shell)
898dnl Vtysh uses libreadline, which looks for termcap functions at
899dnl configure time. We follow readlines search order.
900dnl The required procedures are in libtermcap on NetBSD, in
901dnl [TODO] on Linux, and in [TODO] on Solaris.
902 AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
903 [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
904 [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
905 [AC_CHECK_LIB(ncurses, tputs,
906 LIBREADLINE="$LIBREADLINE -lncurses")]
907 )]
908 )]
909 )
910 AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
911 "$LIBREADLINE")
912 if test $ac_cv_lib_readline_main = no; then
913 AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
914 fi
915 AC_CHECK_HEADER(readline/history.h)
916 if test $ac_cv_header_readline_history_h = no;then
917 AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
918 fi
919 AC_CHECK_LIB(readline, rl_completion_matches,
920 LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
921 if test $ac_cv_lib_readline_rl_completion_matches = no; then
922 AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
923 fi
924 ;;
925esac
926AC_SUBST(LIBREADLINE)
927AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
928
929dnl ----------
930dnl PAM module
931dnl
932dnl FRR detects the PAM library it is built against by checking for a
933dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
934dnl is known to #include pam_appl.h, the standard header of a PAM library, and
935dnl openpam.h doesn't do that, although depends on the header too. Hence a
936dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
937dnl of OpenPAM.
938dnl ----------
939if test "$with_libpam" = "yes"; then
940 AC_CHECK_HEADER([security/pam_misc.h],
941 [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
942 AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
943 pam_conv_func="misc_conv"
944 ],
945 [], FRR_INCLUDES)
946 AC_CHECK_HEADER([security/openpam.h],
947 [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
948 AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
949 pam_conv_func="openpam_ttyconv"
950 ],
951 [], FRR_INCLUDES[#include <security/pam_appl.h>])
952 if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
953 AC_MSG_WARN([*** pam support will not be built ***])
954 with_libpam="no"
955 fi
956fi
957
958if test "$with_libpam" = "yes"; then
959dnl took this test from proftpds configure.in and suited to our needs
960dnl -------------------------------------------------------------------------
961dnl
962dnl This next check looks funky due to a linker problem with some versions
963dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
964dnl omitted requiring libdl linking information. PAM-0.72 or better ships
965dnl with RedHat 6.2 and Debian 2.2 or better.
966AC_CHECK_LIB(pam, pam_start,
967 [AC_CHECK_LIB(pam, $pam_conv_func,
968 [AC_DEFINE(USE_PAM,,Use PAM for authentication)
969 LIBPAM="-lpam"],
970 [AC_DEFINE(USE_PAM,,Use PAM for authentication)
971 LIBPAM="-lpam -lpam_misc"]
972 )
973 ],
974
975 [AC_CHECK_LIB(pam, pam_end,
976 [AC_CHECK_LIB(pam, $pam_conv_func,
977 [AC_DEFINE(USE_PAM,,Use PAM for authentication)
978 LIBPAM="-lpam -ldl"],
979 [AC_DEFINE(USE_PAM,,Use PAM for authentication)
980 LIBPAM="-lpam -ldl -lpam_misc"]
981 )
982 ],AC_MSG_WARN([*** pam support will not be built ***]),
983 [-ldl])
984 ]
985)
986fi
987AC_SUBST(LIBPAM)
988
989dnl -------------------------------
990dnl Endian-ness check
991dnl -------------------------------
992AC_WORDS_BIGENDIAN
993
994dnl -------------------------------
995dnl check the size in byte of the C
996dnl -------------------------------
997dnl AC_CHECK_SIZEOF(char)
998dnl AC_CHECK_SIZEOF(int)
999dnl AC_CHECK_SIZEOF(short)
1000dnl AC_CHECK_SIZEOF(long)
1001
1002dnl ----------------------------
1003dnl check existance of functions
1004dnl ----------------------------
1005AC_FUNC_FNMATCH
1006AC_FUNC_FORK
1007AC_FUNC_MKTIME
1008AC_FUNC_STAT
1009
1010dnl -------------------------------
1011dnl bgpd needs pow() and hence libm
1012dnl -------------------------------
1013TMPLIBS="$LIBS"
1014AC_CHECK_HEADER([math.h],
1015 [AC_CHECK_LIB([m], [pow],
1016 [LIBM="-lm"
1017 LIBS="$LIBS $LIBM"
1018 AC_CHECK_FUNCS(pow,[],[LIBM=""])
1019 ])
1020])
1021if test x"$LIBM" = x ; then
1022 AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1023fi
1024LIBS="$TMPLIBS"
1025AC_SUBST(LIBM)
1026
1027AC_CHECK_FUNCS([ppoll], [
1028 AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1029])
1030AC_CHECK_FUNCS([pollts], [
1031 AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1032])
1033
1034dnl ---------------
1035dnl other functions
1036dnl ---------------
1037AC_CHECK_FUNCS([ \
1038 strlcat strlcpy \
1039 getgrouplist])
1040
1041AC_CHECK_HEADER([asm-generic/unistd.h],
1042 [AC_CHECK_DECL(__NR_setns,
1043 AC_DEFINE(HAVE_NETNS,, Have netns),,
1044 FRR_INCLUDES [#include <asm-generic/unistd.h>
1045 ])
1046 AC_CHECK_FUNCS(setns)]
1047 )
1048
1049dnl --------------------------
1050dnl Determine IS-IS I/O method
1051dnl --------------------------
1052AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1053AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
1054AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
1055AC_CHECK_HEADER(net/bpf.h)
1056AC_CHECK_HEADER(sys/dlpi.h)
1057AC_MSG_CHECKING(zebra IS-IS I/O method)
1058
1059case "$host_os" in
1060 linux*)
1061 AC_MSG_RESULT(pfpacket)
1062 ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1063 ;;
1064 solaris* | sunos*)
1065 AC_MSG_RESULT(DLPI)
1066 ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1067 ;;
1068 *)
1069 if test $ac_cv_header_net_bpf_h = no; then
1070 if test $ac_cv_header_sys_dlpi_h = no; then
1071 AC_MSG_RESULT(none)
1072 if test "${enable_isisd}" = yes; then
1073 AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1074 fi
1075 AC_MSG_WARN([*** IS-IS support will not be built ***])
1076 enable_isisd="no"
1077 else
1078 AC_MSG_RESULT(DLPI)
1079 fi
1080 ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1081 else
1082 AC_MSG_RESULT(BPF)
1083 ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1084 fi
1085 ;;
1086esac
1087AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1088
1089dnl ------------------------------------
1090dnl check for broken CMSG_FIRSTHDR macro
1091dnl ------------------------------------
1092AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1093AC_RUN_IFELSE([AC_LANG_SOURCE([[
1094#ifdef SUNOS_5
1095#define _XPG4_2
1096#define __EXTENSIONS__
1097#endif
1098#include <stdlib.h>
1099#include <sys/types.h>
1100#include <sys/socket.h>
1101
1102main()
1103{
1104 struct msghdr msg;
1105 char buf[4];
1106
1107 msg.msg_control = buf;
1108 msg.msg_controllen = 0;
1109
1110 if (CMSG_FIRSTHDR(&msg) != NULL)
1111 exit(0);
1112 exit (1);
1113}]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1114[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1115
1116dnl ---------------------------------------------------------------
1117dnl figure out how to specify an interface in multicast sockets API
1118dnl ---------------------------------------------------------------
1119AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1120
1121AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1122 #include <sys/socket.h>
1123 #include <netinet/in.h>
1124 #define _LINUX_IN_H /* For Linux <= 2.6.25 */
1125 #include <linux/types.h>
1126])
1127
1128m4_define([FRR_INCLUDES],
1129FRR_INCLUDES
1130[#if HAVE_LINUX_MROUTE_H
1131# include <linux/mroute.h>
1132#endif
1133])dnl
1134
1135AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1136 #include <sys/socket.h>
1137 #include <sys/types.h>
1138 #include <netinet/in.h>
1139 #include <net/route.h>
1140])
1141
1142m4_define([FRR_INCLUDES],
1143FRR_INCLUDES
1144[#if HAVE_NETINET_IP_MROUTE_H
1145# include <netinet/ip_mroute.h>
1146#endif
1147])dnl
1148
1149AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1150AC_TRY_COMPILE([#include <sys/param.h>],
1151[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1152 return (0);
1153#else
1154 #error No support for BSD struct ip_mreq hack detected
1155#endif],[AC_MSG_RESULT(yes)
1156AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1157AC_MSG_RESULT(no))
1158
1159AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1160AC_TRY_COMPILE([
1161#include <sys/types.h>
1162#include <netinet/in.h>
1163], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1164], [AC_MSG_RESULT(yes)
1165AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1166AC_MSG_RESULT(no))
1167
1168dnl ---------------------------------------------------------------
1169dnl figure out how to check link-state
1170dnl ---------------------------------------------------------------
1171AC_CHECK_HEADER( [net/if_media.h],
1172 [m4_define([LINK_DETECT_INCLUDES],
1173 FRR_INCLUDES
1174 [#include <net/if_media.h>
1175 ])
1176 AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1177 AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1178 [], LINK_DETECT_INCLUDES)],
1179 [],
1180 FRR_INCLUDES)
1181
1182dnl ---------------------------------------------------------------
1183dnl Additional, newer way to check link-state using ifi_link_state.
1184dnl Not available in all BSD's when ifmediareq available
1185dnl ---------------------------------------------------------------
1186AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1187 AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1188 [], FRR_INCLUDES)
1189
1190dnl ------------------------
1191dnl TCP_MD5SIG socket option
1192dnl ------------------------
1193
1194AC_CHECK_HEADER([netinet/tcp.h],
1195 [m4_define([MD5_INCLUDES],
1196 FRR_INCLUDES
1197 [#include <netinet/tcp.h>
1198 ])
1199 AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1200 [],
1201 FRR_INCLUDES)
1202if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1203 AC_CHECK_HEADER([linux/tcp.h],
1204 [m4_define([MD5_INCLUDES],
1205 FRR_INCLUDES
1206 [#include <linux/tcp.h>
1207 ])
1208 AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1209fi
1210
1211dnl ----------------------------------------------------------------------------
1212dnl figure out if domainname is available in the utsname struct (GNU extension).
1213dnl ----------------------------------------------------------------------------
1214AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1215
1216dnl ------------------
1217dnl IPv6 header checks
1218dnl ------------------
1219AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1220 netinet6/in6_var.h netinet6/nd6.h], [], [],
1221 FRR_INCLUDES)
1222
1223m4_define([FRR_INCLUDES],dnl
1224FRR_INCLUDES
1225[#if HAVE_NETINET6_IN6_H
1226#include <netinet6/in6.h>
1227#endif
1228#if HAVE_NETINET_IN6_VAR_H
1229#include <netinet/in6_var.h>
1230#endif
1231#include <netinet/icmp6.h>
1232#if HAVE_NETINET6_IN6_VAR_H
1233# include <netinet6/in6_var.h>
1234#endif
1235#if HAVE_NETINET6_ND6_H
1236# include <netinet6/nd6.h>
1237#endif
1238])dnl
1239
1240dnl disable doc check
1241if test "${enable_doc}" = "no";then
1242 DOC=""
1243else
1244 DOC="doc"
1245fi
1246
1247dnl --------------------
1248dnl Daemon disable check
1249dnl --------------------
1250AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1251
1252if test "${enable_bgpd}" = "no";then
1253 BGPD=""
1254else
1255 BGPD="bgpd"
1256fi
1257AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1258
1259AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1260AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1261AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1262
1263AS_IF([test "${enable_ldpd}" != "no"], [
1264 AC_DEFINE(HAVE_LDPD, 1, ldpd)
1265])
1266
1267NHRPD=""
1268case "$host_os" in
1269 linux*)
1270 if test "${enable_nhrpd}" != "no"; then
1271 NHRPD="nhrpd"
1272 fi
1273 ;;
1274 *)
1275 if test "${enable_nhrpd}" = "yes"; then
1276 AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1277 fi
1278 ;;
1279esac
1280AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1281
1282AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1283
1284if test "${enable_watchfrr}" = "no";then
1285 WATCHFRR=""
1286else
1287 WATCHFRR="watchfrr"
1288fi
1289AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1290
1291OSPFCLIENT=""
1292if test "${enable_ospfapi}" != "no";then
1293 AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1294
1295 if test "${enable_ospfclient}" != "no";then
1296 OSPFCLIENT="ospfclient"
1297 fi
1298fi
1299
1300AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1301AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1302AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1303AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1304AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1305AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1306
1307if test "${enable_bgp_announce}" = "no";then
1308 AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1309else
1310 AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1311fi
1312
1313if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1314 with_rfp_path="bgpd/rfp-example"
1315fi
1316if test "${with_rfp_path}" != "no"; then
1317 VNC_RFP_PATH="${with_rfp_path}"
1318 AC_SUBST(VNC_RFP_PATH)
1319fi
1320
1321if test "${enable_bgp_vnc}" != "no";then
1322 AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1323 RFPTEST="${with_rfp_path}/rfptest"
1324 LIBRFP="${with_rfp_path}/librfp"
1325 RFPINC="${with_rfp_path}/librfp"
1326else
1327 RFPTEST=
1328 LIBRFP=
1329 RFPINC="bgpd/rfp-example/librfp"
1330fi
1331# set
1332AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1333
1334AC_SUBST(DOC)
1335AC_SUBST(RFPTEST)
1336AC_SUBST(LIBRFP)
1337AC_SUBST(RFPINC)
1338AC_SUBST(BGPD)
1339AC_SUBST(SOLARIS)
1340AC_SUBST(VTYSH)
1341AC_SUBST(CURSES)
1342AC_CHECK_LIB(crypt, crypt, [],
1343 [AC_CHECK_LIB(crypto, DES_crypt)])
1344AC_CHECK_LIB(resolv, res_init)
1345
1346dnl ---------------------------
1347dnl check system has PCRE regexp
1348dnl ---------------------------
1349if test "x$enable_pcreposix" = "xyes"; then
1350 AC_CHECK_LIB(pcreposix, regexec, [], [
1351 AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1352 ])
1353fi
1354AC_SUBST(HAVE_LIBPCREPOSIX)
1355
1356dnl ------------------
1357dnl check C-Ares library
1358dnl ------------------
1359if test "${NHRPD}" != ""; then
1360 PKG_CHECK_MODULES([CARES], [libcares], , [
1361 AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1362 ])
1363fi
1364
1365
1366dnl ------------------
1367dnl check Net-SNMP library
1368dnl ------------------
1369if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1370 AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1371 if test x"$NETSNMP_CONFIG" = x"no"; then
1372 AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1373 fi
1374 SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1375 SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1376 AC_MSG_CHECKING([whether we can link to Net-SNMP])
1377 AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1378int main(void);
1379],
1380[
1381{
1382 return 0;
1383}
1384])], [
1385 AC_MSG_ERROR([--enable-snmp given but not usable])])
1386 case "${enable_snmp}" in
1387 yes)
1388 SNMP_METHOD=agentx
1389 ;;
1390 smux|agentx)
1391 SNMP_METHOD="${enable_snmp}"
1392 ;;
1393 *)
1394 AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1395 ;;
1396 esac
1397 AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1398 AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1399 AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1400fi
1401AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1402AC_SUBST(SNMP_LIBS)
1403AC_SUBST(SNMP_CFLAGS)
1404
1405dnl ---------------
1406dnl math
1407dnl ---------------
1408AC_SEARCH_LIBS([sqrt], [m])
1409
1410dnl ---------------
1411dnl dlopen & dlinfo
1412dnl ---------------
1413AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1414 AC_MSG_ERROR([unable to find the dlopen()])
1415])
1416
1417AC_CHECK_HEADERS([link.h])
1418
1419AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1420AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1421#include <stdlib.h>
1422#ifdef HAVE_LINK_H
1423#include <link.h>
1424#endif
1425#include <dlfcn.h>
1426]], [[
1427 char origin[1];
1428 dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1429]])], [
1430 AC_MSG_RESULT(yes)
1431 AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1432], [
1433 AC_MSG_RESULT(no)
1434])
1435
1436AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1437AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1438#include <stdlib.h>
1439#ifdef HAVE_LINK_H
1440#include <link.h>
1441#endif
1442#include <dlfcn.h>
1443]], [[
1444 struct link_map *lm = NULL;
1445 dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1446]])], [
1447 AC_MSG_RESULT(yes)
1448 AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1449], [
1450 AC_MSG_RESULT(no)
1451])
1452
1453
1454AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1455
1456dnl ---------------------------
1457dnl sockaddr and netinet checks
1458dnl ---------------------------
1459AC_CHECK_TYPES([
1460 struct sockaddr_dl,
1461 struct vifctl, struct mfcctl, struct sioc_sg_req,
1462 vifi_t, struct sioc_vif_req, struct igmpmsg,
1463 struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1464 struct nd_opt_adv_interval, struct rt_addrinfo,
1465 struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1466 [], [], FRR_INCLUDES)
1467
1468AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1469 struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1470 struct sockaddr_dl.sdl_len,
1471 struct if6_aliasreq.ifra_lifetime,
1472 struct nd_opt_adv_interval.nd_opt_ai_type],
1473 [], [], FRR_INCLUDES)
1474
1475dnl ---------------------------
1476dnl IRDP/pktinfo/icmphdr checks
1477dnl ---------------------------
1478
1479AC_CHECK_TYPES([struct in_pktinfo], [
1480 AC_CHECK_TYPES([struct icmphdr], [
1481 IRDP=true
1482 ], [
1483 IRDP=false
1484 ], [FRR_INCLUDES])
1485], [
1486 IRDP=false
1487], [FRR_INCLUDES])
1488
1489case "${enable_irdp}" in
1490yes)
1491 $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1492 ;;
1493no)
1494 IRDP=false
1495 ;;
1496esac
1497
1498AM_CONDITIONAL(IRDP, $IRDP)
1499
1500dnl -----------------------
1501dnl checking for IP_PKTINFO
1502dnl -----------------------
1503AC_MSG_CHECKING(for IP_PKTINFO)
1504AC_TRY_COMPILE([#include <netdb.h>], [
1505 int opt = IP_PKTINFO;
1506], [
1507 AC_MSG_RESULT(yes)
1508 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1509], [
1510 AC_MSG_RESULT(no)
1511])
1512
1513dnl ---------------------------
1514dnl checking for IP_RECVDSTADDR
1515dnl ---------------------------
1516AC_MSG_CHECKING(for IP_RECVDSTADDR)
1517AC_TRY_COMPILE([#include <netinet/in.h>], [
1518 int opt = IP_RECVDSTADDR;
1519], [
1520 AC_MSG_RESULT(yes)
1521 AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1522], [
1523 AC_MSG_RESULT(no)
1524])
1525
1526dnl ----------------------
1527dnl checking for IP_RECVIF
1528dnl ----------------------
1529AC_MSG_CHECKING(for IP_RECVIF)
1530AC_TRY_COMPILE([#include <netinet/in.h>], [
1531 int opt = IP_RECVIF;
1532], [
1533 AC_MSG_RESULT(yes)
1534 AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1535], [
1536 AC_MSG_RESULT(no)
1537])
1538
1539dnl ----------------------
1540dnl checking for SO_BINDANY
1541dnl ----------------------
1542AC_MSG_CHECKING(for SO_BINDANY)
1543AC_TRY_COMPILE([#include <sys/socket.h>], [
1544 int opt = SO_BINDANY;
1545], [
1546 AC_MSG_RESULT(yes)
1547 AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1548], [
1549 AC_MSG_RESULT(no)
1550])
1551
1552dnl ----------------------
1553dnl checking for IP_FREEBIND
1554dnl ----------------------
1555AC_MSG_CHECKING(for IP_FREEBIND)
1556AC_TRY_COMPILE([#include <netinet/in.h>], [
1557 int opt = IP_FREEBIND;
1558], [
1559 AC_MSG_RESULT(yes)
1560 AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1561], [
1562 AC_MSG_RESULT(no)
1563])
1564
1565dnl --------------------------------------
1566dnl checking for be32dec existence or not
1567dnl --------------------------------------
1568AC_CHECK_DECLS([be32enc, be32dec], [], [],
1569 [#include <sys/endian.h>])
1570
1571dnl --------------------------------------
1572dnl checking for clock_time monotonic struct and call
1573dnl --------------------------------------
1574AC_CHECK_DECL(CLOCK_MONOTONIC,
1575 [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1576 AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1577], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1578
1579dnl --------------------------------------
1580dnl checking for flex and bison
1581dnl --------------------------------------
1582
1583AM_PROG_LEX
1584AC_MSG_CHECKING(version of flex)
1585frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1586frr_ac_flex_version="${frr_ac_flex_version##* }"
1587AC_MSG_RESULT([$frr_ac_flex_version])
1588AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1589 LEX="$SHELL $missing_dir/missing flex"
1590 if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1591 AC_MSG_WARN([using pregenerated flex output files])
1592 else
1593 AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1594 fi
1595 AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1596 AC_SUBST([LEXLIB], [''])
1597])
1598
1599AC_PROG_YACC
1600dnl thanks GNU bison for this b*llshit...
1601AC_MSG_CHECKING(version of bison)
1602frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1603frr_ac_bison_version="${frr_ac_bison_version##* }"
1604frr_ac_bison_missing="false"
1605case "x${frr_ac_bison_version}" in
1606 x2.7*)
1607 BISON_OPENBRACE='"'
1608 BISON_CLOSEBRACE='"'
1609 BISON_VERBOSE=''
1610 AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1611 ;;
1612 x2.*|x1.*)
1613 AC_MSG_RESULT([$frr_ac_bison_version])
1614 AC_MSG_WARN([installed bison is too old. Please install GNU bison 2.7.x or newer.])
1615 frr_ac_bison_missing="true"
1616 ;;
1617 x)
1618 AC_MSG_RESULT([none])
1619 AC_MSG_WARN([could not determine bison version. Please install GNU bison 2.7.x or newer.])
1620 frr_ac_bison_missing="true"
1621 ;;
1622 *)
1623 BISON_OPENBRACE='{'
1624 BISON_CLOSEBRACE='}'
1625 BISON_VERBOSE='-Dparse.error=verbose'
1626 AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1627 ;;
1628esac
1629AC_SUBST(BISON_OPENBRACE)
1630AC_SUBST(BISON_CLOSEBRACE)
1631AC_SUBST(BISON_VERBOSE)
1632
1633if $frr_ac_bison_missing; then
1634 YACC="$SHELL $missing_dir/missing bison -y"
1635 if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1636 AC_MSG_WARN([using pregenerated bison output files])
1637 else
1638 AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1639 fi
1640fi
1641
1642dnl -------------------
1643dnl capabilities checks
1644dnl -------------------
1645if test "${enable_capabilities}" != "no"; then
1646 AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1647 AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1648 [AC_MSG_RESULT(yes)
1649 AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1650 frr_ac_keepcaps="yes"],
1651 AC_MSG_RESULT(no)
1652 )
1653 if test x"${frr_ac_keepcaps}" = x"yes"; then
1654 AC_CHECK_HEADERS(sys/capability.h)
1655 fi
1656 if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1657 AC_CHECK_LIB(cap, cap_init,
1658 [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1659 LIBCAP="-lcap"
1660 frr_ac_lcaps="yes"]
1661 )
1662 else
1663 AC_CHECK_HEADERS(priv.h,
1664 [AC_MSG_CHECKING(Solaris style privileges are available)
1665 AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1666 [AC_MSG_RESULT(yes)
1667 AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1668 frr_ac_scaps="yes"],
1669 AC_MSG_RESULT(no)
1670 )
1671 ]
1672 )
1673 fi
1674 if test x"${frr_ac_scaps}" = x"yes" \
1675 -o x"${frr_ac_lcaps}" = x"yes"; then
1676 AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1677 fi
1678fi
1679AC_SUBST(LIBCAP)
1680
1681dnl ---------------------------
1682dnl check for glibc 'backtrace'
1683dnl ---------------------------
1684if test x"${enable_backtrace}" != x"no" ; then
1685 backtrace_ok=no
1686 AC_CHECK_HEADER([execinfo.h], [
1687 AC_SEARCH_LIBS([backtrace], [execinfo], [
1688 AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1689 AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1690 backtrace_ok=yes
1691 ],, [-lm])
1692 ])
1693
1694 if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1695 dnl user explicitly requested backtrace but we failed to find support
1696 AC_MSG_FAILURE([failed to find backtrace support])
1697 fi
1698fi
1699
1700dnl -----------------------------------------
1701dnl check for malloc mallinfo struct and call
1702dnl this must try and link using LIBS, in
1703dnl order to check no alternative allocator
1704dnl has been specified, which might not provide
1705dnl mallinfo, e.g. such as Umem on Solaris.
1706dnl -----------------------------------------
1707AC_CHECK_HEADER([malloc.h],
1708 [AC_MSG_CHECKING(whether mallinfo is available)
1709 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1710 [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1711 [AC_MSG_RESULT(yes)
1712 AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1713 AC_MSG_RESULT(no)
1714 )
1715 ], [], FRR_INCLUDES)
1716
1717dnl ------
1718dnl ZeroMQ
1719dnl ------
1720if test "x$enable_zeromq" != "xno"; then
1721 PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1722 AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1723 ZEROMQ=true
1724 ], [
1725 if test "x$enable_zeromq" = "xyes"; then
1726 AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1727 fi
1728 ])
1729fi
1730AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1731
1732dnl ----------
1733dnl configure date
1734dnl ----------
1735CONFDATE=`date '+%Y%m%d'`
1736AC_SUBST(CONFDATE)
1737
1738dnl ------------------------------
1739dnl set paths for state directory
1740dnl ------------------------------
1741AC_MSG_CHECKING(directory to use for state file)
1742if test "${prefix}" = "NONE"; then
1743 frr_statedir_prefix="";
1744else
1745 frr_statedir_prefix=${prefix}
1746fi
1747if test "${localstatedir}" = '${prefix}/var'; then
1748 for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1749 ${frr_statedir_prefix}/var/adm dnl
1750 ${frr_statedir_prefix}/etc dnl
1751 /var/run dnl
1752 /var/adm dnl
1753 /etc dnl
1754 /dev/null;
1755 do
1756 test -d $FRR_STATE_DIR && break
1757 done
1758 frr_statedir=$FRR_STATE_DIR
1759else
1760 frr_statedir=${localstatedir}
1761fi
1762if test $frr_statedir = "/dev/null"; then
1763 AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1764fi
1765AC_MSG_RESULT(${frr_statedir})
1766AC_SUBST(frr_statedir)
1767
1768AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1769AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1770AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1771
1772dnl autoconf does this, but it does it too late...
1773test "x$prefix" = xNONE && prefix=$ac_default_prefix
1774test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1775
1776dnl get the full path, recursing through variables...
1777vtysh_bin="$bindir/vtysh"
1778for I in 1 2 3 4 5 6 7 8 9 10; do
1779 eval vtysh_bin="\"$vtysh_bin\""
1780done
1781AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1782
1783CFG_SYSCONF="$sysconfdir"
1784CFG_SBIN="$sbindir"
1785CFG_STATE="$frr_statedir"
1786CFG_MODULE="$moduledir"
1787for I in 1 2 3 4 5 6 7 8 9 10; do
1788 eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1789 eval CFG_SBIN="\"$CFG_SBIN\""
1790 eval CFG_STATE="\"$CFG_STATE\""
1791 eval CFG_MODULE="\"$CFG_MODULE\""
1792done
1793AC_SUBST(CFG_SYSCONF)
1794AC_SUBST(CFG_SBIN)
1795AC_SUBST(CFG_STATE)
1796AC_SUBST(CFG_MODULE)
1797AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1798
1799dnl ---------------------------
1800dnl Check htonl works correctly
1801dnl ---------------------------
1802AC_MSG_CHECKING(for working htonl)
1803AC_CACHE_VAL(ac_cv_htonl_works,
1804 [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1805 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1806 ]
1807)
1808AC_MSG_RESULT($ac_cv_htonl_works)
1809
1810AC_CONFIG_FILES([Makefile
1811 bgpd/Makefile
1812 vtysh/Makefile
1813 doc/Makefile tests/Makefile
1814 bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1815 redhat/frr.spec
1816 snapcraft/snapcraft.yaml
1817 lib/version.h
1818 tests/lib/cli/test_cli.refout
1819 doc/defines.texi
1820 doc/bgpd.8
1821 doc/isisd.8
1822 doc/ospf6d.8
1823 doc/ospfclient.8
1824 doc/ospfd.8
1825 doc/ldpd.8
1826 doc/ripd.8
1827 doc/eigrpd.8
1828 doc/ripngd.8
1829 doc/pimd.8
1830 doc/nhrpd.8
1831 doc/vtysh.1
1832 doc/watchfrr.8
1833 doc/zebra.8
1834 doc/frr.1
1835 doc/frr-args.8
1836 pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1837 pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1838 pkgsrc/eigrpd.sh])
1839
1840if test "${enable_bgp_vnc}" != "no"; then
1841 if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1842 AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1843 fi
1844fi
1845
1846AC_CONFIG_FILES([solaris/Makefile])
1847
1848AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1849
1850AC_CONFIG_COMMANDS([lib/route_types.h], [
1851 dst="${ac_abs_top_builddir}/lib/route_types.h"
1852 ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1853 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1854 > "${dst}.tmp"
1855 test -f "${dst}" \
1856 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1857 && rm "${dst}.tmp" \
1858 || mv "${dst}.tmp" "${dst}"
1859], [
1860 PERL="$PERL"
1861])
1862
1863AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1864 AC_CONFIG_COMMANDS([lib/gitversion.h], [
1865 dst="${ac_abs_top_builddir}/lib/gitversion.h"
1866 ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1867 "${ac_abs_top_srcdir}" \
1868 > "${dst}.tmp"
1869 test -f "${dst}" \
1870 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1871 && rm "${dst}.tmp" \
1872 || mv "${dst}.tmp" "${dst}"
1873 ], [
1874 PERL="$PERL"
1875 ])
1876])
1877
1878## Hack, but working solution to avoid rebuilding of frr.info.
1879## It's already in CVS until texinfo 4.7 is more common.
1880AC_OUTPUT
1881
1882echo "
1883FRRouting configuration
1884------------------------------
1885FRR version : ${PACKAGE_VERSION}
1886host operating system : ${host_os}
1887source code location : ${srcdir}
1888compiler : ${CC}
1889compiler flags : ${CFLAGS}
1890make : ${MAKE-make}
1891linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1892state file directory : ${frr_statedir}
1893config file directory : `eval echo \`echo ${sysconfdir}\``
1894example directory : `eval echo \`echo ${exampledir}\``
1895module directory : ${CFG_MODULE}
1896user to run as : ${enable_user}
1897group to run as : ${enable_group}
1898group for vty sockets : ${enable_vty_group}
1899config file mask : ${enable_configfile_mask}
1900log file mask : ${enable_logfile_mask}
1901zebra protobuf enabled : ${have_protobuf:-no}
1902
1903The above user and group must have read/write access to the state file
1904directory and to the config files in the config file directory."
FRRouting mirror