CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(CheckStructHasMember)
  24 INCLUDE(AddCFlagIfSupported)
  25 INCLUDE(FindPkgConfig)
  26
  27 # Build options
  28 #
  29 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  30 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  31 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  32 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  33 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  34 OPTION( TAGS                            "Generate tags"                                                 OFF )
  35 OPTION( PROFILE                         "Generate profiling information"                OFF )
  36 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  37 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  38
  39 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  40 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  41 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  42 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  43 OPTION( CURL                    "Use curl for HTTP if available" ON)
  44 OPTION( DEBUG_POOL                      "Enable debug pool allocator"                   OFF )
  45
  46 IF(DEBUG_POOL)
  47         ADD_DEFINITIONS(-DGIT_DEBUG_POOL)
  48 ENDIF()
  49
  50 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  51         SET( USE_ICONV ON )
  52         FIND_PACKAGE(Security)
  53         FIND_PACKAGE(CoreFoundation REQUIRED)
  54 ENDIF()
  55
  56 IF(MSVC)
  57         # This option is only available when building with MSVC. By default, libgit2
  58         # is build using the cdecl calling convention, which is useful if you're
  59         # writing C. However, the CLR and Win32 API both expect stdcall.
  60         #
  61         # If you are writing a CLR program and want to link to libgit2, you'll want
  62         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  63         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  64
  65         # This option must match the settings used in your program, in particular if you
  66         # are linking statically
  67         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  68
  69         # If you want to embed a copy of libssh2 into libgit2, pass a
  70         # path to libssh2
  71         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  72
  73         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  74         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  75         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  76 ENDIF()
  77
  78
  79 IF(WIN32)
  80         # By default, libgit2 is built with WinHTTP.  To use the built-in
  81         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  82         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  83 ENDIF()
  84
  85 IF(MSVC)
  86         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  87         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  88 ENDIF()
  89
  90 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  91         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  92 ENDIF()
  93
  94 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtim "sys/types.h;sys/stat.h"
  95         HAVE_STRUCT_STAT_ST_MTIM LANGUAGE C)
  96 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtimespec "sys/types.h;sys/stat.h"
  97         HAVE_STRUCT_STAT_ST_MTIMESPEC LANGUAGE C)
  98 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_nsec sys/stat.h
  99         HAVE_STRUCT_STAT_MTIME_NSEC LANGUAGE C)
 100
 101 IF (HAVE_STRUCT_STAT_ST_MTIM)
 102         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 103                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 104 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 105         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 106                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 107 ELSE ()
 108         SET( HAVE_STRUCT_STAT_NSEC ON )
 109 ENDIF()
 110
 111 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 112         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  ON  )
 113 ENDIF()
 114
 115 # This variable will contain the libraries we need to put into
 116 # libgit2.pc's Requires.private. That is, what we're linking to or
 117 # what someone who's statically linking us needs to link to.
 118 SET(LIBGIT2_PC_REQUIRES "")
 119 # This will be set later if we use the system's http-parser library or
 120 # use iconv (OSX) and will be written to the Libs.private field in the
 121 # pc file.
 122 SET(LIBGIT2_PC_LIBS "")
 123
 124 # Installation paths
 125 #
 126 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 127 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 128 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 129
 130 # Set a couple variables to be substituted inside the .pc file.
 131 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 132 # or relative paths is both valid and supported by cmake.
 133 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 134
 135 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 136   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 137 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 138   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 139 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 140
 141 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 142   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 143 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 144   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 145 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 146
 147 FUNCTION(TARGET_OS_LIBRARIES target)
 148         IF(WIN32)
 149                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 150         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 151                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 152                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 153                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 154         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Haiku")
 155                 TARGET_LINK_LIBRARIES(${target} network)
 156                 LIST(APPEND LIBGIT2_PC_LIBS "-lnetwork")
 157                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 158         ENDIF()
 159         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 160         IF(NEED_LIBRT)
 161                 TARGET_LINK_LIBRARIES(${target} rt)
 162                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 163                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 164         ENDIF()
 165
 166         IF(THREADSAFE)
 167                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 168                 LIST(APPEND LIBGIT2_PC_LIBS ${CMAKE_THREAD_LIBS_INIT})
 169                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 170         ENDIF()
 171 ENDFUNCTION()
 172
 173 # This function splits the sources files up into their appropriate
 174 # subdirectories.  This is especially useful for IDEs like Xcode and
 175 # Visual Studio, so that you can navigate into the libgit2_clar project,
 176 # and see the folders within the tests folder (instead of just seeing all
 177 # source and tests in a single folder.)
 178 FUNCTION(IDE_SPLIT_SOURCES target)
 179         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 180                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 181                 FOREACH(source ${sources})
 182                         IF(source MATCHES ".*/")
 183                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 184                                 IF(rel)
 185                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 186                                         IF(rel)
 187                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 188                                                 SOURCE_GROUP(${rel} FILES ${source})
 189                                         ENDIF()
 190                                 ENDIF()
 191                         ENDIF()
 192                 ENDFOREACH()
 193         ENDIF()
 194 ENDFUNCTION()
 195
 196 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 197
 198 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 199 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 200 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 201 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 202
 203 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 204 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 205
 206 # Find required dependencies
 207 INCLUDE_DIRECTORIES(src include)
 208
 209 IF (SECURITY_FOUND)
 210   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 211   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 212   IF (HAVE_NEWER_SECURITY)
 213     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 214     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 215   ELSE()
 216     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 217     SET(SECURITY_FOUND "NO")
 218     SET(SECURITY_DIRS "")
 219     SET(SECURITY_DIR "")
 220     SET(USE_OPENSSL "ON")
 221   ENDIF()
 222 ENDIF()
 223
 224 IF (COREFOUNDATION_FOUND)
 225   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 226   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 227 ENDIF()
 228
 229
 230 IF (WIN32 AND EMBED_SSH_PATH)
 231         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 232         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 233         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 234         ADD_DEFINITIONS(-DGIT_SSH)
 235 ENDIF()
 236
 237 IF (WIN32 AND WINHTTP)
 238         ADD_DEFINITIONS(-DGIT_WINHTTP)
 239         INCLUDE_DIRECTORIES(deps/http-parser)
 240         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 241
 242         # Since MinGW does not come with headers or an import library for winhttp,
 243         # we have to include a private header and generate our own import library
 244         IF (MINGW)
 245                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 246                 IF (NOT DLLTOOL)
 247                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 248                 ENDIF ()
 249
 250                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 251                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 252
 253                 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 254                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 255                 ELSE()
 256                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 257                 ENDIF()
 258
 259                 ADD_CUSTOM_COMMAND(
 260                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 261                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 262                         DEPENDS ${WINHTTP_DEF}
 263                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 264                 )
 265
 266                 SET_SOURCE_FILES_PROPERTIES(
 267                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 268                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 269                 )
 270
 271                 INCLUDE_DIRECTORIES(deps/winhttp)
 272                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 273         ENDIF ()
 274
 275         LINK_LIBRARIES(winhttp rpcrt4 crypt32 ole32)
 276         LIST(APPEND LIBGIT2_PC_LIBS "-lwinhttp" "-lrpcrt4" "-lcrypt32" "-lole32")
 277 ELSE ()
 278         IF (CURL)
 279                 PKG_CHECK_MODULES(CURL libcurl)
 280         ENDIF ()
 281
 282         IF (NOT AMIGA AND USE_OPENSSL)
 283                 FIND_PACKAGE(OpenSSL)
 284         ENDIF ()
 285
 286         IF (CURL_FOUND)
 287                 ADD_DEFINITIONS(-DGIT_CURL)
 288                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 289                 LINK_LIBRARIES(${CURL_LIBRARIES})
 290                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 291         ENDIF()
 292
 293         FIND_PACKAGE(HTTP_Parser)
 294         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 295                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 296                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 297                 LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 298         ELSE()
 299                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 300                 INCLUDE_DIRECTORIES(deps/http-parser)
 301                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 302         ENDIF()
 303 ENDIF()
 304
 305 # Specify sha1 implementation
 306 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 307         ADD_DEFINITIONS(-DWIN32_SHA1)
 308         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 309 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 310         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 311 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 312         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 313         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 314                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 315         ELSE()
 316                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 317         ENDIF ()
 318 ELSE()
 319         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 320 ENDIF()
 321
 322 # Enable tracing
 323 IF (ENABLE_TRACE STREQUAL "ON")
 324         ADD_DEFINITIONS(-DGIT_TRACE)
 325 ENDIF()
 326
 327 # Include POSIX regex when it is required
 328 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 329         INCLUDE_DIRECTORIES(deps/regex)
 330         SET(SRC_REGEX deps/regex/regex.c)
 331 ENDIF()
 332
 333 # Optional external dependency: zlib
 334 FIND_PACKAGE(ZLIB)
 335 IF (ZLIB_FOUND)
 336         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 337         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 338         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 339                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 340         ELSE()
 341                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 342         ENDIF()
 343 ELSE()
 344         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 345         INCLUDE_DIRECTORIES(deps/zlib)
 346         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 347         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 348 ENDIF()
 349
 350 # Optional external dependency: libssh2
 351 IF (USE_SSH)
 352         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 353 ENDIF()
 354 IF (LIBSSH2_FOUND)
 355         ADD_DEFINITIONS(-DGIT_SSH)
 356         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 357         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 358         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 359         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 360         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 361
 362         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 363         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 364                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 365         ENDIF()
 366 ELSE()
 367         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 368 ENDIF()
 369
 370 # Optional external dependency: libgssapi
 371 IF (USE_GSSAPI)
 372         FIND_PACKAGE(GSSAPI)
 373 ENDIF()
 374 IF (GSSAPI_FOUND)
 375         ADD_DEFINITIONS(-DGIT_GSSAPI)
 376 ENDIF()
 377
 378 # Optional external dependency: iconv
 379 IF (USE_ICONV)
 380         FIND_PACKAGE(Iconv)
 381 ENDIF()
 382 IF (ICONV_FOUND)
 383         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 384         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 385         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 386 ENDIF()
 387
 388 # Platform specific compilation flags
 389 IF (MSVC)
 390
 391         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 392
 393         # /GF - String pooling
 394         # /MP - Parallel build
 395         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 396
 397         IF (STDCALL)
 398                 # /Gz - stdcall calling convention
 399                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 400         ENDIF ()
 401
 402         IF (STATIC_CRT)
 403                 SET(CRT_FLAG_DEBUG "/MTd")
 404                 SET(CRT_FLAG_RELEASE "/MT")
 405         ELSE()
 406                 SET(CRT_FLAG_DEBUG "/MDd")
 407                 SET(CRT_FLAG_RELEASE "/MD")
 408         ENDIF()
 409
 410         IF (MSVC_CRTDBG)
 411                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 412                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 413         ENDIF()
 414
 415         # /Zi - Create debugging information
 416         # /Od - Disable optimization
 417         # /D_DEBUG - #define _DEBUG
 418         # /MTd - Statically link the multithreaded debug version of the CRT
 419         # /MDd - Dynamically link the multithreaded debug version of the CRT
 420         # /RTC1 - Run time checks
 421         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 422
 423         # /DNDEBUG - Disables asserts
 424         # /MT - Statically link the multithreaded release version of the CRT
 425         # /MD - Dynamically link the multithreaded release version of the CRT
 426         # /O2 - Optimize for speed
 427         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 428         # /GL - Link time code generation (whole program optimization)
 429         # /Gy - Function-level linking
 430         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 431
 432         # /Oy- - Disable frame pointer omission (FPO)
 433         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 434
 435         # /O1 - Optimize for size
 436         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 437
 438         # /DYNAMICBASE - Address space load randomization (ASLR)
 439         # /NXCOMPAT - Data execution prevention (DEP)
 440         # /LARGEADDRESSAWARE - >2GB user address space on x86
 441         # /VERSION - Embed version information in PE header
 442         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 443
 444         # /DEBUG - Create a PDB
 445         # /LTCG - Link time code generation (whole program optimization)
 446         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 447         # /INCREMENTAL:NO - Required to use /LTCG
 448         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 449         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 450         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 451         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 452         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 453
 454         # Same linker settings for DLL as EXE
 455         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 456         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 457         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 458         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 459         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 460
 461         SET(WIN_RC "src/win32/git2.rc")
 462
 463    # Precompiled headers
 464
 465 ELSE ()
 466         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 467
 468         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 469                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 470         ENDIF()
 471
 472         IF (WIN32 AND NOT CYGWIN)
 473                 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 474         ENDIF ()
 475
 476         IF (MINGW OR MSYS) # MinGW and MSYS always do PIC and complain if we tell them to
 477                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 478         ELSEIF (BUILD_SHARED_LIBS)
 479                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 480
 481                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 482         ENDIF ()
 483
 484         IF (MINGW)
 485                 # MinGW >= 3.14 uses the C99-style stdio functions
 486                 # automatically, but forks like mingw-w64 still want
 487                 # us to define this in order to use them
 488                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 489         ENDIF ()
 490
 491         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 492         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 493         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 494         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 495         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 496         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 497         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 498
 499         IF (APPLE) # Apple deprecated OpenSSL
 500                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 501         ENDIF()
 502
 503         IF (PROFILE)
 504                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 505                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 506         ENDIF ()
 507 ENDIF()
 508
 509 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 510 IF (HAVE_FUTIMENS)
 511         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 512 ENDIF ()
 513
 514 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 515 IF (HAVE_QSORT_R)
 516         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 517 ENDIF ()
 518
 519 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 520 IF (HAVE_QSORT_S)
 521         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 522 ENDIF ()
 523
 524 IF( NOT CMAKE_CONFIGURATION_TYPES )
 525         # Build Debug by default
 526         IF (NOT CMAKE_BUILD_TYPE)
 527                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 528         ENDIF ()
 529 ELSE()
 530         # Using a multi-configuration generator eg MSVC or Xcode
 531         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 532 ENDIF()
 533
 534 IF (SECURITY_FOUND)
 535   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 536   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 537 ENDIF ()
 538
 539 IF (OPENSSL_FOUND)
 540   ADD_DEFINITIONS(-DGIT_OPENSSL)
 541   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 542   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 543 ENDIF()
 544
 545
 546
 547 IF (THREADSAFE)
 548         IF (NOT WIN32)
 549                 FIND_PACKAGE(Threads REQUIRED)
 550         ENDIF()
 551
 552         ADD_DEFINITIONS(-DGIT_THREADS)
 553 ENDIF()
 554
 555 IF (USE_NSEC)
 556         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 557 ENDIF()
 558
 559 IF (HAVE_STRUCT_STAT_ST_MTIM)
 560         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIM)
 561 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 562         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIMESPEC)
 563 ELSEIF (HAVE_STRUCT_STAT_ST_MTIME_NSEC)
 564         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIME_NSEC)
 565 ENDIF()
 566
 567 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 568
 569 # Collect sourcefiles
 570 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 571
 572 # On Windows use specific platform sources
 573 IF (WIN32 AND NOT CYGWIN)
 574         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 575         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 576 ELSEIF (AMIGA)
 577         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 578 ELSE()
 579         IF (VALGRIND)
 580                 ADD_DEFINITIONS(-DNO_MMAP)
 581         ENDIF()
 582         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 583 ENDIF()
 584 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 585
 586 # Determine architecture of the machine
 587 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 588         ADD_DEFINITIONS(-DGIT_ARCH_64)
 589 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 590         ADD_DEFINITIONS(-DGIT_ARCH_32)
 591 ELSEIF (CMAKE_SIZEOF_VOID_P)
 592         MESSAGE(FATAL_ERROR "Unsupported architecture (pointer size is ${CMAKE_SIZEOF_VOID_P} bytes)")
 593 ELSE()
 594         MESSAGE(FATAL_ERROR "Unsupported architecture (CMAKE_SIZEOF_VOID_P is unset)")
 595 ENDIF()
 596
 597 # Compile and link libgit2
 598 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 599 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 600 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 601 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 602 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 603 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 604 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 605 TARGET_OS_LIBRARIES(git2)
 606
 607 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 608 # Win64+MSVC+static libs = linker error
 609 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 610   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 611 ENDIF()
 612
 613 IDE_SPLIT_SOURCES(git2)
 614
 615 IF (SONAME)
 616         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 617         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 618         IF (LIBGIT2_FILENAME)
 619                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 620                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 621         ELSEIF (DEFINED LIBGIT2_PREFIX)
 622                 SET_TARGET_PROPERTIES(git2 PROPERTIES PREFIX "${LIBGIT2_PREFIX}")
 623         ENDIF()
 624 ENDIF()
 625 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 626 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 627
 628 IF (MSVC_IDE)
 629    # Precompiled headers
 630    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 631    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 632 ENDIF ()
 633
 634 # Install
 635 INSTALL(TARGETS git2
 636         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 637         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 638         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 639 )
 640 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 641 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 642 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 643
 644 # Tests
 645 IF (BUILD_CLAR)
 646         FIND_PACKAGE(PythonInterp)
 647
 648         IF(NOT PYTHONINTERP_FOUND)
 649           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 650             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 651         ENDIF()
 652
 653         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 654         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 655         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 656         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 657         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 658         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 659
 660         INCLUDE_DIRECTORIES(${CLAR_PATH})
 661         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 662         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 663
 664         ADD_CUSTOM_COMMAND(
 665                 OUTPUT ${CLAR_PATH}/clar.suite
 666                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 667                 DEPENDS ${SRC_TEST}
 668                 WORKING_DIRECTORY ${CLAR_PATH}
 669         )
 670
 671         SET_SOURCE_FILES_PROPERTIES(
 672                 ${CLAR_PATH}/clar.c
 673                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 674
 675         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 676
 677         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 678         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 679         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 680         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 681         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 682         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 683         TARGET_OS_LIBRARIES(libgit2_clar)
 684         IDE_SPLIT_SOURCES(libgit2_clar)
 685
 686         IF (MSVC_IDE)
 687                 # Precompiled headers
 688                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 689         ENDIF ()
 690
 691         ENABLE_TESTING()
 692         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 693                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 694         ELSE ()
 695                 ADD_TEST(libgit2_clar libgit2_clar -v)
 696         ENDIF ()
 697
 698         # Add a test target which runs the cred callback tests, to be
 699         # called after setting the url and user
 700         ADD_TEST(libgit2_clar-cred_callback libgit2_clar -v -sonline::clone::cred_callback)
 701         ADD_TEST(libgit2_clar-proxy_credentials_in_url libgit2_clar -v -sonline::clone::proxy_credentials_in_url)
 702         ADD_TEST(libgit2_clar-proxy_credentials_request libgit2_clar -v -sonline::clone::proxy_credentials_request)
 703 ENDIF ()
 704
 705 IF (TAGS)
 706         FIND_PROGRAM(CTAGS ctags)
 707         IF (NOT CTAGS)
 708                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 709         ENDIF ()
 710
 711         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 712
 713         ADD_CUSTOM_COMMAND(
 714                 OUTPUT tags
 715                 COMMAND ${CTAGS} -a ${SRC_ALL}
 716                 DEPENDS ${SRC_ALL}
 717         )
 718         ADD_CUSTOM_TARGET(
 719                 do_tags ALL
 720                 DEPENDS tags
 721         )
 722 ENDIF ()
 723
 724 IF (BUILD_EXAMPLES)
 725         ADD_SUBDIRECTORY(examples)
 726 ENDIF ()