]>
Commit | Line | Data |
---|---|---|
1 | # -*- Autoconf -*- | |
2 | # Process this file with autoconf to produce a configure script. | |
3 | ||
4 | m4_define([lxc_version_major], 1) | |
5 | m4_define([lxc_version_minor], 0) | |
6 | m4_define([lxc_version_micro], 0) | |
7 | m4_define([lxc_version_beta], [beta1]) | |
8 | ||
9 | m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro]) | |
10 | m4_define([lxc_version], | |
11 | [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])]) | |
12 | ||
13 | AC_INIT([lxc], [lxc_version]) | |
14 | ||
15 | # We need pkg-config | |
16 | PKG_PROG_PKG_CONFIG | |
17 | ||
18 | AC_SUBST(LXC_VERSION_BASE, lxc_version_base) | |
19 | AC_SUBST(LXC_VERSION_BETA, lxc_version_beta) | |
20 | ||
21 | AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major]) | |
22 | AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor]) | |
23 | AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro]) | |
24 | AC_SUBST([LXC_VERSION], [lxc_version]) | |
25 | ||
26 | AC_CONFIG_SRCDIR([configure.ac]) | |
27 | AC_CONFIG_AUX_DIR([config]) | |
28 | AC_CONFIG_HEADERS([src/config.h]) | |
29 | AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects]) | |
30 | AC_CANONICAL_HOST | |
31 | AM_PROG_CC_C_O | |
32 | AC_GNU_SOURCE | |
33 | ||
34 | # Detect the distribution. This is used for the default configuration and | |
35 | # for some distro-specific build options. | |
36 | AC_MSG_CHECKING([host distribution]) | |
37 | AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.])) | |
38 | if test "z$with_distro" = "z"; then | |
39 | with_distro=`lsb_release -is` | |
40 | fi | |
41 | if test "z$with_distro" = "z"; then | |
42 | AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat") | |
43 | AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle") | |
44 | AC_CHECK_FILE(/etc/centos-release,with_distro="centos") | |
45 | AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora") | |
46 | AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse") | |
47 | AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo") | |
48 | AC_CHECK_FILE(/etc/debian_version,with_distro="debian") | |
49 | AC_CHECK_FILE(/etc/arch-release,with_distro="arch") | |
50 | AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware") | |
51 | AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware") | |
52 | AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva") | |
53 | AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva") | |
54 | AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus") | |
55 | fi | |
56 | with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'` | |
57 | ||
58 | if test "z$with_distro" = "z"; then | |
59 | with_distro="unknown" | |
60 | fi | |
61 | case $with_distro in | |
62 | ubuntu) | |
63 | distroconf=default.conf.ubuntu | |
64 | ;; | |
65 | redhat|centos|fedora|oracle|oracleserver) | |
66 | distroconf=default.conf.libvirt | |
67 | ;; | |
68 | *) | |
69 | echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty" | |
70 | distroconf=default.conf.unknown | |
71 | ;; | |
72 | esac | |
73 | AC_MSG_RESULT([$with_distro]) | |
74 | AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"]) | |
75 | AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"]) | |
76 | ||
77 | # Check for init system type | |
78 | AC_MSG_CHECKING([for init system type]) | |
79 | AC_ARG_WITH([init-script], | |
80 | [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@], | |
81 | [Type(s) of init script to install: sysv, systemd, upstart, | |
82 | distro @<:@default=distro@:>@])],[],[with_init_script=distro]) | |
83 | case "$with_init_script" in | |
84 | distro) | |
85 | case $with_distro in | |
86 | fedora) | |
87 | init_script=systemd | |
88 | ;; | |
89 | redhat|centos|oracle|oracleserver) | |
90 | init_script=sysv | |
91 | ;; | |
92 | debian) | |
93 | init_script=sysv,upstart,systemd | |
94 | ;; | |
95 | ubuntu) | |
96 | init_script=upstart | |
97 | ;; | |
98 | *) | |
99 | echo -n "Linux distribution init system unknown, defaulting to sysv" | |
100 | init_script=sysv | |
101 | ;; | |
102 | esac | |
103 | ;; | |
104 | *) | |
105 | init_script=$with_init_script | |
106 | ;; | |
107 | esac | |
108 | ||
109 | # Check valid init systems were given, run in subshell so we don't mess up IFS | |
110 | (IFS="," ; for init_sys in $init_script; | |
111 | do | |
112 | case "$init_sys" in | |
113 | none|sysv|systemd|upstart) | |
114 | ;; | |
115 | *) | |
116 | exit 1 | |
117 | ;; | |
118 | esac | |
119 | done) || AC_MSG_ERROR([Unknown init system type in $init_script]) | |
120 | ||
121 | AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysv"]) | |
122 | AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"]) | |
123 | AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"]) | |
124 | AC_MSG_RESULT($init_script) | |
125 | ||
126 | # Allow disabling rpath | |
127 | AC_ARG_ENABLE([rpath], | |
128 | [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])], | |
129 | [], [enable_rpath=no]) | |
130 | AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"]) | |
131 | ||
132 | # Documentation (manpages) | |
133 | AC_ARG_ENABLE([doc], | |
134 | [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])], | |
135 | [], [enable_doc=auto]) | |
136 | ||
137 | if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then | |
138 | db2xman="" | |
139 | dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man" | |
140 | ||
141 | AC_MSG_CHECKING(for docbook2x-man) | |
142 | for name in ${dbparsers}; do | |
143 | if "$name" --help >/dev/null 2>&1; then | |
144 | db2xman="$name" | |
145 | break; | |
146 | fi | |
147 | done | |
148 | ||
149 | if test -n "${db2xman}"; then | |
150 | AC_MSG_RESULT([${db2xman}]) | |
151 | enable_doc="yes" | |
152 | else | |
153 | AC_MSG_RESULT([no]) | |
154 | if test "x$enable_doc" = "xyes"; then | |
155 | AC_MSG_ERROR([docbook2x-man is required, but could not be found]) | |
156 | fi | |
157 | enable_doc="no" | |
158 | fi | |
159 | ||
160 | AC_SUBST(db2xman) | |
161 | fi | |
162 | AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"]) | |
163 | AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"]) | |
164 | ||
165 | if test "x$db2xman" = "xdocbook2man"; then | |
166 | docdtd="\"-//Davenport//DTD DocBook V3.0//EN\"" | |
167 | else | |
168 | docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\"" | |
169 | fi | |
170 | AC_SUBST(docdtd) | |
171 | ||
172 | # Documentation (API) | |
173 | AC_ARG_ENABLE([api-docs], | |
174 | [AC_HELP_STRING([--enable-api-docs], | |
175 | [make API documentation [default=auto]])], | |
176 | [], [enable_api_docs=auto]) | |
177 | ||
178 | if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then | |
179 | AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen]) | |
180 | AC_SUBST([HAVE_DOXYGEN]) | |
181 | ||
182 | if test "x$HAVE_DOXYGEN" != "x"; then | |
183 | enable_api_docs="yes" | |
184 | else | |
185 | if test "x$enable_api_docs" = "xyes"; then | |
186 | AC_MSG_ERROR([doxygen is required, but could not be found]) | |
187 | fi | |
188 | enable_api_docs="no" | |
189 | fi | |
190 | fi | |
191 | ||
192 | AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"]) | |
193 | ||
194 | # Apparmor | |
195 | AC_ARG_ENABLE([apparmor], | |
196 | [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])], | |
197 | [], [enable_apparmor=auto]) | |
198 | ||
199 | if test "$enable_apparmor" = "auto" ; then | |
200 | AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no]) | |
201 | fi | |
202 | AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"]) | |
203 | ||
204 | AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no]) | |
205 | ||
206 | AM_COND_IF([ENABLE_APPARMOR], | |
207 | [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
208 | AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
209 | AC_SUBST([APPARMOR_LIBS], [-lapparmor])]) | |
210 | ||
211 | # SELinux | |
212 | AC_ARG_ENABLE([selinux], | |
213 | [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])], | |
214 | [], [enable_selinux=auto]) | |
215 | ||
216 | if test "x$enable_selinux" = xauto; then | |
217 | AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no]) | |
218 | fi | |
219 | AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"]) | |
220 | AM_COND_IF([ENABLE_SELINUX], | |
221 | [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
222 | AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
223 | AC_SUBST([SELINUX_LIBS])]) | |
224 | ||
225 | # Seccomp syscall filter | |
226 | AC_ARG_ENABLE([seccomp], | |
227 | [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])], | |
228 | [], [enable_seccomp=auto]) | |
229 | ||
230 | if test "x$enable_seccomp" = "xauto" ; then | |
231 | AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no]) | |
232 | fi | |
233 | AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"]) | |
234 | ||
235 | AM_COND_IF([ENABLE_SECCOMP], | |
236 | [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[ | |
237 | AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
238 | AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
239 | AC_SUBST([SECCOMP_LIBS], [-lseccomp]) | |
240 | ]) | |
241 | ]) | |
242 | ||
243 | # Linux capabilities | |
244 | AC_ARG_ENABLE([capabilities], | |
245 | [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])], | |
246 | [], [enable_capabilities=auto]) | |
247 | ||
248 | if test "x$enable_capabilities" = "xauto"; then | |
249 | AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no]) | |
250 | fi | |
251 | AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"]) | |
252 | ||
253 | AM_COND_IF([ENABLE_CAP], | |
254 | [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])]) | |
255 | AC_SUBST([CAP_LIBS], [-lcap])]) | |
256 | ||
257 | # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0 | |
258 | OLD_CFLAGS="$CFLAGS" | |
259 | CFLAGS="$CFLAGS $SECCOMP_CFLAGS" | |
260 | AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]]) | |
261 | CFLAGS="$OLD_CFLAGS" | |
262 | ||
263 | # Configuration examples | |
264 | AC_ARG_ENABLE([examples], | |
265 | [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])], | |
266 | [], [enable_examples=yes]) | |
267 | AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"]) | |
268 | ||
269 | # Python3 module and scripts | |
270 | AC_ARG_ENABLE([python], | |
271 | [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])], | |
272 | [], [enable_python=auto]) | |
273 | ||
274 | if test "x$enable_python" = "xauto"; then | |
275 | PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no]) | |
276 | if test "$CC" = "clang"; then | |
277 | enable_python=no | |
278 | fi | |
279 | fi | |
280 | ||
281 | if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then | |
282 | AC_MSG_ERROR([Python3 is incompatible with the clang compiler]) | |
283 | fi | |
284 | ||
285 | AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"]) | |
286 | ||
287 | AM_COND_IF([ENABLE_PYTHON], | |
288 | [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])]) | |
289 | PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])]) | |
290 | AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])]) | |
291 | ||
292 | # Enable dumping stack traces | |
293 | AC_ARG_ENABLE([mutex-debugging], | |
294 | [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])], | |
295 | [], [enable_mutex_debugging=no]) | |
296 | AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"]) | |
297 | ||
298 | AM_COND_IF([MUTEX_DEBUGGING], | |
299 | AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging])) | |
300 | ||
301 | # Not in older autoconf versions | |
302 | # AS_VAR_COPY(DEST, SOURCE) | |
303 | # ------------------------- | |
304 | # Set the polymorphic shell variable DEST to the contents of the polymorphic | |
305 | # shell variable SOURCE. | |
306 | m4_ifdef([AS_VAR_COPY], [], | |
307 | [AC_DEFUN([AS_VAR_COPY], | |
308 | [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])]) | |
309 | ]) | |
310 | ||
311 | dnl PKG_CHECK_VAR was introduced with pkg-config 0.28 | |
312 | m4_ifdef([PKG_CHECK_VAR], [], | |
313 | [AC_DEFUN([PKG_CHECK_VAR], | |
314 | [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl | |
315 | AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl | |
316 | _PKG_CONFIG([$1], [variable="][$3]["], [$2]) | |
317 | AS_VAR_COPY([$1], [pkg_cv_][$1]) | |
318 | AS_VAR_IF([$1], [""], [$5], [$4])dnl | |
319 | ])# PKG_CHECK_VAR | |
320 | ]) | |
321 | ||
322 | # Lua module and scripts | |
323 | AC_ARG_ENABLE([lua], | |
324 | [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])], | |
325 | [], [enable_lua=auto]) | |
326 | ||
327 | AC_ARG_WITH([lua-pc], | |
328 | [AS_HELP_STRING( | |
329 | [--with-lua-pc=PKG], | |
330 | [Specify pkg-config package name for lua] | |
331 | )], [], [with_lua_pc=no]) | |
332 | ||
333 | if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then | |
334 | # exit with error if not found | |
335 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc]) | |
336 | fi | |
337 | ||
338 | if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then | |
339 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], | |
340 | [LUAPKGCONFIG=$with_lua_pc | |
341 | enable_lua=yes], | |
342 | [enable_lua=no]) | |
343 | fi | |
344 | ||
345 | if test "x$enable_lua" != "xno"; then | |
346 | PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua], | |
347 | [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2], | |
348 | [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1], | |
349 | [AS_IF([test "x$enable_lua" = "xyes"], | |
350 | [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])], | |
351 | [enable_lua=no])] | |
352 | )] | |
353 | )]) | |
354 | AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes]) | |
355 | fi | |
356 | ||
357 | AM_CONDITIONAL([ENABLE_LUA], | |
358 | [test "x$enable_lua" = "xyes"]) | |
359 | ||
360 | AM_COND_IF([ENABLE_LUA], | |
361 | [AC_MSG_CHECKING([Lua version]) | |
362 | PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],, | |
363 | [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])]) | |
364 | AC_MSG_RESULT([$LUA_VERSION]) | |
365 | PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],, | |
366 | [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION]) | |
367 | PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],, | |
368 | [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION]) | |
369 | ]) | |
370 | ||
371 | # Optional test binaries | |
372 | AC_ARG_ENABLE([tests], | |
373 | [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])], | |
374 | [], [enable_tests=no]) | |
375 | AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"]) | |
376 | ||
377 | # LXC container path, where the containers are actually stored | |
378 | # This is overridden by an entry in the file called LXCCONF | |
379 | # (i.e. /etc/lxc/lxc.conf) | |
380 | AC_ARG_WITH([config-path], | |
381 | [AC_HELP_STRING( | |
382 | [--with-config-path=dir], | |
383 | [lxc configuration repository path] | |
384 | )], [], [with_config_path=['${localstatedir}/lib/lxc']]) | |
385 | ||
386 | # The path of the global lxc configuration file. | |
387 | AC_ARG_WITH([global-conf], | |
388 | [AC_HELP_STRING( | |
389 | [--with-global-conf=dir], | |
390 | [global lxc configuration file] | |
391 | )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']]) | |
392 | ||
393 | # The path of the userns network configuration file | |
394 | AC_ARG_WITH([usernic-conf], | |
395 | [AC_HELP_STRING( | |
396 | [--with-usernic-conf], | |
397 | [user network interface configuration file] | |
398 | )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']]) | |
399 | ||
400 | # The path of the runtime usernic database | |
401 | AC_ARG_WITH([usernic-db], | |
402 | [AC_HELP_STRING( | |
403 | [--with-usernic-db], | |
404 | [lxc user nic database] | |
405 | )], [], [with_usernic_db=['/run/lxc/nics']]) | |
406 | ||
407 | # Rootfs path, where the container mount structure is assembled | |
408 | AC_ARG_WITH([rootfs-path], | |
409 | [AC_HELP_STRING( | |
410 | [--with-rootfs-path=dir], | |
411 | [lxc rootfs mount point] | |
412 | )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']]) | |
413 | ||
414 | # cgroup pattern specification | |
415 | AC_ARG_WITH([cgroup-pattern], | |
416 | [AC_HELP_STRING( | |
417 | [--with-cgroup-pattern=pattern], | |
418 | [pattern for container cgroups] | |
419 | )], [], [with_cgroup_pattern=['/lxc/%n']]) | |
420 | ||
421 | # Container log path. By default, use $lxcpath. | |
422 | AC_MSG_CHECKING([Whether to place logfiles in container config path]) | |
423 | AC_ARG_ENABLE([configpath-log], | |
424 | [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])], | |
425 | [], [enable_configpath_log=no]) | |
426 | AC_MSG_RESULT([$enable_configpath_log]) | |
427 | AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"]) | |
428 | ||
429 | if test "$enable_configpath_log" = "yes"; then | |
430 | default_log_path="${with_config_path}" | |
431 | else | |
432 | default_log_path="${localstatedir}/log/lxc" | |
433 | fi | |
434 | ||
435 | AC_ARG_WITH([log-path], | |
436 | [AC_HELP_STRING( | |
437 | [--with-log-path=dir], | |
438 | [per container log path] | |
439 | )], [], [with_log_path=['${default_log_path}']]) | |
440 | ||
441 | # Expand some useful variables | |
442 | AS_AC_EXPAND(PREFIX, "$prefix") | |
443 | AS_AC_EXPAND(LIBDIR, "$libdir") | |
444 | AS_AC_EXPAND(BINDIR, "$bindir") | |
445 | AS_AC_EXPAND(LIBEXECDIR, "$libexecdir") | |
446 | AS_AC_EXPAND(INCLUDEDIR, "$includedir") | |
447 | AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir") | |
448 | AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf") | |
449 | AS_AC_EXPAND(DATADIR, "$datadir") | |
450 | AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir") | |
451 | AS_AC_EXPAND(DOCDIR, "$docdir") | |
452 | AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf") | |
453 | AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)") | |
454 | AS_AC_EXPAND(LXCPATH, "$with_config_path") | |
455 | AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf") | |
456 | AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf") | |
457 | AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db") | |
458 | AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path") | |
459 | AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates") | |
460 | AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config") | |
461 | AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks") | |
462 | AS_AC_EXPAND(LXCINITDIR, "$libexecdir") | |
463 | AS_AC_EXPAND(LOGPATH, "$with_log_path") | |
464 | AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"]) | |
465 | ||
466 | # Check for some standard kernel headers | |
467 | AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h], | |
468 | [], | |
469 | AC_MSG_ERROR([Please install the Linux kernel headers.]), | |
470 | [#include <sys/socket.h>]) | |
471 | ||
472 | # Check for alternate C libraries | |
473 | AC_MSG_CHECKING(for bionic libc) | |
474 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM( | |
475 | [[#ifndef __ANDROID__ | |
476 | error: Not bionic! | |
477 | #endif]])], | |
478 | [is_bionic=yes], | |
479 | [is_bionic=no]) | |
480 | if test "x$is_bionic" = "xyes"; then | |
481 | AC_DEFINE([IS_BIONIC], 1, [bionic libc]) | |
482 | AC_MSG_RESULT([yes]) | |
483 | else | |
484 | AC_MSG_RESULT([no]) | |
485 | fi | |
486 | AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"]) | |
487 | ||
488 | # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP | |
489 | AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>]) | |
490 | ||
491 | # Check for some headers | |
492 | AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h]) | |
493 | ||
494 | # Check for some syscalls functions | |
495 | AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr]) | |
496 | ||
497 | # Check for some functions | |
498 | AC_CHECK_LIB(pthread, main) | |
499 | AC_CHECK_FUNCS(pthread_atfork) | |
500 | AC_CHECK_LIB(util, openpty) | |
501 | AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent]) | |
502 | AC_CHECK_FUNCS([getline], | |
503 | AM_CONDITIONAL(HAVE_GETLINE, true) | |
504 | AC_DEFINE(HAVE_GETLINE,1,[Have getline]), | |
505 | AM_CONDITIONAL(HAVE_GETLINE, false)) | |
506 | AC_CHECK_FUNCS([fgetln], | |
507 | AM_CONDITIONAL(HAVE_FGETLN, true) | |
508 | AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]), | |
509 | AM_CONDITIONAL(HAVE_FGETLN, false)) | |
510 | ||
511 | # Check for some libraries | |
512 | AC_SEARCH_LIBS(sem_open, [rt pthread]) | |
513 | AC_SEARCH_LIBS(clock_gettime, [rt]) | |
514 | ||
515 | # Check for some standard binaries | |
516 | AC_PROG_GCC_TRADITIONAL | |
517 | AC_PROG_SED | |
518 | ||
519 | # See if we support thread-local storage. | |
520 | LXC_CHECK_TLS | |
521 | ||
522 | if test "x$GCC" = "xyes"; then | |
523 | CFLAGS="$CFLAGS -Wall -Werror" | |
524 | fi | |
525 | ||
526 | # Files requiring some variable expansion | |
527 | AC_CONFIG_FILES([ | |
528 | Makefile | |
529 | lxc.pc | |
530 | lxc.spec | |
531 | ||
532 | config/Makefile | |
533 | config/etc/Makefile | |
534 | config/templates/Makefile | |
535 | config/templates/ubuntu-cloud.common.conf | |
536 | config/templates/ubuntu-cloud.lucid.conf | |
537 | config/templates/ubuntu-cloud.userns.conf | |
538 | config/templates/ubuntu.common.conf | |
539 | config/templates/ubuntu.lucid.conf | |
540 | config/templates/ubuntu.userns.conf | |
541 | ||
542 | doc/Makefile | |
543 | doc/api/Makefile | |
544 | doc/legacy/lxc-ls.sgml | |
545 | doc/lxc-attach.sgml | |
546 | doc/lxc-autostart.sgml | |
547 | doc/lxc-cgroup.sgml | |
548 | doc/lxc-checkconfig.sgml | |
549 | doc/lxc-checkpoint.sgml | |
550 | doc/lxc-clone.sgml | |
551 | doc/lxc-console.sgml | |
552 | doc/lxc-create.sgml | |
553 | doc/lxc-destroy.sgml | |
554 | doc/lxc-device.sgml | |
555 | doc/lxc-execute.sgml | |
556 | doc/lxc-freeze.sgml | |
557 | doc/lxc-info.sgml | |
558 | doc/lxc-kill.sgml | |
559 | doc/lxc-ls.sgml | |
560 | doc/lxc-monitor.sgml | |
561 | doc/lxc-netstat.sgml | |
562 | doc/lxc-ps.sgml | |
563 | doc/lxc-restart.sgml | |
564 | doc/lxc-snapshot.sgml | |
565 | doc/lxc-start-ephemeral.sgml | |
566 | doc/lxc-start.sgml | |
567 | doc/lxc-stop.sgml | |
568 | doc/lxc-top.sgml | |
569 | doc/lxc-unfreeze.sgml | |
570 | doc/lxc-unshare.sgml | |
571 | doc/lxc-user-nic.sgml | |
572 | doc/lxc-version.sgml | |
573 | doc/lxc-wait.sgml | |
574 | ||
575 | doc/lxc.conf.sgml | |
576 | doc/lxc-usernet.sgml | |
577 | doc/lxc.sgml | |
578 | doc/common_options.sgml | |
579 | doc/see_also.sgml | |
580 | ||
581 | doc/rootfs/Makefile | |
582 | ||
583 | doc/examples/Makefile | |
584 | doc/examples/lxc-macvlan.conf | |
585 | doc/examples/lxc-vlan.conf | |
586 | doc/examples/lxc-no-netns.conf | |
587 | doc/examples/lxc-empty-netns.conf | |
588 | doc/examples/lxc-phys.conf | |
589 | doc/examples/lxc-veth.conf | |
590 | doc/examples/lxc-complex.conf | |
591 | ||
592 | doc/ja/Makefile | |
593 | doc/ja/legacy/lxc-ls.sgml | |
594 | doc/ja/lxc-attach.sgml | |
595 | doc/ja/lxc-autostart.sgml | |
596 | doc/ja/lxc-cgroup.sgml | |
597 | doc/ja/lxc-checkconfig.sgml | |
598 | doc/ja/lxc-checkpoint.sgml | |
599 | doc/ja/lxc-clone.sgml | |
600 | doc/ja/lxc-console.sgml | |
601 | doc/ja/lxc-create.sgml | |
602 | doc/ja/lxc-destroy.sgml | |
603 | doc/ja/lxc-device.sgml | |
604 | doc/ja/lxc-execute.sgml | |
605 | doc/ja/lxc-freeze.sgml | |
606 | doc/ja/lxc-info.sgml | |
607 | doc/ja/lxc-kill.sgml | |
608 | doc/ja/lxc-ls.sgml | |
609 | doc/ja/lxc-monitor.sgml | |
610 | doc/ja/lxc-netstat.sgml | |
611 | doc/ja/lxc-ps.sgml | |
612 | doc/ja/lxc-restart.sgml | |
613 | doc/ja/lxc-snapshot.sgml | |
614 | doc/ja/lxc-start-ephemeral.sgml | |
615 | doc/ja/lxc-start.sgml | |
616 | doc/ja/lxc-stop.sgml | |
617 | doc/ja/lxc-top.sgml | |
618 | doc/ja/lxc-unfreeze.sgml | |
619 | doc/ja/lxc-unshare.sgml | |
620 | doc/ja/lxc-user-nic.sgml | |
621 | doc/ja/lxc-version.sgml | |
622 | doc/ja/lxc-wait.sgml | |
623 | ||
624 | doc/ja/lxc.conf.sgml | |
625 | doc/ja/lxc-usernet.sgml | |
626 | doc/ja/lxc.sgml | |
627 | doc/ja/common_options.sgml | |
628 | doc/ja/see_also.sgml | |
629 | ||
630 | hooks/Makefile | |
631 | ||
632 | templates/Makefile | |
633 | templates/lxc-cirros | |
634 | templates/lxc-debian | |
635 | templates/lxc-download | |
636 | templates/lxc-ubuntu | |
637 | templates/lxc-ubuntu-cloud | |
638 | templates/lxc-opensuse | |
639 | templates/lxc-busybox | |
640 | templates/lxc-centos | |
641 | templates/lxc-fedora | |
642 | templates/lxc-openmandriva | |
643 | templates/lxc-oracle | |
644 | templates/lxc-altlinux | |
645 | templates/lxc-sshd | |
646 | templates/lxc-archlinux | |
647 | templates/lxc-alpine | |
648 | templates/lxc-plamo | |
649 | ||
650 | src/Makefile | |
651 | src/lxc/Makefile | |
652 | src/lxc/lxc-ps | |
653 | src/lxc/lxc-netstat | |
654 | src/lxc/lxc-checkconfig | |
655 | src/lxc/lxc-version | |
656 | src/lxc/lxc-start-ephemeral | |
657 | src/lxc/legacy/lxc-ls | |
658 | src/lxc/lxc.functions | |
659 | src/lxc/version.h | |
660 | src/python-lxc/Makefile | |
661 | ||
662 | src/lua-lxc/Makefile | |
663 | ||
664 | src/tests/Makefile | |
665 | ]) | |
666 | AC_CONFIG_COMMANDS([default],[[]],[[]]) | |
667 | AC_OUTPUT | |
668 | ||
669 | # Configuration overview | |
670 | cat << EOF | |
671 | ||
672 | ---------------------------- | |
673 | Environment: | |
674 | - compiler: $CC | |
675 | - distribution: $with_distro | |
676 | - init script type(s): $init_script | |
677 | - rpath: $enable_rpath | |
678 | - GnuTLS: $enable_gnutls | |
679 | ||
680 | Security features: | |
681 | - Apparmor: $enable_apparmor | |
682 | - Linux capabilities: $enable_capabilities | |
683 | - seccomp: $enable_seccomp | |
684 | - SELinux: $enable_selinux | |
685 | ||
686 | Bindings: | |
687 | - lua: $enable_lua | |
688 | - python3: $enable_python | |
689 | ||
690 | Documentation: | |
691 | - examples: $enable_examples | |
692 | - API documentation: $enable_api_docs | |
693 | - user documentation: $enable_doc | |
694 | ||
695 | Debugging: | |
696 | - tests: $enable_tests | |
697 | - mutex debugging: $enable_mutex_debugging | |
698 | ||
699 | Paths: | |
700 | - Logs in configpath: $enable_configpath_log | |
701 | EOF | |
702 | ||
703 | if test "x$ac_cv_func_pthread_atfork" = "xno" ; then | |
704 | cat << EOF | |
705 | ||
706 | WARNING: Threading not supported on your platform | |
707 | ||
708 | You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork). | |
709 | Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems. | |
710 | EOF | |
711 | fi |