]>
Commit | Line | Data |
---|---|---|
1 | # -*- Autoconf -*- | |
2 | # Process this file with autoconf to produce a configure script. | |
3 | ||
4 | m4_define([lxc_version_major], 1) | |
5 | m4_define([lxc_version_minor], 1) | |
6 | m4_define([lxc_version_micro], 0) | |
7 | m4_define([lxc_version_beta], []) | |
8 | ||
9 | m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro]) | |
10 | m4_define([lxc_version], | |
11 | [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])]) | |
12 | ||
13 | AC_INIT([lxc], [lxc_version]) | |
14 | ||
15 | # We need pkg-config | |
16 | PKG_PROG_PKG_CONFIG | |
17 | ||
18 | AC_SUBST(LXC_VERSION_BASE, lxc_version_base) | |
19 | AC_SUBST(LXC_VERSION_BETA, lxc_version_beta) | |
20 | ||
21 | AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major]) | |
22 | AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor]) | |
23 | AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro]) | |
24 | AC_SUBST([LXC_VERSION], [lxc_version]) | |
25 | ||
26 | AC_CONFIG_SRCDIR([configure.ac]) | |
27 | AC_CONFIG_AUX_DIR([config]) | |
28 | AC_CONFIG_HEADERS([src/config.h]) | |
29 | AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects]) | |
30 | AC_CANONICAL_HOST | |
31 | AM_PROG_CC_C_O | |
32 | AC_GNU_SOURCE | |
33 | ||
34 | # Detect the distribution. This is used for the default configuration and | |
35 | # for some distro-specific build options. | |
36 | AC_MSG_CHECKING([host distribution]) | |
37 | AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.])) | |
38 | if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then | |
39 | with_distro=`lsb_release -is` | |
40 | fi | |
41 | if test "z$with_distro" = "z"; then | |
42 | AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat") | |
43 | AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle") | |
44 | AC_CHECK_FILE(/etc/centos-release,with_distro="centos") | |
45 | AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora") | |
46 | AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse") | |
47 | AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo") | |
48 | AC_CHECK_FILE(/etc/debian_version,with_distro="debian") | |
49 | AC_CHECK_FILE(/etc/arch-release,with_distro="arch") | |
50 | AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware") | |
51 | AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware") | |
52 | AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva") | |
53 | AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva") | |
54 | AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus") | |
55 | fi | |
56 | with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'` | |
57 | ||
58 | if test "z$with_distro" = "z"; then | |
59 | with_distro="unknown" | |
60 | fi | |
61 | case $with_distro in | |
62 | ubuntu|raspbian) | |
63 | distroconf=default.conf.lxcbr | |
64 | distrosysconf="$sysconfdir/default" | |
65 | ;; | |
66 | redhat|centos|fedora|oracle|oracleserver|suse|opensuse*) | |
67 | distroconf=default.conf.lxcbr | |
68 | distrosysconf="$sysconfdir/sysconfig" | |
69 | ;; | |
70 | *) | |
71 | distroconf=default.conf.unknown | |
72 | distrosysconf="$sysconfdir/default" | |
73 | ;; | |
74 | esac | |
75 | AC_MSG_RESULT([$with_distro]) | |
76 | AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"]) | |
77 | AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"]) | |
78 | ||
79 | AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}]) | |
80 | ||
81 | # Check for init system type | |
82 | AC_MSG_CHECKING([for init system type]) | |
83 | AC_ARG_WITH([init-script], | |
84 | [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@], | |
85 | [Type(s) of init script to install: sysvinit, systemd, upstart, | |
86 | distro @<:@default=distro@:>@])],[],[with_init_script=distro]) | |
87 | case "$with_init_script" in | |
88 | distro) | |
89 | case $with_distro in | |
90 | fedora|opensuse*) | |
91 | init_script=systemd | |
92 | ;; | |
93 | redhat|centos|oracle|oracleserver) | |
94 | init_script=sysvinit | |
95 | ;; | |
96 | debian|raspbian) | |
97 | init_script=upstart,systemd | |
98 | ;; | |
99 | ubuntu) | |
100 | init_script=upstart,systemd | |
101 | ;; | |
102 | *) | |
103 | echo -n "Linux distribution init system unknown." | |
104 | init_script= | |
105 | ;; | |
106 | esac | |
107 | ;; | |
108 | *) | |
109 | init_script=$with_init_script | |
110 | ;; | |
111 | esac | |
112 | ||
113 | # Check valid init systems were given, run in subshell so we don't mess up IFS | |
114 | (IFS="," ; for init_sys in $init_script; | |
115 | do | |
116 | case "$init_sys" in | |
117 | none|sysvinit|systemd|upstart) | |
118 | ;; | |
119 | *) | |
120 | exit 1 | |
121 | ;; | |
122 | esac | |
123 | done) || AC_MSG_ERROR([Unknown init system type in $init_script]) | |
124 | ||
125 | AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"]) | |
126 | AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"]) | |
127 | AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"]) | |
128 | AC_MSG_RESULT($init_script) | |
129 | ||
130 | # systemd unit dir | |
131 | AC_ARG_WITH([systemdsystemunitdir], | |
132 | AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]), | |
133 | [], | |
134 | [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]) | |
135 | if test -z "$with_systemdsystemunitdir"; then | |
136 | with_systemdsystemunitdir=/lib/systemd/system | |
137 | fi | |
138 | if test "x$with_systemdsystemunitdir" != "xno"; then | |
139 | AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir]) | |
140 | fi | |
141 | ||
142 | # Allow disabling rpath | |
143 | AC_ARG_ENABLE([rpath], | |
144 | [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])], | |
145 | [], [enable_rpath=no]) | |
146 | AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"]) | |
147 | ||
148 | # Documentation (manpages) | |
149 | AC_ARG_ENABLE([doc], | |
150 | [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])], | |
151 | [], [enable_doc=auto]) | |
152 | ||
153 | if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then | |
154 | db2xman="" | |
155 | dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man" | |
156 | ||
157 | AC_MSG_CHECKING(for docbook2x-man) | |
158 | for name in ${dbparsers}; do | |
159 | if "$name" --help >/dev/null 2>&1; then | |
160 | db2xman="$name" | |
161 | break; | |
162 | fi | |
163 | done | |
164 | ||
165 | if test -n "${db2xman}"; then | |
166 | AC_MSG_RESULT([${db2xman}]) | |
167 | enable_doc="yes" | |
168 | else | |
169 | AC_MSG_RESULT([no]) | |
170 | if test "x$enable_doc" = "xyes"; then | |
171 | AC_MSG_ERROR([docbook2x-man is required, but could not be found]) | |
172 | fi | |
173 | enable_doc="no" | |
174 | fi | |
175 | ||
176 | AC_SUBST(db2xman) | |
177 | fi | |
178 | AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"]) | |
179 | AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"]) | |
180 | ||
181 | if test "x$db2xman" = "xdocbook2man"; then | |
182 | docdtd="\"-//Davenport//DTD DocBook V3.0//EN\"" | |
183 | else | |
184 | docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\"" | |
185 | fi | |
186 | AC_SUBST(docdtd) | |
187 | ||
188 | # Documentation (API) | |
189 | AC_ARG_ENABLE([api-docs], | |
190 | [AC_HELP_STRING([--enable-api-docs], | |
191 | [make API documentation [default=auto]])], | |
192 | [], [enable_api_docs=auto]) | |
193 | ||
194 | if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then | |
195 | AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen]) | |
196 | AC_SUBST([HAVE_DOXYGEN]) | |
197 | ||
198 | if test "x$HAVE_DOXYGEN" != "x"; then | |
199 | enable_api_docs="yes" | |
200 | else | |
201 | if test "x$enable_api_docs" = "xyes"; then | |
202 | AC_MSG_ERROR([doxygen is required, but could not be found]) | |
203 | fi | |
204 | enable_api_docs="no" | |
205 | fi | |
206 | fi | |
207 | ||
208 | AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"]) | |
209 | ||
210 | # Apparmor | |
211 | AC_ARG_ENABLE([apparmor], | |
212 | [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])], | |
213 | [], [enable_apparmor=auto]) | |
214 | ||
215 | if test "$enable_apparmor" = "auto" ; then | |
216 | AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no]) | |
217 | fi | |
218 | AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"]) | |
219 | ||
220 | AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no]) | |
221 | ||
222 | AM_COND_IF([ENABLE_APPARMOR], | |
223 | [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
224 | AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])]) | |
225 | AC_SUBST([APPARMOR_LIBS], [-lapparmor])]) | |
226 | ||
227 | # SELinux | |
228 | AC_ARG_ENABLE([selinux], | |
229 | [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])], | |
230 | [], [enable_selinux=auto]) | |
231 | ||
232 | if test "x$enable_selinux" = xauto; then | |
233 | AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no]) | |
234 | fi | |
235 | AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"]) | |
236 | AM_COND_IF([ENABLE_SELINUX], | |
237 | [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
238 | AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])]) | |
239 | AC_SUBST([SELINUX_LIBS], [-lselinux])]) | |
240 | ||
241 | # Seccomp syscall filter | |
242 | AC_ARG_ENABLE([seccomp], | |
243 | [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])], | |
244 | [], [enable_seccomp=auto]) | |
245 | ||
246 | if test "x$enable_seccomp" = "xauto" ; then | |
247 | AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no]) | |
248 | fi | |
249 | AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"]) | |
250 | ||
251 | AM_COND_IF([ENABLE_SECCOMP], | |
252 | [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[ | |
253 | AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
254 | AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])]) | |
255 | AC_SUBST([SECCOMP_LIBS], [-lseccomp]) | |
256 | ]) | |
257 | ]) | |
258 | ||
259 | # cgmanager | |
260 | AC_ARG_ENABLE([cgmanager], | |
261 | [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])], | |
262 | [], [enable_cgmanager=auto]) | |
263 | ||
264 | if test "x$enable_cgmanager" = "xauto" ; then | |
265 | AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1]) | |
266 | fi | |
267 | AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"]) | |
268 | ||
269 | AM_COND_IF([ENABLE_CGMANAGER], | |
270 | [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager]) | |
271 | PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2]) | |
272 | PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0]) | |
273 | PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16]) | |
274 | ]) | |
275 | ||
276 | AC_MSG_CHECKING(for get_pid_cgroup_abs_sync) | |
277 | save_LIBS=$LIBS | |
278 | AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1]) | |
279 | LIBS=$save_LIBS | |
280 | if test "x$have_abs_cgroups" = "xyes"; then | |
281 | AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync]) | |
282 | AC_MSG_RESULT([yes]) | |
283 | else | |
284 | AC_MSG_RESULT([no]) | |
285 | fi | |
286 | ||
287 | AC_MSG_CHECKING(for cgmanager_list_controllers) | |
288 | save_LIBS=$LIBS | |
289 | AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1]) | |
290 | LIBS=$save_LIBS | |
291 | if test "x$have_list_controllers" = "xyes"; then | |
292 | AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers]) | |
293 | AC_MSG_RESULT([yes]) | |
294 | else | |
295 | AC_MSG_RESULT([no]) | |
296 | fi | |
297 | ||
298 | # Check for static libcap, make sure the function checked for differs from the | |
299 | # the one checked below so the cache doesn't give a wrong answer | |
300 | OLD_CFLAGS="$CFLAGS" | |
301 | CFLAGS="$CFLAGS -static" | |
302 | AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no]) | |
303 | AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"]) | |
304 | if test "x$have_static_libcap" = "xyes"; then | |
305 | AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap]) | |
306 | fi | |
307 | CFLAGS="$OLD_CFLAGS" | |
308 | ||
309 | ||
310 | # Linux capabilities | |
311 | AC_ARG_ENABLE([capabilities], | |
312 | [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])], | |
313 | [], [enable_capabilities=auto]) | |
314 | ||
315 | if test "x$enable_capabilities" = "xauto"; then | |
316 | AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no]) | |
317 | fi | |
318 | AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"]) | |
319 | ||
320 | AM_COND_IF([ENABLE_CAP], | |
321 | [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])]) | |
322 | AC_SUBST([CAP_LIBS], [-lcap])]) | |
323 | ||
324 | # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0 | |
325 | OLD_CFLAGS="$CFLAGS" | |
326 | CFLAGS="$CFLAGS $SECCOMP_CFLAGS" | |
327 | AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]]) | |
328 | AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]]) | |
329 | CFLAGS="$OLD_CFLAGS" | |
330 | ||
331 | # Configuration examples | |
332 | AC_ARG_ENABLE([examples], | |
333 | [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])], | |
334 | [], [enable_examples=yes]) | |
335 | AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"]) | |
336 | ||
337 | # Python3 module and scripts | |
338 | AC_ARG_ENABLE([python], | |
339 | [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])], | |
340 | [], [enable_python=auto]) | |
341 | ||
342 | if test "x$enable_python" = "xauto"; then | |
343 | PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no]) | |
344 | if test "$CC" = "clang"; then | |
345 | enable_python=no | |
346 | fi | |
347 | fi | |
348 | ||
349 | if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then | |
350 | AC_MSG_ERROR([Python3 is incompatible with the clang compiler]) | |
351 | fi | |
352 | ||
353 | AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"]) | |
354 | ||
355 | AM_COND_IF([ENABLE_PYTHON], | |
356 | [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])]) | |
357 | PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])]) | |
358 | AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])]) | |
359 | ||
360 | # Enable dumping stack traces | |
361 | AC_ARG_ENABLE([mutex-debugging], | |
362 | [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])], | |
363 | [], [enable_mutex_debugging=no]) | |
364 | AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"]) | |
365 | ||
366 | AM_COND_IF([MUTEX_DEBUGGING], | |
367 | AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging])) | |
368 | ||
369 | # Not in older autoconf versions | |
370 | # AS_VAR_COPY(DEST, SOURCE) | |
371 | # ------------------------- | |
372 | # Set the polymorphic shell variable DEST to the contents of the polymorphic | |
373 | # shell variable SOURCE. | |
374 | m4_ifdef([AS_VAR_COPY], [], | |
375 | [AC_DEFUN([AS_VAR_COPY], | |
376 | [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])]) | |
377 | ]) | |
378 | ||
379 | dnl PKG_CHECK_VAR was introduced with pkg-config 0.28 | |
380 | m4_ifdef([PKG_CHECK_VAR], [], | |
381 | [AC_DEFUN([PKG_CHECK_VAR], | |
382 | [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl | |
383 | AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl | |
384 | _PKG_CONFIG([$1], [variable="][$3]["], [$2]) | |
385 | AS_VAR_COPY([$1], [pkg_cv_][$1]) | |
386 | AS_VAR_IF([$1], [""], [$5], [$4])dnl | |
387 | ])# PKG_CHECK_VAR | |
388 | ]) | |
389 | ||
390 | # Lua module and scripts | |
391 | AC_ARG_ENABLE([lua], | |
392 | [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])], | |
393 | [], [enable_lua=auto]) | |
394 | ||
395 | AC_ARG_WITH([lua-pc], | |
396 | [AS_HELP_STRING( | |
397 | [--with-lua-pc=PKG], | |
398 | [Specify pkg-config package name for lua] | |
399 | )], [], [with_lua_pc=no]) | |
400 | ||
401 | if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then | |
402 | # exit with error if not found | |
403 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc]) | |
404 | fi | |
405 | ||
406 | if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then | |
407 | PKG_CHECK_MODULES([LUA], [$with_lua_pc], | |
408 | [LUAPKGCONFIG=$with_lua_pc | |
409 | enable_lua=yes], | |
410 | [enable_lua=no]) | |
411 | fi | |
412 | ||
413 | if test "x$enable_lua" != "xno"; then | |
414 | PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua], | |
415 | [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2], | |
416 | [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1], | |
417 | [AS_IF([test "x$enable_lua" = "xyes"], | |
418 | [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])], | |
419 | [enable_lua=no])] | |
420 | )] | |
421 | )]) | |
422 | AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes]) | |
423 | fi | |
424 | ||
425 | AM_CONDITIONAL([ENABLE_LUA], | |
426 | [test "x$enable_lua" = "xyes"]) | |
427 | ||
428 | AM_COND_IF([ENABLE_LUA], | |
429 | [AC_MSG_CHECKING([Lua version]) | |
430 | PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],, | |
431 | [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])]) | |
432 | AC_MSG_RESULT([$LUA_VERSION]) | |
433 | AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION]) | |
434 | AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION]) | |
435 | ]) | |
436 | ||
437 | # Optional bash integration | |
438 | AC_ARG_ENABLE([bash], | |
439 | [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])], | |
440 | [], [enable_bash=yes]) | |
441 | AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"]) | |
442 | ||
443 | # Optional test binaries | |
444 | AC_ARG_ENABLE([tests], | |
445 | [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])], | |
446 | [], [enable_tests=no]) | |
447 | AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"]) | |
448 | ||
449 | # Allow overriding the default runtime dir (/run) | |
450 | AC_ARG_WITH([runtime-path], | |
451 | [AC_HELP_STRING( | |
452 | [--with-runtime-path=dir], | |
453 | [runtime directory (default: /run)] | |
454 | )], [], [with_runtime_path=['/run']]) | |
455 | ||
456 | # LXC container path, where the containers are actually stored | |
457 | # This is overridden by an entry in the file called LXCCONF | |
458 | # (i.e. /etc/lxc/lxc.conf) | |
459 | AC_ARG_WITH([config-path], | |
460 | [AC_HELP_STRING( | |
461 | [--with-config-path=dir], | |
462 | [lxc configuration repository path] | |
463 | )], [], [with_config_path=['${localstatedir}/lib/lxc']]) | |
464 | ||
465 | # The path of the global lxc configuration file. | |
466 | AC_ARG_WITH([global-conf], | |
467 | [AC_HELP_STRING( | |
468 | [--with-global-conf=dir], | |
469 | [global lxc configuration file] | |
470 | )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']]) | |
471 | ||
472 | # The path of the userns network configuration file | |
473 | AC_ARG_WITH([usernic-conf], | |
474 | [AC_HELP_STRING( | |
475 | [--with-usernic-conf], | |
476 | [user network interface configuration file] | |
477 | )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']]) | |
478 | ||
479 | # The path of the runtime usernic database | |
480 | AC_ARG_WITH([usernic-db], | |
481 | [AC_HELP_STRING( | |
482 | [--with-usernic-db], | |
483 | [lxc user nic database] | |
484 | )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']]) | |
485 | ||
486 | # Rootfs path, where the container mount structure is assembled | |
487 | AC_ARG_WITH([rootfs-path], | |
488 | [AC_HELP_STRING( | |
489 | [--with-rootfs-path=dir], | |
490 | [lxc rootfs mount point] | |
491 | )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']]) | |
492 | ||
493 | # cgroup pattern specification | |
494 | AC_ARG_WITH([cgroup-pattern], | |
495 | [AC_HELP_STRING( | |
496 | [--with-cgroup-pattern=pattern], | |
497 | [pattern for container cgroups] | |
498 | )], [], [with_cgroup_pattern=['/lxc/%n']]) | |
499 | ||
500 | # Container log path. By default, use $lxcpath. | |
501 | AC_MSG_CHECKING([Whether to place logfiles in container config path]) | |
502 | AC_ARG_ENABLE([configpath-log], | |
503 | [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])], | |
504 | [], [enable_configpath_log=no]) | |
505 | AC_MSG_RESULT([$enable_configpath_log]) | |
506 | AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"]) | |
507 | ||
508 | if test "$enable_configpath_log" = "yes"; then | |
509 | default_log_path="${with_config_path}" | |
510 | else | |
511 | default_log_path="${localstatedir}/log/lxc" | |
512 | fi | |
513 | ||
514 | AC_ARG_WITH([log-path], | |
515 | [AC_HELP_STRING( | |
516 | [--with-log-path=dir], | |
517 | [per container log path] | |
518 | )], [], [with_log_path=['${default_log_path}']]) | |
519 | ||
520 | # Expand some useful variables | |
521 | AS_AC_EXPAND(PREFIX, "$prefix") | |
522 | AS_AC_EXPAND(LIBDIR, "$libdir") | |
523 | AS_AC_EXPAND(BINDIR, "$bindir") | |
524 | AS_AC_EXPAND(SBINDIR, "$sbindir") | |
525 | AS_AC_EXPAND(LIBEXECDIR, "$libexecdir") | |
526 | AS_AC_EXPAND(INCLUDEDIR, "$includedir") | |
527 | AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir") | |
528 | AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf") | |
529 | AS_AC_EXPAND(DATADIR, "$datadir") | |
530 | AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir") | |
531 | AS_AC_EXPAND(DOCDIR, "$docdir") | |
532 | AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)") | |
533 | AS_AC_EXPAND(LXCPATH, "$with_config_path") | |
534 | AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf") | |
535 | AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf") | |
536 | AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db") | |
537 | AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf") | |
538 | AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path") | |
539 | AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates") | |
540 | AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config") | |
541 | AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks") | |
542 | AS_AC_EXPAND(LXCINITDIR, "$libexecdir") | |
543 | AS_AC_EXPAND(LOGPATH, "$with_log_path") | |
544 | AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path") | |
545 | AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"]) | |
546 | ||
547 | # We need the install path so criu knows where to reference the hook scripts. | |
548 | AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."]) | |
549 | ||
550 | # Check for some standard kernel headers | |
551 | AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h], | |
552 | [], | |
553 | AC_MSG_ERROR([Please install the Linux kernel headers.]), | |
554 | [#include <sys/socket.h>]) | |
555 | ||
556 | # Check for alternate C libraries | |
557 | AC_MSG_CHECKING(for bionic libc) | |
558 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM( | |
559 | [[#ifndef __ANDROID__ | |
560 | error: Not bionic! | |
561 | #endif]])], | |
562 | [is_bionic=yes], | |
563 | [is_bionic=no]) | |
564 | if test "x$is_bionic" = "xyes"; then | |
565 | AC_DEFINE([IS_BIONIC], 1, [bionic libc]) | |
566 | AC_MSG_RESULT([yes]) | |
567 | else | |
568 | AC_MSG_RESULT([no]) | |
569 | fi | |
570 | AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"]) | |
571 | ||
572 | # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP | |
573 | AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>]) | |
574 | ||
575 | # Check for some headers | |
576 | AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h]) | |
577 | ||
578 | # Check for some syscalls functions | |
579 | AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat]) | |
580 | ||
581 | # Check for some functions | |
582 | AC_CHECK_LIB(pthread, main) | |
583 | AC_CHECK_FUNCS(pthread_atfork) | |
584 | AC_CHECK_FUNCS(statvfs) | |
585 | AC_CHECK_LIB(util, openpty) | |
586 | AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname]) | |
587 | AC_CHECK_FUNCS([getline], | |
588 | AM_CONDITIONAL(HAVE_GETLINE, true) | |
589 | AC_DEFINE(HAVE_GETLINE,1,[Have getline]), | |
590 | AM_CONDITIONAL(HAVE_GETLINE, false)) | |
591 | AC_CHECK_FUNCS([fgetln], | |
592 | AM_CONDITIONAL(HAVE_FGETLN, true) | |
593 | AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]), | |
594 | AM_CONDITIONAL(HAVE_FGETLN, false)) | |
595 | ||
596 | # Check for some libraries | |
597 | AC_SEARCH_LIBS(sem_open, [rt pthread]) | |
598 | AC_SEARCH_LIBS(clock_gettime, [rt]) | |
599 | ||
600 | # Check for some standard binaries | |
601 | AC_PROG_GCC_TRADITIONAL | |
602 | AC_PROG_SED | |
603 | ||
604 | # See if we support thread-local storage. | |
605 | LXC_CHECK_TLS | |
606 | ||
607 | if test "x$GCC" = "xyes"; then | |
608 | CFLAGS="$CFLAGS -Wall -Werror" | |
609 | fi | |
610 | ||
611 | # Files requiring some variable expansion | |
612 | AC_CONFIG_FILES([ | |
613 | Makefile | |
614 | lxc.pc | |
615 | lxc.spec | |
616 | ||
617 | config/Makefile | |
618 | config/apparmor/Makefile | |
619 | config/selinux/Makefile | |
620 | config/bash/Makefile | |
621 | config/bash/lxc | |
622 | config/init/Makefile | |
623 | config/init/common/Makefile | |
624 | config/init/common/lxc-containers | |
625 | config/init/common/lxc-net | |
626 | config/init/systemd/Makefile | |
627 | config/init/systemd/lxc.service | |
628 | config/init/systemd/lxc-net.service | |
629 | config/init/sysvinit/Makefile | |
630 | config/init/sysvinit/lxc-containers | |
631 | config/init/sysvinit/lxc-net | |
632 | config/init/upstart/lxc-net.conf | |
633 | config/init/upstart/Makefile | |
634 | config/etc/Makefile | |
635 | config/templates/Makefile | |
636 | config/templates/archlinux.common.conf | |
637 | config/templates/archlinux.userns.conf | |
638 | config/templates/centos.common.conf | |
639 | config/templates/centos.userns.conf | |
640 | config/templates/common.conf | |
641 | config/templates/common.conf.d/Makefile | |
642 | config/templates/debian.common.conf | |
643 | config/templates/debian.userns.conf | |
644 | config/templates/fedora.common.conf | |
645 | config/templates/fedora.userns.conf | |
646 | config/templates/gentoo.common.conf | |
647 | config/templates/gentoo.moresecure.conf | |
648 | config/templates/gentoo.userns.conf | |
649 | config/templates/opensuse.common.conf | |
650 | config/templates/opensuse.userns.conf | |
651 | config/templates/oracle.common.conf | |
652 | config/templates/oracle.userns.conf | |
653 | config/templates/plamo.common.conf | |
654 | config/templates/plamo.userns.conf | |
655 | config/templates/ubuntu-cloud.common.conf | |
656 | config/templates/ubuntu-cloud.lucid.conf | |
657 | config/templates/ubuntu-cloud.userns.conf | |
658 | config/templates/ubuntu.common.conf | |
659 | config/templates/ubuntu.lucid.conf | |
660 | config/templates/ubuntu.userns.conf | |
661 | config/templates/openwrt.common.conf | |
662 | config/templates/userns.conf | |
663 | config/yum/Makefile | |
664 | config/sysconfig/Makefile | |
665 | config/sysconfig/lxc | |
666 | ||
667 | doc/Makefile | |
668 | doc/api/Makefile | |
669 | doc/legacy/lxc-ls.sgml | |
670 | doc/lxc-attach.sgml | |
671 | doc/lxc-autostart.sgml | |
672 | doc/lxc-cgroup.sgml | |
673 | doc/lxc-checkconfig.sgml | |
674 | doc/lxc-checkpoint.sgml | |
675 | doc/lxc-clone.sgml | |
676 | doc/lxc-config.sgml | |
677 | doc/lxc-console.sgml | |
678 | doc/lxc-create.sgml | |
679 | doc/lxc-destroy.sgml | |
680 | doc/lxc-device.sgml | |
681 | doc/lxc-execute.sgml | |
682 | doc/lxc-freeze.sgml | |
683 | doc/lxc-info.sgml | |
684 | doc/lxc-ls.sgml | |
685 | doc/lxc-monitor.sgml | |
686 | doc/lxc-snapshot.sgml | |
687 | doc/lxc-start-ephemeral.sgml | |
688 | doc/lxc-start.sgml | |
689 | doc/lxc-stop.sgml | |
690 | doc/lxc-top.sgml | |
691 | doc/lxc-unfreeze.sgml | |
692 | doc/lxc-unshare.sgml | |
693 | doc/lxc-user-nic.sgml | |
694 | doc/lxc-usernsexec.sgml | |
695 | doc/lxc-wait.sgml | |
696 | ||
697 | doc/lxc.conf.sgml | |
698 | doc/lxc.container.conf.sgml | |
699 | doc/lxc.system.conf.sgml | |
700 | doc/lxc-usernet.sgml | |
701 | doc/lxc.sgml | |
702 | doc/common_options.sgml | |
703 | doc/see_also.sgml | |
704 | ||
705 | doc/rootfs/Makefile | |
706 | ||
707 | doc/examples/Makefile | |
708 | doc/examples/lxc-macvlan.conf | |
709 | doc/examples/lxc-vlan.conf | |
710 | doc/examples/lxc-no-netns.conf | |
711 | doc/examples/lxc-empty-netns.conf | |
712 | doc/examples/lxc-phys.conf | |
713 | doc/examples/lxc-veth.conf | |
714 | doc/examples/lxc-complex.conf | |
715 | ||
716 | doc/ja/Makefile | |
717 | doc/ja/legacy/lxc-ls.sgml | |
718 | doc/ja/lxc-attach.sgml | |
719 | doc/ja/lxc-autostart.sgml | |
720 | doc/ja/lxc-cgroup.sgml | |
721 | doc/ja/lxc-checkconfig.sgml | |
722 | doc/ja/lxc-checkpoint.sgml | |
723 | doc/ja/lxc-clone.sgml | |
724 | doc/ja/lxc-config.sgml | |
725 | doc/ja/lxc-console.sgml | |
726 | doc/ja/lxc-create.sgml | |
727 | doc/ja/lxc-destroy.sgml | |
728 | doc/ja/lxc-device.sgml | |
729 | doc/ja/lxc-execute.sgml | |
730 | doc/ja/lxc-freeze.sgml | |
731 | doc/ja/lxc-info.sgml | |
732 | doc/ja/lxc-ls.sgml | |
733 | doc/ja/lxc-monitor.sgml | |
734 | doc/ja/lxc-snapshot.sgml | |
735 | doc/ja/lxc-start-ephemeral.sgml | |
736 | doc/ja/lxc-start.sgml | |
737 | doc/ja/lxc-stop.sgml | |
738 | doc/ja/lxc-top.sgml | |
739 | doc/ja/lxc-unfreeze.sgml | |
740 | doc/ja/lxc-unshare.sgml | |
741 | doc/ja/lxc-user-nic.sgml | |
742 | doc/ja/lxc-usernsexec.sgml | |
743 | doc/ja/lxc-wait.sgml | |
744 | ||
745 | doc/ja/lxc.conf.sgml | |
746 | doc/ja/lxc.container.conf.sgml | |
747 | doc/ja/lxc.system.conf.sgml | |
748 | doc/ja/lxc-usernet.sgml | |
749 | doc/ja/lxc.sgml | |
750 | doc/ja/common_options.sgml | |
751 | doc/ja/see_also.sgml | |
752 | ||
753 | doc/ko/Makefile | |
754 | doc/ko/legacy/lxc-ls.sgml | |
755 | doc/ko/lxc-attach.sgml | |
756 | doc/ko/lxc-autostart.sgml | |
757 | doc/ko/lxc-cgroup.sgml | |
758 | doc/ko/lxc-checkconfig.sgml | |
759 | doc/ko/lxc-checkpoint.sgml | |
760 | doc/ko/lxc-clone.sgml | |
761 | doc/ko/lxc-config.sgml | |
762 | doc/ko/lxc-console.sgml | |
763 | doc/ko/lxc-create.sgml | |
764 | doc/ko/lxc-destroy.sgml | |
765 | doc/ko/lxc-device.sgml | |
766 | doc/ko/lxc-execute.sgml | |
767 | doc/ko/lxc-freeze.sgml | |
768 | doc/ko/lxc-info.sgml | |
769 | doc/ko/lxc-ls.sgml | |
770 | doc/ko/lxc-monitor.sgml | |
771 | doc/ko/lxc-snapshot.sgml | |
772 | doc/ko/lxc-start-ephemeral.sgml | |
773 | doc/ko/lxc-start.sgml | |
774 | doc/ko/lxc-stop.sgml | |
775 | doc/ko/lxc-top.sgml | |
776 | doc/ko/lxc-unfreeze.sgml | |
777 | doc/ko/lxc-unshare.sgml | |
778 | doc/ko/lxc-user-nic.sgml | |
779 | doc/ko/lxc-usernsexec.sgml | |
780 | doc/ko/lxc-wait.sgml | |
781 | ||
782 | doc/ko/lxc.conf.sgml | |
783 | doc/ko/lxc.container.conf.sgml | |
784 | doc/ko/lxc.system.conf.sgml | |
785 | doc/ko/lxc-usernet.sgml | |
786 | doc/ko/lxc.sgml | |
787 | doc/ko/common_options.sgml | |
788 | doc/ko/see_also.sgml | |
789 | ||
790 | hooks/Makefile | |
791 | ||
792 | templates/Makefile | |
793 | templates/lxc-alpine | |
794 | templates/lxc-altlinux | |
795 | templates/lxc-archlinux | |
796 | templates/lxc-busybox | |
797 | templates/lxc-centos | |
798 | templates/lxc-cirros | |
799 | templates/lxc-debian | |
800 | templates/lxc-download | |
801 | templates/lxc-fedora | |
802 | templates/lxc-gentoo | |
803 | templates/lxc-openmandriva | |
804 | templates/lxc-opensuse | |
805 | templates/lxc-oracle | |
806 | templates/lxc-plamo | |
807 | templates/lxc-sshd | |
808 | templates/lxc-ubuntu | |
809 | templates/lxc-ubuntu-cloud | |
810 | ||
811 | src/Makefile | |
812 | src/lxc/Makefile | |
813 | src/lxc/lxc-checkconfig | |
814 | src/lxc/lxc-ls | |
815 | src/lxc/lxc-start-ephemeral | |
816 | src/lxc/legacy/lxc-ls | |
817 | src/lxc/lxc.functions | |
818 | src/lxc/version.h | |
819 | src/python-lxc/Makefile | |
820 | src/python-lxc/setup.py | |
821 | ||
822 | src/lua-lxc/Makefile | |
823 | ||
824 | src/tests/Makefile | |
825 | src/tests/lxc-test-usernic | |
826 | ]) | |
827 | AC_CONFIG_COMMANDS([default],[[]],[[]]) | |
828 | AC_OUTPUT | |
829 | ||
830 | # Configuration overview | |
831 | cat << EOF | |
832 | ||
833 | ---------------------------- | |
834 | Environment: | |
835 | - compiler: $CC | |
836 | - distribution: $with_distro | |
837 | - init script type(s): $init_script | |
838 | - rpath: $enable_rpath | |
839 | - GnuTLS: $enable_gnutls | |
840 | - Bash integration: $enable_bash | |
841 | ||
842 | Security features: | |
843 | - Apparmor: $enable_apparmor | |
844 | - Linux capabilities: $enable_capabilities | |
845 | - seccomp: $enable_seccomp | |
846 | - SELinux: $enable_selinux | |
847 | - cgmanager: $enable_cgmanager | |
848 | ||
849 | Bindings: | |
850 | - lua: $enable_lua | |
851 | - python3: $enable_python | |
852 | ||
853 | Documentation: | |
854 | - examples: $enable_examples | |
855 | - API documentation: $enable_api_docs | |
856 | - user documentation: $enable_doc | |
857 | ||
858 | Debugging: | |
859 | - tests: $enable_tests | |
860 | - mutex debugging: $enable_mutex_debugging | |
861 | ||
862 | Paths: | |
863 | - Logs in configpath: $enable_configpath_log | |
864 | EOF | |
865 | ||
866 | if test "x$ac_cv_func_pthread_atfork" = "xno" ; then | |
867 | cat << EOF | |
868 | ||
869 | WARNING: Threading not supported on your platform | |
870 | ||
871 | You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork). | |
872 | Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems. | |
873 | EOF | |
874 | fi |