CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  16
  17 # Add find modules to the path
  18 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  19
  20 INCLUDE(CheckLibraryExists)
  21 INCLUDE(AddCFlagIfSupported)
  22
  23 # Build options
  24 #
  25 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  26 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  27 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   OFF )
  28 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  29 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  30 OPTION( TAGS                            "Generate tags"                                                 OFF )
  31 OPTION( PROFILE                         "Generate profiling information"                OFF )
  32 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  33 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  34
  35 OPTION( ANDROID                         "Build for android NDK"                                 OFF )
  36
  37 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  38 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  39 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  40 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  41
  42 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  43         SET( USE_ICONV ON )
  44 ENDIF()
  45
  46 IF(MSVC)
  47         # This option is only available when building with MSVC. By default, libgit2
  48         # is build using the cdecl calling convention, which is useful if you're
  49         # writing C. However, the CLR and Win32 API both expect stdcall.
  50         #
  51         # If you are writing a CLR program and want to link to libgit2, you'll want
  52         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  53         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  54
  55         # This option must match the settings used in your program, in particular if you
  56         # are linking statically
  57         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  58
  59         # By default, libgit2 is built with WinHTTP.  To use the built-in
  60         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  61         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON  )
  62
  63         # If you want to embed a copy of libssh2 into libgit2, pass a
  64         # path to libssh2
  65         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  66
  67         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  68         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  69         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  70 ENDIF()
  71
  72 # This variable will contain the libraries we need to put into
  73 # libgit2.pc's Requires.private. That is, what we're linking to or
  74 # what someone who's statically linking us needs to link to.
  75 SET(LIBGIT2_PC_REQUIRES "")
  76 # This will be set later if we use the system's http-parser library or
  77 # use iconv (OSX) and will be written to the Libs.private field in the
  78 # pc file.
  79 SET(LIBGIT2_PC_LIBS "")
  80
  81 # Installation paths
  82 #
  83 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
  84 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
  85 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
  86
  87 FUNCTION(TARGET_OS_LIBRARIES target)
  88         IF(WIN32)
  89                 TARGET_LINK_LIBRARIES(${target} ws2_32)
  90         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
  91                 TARGET_LINK_LIBRARIES(${target} socket nsl)
  92                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lsocket -lnsl" PARENT_SCOPE)
  93         ENDIF()
  94         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
  95         IF(NEED_LIBRT)
  96                 TARGET_LINK_LIBRARIES(${target} rt)
  97                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lrt" PARENT_SCOPE)
  98         ENDIF()
  99
 100         IF(THREADSAFE)
 101                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 102         ENDIF()
 103 ENDFUNCTION()
 104
 105 # For the MSVC IDE, this function splits up the source files like windows
 106 # explorer does. This is esp. useful with the libgit2_clar project, were
 107 # usually 2 or more files share the same name.  Sadly, this file grouping
 108 # is a per-directory option in cmake and not per-target, resulting in
 109 # empty virtual folders "tests" for the git2.dll
 110 FUNCTION(MSVC_SPLIT_SOURCES target)
 111         IF(MSVC_IDE)
 112                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 113                 FOREACH(source ${sources})
 114                         IF(source MATCHES ".*/")
 115                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 116                                 IF(rel)
 117                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 118                                         IF(rel)
 119                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 120                                                 SOURCE_GROUP(${rel} FILES ${source})
 121                                         ENDIF()
 122                                 ENDIF()
 123                         ENDIF()
 124                 ENDFOREACH()
 125         ENDIF()
 126 ENDFUNCTION()
 127
 128 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 129
 130 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 131 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 132 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 133 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 134
 135 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 136 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 137
 138 # Find required dependencies
 139 INCLUDE_DIRECTORIES(src include)
 140
 141 IF (WIN32 AND EMBED_SSH_PATH)
 142         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 143         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 144         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 145         ADD_DEFINITIONS(-DGIT_SSH)
 146 ENDIF()
 147
 148 IF (WIN32 AND WINHTTP AND NOT MINGW)
 149         ADD_DEFINITIONS(-DGIT_WINHTTP)
 150         INCLUDE_DIRECTORIES(deps/http-parser)
 151         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 152 ELSE ()
 153         IF (NOT AMIGA)
 154                 FIND_PACKAGE(OpenSSL)
 155         ENDIF ()
 156
 157         FIND_PACKAGE(HTTP_Parser)
 158         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 159                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 160                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 161                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lhttp_parser")
 162         ELSE()
 163                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 164                 INCLUDE_DIRECTORIES(deps/http-parser)
 165                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 166         ENDIF()
 167 ENDIF()
 168
 169 # Specify sha1 implementation
 170 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 171         ADD_DEFINITIONS(-DWIN32_SHA1)
 172         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 173 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 174         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 175         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 176                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lssl")
 177         ELSE()
 178                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 179         ENDIF ()
 180 ELSE()
 181         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 182 ENDIF()
 183
 184 # Enable tracing
 185 IF (ENABLE_TRACE STREQUAL "ON")
 186         ADD_DEFINITIONS(-DGIT_TRACE)
 187 ENDIF()
 188
 189 # Include POSIX regex when it is required
 190 IF(WIN32 OR AMIGA OR ANDROID OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 191         INCLUDE_DIRECTORIES(deps/regex)
 192         SET(SRC_REGEX deps/regex/regex.c)
 193 ENDIF()
 194
 195 # Optional external dependency: zlib
 196 FIND_PACKAGE(ZLIB)
 197 IF (ZLIB_FOUND)
 198         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 199         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 200         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 201                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lz")
 202         ELSE()
 203                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 204         ENDIF()
 205 ELSE()
 206         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 207         INCLUDE_DIRECTORIES(deps/zlib)
 208         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 209         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 210 ENDIF()
 211
 212 # Optional external dependency: libssh2
 213 IF (USE_SSH)
 214         FIND_PACKAGE(LIBSSH2)
 215 ENDIF()
 216 IF (LIBSSH2_FOUND)
 217         ADD_DEFINITIONS(-DGIT_SSH)
 218         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIR})
 219         SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} libssh2")
 220         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 221 ENDIF()
 222
 223 # Optional external dependency: libgssapi
 224 IF (USE_GSSAPI)
 225         FIND_PACKAGE(GSSAPI)
 226 ENDIF()
 227 IF (GSSAPI_FOUND)
 228         ADD_DEFINITIONS(-DGIT_GSSAPI)
 229 ENDIF()
 230
 231 # Optional external dependency: iconv
 232 IF (USE_ICONV)
 233         FIND_PACKAGE(Iconv)
 234 ENDIF()
 235 IF (ICONV_FOUND)
 236         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 237         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 238         SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${ICONV_LIBRARIES}")
 239 ENDIF()
 240
 241 # Platform specific compilation flags
 242 IF (MSVC)
 243
 244         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 245
 246         # /GF - String pooling
 247         # /MP - Parallel build
 248         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 249
 250         IF (STDCALL)
 251                 # /Gz - stdcall calling convention
 252                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 253         ENDIF ()
 254
 255         IF (STATIC_CRT)
 256                 SET(CRT_FLAG_DEBUG "/MTd")
 257                 SET(CRT_FLAG_RELEASE "/MT")
 258         ELSE()
 259                 SET(CRT_FLAG_DEBUG "/MDd")
 260                 SET(CRT_FLAG_RELEASE "/MD")
 261         ENDIF()
 262
 263         # /Zi - Create debugging information
 264         # /Od - Disable optimization
 265         # /D_DEBUG - #define _DEBUG
 266         # /MTd - Statically link the multithreaded debug version of the CRT
 267         # /MDd - Dynamically link the multithreaded debug version of the CRT
 268         # /RTC1 - Run time checks
 269         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 270
 271         # /DNDEBUG - Disables asserts
 272         # /MT - Statically link the multithreaded release version of the CRT
 273         # /MD - Dynamically link the multithreaded release version of the CRT
 274         # /O2 - Optimize for speed
 275         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 276         # /GL - Link time code generation (whole program optimization)
 277         # /Gy - Function-level linking
 278         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 279
 280         # /Oy- - Disable frame pointer omission (FPO)
 281         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 282
 283         # /O1 - Optimize for size
 284         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 285
 286         # /DYNAMICBASE - Address space load randomization (ASLR)
 287         # /NXCOMPAT - Data execution prevention (DEP)
 288         # /LARGEADDRESSAWARE - >2GB user address space on x86
 289         # /VERSION - Embed version information in PE header
 290         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 291
 292         # /DEBUG - Create a PDB
 293         # /LTCG - Link time code generation (whole program optimization)
 294         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 295         # /INCREMENTAL:NO - Required to use /LTCG
 296         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 297         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 298         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 299         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 300         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 301
 302         # Same linker settings for DLL as EXE
 303         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 304         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 305         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 306         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 307         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 308
 309         SET(WIN_RC "src/win32/git2.rc")
 310
 311    # Precompiled headers
 312
 313 ELSE ()
 314         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 315
 316         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 317                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 318         ENDIF()
 319
 320         IF (WIN32 AND NOT CYGWIN)
 321                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 322         ENDIF ()
 323
 324         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 325                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 326                 # MinGW >= 3.14 uses the C99-style stdio functions
 327                 # automatically, but forks like mingw-w64 still want
 328                 # us to define this in order to use them
 329                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 330
 331         ELSEIF (BUILD_SHARED_LIBS)
 332                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 333
 334                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 335         ENDIF ()
 336
 337         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 338         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 339         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 340         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 341         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 342         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 343
 344         IF (APPLE) # Apple deprecated OpenSSL
 345                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 346         ENDIF()
 347
 348         IF (PROFILE)
 349                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 350                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 351         ENDIF ()
 352 ENDIF()
 353
 354 IF( NOT CMAKE_CONFIGURATION_TYPES )
 355         # Build Debug by default
 356         IF (NOT CMAKE_BUILD_TYPE)
 357                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 358         ENDIF ()
 359 ELSE()
 360         # Using a multi-configuration generator eg MSVC or Xcode
 361         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 362 ENDIF()
 363
 364 IF (OPENSSL_FOUND)
 365   ADD_DEFINITIONS(-DGIT_SSL)
 366   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 367   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 368 ENDIF()
 369
 370 IF (THREADSAFE)
 371         IF (NOT WIN32)
 372                 FIND_PACKAGE(Threads REQUIRED)
 373         ENDIF()
 374
 375         ADD_DEFINITIONS(-DGIT_THREADS)
 376 ENDIF()
 377
 378 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 379
 380 # Collect sourcefiles
 381 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 382
 383 # On Windows use specific platform sources
 384 IF (WIN32 AND NOT CYGWIN)
 385         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 386         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 387 ELSEIF (AMIGA)
 388         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 389 ELSE()
 390         IF (VALGRIND)
 391                 ADD_DEFINITIONS(-DNO_MMAP)
 392         ENDIF()
 393         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 394 ENDIF()
 395 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 396
 397 # Determine architecture of the machine
 398 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 399         ADD_DEFINITIONS(-DGIT_ARCH_64)
 400 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 401         ADD_DEFINITIONS(-DGIT_ARCH_32)
 402 ELSE()
 403         MESSAGE(FATAL_ERROR "Unsupported architecture")
 404 ENDIF()
 405
 406 # Compile and link libgit2
 407 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 408 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 409 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 410 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 411 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 412 TARGET_OS_LIBRARIES(git2)
 413
 414 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 415 # Win64+MSVC+static libs = linker error
 416 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 417   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 418 ENDIF()
 419
 420 MSVC_SPLIT_SOURCES(git2)
 421
 422 IF (SONAME)
 423         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 424         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 425         IF (LIBGIT2_FILENAME)
 426                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 427                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 428         ENDIF()
 429 ENDIF()
 430 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 431
 432 IF (MSVC_IDE)
 433    # Precompiled headers
 434    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 435    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 436 ENDIF ()
 437
 438 # Install
 439 INSTALL(TARGETS git2
 440         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 441         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 442         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 443 )
 444 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 445 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 446 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 447
 448 # Tests
 449 IF (BUILD_CLAR)
 450         FIND_PACKAGE(PythonInterp REQUIRED)
 451
 452         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 453         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 454         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 455         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 456         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 457
 458         INCLUDE_DIRECTORIES(${CLAR_PATH})
 459         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 460         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar.c")
 461
 462         ADD_CUSTOM_COMMAND(
 463                 OUTPUT ${CLAR_PATH}/clar.suite
 464                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 465                 DEPENDS ${SRC_TEST}
 466                 WORKING_DIRECTORY ${CLAR_PATH}
 467         )
 468
 469         SET_SOURCE_FILES_PROPERTIES(
 470                 ${CLAR_PATH}/clar.c
 471                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 472
 473         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 474
 475         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 476         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 477         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 478         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 479         TARGET_OS_LIBRARIES(libgit2_clar)
 480         MSVC_SPLIT_SOURCES(libgit2_clar)
 481
 482         IF (MSVC_IDE)
 483                 # Precompiled headers
 484                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 485         ENDIF ()
 486
 487         ENABLE_TESTING()
 488         ADD_TEST(libgit2_clar libgit2_clar -ionline)
 489 ENDIF ()
 490
 491 IF (TAGS)
 492         FIND_PROGRAM(CTAGS ctags)
 493         IF (NOT CTAGS)
 494                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 495         ENDIF ()
 496
 497         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 498
 499         ADD_CUSTOM_COMMAND(
 500                 OUTPUT tags
 501                 COMMAND ${CTAGS} -a ${SRC_ALL}
 502                 DEPENDS ${SRC_ALL}
 503         )
 504         ADD_CUSTOM_TARGET(
 505                 do_tags ALL
 506                 DEPENDS tags
 507         )
 508 ENDIF ()
 509
 510 IF (BUILD_EXAMPLES)
 511         ADD_SUBDIRECTORY(examples)
 512 ENDIF ()