CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  16
  17 # Add find modules to the path
  18 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  19
  20 INCLUDE(CheckLibraryExists)
  21 INCLUDE(AddCFlagIfSupported)
  22
  23 # Build options
  24 #
  25 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  26 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  27 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   OFF )
  28 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  29 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  30 OPTION( TAGS                            "Generate tags"                                                 OFF )
  31 OPTION( PROFILE                         "Generate profiling information"                OFF )
  32 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  33 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  34
  35 OPTION( ANDROID                         "Build for android NDK"                                 OFF )
  36
  37 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  38 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  39 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  40 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  41
  42 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  43         SET( USE_ICONV ON )
  44         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
  45 ENDIF()
  46
  47 IF(MSVC)
  48         # This option is only available when building with MSVC. By default, libgit2
  49         # is build using the cdecl calling convention, which is useful if you're
  50         # writing C. However, the CLR and Win32 API both expect stdcall.
  51         #
  52         # If you are writing a CLR program and want to link to libgit2, you'll want
  53         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  54         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  55
  56         # This option must match the settings used in your program, in particular if you
  57         # are linking statically
  58         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  59
  60         # By default, libgit2 is built with WinHTTP.  To use the built-in
  61         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  62         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON  )
  63
  64         # If you want to embed a copy of libssh2 into libgit2, pass a
  65         # path to libssh2
  66         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  67
  68         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  69         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  70         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  71 ENDIF()
  72
  73 # This variable will contain the libraries we need to put into
  74 # libgit2.pc's Requires.private. That is, what we're linking to or
  75 # what someone who's statically linking us needs to link to.
  76 SET(LIBGIT2_PC_REQUIRES "")
  77 # This will be set later if we use the system's http-parser library or
  78 # use iconv (OSX) and will be written to the Libs.private field in the
  79 # pc file.
  80 SET(LIBGIT2_PC_LIBS "")
  81
  82 # Installation paths
  83 #
  84 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
  85 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
  86 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
  87
  88 FUNCTION(TARGET_OS_LIBRARIES target)
  89         IF(WIN32)
  90                 TARGET_LINK_LIBRARIES(${target} ws2_32)
  91         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
  92                 TARGET_LINK_LIBRARIES(${target} socket nsl)
  93                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lsocket -lnsl" PARENT_SCOPE)
  94         ENDIF()
  95         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
  96         IF(NEED_LIBRT)
  97                 TARGET_LINK_LIBRARIES(${target} rt)
  98                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lrt" PARENT_SCOPE)
  99         ENDIF()
 100
 101         IF(THREADSAFE)
 102                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 103         ENDIF()
 104 ENDFUNCTION()
 105
 106 # For the MSVC IDE, this function splits up the source files like windows
 107 # explorer does. This is esp. useful with the libgit2_clar project, were
 108 # usually 2 or more files share the same name.  Sadly, this file grouping
 109 # is a per-directory option in cmake and not per-target, resulting in
 110 # empty virtual folders "tests" for the git2.dll
 111 FUNCTION(MSVC_SPLIT_SOURCES target)
 112         IF(MSVC_IDE)
 113                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 114                 FOREACH(source ${sources})
 115                         IF(source MATCHES ".*/")
 116                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 117                                 IF(rel)
 118                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 119                                         IF(rel)
 120                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 121                                                 SOURCE_GROUP(${rel} FILES ${source})
 122                                         ENDIF()
 123                                 ENDIF()
 124                         ENDIF()
 125                 ENDFOREACH()
 126         ENDIF()
 127 ENDFUNCTION()
 128
 129 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 130
 131 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 132 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 133 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 134 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 135
 136 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 137 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 138
 139 # Find required dependencies
 140 INCLUDE_DIRECTORIES(src include)
 141
 142 IF (WIN32 AND EMBED_SSH_PATH)
 143         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 144         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 145         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 146         ADD_DEFINITIONS(-DGIT_SSH)
 147 ENDIF()
 148
 149 IF (WIN32 AND WINHTTP AND NOT MINGW)
 150         ADD_DEFINITIONS(-DGIT_WINHTTP)
 151         INCLUDE_DIRECTORIES(deps/http-parser)
 152         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 153 ELSE ()
 154         IF (NOT AMIGA)
 155                 FIND_PACKAGE(OpenSSL)
 156         ENDIF ()
 157
 158         FIND_PACKAGE(HTTP_Parser)
 159         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 160                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 161                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 162                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lhttp_parser")
 163         ELSE()
 164                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 165                 INCLUDE_DIRECTORIES(deps/http-parser)
 166                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 167         ENDIF()
 168 ENDIF()
 169
 170 # Specify sha1 implementation
 171 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 172         ADD_DEFINITIONS(-DWIN32_SHA1)
 173         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 174 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 175         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 176         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 177                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lssl")
 178         ELSE()
 179                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 180         ENDIF ()
 181 ELSE()
 182         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 183 ENDIF()
 184
 185 # Enable tracing
 186 IF (ENABLE_TRACE STREQUAL "ON")
 187         ADD_DEFINITIONS(-DGIT_TRACE)
 188 ENDIF()
 189
 190 # Include POSIX regex when it is required
 191 IF(WIN32 OR AMIGA OR ANDROID OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 192         INCLUDE_DIRECTORIES(deps/regex)
 193         SET(SRC_REGEX deps/regex/regex.c)
 194 ENDIF()
 195
 196 # Optional external dependency: zlib
 197 FIND_PACKAGE(ZLIB)
 198 IF (ZLIB_FOUND)
 199         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 200         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 201         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 202                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lz")
 203         ELSE()
 204                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 205         ENDIF()
 206 ELSE()
 207         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 208         INCLUDE_DIRECTORIES(deps/zlib)
 209         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 210         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 211 ENDIF()
 212
 213 # Optional external dependency: libssh2
 214 IF (USE_SSH)
 215         FIND_PACKAGE(LIBSSH2)
 216 ENDIF()
 217 IF (LIBSSH2_FOUND)
 218         ADD_DEFINITIONS(-DGIT_SSH)
 219         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIR})
 220         SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} libssh2")
 221         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 222 ENDIF()
 223
 224 # Optional external dependency: libgssapi
 225 IF (USE_GSSAPI)
 226         FIND_PACKAGE(GSSAPI)
 227 ENDIF()
 228 IF (GSSAPI_FOUND)
 229         ADD_DEFINITIONS(-DGIT_GSSAPI)
 230 ENDIF()
 231
 232 # Optional external dependency: iconv
 233 IF (USE_ICONV)
 234         FIND_PACKAGE(Iconv)
 235 ENDIF()
 236 IF (ICONV_FOUND)
 237         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 238         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 239         SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${ICONV_LIBRARIES}")
 240 ENDIF()
 241
 242 # Platform specific compilation flags
 243 IF (MSVC)
 244
 245         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 246
 247         # /GF - String pooling
 248         # /MP - Parallel build
 249         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 250
 251         IF (STDCALL)
 252                 # /Gz - stdcall calling convention
 253                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 254         ENDIF ()
 255
 256         IF (STATIC_CRT)
 257                 SET(CRT_FLAG_DEBUG "/MTd")
 258                 SET(CRT_FLAG_RELEASE "/MT")
 259         ELSE()
 260                 SET(CRT_FLAG_DEBUG "/MDd")
 261                 SET(CRT_FLAG_RELEASE "/MD")
 262         ENDIF()
 263
 264         # /Zi - Create debugging information
 265         # /Od - Disable optimization
 266         # /D_DEBUG - #define _DEBUG
 267         # /MTd - Statically link the multithreaded debug version of the CRT
 268         # /MDd - Dynamically link the multithreaded debug version of the CRT
 269         # /RTC1 - Run time checks
 270         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 271
 272         # /DNDEBUG - Disables asserts
 273         # /MT - Statically link the multithreaded release version of the CRT
 274         # /MD - Dynamically link the multithreaded release version of the CRT
 275         # /O2 - Optimize for speed
 276         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 277         # /GL - Link time code generation (whole program optimization)
 278         # /Gy - Function-level linking
 279         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 280
 281         # /Oy- - Disable frame pointer omission (FPO)
 282         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 283
 284         # /O1 - Optimize for size
 285         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 286
 287         # /DYNAMICBASE - Address space load randomization (ASLR)
 288         # /NXCOMPAT - Data execution prevention (DEP)
 289         # /LARGEADDRESSAWARE - >2GB user address space on x86
 290         # /VERSION - Embed version information in PE header
 291         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 292
 293         # /DEBUG - Create a PDB
 294         # /LTCG - Link time code generation (whole program optimization)
 295         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 296         # /INCREMENTAL:NO - Required to use /LTCG
 297         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 298         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 299         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 300         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 301         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 302
 303         # Same linker settings for DLL as EXE
 304         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 305         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 306         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 307         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 308         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 309
 310         SET(WIN_RC "src/win32/git2.rc")
 311
 312    # Precompiled headers
 313
 314 ELSE ()
 315         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 316
 317         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 318                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 319         ENDIF()
 320
 321         IF (WIN32 AND NOT CYGWIN)
 322                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 323         ENDIF ()
 324
 325         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 326                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 327                 # MinGW >= 3.14 uses the C99-style stdio functions
 328                 # automatically, but forks like mingw-w64 still want
 329                 # us to define this in order to use them
 330                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 331
 332         ELSEIF (BUILD_SHARED_LIBS)
 333                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 334
 335                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 336         ENDIF ()
 337
 338         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 339         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 340         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 341         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 342         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 343         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 344
 345         IF (APPLE) # Apple deprecated OpenSSL
 346                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 347         ENDIF()
 348
 349         IF (PROFILE)
 350                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 351                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 352         ENDIF ()
 353 ENDIF()
 354
 355 IF( NOT CMAKE_CONFIGURATION_TYPES )
 356         # Build Debug by default
 357         IF (NOT CMAKE_BUILD_TYPE)
 358                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 359         ENDIF ()
 360 ELSE()
 361         # Using a multi-configuration generator eg MSVC or Xcode
 362         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 363 ENDIF()
 364
 365 IF (OPENSSL_FOUND)
 366   ADD_DEFINITIONS(-DGIT_SSL)
 367   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 368   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 369 ENDIF()
 370
 371 IF (THREADSAFE)
 372         IF (NOT WIN32)
 373                 FIND_PACKAGE(Threads REQUIRED)
 374         ENDIF()
 375
 376         ADD_DEFINITIONS(-DGIT_THREADS)
 377 ENDIF()
 378
 379 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 380
 381 # Collect sourcefiles
 382 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 383
 384 # On Windows use specific platform sources
 385 IF (WIN32 AND NOT CYGWIN)
 386         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 387         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 388 ELSEIF (AMIGA)
 389         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 390 ELSE()
 391         IF (VALGRIND)
 392                 ADD_DEFINITIONS(-DNO_MMAP)
 393         ENDIF()
 394         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 395 ENDIF()
 396 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 397
 398 # Determine architecture of the machine
 399 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 400         ADD_DEFINITIONS(-DGIT_ARCH_64)
 401 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 402         ADD_DEFINITIONS(-DGIT_ARCH_32)
 403 ELSE()
 404         MESSAGE(FATAL_ERROR "Unsupported architecture")
 405 ENDIF()
 406
 407 # Compile and link libgit2
 408 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 409 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 410 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 411 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 412 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 413 TARGET_OS_LIBRARIES(git2)
 414
 415 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 416 # Win64+MSVC+static libs = linker error
 417 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 418   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 419 ENDIF()
 420
 421 MSVC_SPLIT_SOURCES(git2)
 422
 423 IF (SONAME)
 424         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 425         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 426         IF (LIBGIT2_FILENAME)
 427                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 428                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 429         ENDIF()
 430 ENDIF()
 431 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 432
 433 IF (MSVC_IDE)
 434    # Precompiled headers
 435    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 436    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 437 ENDIF ()
 438
 439 # Install
 440 INSTALL(TARGETS git2
 441         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 442         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 443         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 444 )
 445 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 446 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 447 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 448
 449 # Tests
 450 IF (BUILD_CLAR)
 451         FIND_PACKAGE(PythonInterp REQUIRED)
 452
 453         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 454         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 455         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 456         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 457         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 458         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 459
 460         INCLUDE_DIRECTORIES(${CLAR_PATH})
 461         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 462         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar.c")
 463
 464         ADD_CUSTOM_COMMAND(
 465                 OUTPUT ${CLAR_PATH}/clar.suite
 466                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 467                 DEPENDS ${SRC_TEST}
 468                 WORKING_DIRECTORY ${CLAR_PATH}
 469         )
 470
 471         SET_SOURCE_FILES_PROPERTIES(
 472                 ${CLAR_PATH}/clar.c
 473                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 474
 475         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 476
 477         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 478         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 479         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 480         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 481         TARGET_OS_LIBRARIES(libgit2_clar)
 482         MSVC_SPLIT_SOURCES(libgit2_clar)
 483
 484         IF (MSVC_IDE)
 485                 # Precompiled headers
 486                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 487         ENDIF ()
 488
 489         ENABLE_TESTING()
 490         ADD_TEST(libgit2_clar libgit2_clar -ionline)
 491 ENDIF ()
 492
 493 IF (TAGS)
 494         FIND_PROGRAM(CTAGS ctags)
 495         IF (NOT CTAGS)
 496                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 497         ENDIF ()
 498
 499         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 500
 501         ADD_CUSTOM_COMMAND(
 502                 OUTPUT tags
 503                 COMMAND ${CTAGS} -a ${SRC_ALL}
 504                 DEPENDS ${SRC_ALL}
 505         )
 506         ADD_CUSTOM_TARGET(
 507                 do_tags ALL
 508                 DEPENDS tags
 509         )
 510 ENDIF ()
 511
 512 IF (BUILD_EXAMPLES)
 513         ADD_SUBDIRECTORY(examples)
 514 ENDIF ()