CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  16
  17 FILE(STRINGS "include/git2.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
  18
  19 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
  20 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
  21 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
  22 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
  23
  24 # Find required dependencies
  25 INCLUDE_DIRECTORIES(deps/zlib src include)
  26
  27 # Installation paths
  28 SET(INSTALL_BIN bin CACHE PATH "Where to install binaries to.")
  29 SET(INSTALL_LIB lib CACHE PATH "Where to install libraries to.")
  30 SET(INSTALL_INC include CACHE PATH "Where to install headers to.")
  31
  32 # Build options
  33 OPTION (BUILD_SHARED_LIBS "Build Shared Library (OFF for Static)" ON)
  34 OPTION (BUILD_TESTS "Build Tests" ON)
  35 OPTION (THREADSAFE "Build libgit2 as threadsafe" OFF)
  36
  37 # Platform specific compilation flags
  38 IF (MSVC)
  39         SET(CMAKE_C_FLAGS "/W4 /WX /nologo /Zi")
  40         # TODO: bring back /RTC1 /RTCc
  41         SET(CMAKE_C_FLAGS_DEBUG "/Od /DEBUG /MTd")
  42         SET(CMAKE_C_FLAGS_RELEASE "/MT /O2")
  43 ELSE ()
  44         SET(CMAKE_C_FLAGS "-Wall -Wextra -fPIC")
  45         SET(CMAKE_C_FLAGS_DEBUG "-g -O0")
  46         SET(CMAKE_C_FLAGS_RELEASE "-O2")
  47 ENDIF()
  48
  49 # Build Debug by default
  50 IF (NOT CMAKE_BUILD_TYPE)
  51         SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  52 ENDIF ()
  53
  54 IF (THREADSAFE)
  55         IF (NOT WIN32)
  56                 find_package(Threads REQUIRED)
  57         ENDIF()
  58
  59         ADD_DEFINITIONS(-DGIT_THREADS)
  60 ENDIF()
  61
  62 # Collect sourcefiles
  63 FILE(GLOB SRC src/*.c)
  64 FILE(GLOB SRC_ZLIB deps/zlib/*.c)
  65 FILE(GLOB SRC_H include/git2/*.h)
  66
  67 # On Windows use specific platform sources
  68 IF (WIN32 AND NOT CYGWIN)
  69     ADD_DEFINITIONS(-DWIN32 -D_DEBUG -D_LIB)
  70         FILE(GLOB SRC src/*.c src/win32/*.c)
  71 ENDIF ()
  72
  73 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
  74
  75 # Compile and link libgit2
  76 ADD_LIBRARY(git2 ${SRC} ${SRC_ZLIB})
  77 TARGET_LINK_LIBRARIES(git2 ${CMAKE_THREAD_LIBS_INIT})
  78 SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
  79 SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_VERSION_MAJOR})
  80
  81 # Install
  82 INSTALL(TARGETS git2
  83     RUNTIME DESTINATION ${INSTALL_BIN}
  84     LIBRARY DESTINATION ${INSTALL_LIB}
  85     ARCHIVE DESTINATION ${INSTALL_LIB}
  86 )
  87 INSTALL(DIRECTORY include/git2 DESTINATION ${INSTALL_INC} )
  88 INSTALL(FILES include/git2.h DESTINATION ${INSTALL_INC} )
  89
  90 # Tests
  91 IF (BUILD_TESTS)
  92         SET(TEST_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
  93     ADD_DEFINITIONS(-DTEST_RESOURCES=\"${TEST_RESOURCES}\")
  94
  95     INCLUDE_DIRECTORIES(tests)
  96         FILE(GLOB SRC_TEST tests/t??-*.c)
  97
  98         ADD_EXECUTABLE(libgit2_test tests/test_main.c tests/test_lib.c tests/test_helpers.c ${SRC} ${SRC_TEST} ${SRC_ZLIB})
  99         TARGET_LINK_LIBRARIES(libgit2_test ${CMAKE_THREAD_LIBS_INIT})
 100
 101         ENABLE_TESTING()
 102         ADD_TEST(libgit2_test libgit2_test)
 103 ENDIF ()