]>
Commit | Line | Data |
---|---|---|
1 | package PVE::Tools; | |
2 | ||
3 | use strict; | |
4 | use warnings; | |
5 | use POSIX qw(EINTR EEXIST EOPNOTSUPP); | |
6 | use IO::Socket::IP; | |
7 | use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM | |
8 | IPPROTO_TCP); | |
9 | use IO::Select; | |
10 | use File::Basename; | |
11 | use File::Path qw(make_path); | |
12 | use Filesys::Df (); # don't overwrite our df() | |
13 | use IO::Pipe; | |
14 | use IO::File; | |
15 | use IO::Dir; | |
16 | use IO::Handle; | |
17 | use IPC::Open3; | |
18 | use Fcntl qw(:DEFAULT :flock); | |
19 | use base 'Exporter'; | |
20 | use URI::Escape; | |
21 | use Encode; | |
22 | use Digest::SHA; | |
23 | use JSON; | |
24 | use Text::ParseWords; | |
25 | use String::ShellQuote; | |
26 | use Time::HiRes qw(usleep gettimeofday tv_interval alarm); | |
27 | use Net::DBus qw(dbus_uint32 dbus_uint64); | |
28 | use Net::DBus::Callback; | |
29 | use Net::DBus::Reactor; | |
30 | use Scalar::Util 'weaken'; | |
31 | use PVE::Syscall; | |
32 | ||
33 | # avoid warning when parsing long hex values with hex() | |
34 | no warnings 'portable'; # Support for 64-bit ints required | |
35 | ||
36 | our @EXPORT_OK = qw( | |
37 | $IPV6RE | |
38 | $IPV4RE | |
39 | lock_file | |
40 | lock_file_full | |
41 | run_command | |
42 | file_set_contents | |
43 | file_get_contents | |
44 | file_read_firstline | |
45 | dir_glob_regex | |
46 | dir_glob_foreach | |
47 | split_list | |
48 | template_replace | |
49 | safe_print | |
50 | trim | |
51 | extract_param | |
52 | file_copy | |
53 | O_PATH | |
54 | O_TMPFILE | |
55 | ); | |
56 | ||
57 | my $pvelogdir = "/var/log/pve"; | |
58 | my $pvetaskdir = "$pvelogdir/tasks"; | |
59 | ||
60 | mkdir $pvelogdir; | |
61 | mkdir $pvetaskdir; | |
62 | ||
63 | my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])"; | |
64 | our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)"; | |
65 | my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})"; | |
66 | my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))"; | |
67 | ||
68 | our $IPV6RE = "(?:" . | |
69 | "(?:(?:" . "(?:$IPV6H16:){6})$IPV6LS32)|" . | |
70 | "(?:(?:" . "::(?:$IPV6H16:){5})$IPV6LS32)|" . | |
71 | "(?:(?:(?:" . "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" . | |
72 | "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" . | |
73 | "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" . | |
74 | "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" . | |
75 | "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" . ")$IPV6LS32)|" . | |
76 | "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" . ")$IPV6H16)|" . | |
77 | "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" . ")))"; | |
78 | ||
79 | our $IPRE = "(?:$IPV4RE|$IPV6RE)"; | |
80 | ||
81 | use constant {CLONE_NEWNS => 0x00020000, | |
82 | CLONE_NEWUTS => 0x04000000, | |
83 | CLONE_NEWIPC => 0x08000000, | |
84 | CLONE_NEWUSER => 0x10000000, | |
85 | CLONE_NEWPID => 0x20000000, | |
86 | CLONE_NEWNET => 0x40000000}; | |
87 | ||
88 | use constant {O_PATH => 0x00200000, | |
89 | O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY | |
90 | ||
91 | sub run_with_timeout { | |
92 | my ($timeout, $code, @param) = @_; | |
93 | ||
94 | die "got timeout\n" if $timeout <= 0; | |
95 | ||
96 | my $prev_alarm = alarm 0; # suspend outer alarm early | |
97 | ||
98 | my $sigcount = 0; | |
99 | ||
100 | my $res; | |
101 | ||
102 | eval { | |
103 | local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; }; | |
104 | local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" }; | |
105 | local $SIG{__DIE__}; # see SA bug 4631 | |
106 | ||
107 | alarm($timeout); | |
108 | ||
109 | eval { $res = &$code(@param); }; | |
110 | ||
111 | alarm(0); # avoid race conditions | |
112 | ||
113 | die $@ if $@; | |
114 | }; | |
115 | ||
116 | my $err = $@; | |
117 | ||
118 | alarm $prev_alarm; | |
119 | ||
120 | # this shouldn't happen anymore? | |
121 | die "unknown error" if $sigcount && !$err; # seems to happen sometimes | |
122 | ||
123 | die $err if $err; | |
124 | ||
125 | return $res; | |
126 | } | |
127 | ||
128 | # flock: we use one file handle per process, so lock file | |
129 | # can be nested multiple times and succeeds for the same process. | |
130 | # | |
131 | # Since this is the only way we lock now and we don't have the old | |
132 | # 'lock(); code(); unlock();' pattern anymore we do not actually need to | |
133 | # count how deep we're nesting. Therefore this hash now stores a weak reference | |
134 | # to a boolean telling us whether we already have a lock. | |
135 | ||
136 | my $lock_handles = {}; | |
137 | ||
138 | sub lock_file_full { | |
139 | my ($filename, $timeout, $shared, $code, @param) = @_; | |
140 | ||
141 | $timeout = 10 if !$timeout; | |
142 | ||
143 | my $mode = $shared ? LOCK_SH : LOCK_EX; | |
144 | ||
145 | my $lockhash = ($lock_handles->{$$} //= {}); | |
146 | ||
147 | # Returns a locked file handle. | |
148 | my $get_locked_file = sub { | |
149 | my $fh = IO::File->new(">>$filename") | |
150 | or die "can't open file - $!\n"; | |
151 | ||
152 | if (!flock($fh, $mode|LOCK_NB)) { | |
153 | print STDERR "trying to acquire lock...\n"; | |
154 | my $success; | |
155 | while(1) { | |
156 | $success = flock($fh, $mode); | |
157 | # try again on EINTR (see bug #273) | |
158 | if ($success || ($! != EINTR)) { | |
159 | last; | |
160 | } | |
161 | } | |
162 | if (!$success) { | |
163 | print STDERR " failed\n"; | |
164 | die "can't acquire lock '$filename' - $!\n"; | |
165 | } | |
166 | print STDERR " OK\n"; | |
167 | } | |
168 | ||
169 | return $fh; | |
170 | }; | |
171 | ||
172 | my $res; | |
173 | my $checkptr = $lockhash->{$filename}; | |
174 | my $check = 0; # This must not go out of scope before running the code. | |
175 | my $local_fh; # This must stay local | |
176 | if (!$checkptr || !$$checkptr) { | |
177 | # We cannot create a weak reference in a single atomic step, so we first | |
178 | # create a false-value, then create a reference to it, then weaken it, | |
179 | # and after successfully locking the file we change the boolean value. | |
180 | # | |
181 | # The reason for this is that if an outer SIGALRM throws an exception | |
182 | # between creating the reference and weakening it, a subsequent call to | |
183 | # lock_file_full() will see a leftover full reference to a valid | |
184 | # variable. This variable must be 0 in order for said call to attempt to | |
185 | # lock the file anew. | |
186 | # | |
187 | # An externally triggered exception elsewhere in the code will cause the | |
188 | # weak reference to become 'undef', and since the file handle is only | |
189 | # stored in the local scope in $local_fh, the file will be closed by | |
190 | # perl's cleanup routines as well. | |
191 | # | |
192 | # This still assumes that an IO::File handle can properly deal with such | |
193 | # exceptions thrown during its own destruction, but that's up to perls | |
194 | # guts now. | |
195 | $lockhash->{$filename} = \$check; | |
196 | weaken $lockhash->{$filename}; | |
197 | $local_fh = eval { run_with_timeout($timeout, $get_locked_file) }; | |
198 | if ($@) { | |
199 | $@ = "can't lock file '$filename' - $@"; | |
200 | return undef; | |
201 | } | |
202 | $check = 1; | |
203 | } | |
204 | $res = eval { &$code(@param); }; | |
205 | return undef if $@; | |
206 | return $res; | |
207 | } | |
208 | ||
209 | ||
210 | sub lock_file { | |
211 | my ($filename, $timeout, $code, @param) = @_; | |
212 | ||
213 | return lock_file_full($filename, $timeout, 0, $code, @param); | |
214 | } | |
215 | ||
216 | sub file_set_contents { | |
217 | my ($filename, $data, $perm) = @_; | |
218 | ||
219 | $perm = 0644 if !defined($perm); | |
220 | ||
221 | my $tmpname = "$filename.tmp.$$"; | |
222 | ||
223 | eval { | |
224 | my ($fh, $tries) = (undef, 0); | |
225 | while (!$fh && $tries++ < 3) { | |
226 | $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm); | |
227 | if (!$fh && $! == EEXIST) { | |
228 | unlink($tmpname) or die "unable to delete old temp file: $!\n"; | |
229 | } | |
230 | } | |
231 | die "unable to open file '$tmpname' - $!\n" if !$fh; | |
232 | die "unable to write '$tmpname' - $!\n" unless print $fh $data; | |
233 | die "closing file '$tmpname' failed - $!\n" unless close $fh; | |
234 | }; | |
235 | my $err = $@; | |
236 | ||
237 | if ($err) { | |
238 | unlink $tmpname; | |
239 | die $err; | |
240 | } | |
241 | ||
242 | if (!rename($tmpname, $filename)) { | |
243 | my $msg = "close (rename) atomic file '$filename' failed: $!\n"; | |
244 | unlink $tmpname; | |
245 | die $msg; | |
246 | } | |
247 | } | |
248 | ||
249 | sub file_get_contents { | |
250 | my ($filename, $max) = @_; | |
251 | ||
252 | my $fh = IO::File->new($filename, "r") || | |
253 | die "can't open '$filename' - $!\n"; | |
254 | ||
255 | my $content = safe_read_from($fh, $max, 0, $filename); | |
256 | ||
257 | close $fh; | |
258 | ||
259 | return $content; | |
260 | } | |
261 | ||
262 | sub file_copy { | |
263 | my ($filename, $dst, $max, $perm) = @_; | |
264 | ||
265 | file_set_contents ($dst, file_get_contents($filename, $max), $perm); | |
266 | } | |
267 | ||
268 | sub file_read_firstline { | |
269 | my ($filename) = @_; | |
270 | ||
271 | my $fh = IO::File->new ($filename, "r"); | |
272 | return undef if !$fh; | |
273 | my $res = <$fh>; | |
274 | chomp $res if $res; | |
275 | $fh->close; | |
276 | return $res; | |
277 | } | |
278 | ||
279 | sub safe_read_from { | |
280 | my ($fh, $max, $oneline, $filename) = @_; | |
281 | ||
282 | $max = 32768 if !$max; | |
283 | ||
284 | my $subject = defined($filename) ? "file '$filename'" : 'input'; | |
285 | ||
286 | my $br = 0; | |
287 | my $input = ''; | |
288 | my $count; | |
289 | while ($count = sysread($fh, $input, 8192, $br)) { | |
290 | $br += $count; | |
291 | die "$subject too long - aborting\n" if $br > $max; | |
292 | if ($oneline && $input =~ m/^(.*)\n/) { | |
293 | $input = $1; | |
294 | last; | |
295 | } | |
296 | } | |
297 | die "unable to read $subject - $!\n" if !defined($count); | |
298 | ||
299 | return $input; | |
300 | } | |
301 | ||
302 | # The $cmd parameter can be: | |
303 | # -) a string | |
304 | # This is generally executed by passing it to the shell with the -c option. | |
305 | # However, it can be executed in one of two ways, depending on whether | |
306 | # there's a pipe involved: | |
307 | # *) with pipe: passed explicitly to bash -c, prefixed with: | |
308 | # set -o pipefail && | |
309 | # *) without a pipe: passed to perl's open3 which uses 'sh -c' | |
310 | # (Note that this may result in two different syntax requirements!) | |
311 | # FIXME? | |
312 | # -) an array of arguments (strings) | |
313 | # Will be executed without interference from a shell. (Parameters are passed | |
314 | # as is, no escape sequences of strings will be touched.) | |
315 | # -) an array of arrays | |
316 | # Each array represents a command, and each command's output is piped into | |
317 | # the following command's standard input. | |
318 | # For this a shell command string is created with pipe symbols between each | |
319 | # command. | |
320 | # Each command is a list of strings meant to end up in the final command | |
321 | # unchanged. In order to achieve this, every argument is shell-quoted. | |
322 | # Quoting can be disabled for a particular argument by turning it into a | |
323 | # reference, this allows inserting arbitrary shell options. | |
324 | # For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not | |
325 | # produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ] | |
326 | # will literally print: hello >/dev/null | |
327 | sub run_command { | |
328 | my ($cmd, %param) = @_; | |
329 | ||
330 | my $old_umask; | |
331 | my $cmdstr; | |
332 | ||
333 | if (my $ref = ref($cmd)) { | |
334 | if (ref($cmd->[0])) { | |
335 | $cmdstr = 'set -o pipefail && '; | |
336 | my $pipe = ''; | |
337 | foreach my $command (@$cmd) { | |
338 | # concatenate quoted parameters | |
339 | # strings which are passed by reference are NOT shell quoted | |
340 | $cmdstr .= $pipe . join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command); | |
341 | $pipe = ' | '; | |
342 | } | |
343 | $cmd = [ '/bin/bash', '-c', "$cmdstr" ]; | |
344 | } else { | |
345 | $cmdstr = cmd2string($cmd); | |
346 | } | |
347 | } else { | |
348 | $cmdstr = $cmd; | |
349 | if ($cmd =~ m/\|/) { | |
350 | # see 'man bash' for option pipefail | |
351 | $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ]; | |
352 | } else { | |
353 | $cmd = [ $cmd ]; | |
354 | } | |
355 | } | |
356 | ||
357 | my $errmsg; | |
358 | my $laststderr; | |
359 | my $timeout; | |
360 | my $oldtimeout; | |
361 | my $pid; | |
362 | my $exitcode = -1; | |
363 | ||
364 | my $outfunc; | |
365 | my $errfunc; | |
366 | my $logfunc; | |
367 | my $input; | |
368 | my $output; | |
369 | my $afterfork; | |
370 | my $noerr; | |
371 | my $keeplocale; | |
372 | ||
373 | eval { | |
374 | ||
375 | foreach my $p (keys %param) { | |
376 | if ($p eq 'timeout') { | |
377 | $timeout = $param{$p}; | |
378 | } elsif ($p eq 'umask') { | |
379 | $old_umask = umask($param{$p}); | |
380 | } elsif ($p eq 'errmsg') { | |
381 | $errmsg = $param{$p}; | |
382 | } elsif ($p eq 'input') { | |
383 | $input = $param{$p}; | |
384 | } elsif ($p eq 'output') { | |
385 | $output = $param{$p}; | |
386 | } elsif ($p eq 'outfunc') { | |
387 | $outfunc = $param{$p}; | |
388 | } elsif ($p eq 'errfunc') { | |
389 | $errfunc = $param{$p}; | |
390 | } elsif ($p eq 'logfunc') { | |
391 | $logfunc = $param{$p}; | |
392 | } elsif ($p eq 'afterfork') { | |
393 | $afterfork = $param{$p}; | |
394 | } elsif ($p eq 'noerr') { | |
395 | $noerr = $param{$p}; | |
396 | } elsif ($p eq 'keeplocale') { | |
397 | $keeplocale = $param{$p}; | |
398 | } else { | |
399 | die "got unknown parameter '$p' for run_command\n"; | |
400 | } | |
401 | } | |
402 | ||
403 | if ($errmsg) { | |
404 | my $origerrfunc = $errfunc; | |
405 | $errfunc = sub { | |
406 | if ($laststderr) { | |
407 | if ($origerrfunc) { | |
408 | &$origerrfunc("$laststderr\n"); | |
409 | } else { | |
410 | print STDERR "$laststderr\n" if $laststderr; | |
411 | } | |
412 | } | |
413 | $laststderr = shift; | |
414 | }; | |
415 | } | |
416 | ||
417 | my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new(); | |
418 | my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new(); | |
419 | my $error = IO::File->new(); | |
420 | ||
421 | my $orig_pid = $$; | |
422 | ||
423 | eval { | |
424 | local $ENV{LC_ALL} = 'C' if !$keeplocale; | |
425 | ||
426 | # suppress LVM warnings like: "File descriptor 3 left open"; | |
427 | local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1"; | |
428 | ||
429 | $pid = open3($writer, $reader, $error, @$cmd) || die $!; | |
430 | ||
431 | # if we pipe fron STDIN, open3 closes STDIN, so we we | |
432 | # a perl warning "Filehandle STDIN reopened as GENXYZ .. " | |
433 | # as soon as we open a new file. | |
434 | # to avoid that we open /dev/null | |
435 | if (!ref($writer) && !defined(fileno(STDIN))) { | |
436 | POSIX::close(0); | |
437 | open(STDIN, "</dev/null"); | |
438 | } | |
439 | }; | |
440 | ||
441 | my $err = $@; | |
442 | ||
443 | # catch exec errors | |
444 | if ($orig_pid != $$) { | |
445 | warn "ERROR: $err"; | |
446 | POSIX::_exit (1); | |
447 | kill ('KILL', $$); | |
448 | } | |
449 | ||
450 | die $err if $err; | |
451 | ||
452 | local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout; | |
453 | $oldtimeout = alarm($timeout) if $timeout; | |
454 | ||
455 | &$afterfork() if $afterfork; | |
456 | ||
457 | if (ref($writer)) { | |
458 | print $writer $input if defined $input; | |
459 | close $writer; | |
460 | } | |
461 | ||
462 | my $select = new IO::Select; | |
463 | $select->add($reader) if ref($reader); | |
464 | $select->add($error); | |
465 | ||
466 | my $outlog = ''; | |
467 | my $errlog = ''; | |
468 | ||
469 | my $starttime = time(); | |
470 | ||
471 | while ($select->count) { | |
472 | my @handles = $select->can_read(1); | |
473 | ||
474 | foreach my $h (@handles) { | |
475 | my $buf = ''; | |
476 | my $count = sysread ($h, $buf, 4096); | |
477 | if (!defined ($count)) { | |
478 | my $err = $!; | |
479 | kill (9, $pid); | |
480 | waitpid ($pid, 0); | |
481 | die $err; | |
482 | } | |
483 | $select->remove ($h) if !$count; | |
484 | if ($h eq $reader) { | |
485 | if ($outfunc || $logfunc) { | |
486 | eval { | |
487 | $outlog .= $buf; | |
488 | while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) { | |
489 | my $line = $1; | |
490 | &$outfunc($line) if $outfunc; | |
491 | &$logfunc($line) if $logfunc; | |
492 | } | |
493 | }; | |
494 | my $err = $@; | |
495 | if ($err) { | |
496 | kill (9, $pid); | |
497 | waitpid ($pid, 0); | |
498 | die $err; | |
499 | } | |
500 | } else { | |
501 | print $buf; | |
502 | *STDOUT->flush(); | |
503 | } | |
504 | } elsif ($h eq $error) { | |
505 | if ($errfunc || $logfunc) { | |
506 | eval { | |
507 | $errlog .= $buf; | |
508 | while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) { | |
509 | my $line = $1; | |
510 | &$errfunc($line) if $errfunc; | |
511 | &$logfunc($line) if $logfunc; | |
512 | } | |
513 | }; | |
514 | my $err = $@; | |
515 | if ($err) { | |
516 | kill (9, $pid); | |
517 | waitpid ($pid, 0); | |
518 | die $err; | |
519 | } | |
520 | } else { | |
521 | print STDERR $buf; | |
522 | *STDERR->flush(); | |
523 | } | |
524 | } | |
525 | } | |
526 | } | |
527 | ||
528 | &$outfunc($outlog) if $outfunc && $outlog; | |
529 | &$logfunc($outlog) if $logfunc && $outlog; | |
530 | ||
531 | &$errfunc($errlog) if $errfunc && $errlog; | |
532 | &$logfunc($errlog) if $logfunc && $errlog; | |
533 | ||
534 | waitpid ($pid, 0); | |
535 | ||
536 | if ($? == -1) { | |
537 | die "failed to execute\n"; | |
538 | } elsif (my $sig = ($? & 127)) { | |
539 | die "got signal $sig\n"; | |
540 | } elsif ($exitcode = ($? >> 8)) { | |
541 | if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) { | |
542 | if ($errmsg && $laststderr) { | |
543 | my $lerr = $laststderr; | |
544 | $laststderr = undef; | |
545 | die "$lerr\n"; | |
546 | } | |
547 | die "exit code $exitcode\n"; | |
548 | } | |
549 | } | |
550 | ||
551 | alarm(0); | |
552 | }; | |
553 | ||
554 | my $err = $@; | |
555 | ||
556 | alarm(0); | |
557 | ||
558 | if ($errmsg && $laststderr) { | |
559 | &$errfunc(undef); # flush laststderr | |
560 | } | |
561 | ||
562 | umask ($old_umask) if defined($old_umask); | |
563 | ||
564 | alarm($oldtimeout) if $oldtimeout; | |
565 | ||
566 | if ($err) { | |
567 | if ($pid && ($err eq "got timeout\n")) { | |
568 | kill (9, $pid); | |
569 | waitpid ($pid, 0); | |
570 | die "command '$cmdstr' failed: $err"; | |
571 | } | |
572 | ||
573 | if ($errmsg) { | |
574 | $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|; | |
575 | die "$errmsg: $err"; | |
576 | } elsif(!$noerr) { | |
577 | die "command '$cmdstr' failed: $err"; | |
578 | } | |
579 | } | |
580 | ||
581 | return $exitcode; | |
582 | } | |
583 | ||
584 | # Run a command with a tcp socket as standard input. | |
585 | sub pipe_socket_to_command { | |
586 | my ($cmd, $ip, $port) = @_; | |
587 | ||
588 | my $params = { | |
589 | Listen => 1, | |
590 | ReuseAddr => 1, | |
591 | Proto => &Socket::IPPROTO_TCP, | |
592 | GetAddrInfoFlags => 0, | |
593 | LocalAddr => $ip, | |
594 | LocalPort => $port, | |
595 | }; | |
596 | my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n"; | |
597 | ||
598 | print "$ip\n$port\n"; # tell remote where to connect | |
599 | *STDOUT->flush(); | |
600 | ||
601 | alarm 0; | |
602 | local $SIG{ALRM} = sub { die "timed out waiting for client\n" }; | |
603 | alarm 30; | |
604 | my $client = $socket->accept; # Wait for a client | |
605 | alarm 0; | |
606 | close($socket); | |
607 | ||
608 | # We want that the command talks over the TCP socket and takes | |
609 | # ownership of it, so that when it closes it the connection is | |
610 | # terminated, so we need to be able to close the socket. So we | |
611 | # can't really use PVE::Tools::run_command(). | |
612 | my $pid = fork() // die "fork failed: $!\n"; | |
613 | if (!$pid) { | |
614 | POSIX::dup2(fileno($client), 0); | |
615 | POSIX::dup2(fileno($client), 1); | |
616 | close($client); | |
617 | exec {$cmd->[0]} @$cmd or do { | |
618 | warn "exec failed: $!\n"; | |
619 | POSIX::_exit(1); | |
620 | }; | |
621 | } | |
622 | ||
623 | close($client); | |
624 | if (waitpid($pid, 0) != $pid) { | |
625 | kill(15 => $pid); # if we got interrupted terminate the child | |
626 | my $count = 0; | |
627 | while (waitpid($pid, POSIX::WNOHANG) != $pid) { | |
628 | usleep(100000); | |
629 | $count++; | |
630 | kill(9 => $pid), last if $count > 300; # 30 second timeout | |
631 | } | |
632 | } | |
633 | if (my $sig = ($? & 127)) { | |
634 | die "got signal $sig\n"; | |
635 | } elsif (my $exitcode = ($? >> 8)) { | |
636 | die "exit code $exitcode\n"; | |
637 | } | |
638 | ||
639 | return undef; | |
640 | } | |
641 | ||
642 | sub split_list { | |
643 | my $listtxt = shift || ''; | |
644 | ||
645 | return split (/\0/, $listtxt) if $listtxt =~ m/\0/; | |
646 | ||
647 | $listtxt =~ s/[,;]/ /g; | |
648 | $listtxt =~ s/^\s+//; | |
649 | ||
650 | my @data = split (/\s+/, $listtxt); | |
651 | ||
652 | return @data; | |
653 | } | |
654 | ||
655 | sub trim { | |
656 | my $txt = shift; | |
657 | ||
658 | return $txt if !defined($txt); | |
659 | ||
660 | $txt =~ s/^\s+//; | |
661 | $txt =~ s/\s+$//; | |
662 | ||
663 | return $txt; | |
664 | } | |
665 | ||
666 | # simple uri templates like "/vms/{vmid}" | |
667 | sub template_replace { | |
668 | my ($tmpl, $data) = @_; | |
669 | ||
670 | return $tmpl if !$tmpl; | |
671 | ||
672 | my $res = ''; | |
673 | while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) { | |
674 | $res .= $1 if $1; | |
675 | $res .= ($data->{$3} || '-') if $2; | |
676 | } | |
677 | return $res; | |
678 | } | |
679 | ||
680 | sub safe_print { | |
681 | my ($filename, $fh, $data) = @_; | |
682 | ||
683 | return if !$data; | |
684 | ||
685 | my $res = print $fh $data; | |
686 | ||
687 | die "write to '$filename' failed\n" if !$res; | |
688 | } | |
689 | ||
690 | sub debmirrors { | |
691 | ||
692 | return { | |
693 | 'at' => 'ftp.at.debian.org', | |
694 | 'au' => 'ftp.au.debian.org', | |
695 | 'be' => 'ftp.be.debian.org', | |
696 | 'bg' => 'ftp.bg.debian.org', | |
697 | 'br' => 'ftp.br.debian.org', | |
698 | 'ca' => 'ftp.ca.debian.org', | |
699 | 'ch' => 'ftp.ch.debian.org', | |
700 | 'cl' => 'ftp.cl.debian.org', | |
701 | 'cz' => 'ftp.cz.debian.org', | |
702 | 'de' => 'ftp.de.debian.org', | |
703 | 'dk' => 'ftp.dk.debian.org', | |
704 | 'ee' => 'ftp.ee.debian.org', | |
705 | 'es' => 'ftp.es.debian.org', | |
706 | 'fi' => 'ftp.fi.debian.org', | |
707 | 'fr' => 'ftp.fr.debian.org', | |
708 | 'gr' => 'ftp.gr.debian.org', | |
709 | 'hk' => 'ftp.hk.debian.org', | |
710 | 'hr' => 'ftp.hr.debian.org', | |
711 | 'hu' => 'ftp.hu.debian.org', | |
712 | 'ie' => 'ftp.ie.debian.org', | |
713 | 'is' => 'ftp.is.debian.org', | |
714 | 'it' => 'ftp.it.debian.org', | |
715 | 'jp' => 'ftp.jp.debian.org', | |
716 | 'kr' => 'ftp.kr.debian.org', | |
717 | 'mx' => 'ftp.mx.debian.org', | |
718 | 'nl' => 'ftp.nl.debian.org', | |
719 | 'no' => 'ftp.no.debian.org', | |
720 | 'nz' => 'ftp.nz.debian.org', | |
721 | 'pl' => 'ftp.pl.debian.org', | |
722 | 'pt' => 'ftp.pt.debian.org', | |
723 | 'ro' => 'ftp.ro.debian.org', | |
724 | 'ru' => 'ftp.ru.debian.org', | |
725 | 'se' => 'ftp.se.debian.org', | |
726 | 'si' => 'ftp.si.debian.org', | |
727 | 'sk' => 'ftp.sk.debian.org', | |
728 | 'tr' => 'ftp.tr.debian.org', | |
729 | 'tw' => 'ftp.tw.debian.org', | |
730 | 'gb' => 'ftp.uk.debian.org', | |
731 | 'us' => 'ftp.us.debian.org', | |
732 | }; | |
733 | } | |
734 | ||
735 | my $keymaphash = { | |
736 | 'dk' => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'], | |
737 | 'de' => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ], | |
738 | 'de-ch' => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz', 'ch', 'de_nodeadkeys' ], | |
739 | 'en-gb' => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef], | |
740 | 'en-us' => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz', 'us', undef ], | |
741 | 'es' => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'], | |
742 | #'et' => [], # Ethopia or Estonia ?? | |
743 | 'fi' => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'], | |
744 | #'fo' => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'], | |
745 | 'fr' => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'], | |
746 | 'fr-be' => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'], | |
747 | 'fr-ca' => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'], | |
748 | 'fr-ch' => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'], | |
749 | #'hr' => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2? | |
750 | 'hu' => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef], | |
751 | 'is' => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'], | |
752 | 'it' => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'], | |
753 | 'jp' => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef], | |
754 | 'lt' => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'], | |
755 | #'lv' => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7? | |
756 | 'mk' => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'], | |
757 | 'nl' => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef], | |
758 | #'nl-be' => ['Belgium-Dutch', 'nl-be', ?, ?, ?], | |
759 | 'no' => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'], | |
760 | 'pl' => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef], | |
761 | 'pt' => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'], | |
762 | 'pt-br' => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'], | |
763 | #'ru' => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know? | |
764 | 'si' => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef], | |
765 | 'se' => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'], | |
766 | #'th' => [], | |
767 | 'tr' => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef], | |
768 | }; | |
769 | ||
770 | my $kvmkeymaparray = []; | |
771 | foreach my $lc (sort keys %$keymaphash) { | |
772 | push @$kvmkeymaparray, $keymaphash->{$lc}->[1]; | |
773 | } | |
774 | ||
775 | sub kvmkeymaps { | |
776 | return $keymaphash; | |
777 | } | |
778 | ||
779 | sub kvmkeymaplist { | |
780 | return $kvmkeymaparray; | |
781 | } | |
782 | ||
783 | sub extract_param { | |
784 | my ($param, $key) = @_; | |
785 | ||
786 | my $res = $param->{$key}; | |
787 | delete $param->{$key}; | |
788 | ||
789 | return $res; | |
790 | } | |
791 | ||
792 | # Note: we use this to wait until vncterm/spiceterm is ready | |
793 | sub wait_for_vnc_port { | |
794 | my ($port, $family, $timeout) = @_; | |
795 | ||
796 | $timeout = 5 if !$timeout; | |
797 | my $sleeptime = 0; | |
798 | my $starttime = [gettimeofday]; | |
799 | my $elapsed; | |
800 | ||
801 | my $cmd = ['/bin/ss', '-Htln', "sport = :$port"]; | |
802 | push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family); | |
803 | ||
804 | my $found; | |
805 | while (($elapsed = tv_interval($starttime)) < $timeout) { | |
806 | # -Htln = don't print header, tcp, listening sockets only, numeric ports | |
807 | run_command($cmd, outfunc => sub { | |
808 | my $line = shift; | |
809 | if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) { | |
810 | $found = 1 if ($port == $1); | |
811 | } | |
812 | }); | |
813 | return 1 if $found; | |
814 | $sleeptime += 100000 if $sleeptime < 1000000; | |
815 | usleep($sleeptime); | |
816 | } | |
817 | ||
818 | die "Timeout while waiting for port '$port' to get ready!\n"; | |
819 | } | |
820 | ||
821 | sub next_unused_port { | |
822 | my ($range_start, $range_end, $family, $address) = @_; | |
823 | ||
824 | # We use a file to register allocated ports. | |
825 | # Those registrations expires after $expiretime. | |
826 | # We use this to avoid race conditions between | |
827 | # allocation and use of ports. | |
828 | ||
829 | my $filename = "/var/tmp/pve-reserved-ports"; | |
830 | ||
831 | my $code = sub { | |
832 | ||
833 | my $expiretime = 5; | |
834 | my $ctime = time(); | |
835 | ||
836 | my $ports = {}; | |
837 | ||
838 | if (my $fh = IO::File->new ($filename, "r")) { | |
839 | while (my $line = <$fh>) { | |
840 | if ($line =~ m/^(\d+)\s(\d+)$/) { | |
841 | my ($port, $timestamp) = ($1, $2); | |
842 | if (($timestamp + $expiretime) > $ctime) { | |
843 | $ports->{$port} = $timestamp; # not expired | |
844 | } | |
845 | } | |
846 | } | |
847 | } | |
848 | ||
849 | my $newport; | |
850 | my %sockargs = (Listen => 5, | |
851 | ReuseAddr => 1, | |
852 | Family => $family, | |
853 | Proto => IPPROTO_TCP, | |
854 | GetAddrInfoFlags => 0); | |
855 | $sockargs{LocalAddr} = $address if defined($address); | |
856 | ||
857 | for (my $p = $range_start; $p < $range_end; $p++) { | |
858 | next if $ports->{$p}; # reserved | |
859 | ||
860 | $sockargs{LocalPort} = $p; | |
861 | my $sock = IO::Socket::IP->new(%sockargs); | |
862 | ||
863 | if ($sock) { | |
864 | close($sock); | |
865 | $newport = $p; | |
866 | $ports->{$p} = $ctime; | |
867 | last; | |
868 | } | |
869 | } | |
870 | ||
871 | my $data = ""; | |
872 | foreach my $p (keys %$ports) { | |
873 | $data .= "$p $ports->{$p}\n"; | |
874 | } | |
875 | ||
876 | file_set_contents($filename, $data); | |
877 | ||
878 | return $newport; | |
879 | }; | |
880 | ||
881 | my $p = lock_file('/var/lock/pve-ports.lck', 10, $code); | |
882 | die $@ if $@; | |
883 | ||
884 | die "unable to find free port (${range_start}-${range_end})\n" if !$p; | |
885 | ||
886 | return $p; | |
887 | } | |
888 | ||
889 | sub next_migrate_port { | |
890 | my ($family, $address) = @_; | |
891 | return next_unused_port(60000, 60050, $family, $address); | |
892 | } | |
893 | ||
894 | sub next_vnc_port { | |
895 | my ($family, $address) = @_; | |
896 | return next_unused_port(5900, 6000, $family, $address); | |
897 | } | |
898 | ||
899 | sub next_spice_port { | |
900 | my ($family, $address) = @_; | |
901 | return next_unused_port(61000, 61099, $family, $address); | |
902 | } | |
903 | ||
904 | # sigkill after $timeout a $sub running in a fork if it can't write a pipe | |
905 | # the $sub has to return a single scalar | |
906 | sub run_fork_with_timeout { | |
907 | my ($timeout, $sub) = @_; | |
908 | ||
909 | my $res; | |
910 | my $error; | |
911 | my $pipe_out = IO::Pipe->new(); | |
912 | ||
913 | # disable pending alarms, save their remaining time | |
914 | my $prev_alarm = alarm 0; | |
915 | ||
916 | # avoid leaving a zombie if the parent gets interrupted | |
917 | my $sig_received; | |
918 | local $SIG{INT} = sub { $sig_received++; }; | |
919 | ||
920 | my $child = fork(); | |
921 | if (!defined($child)) { | |
922 | die "fork failed: $!\n"; | |
923 | return $res; | |
924 | } | |
925 | ||
926 | if (!$child) { | |
927 | $pipe_out->writer(); | |
928 | ||
929 | eval { | |
930 | $res = $sub->(); | |
931 | print {$pipe_out} encode_json({ result => $res }); | |
932 | $pipe_out->flush(); | |
933 | }; | |
934 | if (my $err = $@) { | |
935 | print {$pipe_out} encode_json({ error => $err }); | |
936 | $pipe_out->flush(); | |
937 | POSIX::_exit(1); | |
938 | } | |
939 | POSIX::_exit(0); | |
940 | } | |
941 | ||
942 | $pipe_out->reader(); | |
943 | ||
944 | my $readvalues = sub { | |
945 | local $/ = undef; | |
946 | my $child_res = decode_json(scalar<$pipe_out>); | |
947 | $res = $child_res->{result}; | |
948 | $error = $child_res->{error}; | |
949 | }; | |
950 | eval { | |
951 | if (defined($timeout)) { | |
952 | run_with_timeout($timeout, $readvalues); | |
953 | } else { | |
954 | $readvalues->(); | |
955 | } | |
956 | }; | |
957 | warn $@ if $@; | |
958 | $pipe_out->close(); | |
959 | kill('KILL', $child); | |
960 | waitpid($child, 0); | |
961 | ||
962 | alarm $prev_alarm; | |
963 | die "interrupted by unexpected signal\n" if $sig_received; | |
964 | ||
965 | die $error if $error; | |
966 | return $res; | |
967 | } | |
968 | ||
969 | sub run_fork { | |
970 | my ($code) = @_; | |
971 | return run_fork_with_timeout(undef, $code); | |
972 | } | |
973 | ||
974 | # NOTE: NFS syscall can't be interrupted, so alarm does | |
975 | # not work to provide timeouts. | |
976 | # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation" | |
977 | # So fork() before using Filesys::Df | |
978 | sub df { | |
979 | my ($path, $timeout) = @_; | |
980 | ||
981 | my $res = { | |
982 | total => 0, | |
983 | used => 0, | |
984 | avail => 0, | |
985 | }; | |
986 | ||
987 | my $pipe = IO::Pipe->new(); | |
988 | my $child = fork(); | |
989 | if (!defined($child)) { | |
990 | warn "fork failed: $!\n"; | |
991 | return $res; | |
992 | } | |
993 | ||
994 | if (!$child) { | |
995 | $pipe->writer(); | |
996 | eval { | |
997 | my $df = Filesys::Df::df($path, 1); | |
998 | print {$pipe} "$df->{blocks}\n$df->{used}\n$df->{bavail}\n" | |
999 | if defined($df); | |
1000 | $pipe->close(); | |
1001 | }; | |
1002 | if (my $err = $@) { | |
1003 | warn $err; | |
1004 | POSIX::_exit(1); | |
1005 | } | |
1006 | POSIX::_exit(0); | |
1007 | } | |
1008 | ||
1009 | $pipe->reader(); | |
1010 | ||
1011 | my $readvalues = sub { | |
1012 | $res->{total} = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]); | |
1013 | $res->{used} = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]); | |
1014 | $res->{avail} = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]); | |
1015 | }; | |
1016 | eval { | |
1017 | run_with_timeout($timeout, $readvalues); | |
1018 | }; | |
1019 | warn $@ if $@; | |
1020 | $pipe->close(); | |
1021 | kill('KILL', $child); | |
1022 | waitpid($child, 0); | |
1023 | return $res; | |
1024 | } | |
1025 | ||
1026 | # UPID helper | |
1027 | # We use this to uniquely identify a process. | |
1028 | # An 'Unique Process ID' has the following format: | |
1029 | # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user" | |
1030 | ||
1031 | sub upid_encode { | |
1032 | my $d = shift; | |
1033 | ||
1034 | # Note: pstart can be > 32bit if uptime > 497 days, so this can result in | |
1035 | # more that 8 characters for pstart | |
1036 | return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid}, | |
1037 | $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id}, | |
1038 | $d->{user}); | |
1039 | } | |
1040 | ||
1041 | sub upid_decode { | |
1042 | my ($upid, $noerr) = @_; | |
1043 | ||
1044 | my $res; | |
1045 | my $filename; | |
1046 | ||
1047 | # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user" | |
1048 | # Note: allow up to 9 characters for pstart (work until 20 years uptime) | |
1049 | if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) { | |
1050 | $res->{node} = $1; | |
1051 | $res->{pid} = hex($3); | |
1052 | $res->{pstart} = hex($4); | |
1053 | $res->{starttime} = hex($5); | |
1054 | $res->{type} = $6; | |
1055 | $res->{id} = $7; | |
1056 | $res->{user} = $8; | |
1057 | ||
1058 | my $subdir = substr($5, 7, 8); | |
1059 | $filename = "$pvetaskdir/$subdir/$upid"; | |
1060 | ||
1061 | } else { | |
1062 | return undef if $noerr; | |
1063 | die "unable to parse worker upid '$upid'\n"; | |
1064 | } | |
1065 | ||
1066 | return wantarray ? ($res, $filename) : $res; | |
1067 | } | |
1068 | ||
1069 | sub upid_open { | |
1070 | my ($upid) = @_; | |
1071 | ||
1072 | my ($task, $filename) = upid_decode($upid); | |
1073 | ||
1074 | my $dirname = dirname($filename); | |
1075 | make_path($dirname); | |
1076 | ||
1077 | my $wwwid = getpwnam('www-data') || | |
1078 | die "getpwnam failed"; | |
1079 | ||
1080 | my $perm = 0640; | |
1081 | ||
1082 | my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) || | |
1083 | die "unable to create output file '$filename' - $!\n"; | |
1084 | chown $wwwid, -1, $outfh; | |
1085 | ||
1086 | return $outfh; | |
1087 | }; | |
1088 | ||
1089 | sub upid_read_status { | |
1090 | my ($upid) = @_; | |
1091 | ||
1092 | my ($task, $filename) = upid_decode($upid); | |
1093 | my $fh = IO::File->new($filename, "r"); | |
1094 | return "unable to open file - $!" if !$fh; | |
1095 | my $maxlen = 4096; | |
1096 | sysseek($fh, -$maxlen, 2); | |
1097 | my $readbuf = ''; | |
1098 | my $br = sysread($fh, $readbuf, $maxlen); | |
1099 | close($fh); | |
1100 | if ($br) { | |
1101 | return "unable to extract last line" | |
1102 | if $readbuf !~ m/\n?(.+)$/; | |
1103 | my $line = $1; | |
1104 | if ($line =~ m/^TASK OK$/) { | |
1105 | return 'OK'; | |
1106 | } elsif ($line =~ m/^TASK ERROR: (.+)$/) { | |
1107 | return $1; | |
1108 | } else { | |
1109 | return "unexpected status"; | |
1110 | } | |
1111 | } | |
1112 | return "unable to read tail (got $br bytes)"; | |
1113 | } | |
1114 | ||
1115 | # useful functions to store comments in config files | |
1116 | sub encode_text { | |
1117 | my ($text) = @_; | |
1118 | ||
1119 | # all control and hi-bit characters, and ':' | |
1120 | my $unsafe = "^\x20-\x39\x3b-\x7e"; | |
1121 | return uri_escape(Encode::encode("utf8", $text), $unsafe); | |
1122 | } | |
1123 | ||
1124 | sub decode_text { | |
1125 | my ($data) = @_; | |
1126 | ||
1127 | return Encode::decode("utf8", uri_unescape($data)); | |
1128 | } | |
1129 | ||
1130 | # depreciated - do not use! | |
1131 | # we now decode all parameters by default | |
1132 | sub decode_utf8_parameters { | |
1133 | my ($param) = @_; | |
1134 | ||
1135 | foreach my $p (qw(comment description firstname lastname)) { | |
1136 | $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p}; | |
1137 | } | |
1138 | ||
1139 | return $param; | |
1140 | } | |
1141 | ||
1142 | sub random_ether_addr { | |
1143 | my ($prefix) = @_; | |
1144 | ||
1145 | my ($seconds, $microseconds) = gettimeofday; | |
1146 | ||
1147 | my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds); | |
1148 | ||
1149 | # clear multicast, set local id | |
1150 | vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2; | |
1151 | ||
1152 | my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand)); | |
1153 | if (defined($prefix)) { | |
1154 | $addr = uc($prefix) . substr($addr, length($prefix)); | |
1155 | } | |
1156 | return $addr; | |
1157 | } | |
1158 | ||
1159 | sub shellquote { | |
1160 | my $str = shift; | |
1161 | ||
1162 | return String::ShellQuote::shell_quote($str); | |
1163 | } | |
1164 | ||
1165 | sub cmd2string { | |
1166 | my ($cmd) = @_; | |
1167 | ||
1168 | die "no arguments" if !$cmd; | |
1169 | ||
1170 | return $cmd if !ref($cmd); | |
1171 | ||
1172 | my @qa = (); | |
1173 | foreach my $arg (@$cmd) { push @qa, shellquote($arg); } | |
1174 | ||
1175 | return join (' ', @qa); | |
1176 | } | |
1177 | ||
1178 | # split an shell argument string into an array, | |
1179 | sub split_args { | |
1180 | my ($str) = @_; | |
1181 | ||
1182 | return $str ? [ Text::ParseWords::shellwords($str) ] : []; | |
1183 | } | |
1184 | ||
1185 | sub dump_logfile { | |
1186 | my ($filename, $start, $limit, $filter) = @_; | |
1187 | ||
1188 | my $lines = []; | |
1189 | my $count = 0; | |
1190 | ||
1191 | my $fh = IO::File->new($filename, "r"); | |
1192 | if (!$fh) { | |
1193 | $count++; | |
1194 | push @$lines, { n => $count, t => "unable to open file - $!"}; | |
1195 | return ($count, $lines); | |
1196 | } | |
1197 | ||
1198 | $start = 0 if !$start; | |
1199 | $limit = 50 if !$limit; | |
1200 | ||
1201 | my $line; | |
1202 | ||
1203 | if ($filter) { | |
1204 | # duplicate code, so that we do not slow down normal path | |
1205 | while (defined($line = <$fh>)) { | |
1206 | next if $line !~ m/$filter/; | |
1207 | next if $count++ < $start; | |
1208 | next if $limit <= 0; | |
1209 | chomp $line; | |
1210 | push @$lines, { n => $count, t => $line}; | |
1211 | $limit--; | |
1212 | } | |
1213 | } else { | |
1214 | while (defined($line = <$fh>)) { | |
1215 | next if $count++ < $start; | |
1216 | next if $limit <= 0; | |
1217 | chomp $line; | |
1218 | push @$lines, { n => $count, t => $line}; | |
1219 | $limit--; | |
1220 | } | |
1221 | } | |
1222 | ||
1223 | close($fh); | |
1224 | ||
1225 | # HACK: ExtJS store.guaranteeRange() does not like empty array | |
1226 | # so we add a line | |
1227 | if (!$count) { | |
1228 | $count++; | |
1229 | push @$lines, { n => $count, t => "no content"}; | |
1230 | } | |
1231 | ||
1232 | return ($count, $lines); | |
1233 | } | |
1234 | ||
1235 | sub dump_journal { | |
1236 | my ($start, $limit, $since, $until, $service) = @_; | |
1237 | ||
1238 | my $lines = []; | |
1239 | my $count = 0; | |
1240 | ||
1241 | $start = 0 if !$start; | |
1242 | $limit = 50 if !$limit; | |
1243 | ||
1244 | my $parser = sub { | |
1245 | my $line = shift; | |
1246 | ||
1247 | return if $count++ < $start; | |
1248 | return if $limit <= 0; | |
1249 | push @$lines, { n => int($count), t => $line}; | |
1250 | $limit--; | |
1251 | }; | |
1252 | ||
1253 | my $cmd = ['journalctl', '-o', 'short', '--no-pager']; | |
1254 | ||
1255 | push @$cmd, '--unit', $service if $service; | |
1256 | push @$cmd, '--since', $since if $since; | |
1257 | push @$cmd, '--until', $until if $until; | |
1258 | run_command($cmd, outfunc => $parser); | |
1259 | ||
1260 | # HACK: ExtJS store.guaranteeRange() does not like empty array | |
1261 | # so we add a line | |
1262 | if (!$count) { | |
1263 | $count++; | |
1264 | push @$lines, { n => $count, t => "no content"}; | |
1265 | } | |
1266 | ||
1267 | return ($count, $lines); | |
1268 | } | |
1269 | ||
1270 | sub dir_glob_regex { | |
1271 | my ($dir, $regex) = @_; | |
1272 | ||
1273 | my $dh = IO::Dir->new ($dir); | |
1274 | return wantarray ? () : undef if !$dh; | |
1275 | ||
1276 | while (defined(my $tmp = $dh->read)) { | |
1277 | if (my @res = $tmp =~ m/^($regex)$/) { | |
1278 | $dh->close; | |
1279 | return wantarray ? @res : $tmp; | |
1280 | } | |
1281 | } | |
1282 | $dh->close; | |
1283 | ||
1284 | return wantarray ? () : undef; | |
1285 | } | |
1286 | ||
1287 | sub dir_glob_foreach { | |
1288 | my ($dir, $regex, $func) = @_; | |
1289 | ||
1290 | my $dh = IO::Dir->new ($dir); | |
1291 | if (defined $dh) { | |
1292 | while (defined(my $tmp = $dh->read)) { | |
1293 | if (my @res = $tmp =~ m/^($regex)$/) { | |
1294 | &$func (@res); | |
1295 | } | |
1296 | } | |
1297 | } | |
1298 | } | |
1299 | ||
1300 | sub assert_if_modified { | |
1301 | my ($digest1, $digest2) = @_; | |
1302 | ||
1303 | if ($digest1 && $digest2 && ($digest1 ne $digest2)) { | |
1304 | die "detected modified configuration - file changed by other user? Try again.\n"; | |
1305 | } | |
1306 | } | |
1307 | ||
1308 | # Digest for short strings | |
1309 | # like FNV32a, but we only return 31 bits (positive numbers) | |
1310 | sub fnv31a { | |
1311 | my ($string) = @_; | |
1312 | ||
1313 | my $hval = 0x811c9dc5; | |
1314 | ||
1315 | foreach my $c (unpack('C*', $string)) { | |
1316 | $hval ^= $c; | |
1317 | $hval += ( | |
1318 | (($hval << 1) ) + | |
1319 | (($hval << 4) ) + | |
1320 | (($hval << 7) ) + | |
1321 | (($hval << 8) ) + | |
1322 | (($hval << 24) ) ); | |
1323 | $hval = $hval & 0xffffffff; | |
1324 | } | |
1325 | return $hval & 0x7fffffff; | |
1326 | } | |
1327 | ||
1328 | sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); } | |
1329 | ||
1330 | sub unpack_sockaddr_in46 { | |
1331 | my ($sin) = @_; | |
1332 | my $family = Socket::sockaddr_family($sin); | |
1333 | my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin) | |
1334 | : Socket::unpack_sockaddr_in($sin)); | |
1335 | return ($family, $port, $host); | |
1336 | } | |
1337 | ||
1338 | sub getaddrinfo_all { | |
1339 | my ($hostname, @opts) = @_; | |
1340 | my %hints = ( flags => AI_V4MAPPED | AI_ALL, | |
1341 | @opts ); | |
1342 | my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints); | |
1343 | die "failed to get address info for: $hostname: $err\n" if $err; | |
1344 | return @res; | |
1345 | } | |
1346 | ||
1347 | sub get_host_address_family { | |
1348 | my ($hostname, $socktype) = @_; | |
1349 | my @res = getaddrinfo_all($hostname, socktype => $socktype); | |
1350 | return $res[0]->{family}; | |
1351 | } | |
1352 | ||
1353 | # get the fully qualified domain name of a host | |
1354 | # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns, | |
1355 | # given a nodename as a parameter | |
1356 | sub get_fqdn { | |
1357 | my ($nodename) = @_; | |
1358 | ||
1359 | my $hints = { | |
1360 | flags => AI_CANONNAME, | |
1361 | socktype => SOCK_DGRAM | |
1362 | }; | |
1363 | ||
1364 | my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints); | |
1365 | ||
1366 | die "getaddrinfo: $err" if $err; | |
1367 | ||
1368 | return $addrs[0]->{canonname}; | |
1369 | } | |
1370 | ||
1371 | # Parses any sane kind of host, or host+port pair: | |
1372 | # The port is always optional and thus may be undef. | |
1373 | sub parse_host_and_port { | |
1374 | my ($address) = @_; | |
1375 | if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ || # ipv4 or host with optional ':port' | |
1376 | $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port' | |
1377 | $address =~ /^($IPV6RE)(?:\.(\d+))?$/) # ipv6 with optional port separated by dot | |
1378 | { | |
1379 | return ($1, $2, 1); # end with 1 to support simple if(parse...) tests | |
1380 | } | |
1381 | return; # nothing | |
1382 | } | |
1383 | ||
1384 | sub unshare($) { | |
1385 | my ($flags) = @_; | |
1386 | return 0 == syscall(PVE::Syscall::unshare, $flags); | |
1387 | } | |
1388 | ||
1389 | sub setns($$) { | |
1390 | my ($fileno, $nstype) = @_; | |
1391 | return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype); | |
1392 | } | |
1393 | ||
1394 | sub syncfs($) { | |
1395 | my ($fileno) = @_; | |
1396 | return 0 == syscall(PVE::Syscall::syncfs, $fileno); | |
1397 | } | |
1398 | ||
1399 | sub sync_mountpoint { | |
1400 | my ($path) = @_; | |
1401 | sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n"; | |
1402 | my $result = syncfs(fileno($fd)); | |
1403 | close($fd); | |
1404 | return $result; | |
1405 | } | |
1406 | ||
1407 | # support sending multi-part mail messages with a text and or a HTML part | |
1408 | # mailto may be a single email string or an array of receivers | |
1409 | sub sendmail { | |
1410 | my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_; | |
1411 | my $mail_re = qr/[^-a-zA-Z0-9+._@]/; | |
1412 | ||
1413 | $mailto = [ $mailto ] if !ref($mailto); | |
1414 | ||
1415 | foreach (@$mailto) { | |
1416 | die "illegal character in mailto address\n" | |
1417 | if ($_ =~ $mail_re); | |
1418 | } | |
1419 | ||
1420 | my $rcvrtxt = join (', ', @$mailto); | |
1421 | ||
1422 | $mailfrom = $mailfrom || "root"; | |
1423 | die "illegal character in mailfrom address\n" | |
1424 | if $mailfrom =~ $mail_re; | |
1425 | ||
1426 | $author = $author || 'Proxmox VE'; | |
1427 | ||
1428 | open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) || | |
1429 | die "unable to open 'sendmail' - $!"; | |
1430 | ||
1431 | # multipart spec see https://www.ietf.org/rfc/rfc1521.txt | |
1432 | my $boundary = "----_=_NextPart_001_".int(time).$$; | |
1433 | ||
1434 | print MAIL "Content-Type: multipart/alternative;\n"; | |
1435 | print MAIL "\tboundary=\"$boundary\"\n"; | |
1436 | print MAIL "MIME-Version: 1.0\n"; | |
1437 | ||
1438 | print MAIL "FROM: $author <$mailfrom>\n"; | |
1439 | print MAIL "TO: $rcvrtxt\n"; | |
1440 | print MAIL "SUBJECT: $subject\n"; | |
1441 | print MAIL "\n"; | |
1442 | print MAIL "This is a multi-part message in MIME format.\n\n"; | |
1443 | print MAIL "--$boundary\n"; | |
1444 | ||
1445 | if (defined($text)) { | |
1446 | print MAIL "Content-Type: text/plain;\n"; | |
1447 | print MAIL "\tcharset=\"UTF8\"\n"; | |
1448 | print MAIL "Content-Transfer-Encoding: 8bit\n"; | |
1449 | print MAIL "\n"; | |
1450 | ||
1451 | # avoid 'remove extra line breaks' issue (MS Outlook) | |
1452 | my $fill = ' '; | |
1453 | $text =~ s/^/$fill/gm; | |
1454 | ||
1455 | print MAIL $text; | |
1456 | ||
1457 | print MAIL "\n--$boundary\n"; | |
1458 | } | |
1459 | ||
1460 | if (defined($html)) { | |
1461 | print MAIL "Content-Type: text/html;\n"; | |
1462 | print MAIL "\tcharset=\"UTF8\"\n"; | |
1463 | print MAIL "Content-Transfer-Encoding: 8bit\n"; | |
1464 | print MAIL "\n"; | |
1465 | ||
1466 | print MAIL $html; | |
1467 | ||
1468 | print MAIL "\n--$boundary--\n"; | |
1469 | } | |
1470 | ||
1471 | close(MAIL); | |
1472 | } | |
1473 | ||
1474 | sub tempfile { | |
1475 | my ($perm, %opts) = @_; | |
1476 | ||
1477 | # default permissions are stricter than with file_set_contents | |
1478 | $perm = 0600 if !defined($perm); | |
1479 | ||
1480 | my $dir = $opts{dir} // '/run'; | |
1481 | my $mode = $opts{mode} // O_RDWR; | |
1482 | $mode |= O_EXCL if !$opts{allow_links}; | |
1483 | ||
1484 | my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm); | |
1485 | if (!$fh && $! == EOPNOTSUPP) { | |
1486 | $dir = '/tmp' if !defined($opts{dir}); | |
1487 | $dir .= "/.tmpfile.$$"; | |
1488 | $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm); | |
1489 | unlink($dir) if $fh; | |
1490 | } | |
1491 | die "failed to create tempfile: $!\n" if !$fh; | |
1492 | return $fh; | |
1493 | } | |
1494 | ||
1495 | sub tempfile_contents { | |
1496 | my ($data, $perm, %opts) = @_; | |
1497 | ||
1498 | my $fh = tempfile($perm, %opts); | |
1499 | eval { | |
1500 | die "unable to write to tempfile: $!\n" if !print {$fh} $data; | |
1501 | die "unable to flush to tempfile: $!\n" if !defined($fh->flush()); | |
1502 | }; | |
1503 | if (my $err = $@) { | |
1504 | close $fh; | |
1505 | die $err; | |
1506 | } | |
1507 | ||
1508 | return ("/proc/$$/fd/".$fh->fileno, $fh); | |
1509 | } | |
1510 | ||
1511 | sub validate_ssh_public_keys { | |
1512 | my ($raw) = @_; | |
1513 | my @lines = split(/\n/, $raw); | |
1514 | ||
1515 | foreach my $line (@lines) { | |
1516 | next if $line =~ m/^\s*$/; | |
1517 | eval { | |
1518 | my ($filename, $handle) = tempfile_contents($line); | |
1519 | run_command(["ssh-keygen", "-l", "-f", $filename], | |
1520 | outfunc => sub {}, errfunc => sub {}); | |
1521 | }; | |
1522 | die "SSH public key validation error\n" if $@; | |
1523 | } | |
1524 | } | |
1525 | ||
1526 | sub openat($$$;$) { | |
1527 | my ($dirfd, $pathname, $flags, $mode) = @_; | |
1528 | my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0); | |
1529 | return undef if $fd < 0; | |
1530 | # sysopen() doesn't deal with numeric file descriptors apparently | |
1531 | # so we need to convert to a mode string for IO::Handle->new_from_fd | |
1532 | my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r'; | |
1533 | my $handle = IO::Handle->new_from_fd($fd, $flagstr); | |
1534 | return $handle if $handle; | |
1535 | my $err = $!; # save error before closing the raw fd | |
1536 | syscall(PVE::Syscall::close, $fd); # close | |
1537 | $! = $err; | |
1538 | return undef; | |
1539 | } | |
1540 | ||
1541 | sub mkdirat($$$) { | |
1542 | my ($dirfd, $name, $mode) = @_; | |
1543 | return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0; | |
1544 | } | |
1545 | ||
1546 | # NOTE: This calls the dbus main loop and must not be used when another dbus | |
1547 | # main loop is being used as we need to wait for the JobRemoved signal. | |
1548 | # Polling the job status instead doesn't work because this doesn't give us the | |
1549 | # distinction between success and failure. | |
1550 | # | |
1551 | # Note that the description is mandatory for security reasons. | |
1552 | sub enter_systemd_scope { | |
1553 | my ($unit, $description, %extra) = @_; | |
1554 | die "missing description\n" if !defined($description); | |
1555 | ||
1556 | my $timeout = delete $extra{timeout}; | |
1557 | ||
1558 | $unit .= '.scope'; | |
1559 | my $properties = [ [PIDs => [dbus_uint32($$)]] ]; | |
1560 | ||
1561 | foreach my $key (keys %extra) { | |
1562 | if ($key eq 'Slice' || $key eq 'KillMode') { | |
1563 | push @$properties, [$key, $extra{$key}]; | |
1564 | } elsif ($key eq 'CPUShares') { | |
1565 | push @$properties, [$key, dbus_uint64($extra{$key})]; | |
1566 | } elsif ($key eq 'CPUQuota') { | |
1567 | push @$properties, ['CPUQuotaPerSecUSec', | |
1568 | dbus_uint64($extra{$key} * 10000)]; | |
1569 | } else { | |
1570 | die "Don't know how to encode $key for systemd scope\n"; | |
1571 | } | |
1572 | } | |
1573 | ||
1574 | my $job; | |
1575 | my $done = 0; | |
1576 | ||
1577 | my $bus = Net::DBus->system(); | |
1578 | my $reactor = Net::DBus::Reactor->main(); | |
1579 | ||
1580 | my $service = $bus->get_service('org.freedesktop.systemd1'); | |
1581 | my $if = $service->get_object('/org/freedesktop/systemd1', 'org.freedesktop.systemd1.Manager'); | |
1582 | # Connect to the JobRemoved signal since we want to wait for it to finish | |
1583 | my $sigid; | |
1584 | my $timer; | |
1585 | my $cleanup = sub { | |
1586 | my ($no_shutdown) = @_; | |
1587 | $if->disconnect_from_signal('JobRemoved', $sigid) if defined($if); | |
1588 | $if = undef; | |
1589 | $sigid = undef; | |
1590 | $reactor->remove_timeout($timer) if defined($timer); | |
1591 | $timer = undef; | |
1592 | return if $no_shutdown; | |
1593 | $reactor->shutdown(); | |
1594 | }; | |
1595 | ||
1596 | $sigid = $if->connect_to_signal('JobRemoved', sub { | |
1597 | my ($id, $removed_job, $signaled_unit, $result) = @_; | |
1598 | return if $signaled_unit ne $unit || $removed_job ne $job; | |
1599 | $cleanup->(0); | |
1600 | die "systemd job failed\n" if $result ne 'done'; | |
1601 | $done = 1; | |
1602 | }); | |
1603 | ||
1604 | my $on_timeout = sub { | |
1605 | $cleanup->(0); | |
1606 | die "systemd job timed out\n"; | |
1607 | }; | |
1608 | ||
1609 | $timer = $reactor->add_timeout($timeout * 1000, Net::DBus::Callback->new(method => $on_timeout)) | |
1610 | if defined($timeout); | |
1611 | $job = $if->StartTransientUnit($unit, 'fail', $properties, []); | |
1612 | $reactor->run(); | |
1613 | $cleanup->(1); | |
1614 | die "systemd job never completed\n" if !$done; | |
1615 | } | |
1616 | ||
1617 | my $salt_starter = time(); | |
1618 | ||
1619 | sub encrypt_pw { | |
1620 | my ($pw) = @_; | |
1621 | ||
1622 | $salt_starter++; | |
1623 | my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8); | |
1624 | ||
1625 | # crypt does not want '+' in salt (see 'man crypt') | |
1626 | $salt =~ s/\+/X/g; | |
1627 | ||
1628 | return crypt(encode("utf8", $pw), "\$5\$$salt\$"); | |
1629 | } | |
1630 | ||
1631 | # intended usage: convert_size($val, "kb" => "gb") | |
1632 | # we round up to the next integer by default | |
1633 | # E.g. `convert_size(1023, "b" => "kb")` returns 1 | |
1634 | # use $no_round_up to switch this off, above example would then return 0 | |
1635 | # this is also true for converting down e.g. 0.0005 gb to mb returns 1 | |
1636 | # (0 if $no_round_up is true) | |
1637 | # allowed formats for value: | |
1638 | # 1234 | |
1639 | # 1234. | |
1640 | # 1234.1234 | |
1641 | # .1234 | |
1642 | sub convert_size { | |
1643 | my ($value, $from, $to, $no_round_up) = @_; | |
1644 | ||
1645 | my $units = { | |
1646 | b => 0, | |
1647 | kb => 1, | |
1648 | mb => 2, | |
1649 | gb => 3, | |
1650 | tb => 4, | |
1651 | pb => 5, | |
1652 | }; | |
1653 | ||
1654 | die "no value given" | |
1655 | if !defined($value) || $value eq ""; | |
1656 | ||
1657 | $from = lc($from // ''); $to = lc($to // ''); | |
1658 | die "unknown 'from' and/or 'to' units ($from => $to)" | |
1659 | if !defined($units->{$from}) || !defined($units->{$to}); | |
1660 | ||
1661 | die "value '$value' is not a valid, positive number" | |
1662 | if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/; | |
1663 | ||
1664 | my $shift_amount = ($units->{$from} - $units->{$to}) * 10; | |
1665 | ||
1666 | $value *= 2**$shift_amount; | |
1667 | $value++ if !$no_round_up && ($value - int($value)) > 0.0; | |
1668 | ||
1669 | return int($value); | |
1670 | } | |
1671 | ||
1672 | 1; |