]>
Commit | Line | Data |
---|---|---|
1 | # -*- Autoconf -*- | |
2 | # Process this file with autoconf to produce a configure script. | |
3 | ||
4 | m4_define([lxc_version_major], 1) | |
5 | m4_define([lxc_version_minor], 0) | |
6 | m4_define([lxc_version_micro], 0) | |
7 | m4_define([lxc_version_beta], [alpha2]) | |
8 | ||
9 | m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro]) | |
10 | m4_define([lxc_version], | |
11 | [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])]) | |
12 | ||
13 | AC_INIT([lxc], [lxc_version]) | |
14 | AC_SUBST(LXC_VERSION_BASE, lxc_version_base) | |
15 | AC_SUBST(LXC_VERSION_BETA, lxc_version_beta) | |
16 | ||
17 | AC_CONFIG_SRCDIR([configure.ac]) | |
18 | AC_CONFIG_AUX_DIR([config]) | |
19 | AC_CONFIG_HEADERS([src/config.h]) | |
20 | AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects]) | |
21 | AC_CANONICAL_HOST | |
22 | AM_PROG_CC_C_O | |
23 | AC_GNU_SOURCE | |
24 | ||
25 | # Detect the distribution. This is used for the default configuration and | |
26 | # for some distro-specific build options. | |
27 | AC_MSG_CHECKING([host distribution]) | |
28 | AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.])) | |
29 | if test "z$with_distro" = "z"; then | |
30 | with_distro=`lsb_release -is` | |
31 | fi | |
32 | if test "z$with_distro" = "z"; then | |
33 | AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat") | |
34 | AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle") | |
35 | AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora") | |
36 | AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse") | |
37 | AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo") | |
38 | AC_CHECK_FILE(/etc/debian_version,with_distro="debian") | |
39 | AC_CHECK_FILE(/etc/arch-release,with_distro="arch") | |
40 | AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware") | |
41 | AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware") | |
42 | AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva") | |
43 | AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva") | |
44 | AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus") | |
45 | fi | |
46 | with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'` | |
47 | ||
48 | if test "z$with_distro" = "z"; then | |
49 | with_distro="unknown" | |
50 | fi | |
51 | case $with_distro in | |
52 | ubuntu) | |
53 | distroconf=default.conf.ubuntu | |
54 | ;; | |
55 | redhat|fedora|oracle|oracleserver) | |
56 | distroconf=default.conf.libvirt | |
57 | ;; | |
58 | *) | |
59 | echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty" | |
60 | distroconf=default.conf.unknown | |
61 | ;; | |
62 | esac | |
63 | AC_MSG_RESULT([$with_distro]) | |
64 | AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"]) | |
65 | AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"]) | |
66 | ||
67 | # Detect the newuidmap tool (required for userns) | |
68 | AC_CHECK_PROG([NEWUIDMAP], [newuidmap], [newuidmap]) | |
69 | AM_CONDITIONAL([HAVE_NEWUIDMAP], [test -n "$NEWUIDMAP"]) | |
70 | ||
71 | # Allow disabling rpath | |
72 | AC_ARG_ENABLE([rpath], | |
73 | [AC_HELP_STRING([--disable-rpath], [do not set rpath in executables])], | |
74 | [], [enable_rpath=yes]) | |
75 | AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"]) | |
76 | ||
77 | # Documentation (manpages) | |
78 | AC_ARG_ENABLE([doc], | |
79 | [AC_HELP_STRING([--enable-doc], [make mans (requires docbook2man or docbook2x-man to be installed) [default=auto]])], | |
80 | [], [enable_doc=auto]) | |
81 | ||
82 | if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then | |
83 | db2xman="" | |
84 | dbparsers="docbook2x-man db2x_docbook2man docbook2man" | |
85 | ||
86 | AC_MSG_CHECKING(for docbook2x-man) | |
87 | for name in ${dbparsers}; do | |
88 | if "$name" --help >/dev/null 2>&1; then | |
89 | db2xman="$name" | |
90 | break; | |
91 | fi | |
92 | done | |
93 | ||
94 | if test -n "${db2xman}"; then | |
95 | AC_MSG_RESULT([${db2xman}]) | |
96 | else | |
97 | AC_MSG_RESULT([no]) | |
98 | if test "x$enable_doc" = "xyes"; then | |
99 | AC_MSG_ERROR([docbook2x-man required by man request, but not found]) | |
100 | fi | |
101 | fi | |
102 | ||
103 | AC_SUBST(db2xman) | |
104 | fi | |
105 | AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"]) | |
106 | AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"]) | |
107 | ||
108 | if test "x$db2xman" = "xdocbook2man"; then | |
109 | docdtd="\"-//Davenport//DTD DocBook V3.0//EN\"" | |
110 | else | |
111 | docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\"" | |
112 | fi | |
113 | AC_SUBST(docdtd) | |
114 | ||
115 | # Apparmor | |
116 | AC_ARG_ENABLE([apparmor], | |
117 | [AC_HELP_STRING([--enable-apparmor], [enable apparmor])], | |
118 | [], [enable_apparmor=check]) | |
119 | ||
120 | if test "$enable_apparmor" = "check" ; then | |
121 | AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no]) | |
122 | fi | |
123 | AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"]) | |
124 | ||
125 | AC_CHECK_LIB([gnutls], [gnutls_hash_fast]) | |
126 | ||
127 | AM_COND_IF([ENABLE_APPARMOR], | |
128 | [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
129 | AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
130 | AC_SUBST([APPARMOR_LIBS], [-lapparmor])]) | |
131 | ||
132 | # SELinux | |
133 | AC_ARG_ENABLE([selinux], | |
134 | [AC_HELP_STRING([--enable-selinux], [enable SELinux support])], | |
135 | [], [enable_selinux=check]) | |
136 | ||
137 | if test "x$enable_selinux" = xcheck; then | |
138 | AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no]) | |
139 | fi | |
140 | AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"]) | |
141 | AM_COND_IF([ENABLE_SELINUX], | |
142 | [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
143 | AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
144 | AC_SUBST([SELINUX_LIBS])]) | |
145 | ||
146 | # Seccomp syscall filter | |
147 | AC_ARG_ENABLE([seccomp], | |
148 | [AC_HELP_STRING([--enable-seccomp], [enable seccomp])], | |
149 | [], [enable_seccomp=check]) | |
150 | ||
151 | if test "$enable_seccomp" = "check" ; then | |
152 | AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no]) | |
153 | fi | |
154 | AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"]) | |
155 | ||
156 | AM_COND_IF([ENABLE_SECCOMP], | |
157 | [AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
158 | AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
159 | AC_SUBST([SECCOMP_LIBS], [-lseccomp])]) | |
160 | ||
161 | # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0 | |
162 | AC_CHECK_TYPES([scmp_filter_ctx], [], [], [#include <seccomp.h>]) | |
163 | ||
164 | # Configuration examples | |
165 | AC_ARG_ENABLE([examples], | |
166 | [AC_HELP_STRING([--disable-examples], [do not install configuration examples])], | |
167 | [], [enable_examples=yes]) | |
168 | AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"]) | |
169 | ||
170 | # Python3 module and scripts | |
171 | AC_ARG_ENABLE([python], | |
172 | [AC_HELP_STRING([--enable-python], [enable python binding])], | |
173 | [enable_python=yes], [enable_python=no]) | |
174 | AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"]) | |
175 | ||
176 | AM_COND_IF([ENABLE_PYTHON], | |
177 | [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])]) | |
178 | PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])]) | |
179 | AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])]) | |
180 | ||
181 | # Not in older autoconf versions | |
182 | # AS_VAR_COPY(DEST, SOURCE) | |
183 | # ------------------------- | |
184 | # Set the polymorphic shell variable DEST to the contents of the polymorphic | |
185 | # shell variable SOURCE. | |
186 | m4_ifdef([AS_VAR_COPY], [], | |
187 | [AC_DEFUN([AS_VAR_COPY], | |
188 | [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])]) | |
189 | ]) | |
190 | ||
191 | dnl PKG_CHECK_VAR was introduced with pkg-config 0.28 | |
192 | m4_ifdef([PKG_CHECK_VAR], [], | |
193 | [AC_DEFUN([PKG_CHECK_VAR], | |
194 | [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl | |
195 | AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl | |
196 | _PKG_CONFIG([$1], [variable="][$3]["], [$2]) | |
197 | AS_VAR_COPY([$1], [pkg_cv_][$1]) | |
198 | AS_VAR_IF([$1], [""], [$5], [$4])dnl | |
199 | ])# PKG_CHECK_VAR | |
200 | ]) | |
201 | ||
202 | # Lua module and scripts | |
203 | AC_ARG_ENABLE([lua], | |
204 | [AC_HELP_STRING([--enable-lua], [enable lua binding])], | |
205 | [], [enable_lua=check]) | |
206 | ||
207 | AC_ARG_WITH([lua-pc], | |
208 | [AS_HELP_STRING( | |
209 | [--with-lua-pc=PKG], | |
210 | [Specify pkg-config package name for lua] | |
211 | )], [], [with_lua_pc=no]) | |
212 | ||
213 | if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then | |
214 | # exit with error if not found | |
215 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc]) | |
216 | fi | |
217 | ||
218 | if test "x$enable_lua" = "xcheck" -a "x$with_lua_pc" != "xno"; then | |
219 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], | |
220 | [LUAPKGCONFIG=$with_lua_pc | |
221 | enable_lua=yes], | |
222 | [enable_lua=no]) | |
223 | fi | |
224 | ||
225 | if test "x$enable_lua" != "xno"; then | |
226 | PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua], | |
227 | [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2], | |
228 | [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1], | |
229 | [AS_IF([test "x$enable_lua" = "xyes"], | |
230 | [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])], | |
231 | [enable_lua=no])] | |
232 | )] | |
233 | )]) | |
234 | AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes]) | |
235 | fi | |
236 | ||
237 | AM_CONDITIONAL([ENABLE_LUA], | |
238 | [test "x$enable_lua" = "xyes"]) | |
239 | ||
240 | AM_COND_IF([ENABLE_LUA], | |
241 | [AC_MSG_CHECKING([Lua version]) | |
242 | PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],, | |
243 | [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])]) | |
244 | AC_MSG_RESULT([$LUA_VERSION]) | |
245 | PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],, | |
246 | [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION]) | |
247 | PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],, | |
248 | [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION]) | |
249 | ]) | |
250 | ||
251 | # Optional test binaries | |
252 | AC_ARG_ENABLE([tests], | |
253 | [AC_HELP_STRING([--enable-tests], [build test/example binaries])], | |
254 | [enable_tests=yes], [enable_tests=no]) | |
255 | AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"]) | |
256 | ||
257 | # LXC container path, where the containers are actually stored | |
258 | # This is overridden by an entry in the file called LXCCONF | |
259 | # (i.e. /etc/lxc/lxc.conf) | |
260 | AC_ARG_WITH([config-path], | |
261 | [AC_HELP_STRING( | |
262 | [--with-config-path=dir], | |
263 | [lxc configuration repository path] | |
264 | )], [], [with_config_path=['${localstatedir}/lib/lxc']]) | |
265 | ||
266 | # The path of the global lxc configuration file. | |
267 | AC_ARG_WITH([global-conf], | |
268 | [AC_HELP_STRING( | |
269 | [--with-global-conf=dir], | |
270 | [global lxc configuration file] | |
271 | )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']]) | |
272 | ||
273 | # The path of the userns network configuration file | |
274 | AC_ARG_WITH([usernic-conf], | |
275 | [AC_HELP_STRING( | |
276 | [--with-usernic-conf], | |
277 | [user network interface configuration file] | |
278 | )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']]) | |
279 | ||
280 | # The path of the runtime usernic database | |
281 | AC_ARG_WITH([usernic-db], | |
282 | [AC_HELP_STRING( | |
283 | [--with-usernic-db], | |
284 | [lxc user nic database] | |
285 | )], [], [with_usernic_db=['/run/lxc/nics']]) | |
286 | ||
287 | # Rootfs path, where the container mount structure is assembled | |
288 | AC_ARG_WITH([rootfs-path], | |
289 | [AC_HELP_STRING( | |
290 | [--with-rootfs-path=dir], | |
291 | [lxc rootfs mount point] | |
292 | )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']]) | |
293 | ||
294 | # cgroup pattern specification | |
295 | AC_ARG_WITH([cgroup-pattern], | |
296 | [AC_HELP_STRING( | |
297 | [--with-cgroup-pattern=pattern], | |
298 | [pattern for container cgroups] | |
299 | )], [], [with_cgroup_pattern=['/lxc/%n']]) | |
300 | ||
301 | # Container log path. By default, use $lxcpath. | |
302 | AC_MSG_CHECKING([Whether to place logfiles in container config path]) | |
303 | AC_ARG_ENABLE([configpath-log], | |
304 | [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path])], | |
305 | [use_configpath_logs=yes], [use_configpath_logs=no]) | |
306 | AC_MSG_RESULT([$use_configpath_logs]) | |
307 | AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$use_configpath_logs" = "yes"]) | |
308 | ||
309 | if test "$use_configpath_logs" = "yes"; then | |
310 | default_log_path="${with_config_path}" | |
311 | else | |
312 | default_log_path="${localstatedir}/log/lxc" | |
313 | fi | |
314 | ||
315 | AC_ARG_WITH([log-path], | |
316 | [AC_HELP_STRING( | |
317 | [--with-log-path=dir], | |
318 | [per container log path] | |
319 | )], [], [with_log_path=['${default_log_path}']]) | |
320 | ||
321 | # Expand some useful variables | |
322 | AS_AC_EXPAND(PREFIX, "$prefix") | |
323 | AS_AC_EXPAND(LIBDIR, "$libdir") | |
324 | AS_AC_EXPAND(BINDIR, "$bindir") | |
325 | AS_AC_EXPAND(LIBEXECDIR, "$libexecdir") | |
326 | AS_AC_EXPAND(INCLUDEDIR, "$includedir") | |
327 | AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir") | |
328 | AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf") | |
329 | AS_AC_EXPAND(DATADIR, "$datadir") | |
330 | AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir") | |
331 | AS_AC_EXPAND(DOCDIR, "$docdir") | |
332 | AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf") | |
333 | AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)") | |
334 | AS_AC_EXPAND(LXCPATH, "$with_config_path") | |
335 | AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf") | |
336 | AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf") | |
337 | AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db") | |
338 | AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path") | |
339 | AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates") | |
340 | AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks") | |
341 | AS_AC_EXPAND(LXCINITDIR, "$libexecdir") | |
342 | AS_AC_EXPAND(LOGPATH, "$with_log_path") | |
343 | AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"]) | |
344 | ||
345 | # Check for some standard kernel headers | |
346 | AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h], | |
347 | [], | |
348 | AC_MSG_ERROR([Please install the Linux kernel headers.]), | |
349 | [#include <sys/socket.h>]) | |
350 | ||
351 | # Allow disabling libcap support | |
352 | AC_ARG_ENABLE([capabilities], | |
353 | [AC_HELP_STRING([--disable-capabilities], [disable kernel capabilities])], | |
354 | [], [enable_capabilities=yes]) | |
355 | ||
356 | # Check for libcap support | |
357 | if test "x$enable_capabilities" = "xyes"; then | |
358 | AC_CHECK_LIB(cap,cap_set_proc,caplib=yes,caplib=no) | |
359 | AC_MSG_CHECKING([linux capabilities]) | |
360 | if test "x$caplib" = "xyes" ; then | |
361 | CAP_LIBS="-lcap" | |
362 | AC_MSG_RESULT([$CAP_LIBS]) | |
363 | else | |
364 | AC_MSG_RESULT([no]) | |
365 | AC_MSG_ERROR([You are missing libcap support. If you really want to build without kernel capabilities, use --disable-capabilities]) | |
366 | fi | |
367 | else | |
368 | CAP_LIBS="" | |
369 | fi | |
370 | AC_SUBST([CAP_LIBS]) | |
371 | ||
372 | # Check for alternate C libraries | |
373 | AC_MSG_CHECKING(for bionic libc) | |
374 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM( | |
375 | [[#ifndef __ANDROID__ | |
376 | error: Not bionic! | |
377 | #endif]])], | |
378 | [is_bionic=yes], | |
379 | [is_bionic=no]) | |
380 | if test "x$is_bionic" = "xyes"; then | |
381 | AC_DEFINE([IS_BIONIC], 1, [bionic libc]) | |
382 | AC_MSG_RESULT([yes]) | |
383 | else | |
384 | AC_MSG_RESULT([no]) | |
385 | fi | |
386 | AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"]) | |
387 | ||
388 | # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP | |
389 | AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>]) | |
390 | ||
391 | # Check for some headers | |
392 | AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h]) | |
393 | ||
394 | # Check for some syscalls functions | |
395 | AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr]) | |
396 | ||
397 | # Check for some functions | |
398 | AC_CHECK_LIB(util, openpty) | |
399 | AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent]) | |
400 | AC_CHECK_FUNCS([getline], | |
401 | AM_CONDITIONAL(HAVE_GETLINE, true) | |
402 | AC_DEFINE(HAVE_GETLINE,1,[Have getline]), | |
403 | AM_CONDITIONAL(HAVE_GETLINE, false)) | |
404 | AC_CHECK_FUNCS([fgetln], | |
405 | AM_CONDITIONAL(HAVE_FGETLN, true) | |
406 | AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]), | |
407 | AM_CONDITIONAL(HAVE_FGETLN, false)) | |
408 | ||
409 | # Check for some libraries | |
410 | AC_SEARCH_LIBS(sem_open, [rt pthread]) | |
411 | AC_SEARCH_LIBS(clock_gettime, [rt]) | |
412 | ||
413 | # Check for some standard binaries | |
414 | AC_PROG_GCC_TRADITIONAL | |
415 | AC_PROG_SED | |
416 | ||
417 | if test "x$GCC" = "xyes"; then | |
418 | CFLAGS="$CFLAGS -Wall -Werror" | |
419 | fi | |
420 | ||
421 | # Files requiring some variable expansion | |
422 | AC_CONFIG_FILES([ | |
423 | Makefile | |
424 | lxc.pc | |
425 | lxc.spec | |
426 | config/Makefile | |
427 | ||
428 | doc/Makefile | |
429 | doc/legacy/lxc-ls.sgml | |
430 | doc/lxc-attach.sgml | |
431 | doc/lxc-cgroup.sgml | |
432 | doc/lxc-checkconfig.sgml | |
433 | doc/lxc-checkpoint.sgml | |
434 | doc/lxc-clone.sgml | |
435 | doc/lxc-console.sgml | |
436 | doc/lxc-create.sgml | |
437 | doc/lxc-destroy.sgml | |
438 | doc/lxc-device.sgml | |
439 | doc/lxc-execute.sgml | |
440 | doc/lxc-freeze.sgml | |
441 | doc/lxc-info.sgml | |
442 | doc/lxc-kill.sgml | |
443 | doc/lxc-ls.sgml | |
444 | doc/lxc-monitor.sgml | |
445 | doc/lxc-netstat.sgml | |
446 | doc/lxc-ps.sgml | |
447 | doc/lxc-restart.sgml | |
448 | doc/lxc-snapshot.sgml | |
449 | doc/lxc-start-ephemeral.sgml | |
450 | doc/lxc-start.sgml | |
451 | doc/lxc-stop.sgml | |
452 | doc/lxc-top.sgml | |
453 | doc/lxc-unfreeze.sgml | |
454 | doc/lxc-unshare.sgml | |
455 | doc/lxc-version.sgml | |
456 | doc/lxc-wait.sgml | |
457 | ||
458 | doc/lxc.conf.sgml | |
459 | doc/lxc.sgml | |
460 | doc/common_options.sgml | |
461 | doc/see_also.sgml | |
462 | ||
463 | doc/rootfs/Makefile | |
464 | ||
465 | doc/examples/Makefile | |
466 | doc/examples/lxc-macvlan.conf | |
467 | doc/examples/lxc-vlan.conf | |
468 | doc/examples/lxc-no-netns.conf | |
469 | doc/examples/lxc-empty-netns.conf | |
470 | doc/examples/lxc-phys.conf | |
471 | doc/examples/lxc-veth.conf | |
472 | doc/examples/lxc-complex.conf | |
473 | ||
474 | doc/ja/Makefile | |
475 | doc/ja/legacy/lxc-ls.sgml | |
476 | doc/ja/lxc-attach.sgml | |
477 | doc/ja/lxc-cgroup.sgml | |
478 | doc/ja/lxc-checkconfig.sgml | |
479 | doc/ja/lxc-checkpoint.sgml | |
480 | doc/ja/lxc-clone.sgml | |
481 | doc/ja/lxc-console.sgml | |
482 | doc/ja/lxc-create.sgml | |
483 | doc/ja/lxc-destroy.sgml | |
484 | doc/ja/lxc-device.sgml | |
485 | doc/ja/lxc-execute.sgml | |
486 | doc/ja/lxc-freeze.sgml | |
487 | doc/ja/lxc-info.sgml | |
488 | doc/ja/lxc-kill.sgml | |
489 | doc/ja/lxc-ls.sgml | |
490 | doc/ja/lxc-monitor.sgml | |
491 | doc/ja/lxc-netstat.sgml | |
492 | doc/ja/lxc-ps.sgml | |
493 | doc/ja/lxc-restart.sgml | |
494 | doc/ja/lxc-snapshot.sgml | |
495 | doc/ja/lxc-start-ephemeral.sgml | |
496 | doc/ja/lxc-start.sgml | |
497 | doc/ja/lxc-stop.sgml | |
498 | doc/ja/lxc-top.sgml | |
499 | doc/ja/lxc-unfreeze.sgml | |
500 | doc/ja/lxc-unshare.sgml | |
501 | doc/ja/lxc-version.sgml | |
502 | doc/ja/lxc-wait.sgml | |
503 | ||
504 | doc/ja/lxc.conf.sgml | |
505 | doc/ja/lxc.sgml | |
506 | doc/ja/common_options.sgml | |
507 | doc/ja/see_also.sgml | |
508 | ||
509 | hooks/Makefile | |
510 | ||
511 | templates/Makefile | |
512 | templates/lxc-cirros | |
513 | templates/lxc-debian | |
514 | templates/lxc-ubuntu | |
515 | templates/lxc-ubuntu-cloud | |
516 | templates/lxc-opensuse | |
517 | templates/lxc-busybox | |
518 | templates/lxc-fedora | |
519 | templates/lxc-openmandriva | |
520 | templates/lxc-oracle | |
521 | templates/lxc-altlinux | |
522 | templates/lxc-sshd | |
523 | templates/lxc-archlinux | |
524 | templates/lxc-alpine | |
525 | templates/lxc-plamo | |
526 | ||
527 | src/Makefile | |
528 | src/lxc/Makefile | |
529 | src/lxc/lxc-ps | |
530 | src/lxc/lxc-netstat | |
531 | src/lxc/lxc-checkconfig | |
532 | src/lxc/lxc-version | |
533 | src/lxc/lxc-start-ephemeral | |
534 | src/lxc/legacy/lxc-ls | |
535 | src/lxc/lxc.functions | |
536 | ||
537 | src/python-lxc/Makefile | |
538 | ||
539 | src/lua-lxc/Makefile | |
540 | ||
541 | src/tests/Makefile | |
542 | ]) | |
543 | AC_CONFIG_COMMANDS([default],[[]],[[]]) | |
544 | AC_OUTPUT |