CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(AddCFlagIfSupported)
  24 INCLUDE(FindPkgConfig)
  25
  26 # Build options
  27 #
  28 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  29 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  30 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  31 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  32 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  33 OPTION( TAGS                            "Generate tags"                                                 OFF )
  34 OPTION( PROFILE                         "Generate profiling information"                OFF )
  35 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  36 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  37
  38 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  39 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  40 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  41 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  42 OPTION( CURL                    "User curl for HTTP if available" ON)
  43
  44 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  45         SET( USE_ICONV ON )
  46         FIND_PACKAGE(Security)
  47         FIND_PACKAGE(CoreFoundation REQUIRED)
  48 ENDIF()
  49
  50 IF(MSVC)
  51         # This option is only available when building with MSVC. By default, libgit2
  52         # is build using the cdecl calling convention, which is useful if you're
  53         # writing C. However, the CLR and Win32 API both expect stdcall.
  54         #
  55         # If you are writing a CLR program and want to link to libgit2, you'll want
  56         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  57         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  58
  59         # This option must match the settings used in your program, in particular if you
  60         # are linking statically
  61         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  62
  63         # If you want to embed a copy of libssh2 into libgit2, pass a
  64         # path to libssh2
  65         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  66
  67         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  68         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  69         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  70 ENDIF()
  71
  72
  73 IF(WIN32)
  74         # By default, libgit2 is built with WinHTTP.  To use the built-in
  75         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  76         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  77 ENDIF()
  78
  79 IF(MSVC)
  80         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  81         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  82 ENDIF()
  83
  84 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  85         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  86 ENDIF()
  87
  88 # This variable will contain the libraries we need to put into
  89 # libgit2.pc's Requires.private. That is, what we're linking to or
  90 # what someone who's statically linking us needs to link to.
  91 SET(LIBGIT2_PC_REQUIRES "")
  92 # This will be set later if we use the system's http-parser library or
  93 # use iconv (OSX) and will be written to the Libs.private field in the
  94 # pc file.
  95 SET(LIBGIT2_PC_LIBS "")
  96
  97 # Installation paths
  98 #
  99 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 100 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 101 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 102
 103 # Set a couple variables to be substituted inside the .pc file.
 104 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 105 # or relative paths is both valid and supported by cmake.
 106 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 107
 108 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 109   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 110 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 111   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 112 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 113
 114 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 115   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 116 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 117   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 118 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 119
 120 FUNCTION(TARGET_OS_LIBRARIES target)
 121         IF(WIN32)
 122                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 123         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 124                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 125                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 126                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 127         ENDIF()
 128         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 129         IF(NEED_LIBRT)
 130                 TARGET_LINK_LIBRARIES(${target} rt)
 131                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 132                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 133         ENDIF()
 134
 135         IF(THREADSAFE)
 136                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 137         ENDIF()
 138 ENDFUNCTION()
 139
 140 # This function splits the sources files up into their appropriate
 141 # subdirectories.  This is especially useful for IDEs like Xcode and
 142 # Visual Studio, so that you can navigate into the libgit2_clar project,
 143 # and see the folders within the tests folder (instead of just seeing all
 144 # source and tests in a single folder.)
 145 FUNCTION(IDE_SPLIT_SOURCES target)
 146         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 147                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 148                 FOREACH(source ${sources})
 149                         IF(source MATCHES ".*/")
 150                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 151                                 IF(rel)
 152                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 153                                         IF(rel)
 154                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 155                                                 SOURCE_GROUP(${rel} FILES ${source})
 156                                         ENDIF()
 157                                 ENDIF()
 158                         ENDIF()
 159                 ENDFOREACH()
 160         ENDIF()
 161 ENDFUNCTION()
 162
 163 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 164
 165 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 166 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 167 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 168 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 169
 170 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 171 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 172
 173 # Find required dependencies
 174 INCLUDE_DIRECTORIES(src include)
 175
 176 IF (SECURITY_FOUND)
 177   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 178   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 179   IF (HAVE_NEWER_SECURITY)
 180     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 181     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 182   ELSE()
 183     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 184     SET(SECURITY_FOUND "NO")
 185     SET(SECURITY_DIRS "")
 186     SET(SECURITY_DIR "")
 187     SET(USE_OPENSSL "ON")
 188   ENDIF()
 189 ENDIF()
 190
 191 IF (COREFOUNDATION_FOUND)
 192   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 193   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 194 ENDIF()
 195
 196
 197 IF (WIN32 AND EMBED_SSH_PATH)
 198         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 199         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 200         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 201         ADD_DEFINITIONS(-DGIT_SSH)
 202 ENDIF()
 203
 204 IF (WIN32 AND WINHTTP)
 205         ADD_DEFINITIONS(-DGIT_WINHTTP)
 206         INCLUDE_DIRECTORIES(deps/http-parser)
 207         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 208
 209         # Since MinGW does not come with headers or an import library for winhttp,
 210         # we have to include a private header and generate our own import library
 211         IF (MINGW)
 212                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 213                 IF (NOT DLLTOOL)
 214                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 215                 ENDIF ()
 216
 217                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 218                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 219
 220                 IF ("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
 221                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 222                 ELSE()
 223                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 224                 ENDIF()
 225
 226                 ADD_CUSTOM_COMMAND(
 227                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 228                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 229                         DEPENDS ${WINHTTP_DEF}
 230                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 231                 )
 232
 233                 SET_SOURCE_FILES_PROPERTIES(
 234                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 235                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 236                 )
 237
 238                 INCLUDE_DIRECTORIES(deps/winhttp)
 239                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 240         ENDIF ()
 241
 242         LINK_LIBRARIES(winhttp rpcrt4 crypt32)
 243 ELSE ()
 244         IF (CURL)
 245                 PKG_CHECK_MODULES(CURL libcurl)
 246         ENDIF ()
 247
 248         IF (NOT AMIGA AND USE_OPENSSL)
 249                 FIND_PACKAGE(OpenSSL)
 250         ENDIF ()
 251
 252         IF (CURL_FOUND)
 253                 ADD_DEFINITIONS(-DGIT_CURL)
 254                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 255                 LINK_LIBRARIES(${CURL_LIBRARIES})
 256                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 257         ENDIF()
 258
 259         FIND_PACKAGE(HTTP_Parser)
 260         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 261                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 262                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 263                 LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 264         ELSE()
 265                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 266                 INCLUDE_DIRECTORIES(deps/http-parser)
 267                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 268         ENDIF()
 269 ENDIF()
 270
 271 # Specify sha1 implementation
 272 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 273         ADD_DEFINITIONS(-DWIN32_SHA1)
 274         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 275 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 276         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 277 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 278         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 279         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 280                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 281         ELSE()
 282                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 283         ENDIF ()
 284 ELSE()
 285         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 286 ENDIF()
 287
 288 # Enable tracing
 289 IF (ENABLE_TRACE STREQUAL "ON")
 290         ADD_DEFINITIONS(-DGIT_TRACE)
 291 ENDIF()
 292
 293 # Include POSIX regex when it is required
 294 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 295         INCLUDE_DIRECTORIES(deps/regex)
 296         SET(SRC_REGEX deps/regex/regex.c)
 297 ENDIF()
 298
 299 # Optional external dependency: zlib
 300 FIND_PACKAGE(ZLIB)
 301 IF (ZLIB_FOUND)
 302         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 303         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 304         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 305                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 306         ELSE()
 307                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 308         ENDIF()
 309 ELSE()
 310         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 311         INCLUDE_DIRECTORIES(deps/zlib)
 312         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 313         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 314 ENDIF()
 315
 316 # Optional external dependency: libssh2
 317 IF (USE_SSH)
 318         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 319 ENDIF()
 320 IF (LIBSSH2_FOUND)
 321         ADD_DEFINITIONS(-DGIT_SSH)
 322         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 323         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 324         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 325         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 326         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 327
 328         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 329         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 330                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 331         ENDIF()
 332 ELSE()
 333         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 334 ENDIF()
 335
 336 # Optional external dependency: libgssapi
 337 IF (USE_GSSAPI)
 338         FIND_PACKAGE(GSSAPI)
 339 ENDIF()
 340 IF (GSSAPI_FOUND)
 341         ADD_DEFINITIONS(-DGIT_GSSAPI)
 342 ENDIF()
 343
 344 # Optional external dependency: iconv
 345 IF (USE_ICONV)
 346         FIND_PACKAGE(Iconv)
 347 ENDIF()
 348 IF (ICONV_FOUND)
 349         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 350         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 351         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 352 ENDIF()
 353
 354 # Platform specific compilation flags
 355 IF (MSVC)
 356
 357         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 358
 359         # /GF - String pooling
 360         # /MP - Parallel build
 361         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 362
 363         IF (STDCALL)
 364                 # /Gz - stdcall calling convention
 365                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 366         ENDIF ()
 367
 368         IF (STATIC_CRT)
 369                 SET(CRT_FLAG_DEBUG "/MTd")
 370                 SET(CRT_FLAG_RELEASE "/MT")
 371         ELSE()
 372                 SET(CRT_FLAG_DEBUG "/MDd")
 373                 SET(CRT_FLAG_RELEASE "/MD")
 374         ENDIF()
 375
 376         IF (MSVC_CRTDBG)
 377                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 378                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 379         ENDIF()
 380
 381         # /Zi - Create debugging information
 382         # /Od - Disable optimization
 383         # /D_DEBUG - #define _DEBUG
 384         # /MTd - Statically link the multithreaded debug version of the CRT
 385         # /MDd - Dynamically link the multithreaded debug version of the CRT
 386         # /RTC1 - Run time checks
 387         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 388
 389         # /DNDEBUG - Disables asserts
 390         # /MT - Statically link the multithreaded release version of the CRT
 391         # /MD - Dynamically link the multithreaded release version of the CRT
 392         # /O2 - Optimize for speed
 393         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 394         # /GL - Link time code generation (whole program optimization)
 395         # /Gy - Function-level linking
 396         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 397
 398         # /Oy- - Disable frame pointer omission (FPO)
 399         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 400
 401         # /O1 - Optimize for size
 402         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 403
 404         # /DYNAMICBASE - Address space load randomization (ASLR)
 405         # /NXCOMPAT - Data execution prevention (DEP)
 406         # /LARGEADDRESSAWARE - >2GB user address space on x86
 407         # /VERSION - Embed version information in PE header
 408         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 409
 410         # /DEBUG - Create a PDB
 411         # /LTCG - Link time code generation (whole program optimization)
 412         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 413         # /INCREMENTAL:NO - Required to use /LTCG
 414         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 415         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 416         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 417         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 418         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 419
 420         # Same linker settings for DLL as EXE
 421         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 422         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 423         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 424         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 425         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 426
 427         SET(WIN_RC "src/win32/git2.rc")
 428
 429    # Precompiled headers
 430
 431 ELSE ()
 432         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 433
 434         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 435                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 436         ENDIF()
 437
 438         IF (WIN32 AND NOT CYGWIN)
 439                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 440         ENDIF ()
 441
 442         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 443                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 444                 # MinGW >= 3.14 uses the C99-style stdio functions
 445                 # automatically, but forks like mingw-w64 still want
 446                 # us to define this in order to use them
 447                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 448
 449         ELSEIF (BUILD_SHARED_LIBS)
 450                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 451
 452                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 453         ENDIF ()
 454
 455         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 456         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 457         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 458         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 459         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 460         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 461         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 462
 463         IF (APPLE) # Apple deprecated OpenSSL
 464                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 465         ENDIF()
 466
 467         IF (PROFILE)
 468                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 469                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 470         ENDIF ()
 471 ENDIF()
 472
 473 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 474 IF (HAVE_FUTIMENS)
 475         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 476 ENDIF ()
 477
 478 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 479 IF (HAVE_QSORT_R)
 480         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 481 ENDIF ()
 482
 483 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 484 IF (HAVE_QSORT_S)
 485         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 486 ENDIF ()
 487
 488 IF( NOT CMAKE_CONFIGURATION_TYPES )
 489         # Build Debug by default
 490         IF (NOT CMAKE_BUILD_TYPE)
 491                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 492         ENDIF ()
 493 ELSE()
 494         # Using a multi-configuration generator eg MSVC or Xcode
 495         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 496 ENDIF()
 497
 498 IF (SECURITY_FOUND)
 499   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 500   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 501 ENDIF ()
 502
 503 IF (OPENSSL_FOUND)
 504   ADD_DEFINITIONS(-DGIT_OPENSSL)
 505   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 506   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 507 ENDIF()
 508
 509
 510
 511 IF (THREADSAFE)
 512         IF (NOT WIN32)
 513                 FIND_PACKAGE(Threads REQUIRED)
 514         ENDIF()
 515
 516         ADD_DEFINITIONS(-DGIT_THREADS)
 517 ENDIF()
 518
 519 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 520
 521 # Collect sourcefiles
 522 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 523
 524 # On Windows use specific platform sources
 525 IF (WIN32 AND NOT CYGWIN)
 526         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 527         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 528 ELSEIF (AMIGA)
 529         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 530 ELSE()
 531         IF (VALGRIND)
 532                 ADD_DEFINITIONS(-DNO_MMAP)
 533         ENDIF()
 534         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 535 ENDIF()
 536 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 537
 538 # Determine architecture of the machine
 539 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 540         ADD_DEFINITIONS(-DGIT_ARCH_64)
 541 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 542         ADD_DEFINITIONS(-DGIT_ARCH_32)
 543 ELSE()
 544         MESSAGE(FATAL_ERROR "Unsupported architecture")
 545 ENDIF()
 546
 547 # Compile and link libgit2
 548 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 549 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 550 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 551 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 552 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 553 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 554 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 555 TARGET_OS_LIBRARIES(git2)
 556
 557 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 558 # Win64+MSVC+static libs = linker error
 559 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 560   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 561 ENDIF()
 562
 563 IDE_SPLIT_SOURCES(git2)
 564
 565 IF (SONAME)
 566         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 567         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 568         IF (LIBGIT2_FILENAME)
 569                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 570                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 571         ENDIF()
 572 ENDIF()
 573 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 574 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 575
 576 IF (MSVC_IDE)
 577    # Precompiled headers
 578    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 579    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 580 ENDIF ()
 581
 582 # Install
 583 INSTALL(TARGETS git2
 584         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 585         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 586         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 587 )
 588 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 589 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 590 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 591
 592 # Tests
 593 IF (BUILD_CLAR)
 594         FIND_PACKAGE(PythonInterp)
 595
 596         IF(NOT PYTHONINTERP_FOUND)
 597           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 598             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 599         ENDIF()
 600
 601         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 602         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 603         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 604         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 605         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 606         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 607
 608         INCLUDE_DIRECTORIES(${CLAR_PATH})
 609         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 610         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 611
 612         ADD_CUSTOM_COMMAND(
 613                 OUTPUT ${CLAR_PATH}/clar.suite
 614                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 615                 DEPENDS ${SRC_TEST}
 616                 WORKING_DIRECTORY ${CLAR_PATH}
 617         )
 618
 619         SET_SOURCE_FILES_PROPERTIES(
 620                 ${CLAR_PATH}/clar.c
 621                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 622
 623         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 624
 625         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 626         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 627         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 628         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 629         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 630         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 631         TARGET_OS_LIBRARIES(libgit2_clar)
 632         IDE_SPLIT_SOURCES(libgit2_clar)
 633
 634         IF (MSVC_IDE)
 635                 # Precompiled headers
 636                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 637         ENDIF ()
 638
 639         ENABLE_TESTING()
 640         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 641                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 642         ELSE ()
 643                 ADD_TEST(libgit2_clar libgit2_clar -v)
 644         ENDIF ()
 645 ENDIF ()
 646
 647 IF (TAGS)
 648         FIND_PROGRAM(CTAGS ctags)
 649         IF (NOT CTAGS)
 650                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 651         ENDIF ()
 652
 653         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 654
 655         ADD_CUSTOM_COMMAND(
 656                 OUTPUT tags
 657                 COMMAND ${CTAGS} -a ${SRC_ALL}
 658                 DEPENDS ${SRC_ALL}
 659         )
 660         ADD_CUSTOM_TARGET(
 661                 do_tags ALL
 662                 DEPENDS tags
 663         )
 664 ENDIF ()
 665
 666 IF (BUILD_EXAMPLES)
 667         ADD_SUBDIRECTORY(examples)
 668 ENDIF ()