CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(CheckStructHasMember)
  24 INCLUDE(AddCFlagIfSupported)
  25 INCLUDE(FindPkgConfig)
  26
  27 # Build options
  28 #
  29 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  30 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  31 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  32 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  33 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  34 OPTION( TAGS                            "Generate tags"                                                 OFF )
  35 OPTION( PROFILE                         "Generate profiling information"                OFF )
  36 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  37 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  38
  39 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  40 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  41 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  42 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  43 OPTION( CURL                    "User curl for HTTP if available" ON)
  44
  45 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  46         SET( USE_ICONV ON )
  47         FIND_PACKAGE(Security)
  48         FIND_PACKAGE(CoreFoundation REQUIRED)
  49 ENDIF()
  50
  51 IF(MSVC)
  52         # This option is only available when building with MSVC. By default, libgit2
  53         # is build using the cdecl calling convention, which is useful if you're
  54         # writing C. However, the CLR and Win32 API both expect stdcall.
  55         #
  56         # If you are writing a CLR program and want to link to libgit2, you'll want
  57         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  58         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  59
  60         # This option must match the settings used in your program, in particular if you
  61         # are linking statically
  62         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  63
  64         # If you want to embed a copy of libssh2 into libgit2, pass a
  65         # path to libssh2
  66         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  67
  68         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  69         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  70         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  71 ENDIF()
  72
  73
  74 IF(WIN32)
  75         # By default, libgit2 is built with WinHTTP.  To use the built-in
  76         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  77         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  78 ENDIF()
  79
  80 IF(MSVC)
  81         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  82         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  83 ENDIF()
  84
  85 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  86         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  87 ENDIF()
  88
  89 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_atim "sys/types.h;sys/stat.h"
  90         HAVE_STRUCT_STAT_ST_ATIM LANGUAGE C)
  91 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_atimespec "sys/types.h;sys/stat.h"
  92         HAVE_STRUCT_STAT_ST_ATIMESPEC LANGUAGE C)
  93
  94 IF (HAVE_STRUCT_STAT_ST_ATIM)
  95         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
  96                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
  97 ELSEIF (HAVE_STRUCT_STAT_ST_ATIMESPEC)
  98         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
  99                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 100 ENDIF()
 101
 102 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 103         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  OFF )
 104 ENDIF()
 105
 106 # This variable will contain the libraries we need to put into
 107 # libgit2.pc's Requires.private. That is, what we're linking to or
 108 # what someone who's statically linking us needs to link to.
 109 SET(LIBGIT2_PC_REQUIRES "")
 110 # This will be set later if we use the system's http-parser library or
 111 # use iconv (OSX) and will be written to the Libs.private field in the
 112 # pc file.
 113 SET(LIBGIT2_PC_LIBS "")
 114
 115 # Installation paths
 116 #
 117 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 118 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 119 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 120
 121 # Set a couple variables to be substituted inside the .pc file.
 122 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 123 # or relative paths is both valid and supported by cmake.
 124 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 125
 126 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 127   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 128 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 129   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 130 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 131
 132 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 133   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 134 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 135   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 136 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 137
 138 FUNCTION(TARGET_OS_LIBRARIES target)
 139         IF(WIN32)
 140                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 141         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 142                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 143                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 144                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 145         ENDIF()
 146         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 147         IF(NEED_LIBRT)
 148                 TARGET_LINK_LIBRARIES(${target} rt)
 149                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 150                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 151         ENDIF()
 152
 153         IF(THREADSAFE)
 154                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 155         ENDIF()
 156 ENDFUNCTION()
 157
 158 # This function splits the sources files up into their appropriate
 159 # subdirectories.  This is especially useful for IDEs like Xcode and
 160 # Visual Studio, so that you can navigate into the libgit2_clar project,
 161 # and see the folders within the tests folder (instead of just seeing all
 162 # source and tests in a single folder.)
 163 FUNCTION(IDE_SPLIT_SOURCES target)
 164         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 165                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 166                 FOREACH(source ${sources})
 167                         IF(source MATCHES ".*/")
 168                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 169                                 IF(rel)
 170                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 171                                         IF(rel)
 172                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 173                                                 SOURCE_GROUP(${rel} FILES ${source})
 174                                         ENDIF()
 175                                 ENDIF()
 176                         ENDIF()
 177                 ENDFOREACH()
 178         ENDIF()
 179 ENDFUNCTION()
 180
 181 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 182
 183 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 184 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 185 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 186 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 187
 188 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 189 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 190
 191 # Find required dependencies
 192 INCLUDE_DIRECTORIES(src include)
 193
 194 IF (SECURITY_FOUND)
 195   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 196   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 197   IF (HAVE_NEWER_SECURITY)
 198     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 199     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 200   ELSE()
 201     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 202     SET(SECURITY_FOUND "NO")
 203     SET(SECURITY_DIRS "")
 204     SET(SECURITY_DIR "")
 205     SET(USE_OPENSSL "ON")
 206   ENDIF()
 207 ENDIF()
 208
 209 IF (COREFOUNDATION_FOUND)
 210   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 211   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 212 ENDIF()
 213
 214
 215 IF (WIN32 AND EMBED_SSH_PATH)
 216         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 217         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 218         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 219         ADD_DEFINITIONS(-DGIT_SSH)
 220 ENDIF()
 221
 222 IF (WIN32 AND WINHTTP)
 223         ADD_DEFINITIONS(-DGIT_WINHTTP)
 224         INCLUDE_DIRECTORIES(deps/http-parser)
 225         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 226
 227         # Since MinGW does not come with headers or an import library for winhttp,
 228         # we have to include a private header and generate our own import library
 229         IF (MINGW)
 230                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 231                 IF (NOT DLLTOOL)
 232                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 233                 ENDIF ()
 234
 235                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 236                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 237
 238                 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 239                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 240                 ELSE()
 241                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 242                 ENDIF()
 243
 244                 ADD_CUSTOM_COMMAND(
 245                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 246                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 247                         DEPENDS ${WINHTTP_DEF}
 248                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 249                 )
 250
 251                 SET_SOURCE_FILES_PROPERTIES(
 252                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 253                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 254                 )
 255
 256                 INCLUDE_DIRECTORIES(deps/winhttp)
 257                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 258         ENDIF ()
 259
 260         LINK_LIBRARIES(winhttp rpcrt4 crypt32)
 261 ELSE ()
 262         IF (CURL)
 263                 PKG_CHECK_MODULES(CURL libcurl)
 264         ENDIF ()
 265
 266         IF (NOT AMIGA AND USE_OPENSSL)
 267                 FIND_PACKAGE(OpenSSL)
 268         ENDIF ()
 269
 270         IF (CURL_FOUND)
 271                 ADD_DEFINITIONS(-DGIT_CURL)
 272                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 273                 LINK_LIBRARIES(${CURL_LIBRARIES})
 274                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 275         ENDIF()
 276
 277         FIND_PACKAGE(HTTP_Parser)
 278         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 279                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 280                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 281                 LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 282         ELSE()
 283                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 284                 INCLUDE_DIRECTORIES(deps/http-parser)
 285                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 286         ENDIF()
 287 ENDIF()
 288
 289 # Specify sha1 implementation
 290 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 291         ADD_DEFINITIONS(-DWIN32_SHA1)
 292         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 293 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 294         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 295 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 296         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 297         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 298                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 299         ELSE()
 300                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 301         ENDIF ()
 302 ELSE()
 303         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 304 ENDIF()
 305
 306 # Enable tracing
 307 IF (ENABLE_TRACE STREQUAL "ON")
 308         ADD_DEFINITIONS(-DGIT_TRACE)
 309 ENDIF()
 310
 311 # Include POSIX regex when it is required
 312 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 313         INCLUDE_DIRECTORIES(deps/regex)
 314         SET(SRC_REGEX deps/regex/regex.c)
 315 ENDIF()
 316
 317 # Optional external dependency: zlib
 318 FIND_PACKAGE(ZLIB)
 319 IF (ZLIB_FOUND)
 320         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 321         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 322         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 323                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 324         ELSE()
 325                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 326         ENDIF()
 327 ELSE()
 328         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 329         INCLUDE_DIRECTORIES(deps/zlib)
 330         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 331         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 332 ENDIF()
 333
 334 # Optional external dependency: libssh2
 335 IF (USE_SSH)
 336         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 337 ENDIF()
 338 IF (LIBSSH2_FOUND)
 339         ADD_DEFINITIONS(-DGIT_SSH)
 340         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 341         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 342         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 343         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 344         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 345
 346         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 347         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 348                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 349         ENDIF()
 350 ELSE()
 351         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 352 ENDIF()
 353
 354 # Optional external dependency: libgssapi
 355 IF (USE_GSSAPI)
 356         FIND_PACKAGE(GSSAPI)
 357 ENDIF()
 358 IF (GSSAPI_FOUND)
 359         ADD_DEFINITIONS(-DGIT_GSSAPI)
 360 ENDIF()
 361
 362 # Optional external dependency: iconv
 363 IF (USE_ICONV)
 364         FIND_PACKAGE(Iconv)
 365 ENDIF()
 366 IF (ICONV_FOUND)
 367         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 368         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 369         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 370 ENDIF()
 371
 372 # Platform specific compilation flags
 373 IF (MSVC)
 374
 375         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 376
 377         # /GF - String pooling
 378         # /MP - Parallel build
 379         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 380
 381         IF (STDCALL)
 382                 # /Gz - stdcall calling convention
 383                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 384         ENDIF ()
 385
 386         IF (STATIC_CRT)
 387                 SET(CRT_FLAG_DEBUG "/MTd")
 388                 SET(CRT_FLAG_RELEASE "/MT")
 389         ELSE()
 390                 SET(CRT_FLAG_DEBUG "/MDd")
 391                 SET(CRT_FLAG_RELEASE "/MD")
 392         ENDIF()
 393
 394         IF (MSVC_CRTDBG)
 395                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 396                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 397         ENDIF()
 398
 399         # /Zi - Create debugging information
 400         # /Od - Disable optimization
 401         # /D_DEBUG - #define _DEBUG
 402         # /MTd - Statically link the multithreaded debug version of the CRT
 403         # /MDd - Dynamically link the multithreaded debug version of the CRT
 404         # /RTC1 - Run time checks
 405         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 406
 407         # /DNDEBUG - Disables asserts
 408         # /MT - Statically link the multithreaded release version of the CRT
 409         # /MD - Dynamically link the multithreaded release version of the CRT
 410         # /O2 - Optimize for speed
 411         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 412         # /GL - Link time code generation (whole program optimization)
 413         # /Gy - Function-level linking
 414         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 415
 416         # /Oy- - Disable frame pointer omission (FPO)
 417         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 418
 419         # /O1 - Optimize for size
 420         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 421
 422         # /DYNAMICBASE - Address space load randomization (ASLR)
 423         # /NXCOMPAT - Data execution prevention (DEP)
 424         # /LARGEADDRESSAWARE - >2GB user address space on x86
 425         # /VERSION - Embed version information in PE header
 426         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 427
 428         # /DEBUG - Create a PDB
 429         # /LTCG - Link time code generation (whole program optimization)
 430         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 431         # /INCREMENTAL:NO - Required to use /LTCG
 432         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 433         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 434         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 435         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 436         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 437
 438         # Same linker settings for DLL as EXE
 439         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 440         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 441         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 442         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 443         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 444
 445         SET(WIN_RC "src/win32/git2.rc")
 446
 447    # Precompiled headers
 448
 449 ELSE ()
 450         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 451
 452         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 453                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 454         ENDIF()
 455
 456         IF (WIN32 AND NOT CYGWIN)
 457                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 458         ENDIF ()
 459
 460         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 461                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 462                 # MinGW >= 3.14 uses the C99-style stdio functions
 463                 # automatically, but forks like mingw-w64 still want
 464                 # us to define this in order to use them
 465                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 466
 467         ELSEIF (BUILD_SHARED_LIBS)
 468                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 469
 470                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 471         ENDIF ()
 472
 473         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 474         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 475         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 476         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 477         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 478         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 479         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 480
 481         IF (APPLE) # Apple deprecated OpenSSL
 482                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 483         ENDIF()
 484
 485         IF (PROFILE)
 486                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 487                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 488         ENDIF ()
 489 ENDIF()
 490
 491 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 492 IF (HAVE_FUTIMENS)
 493         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 494 ENDIF ()
 495
 496 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 497 IF (HAVE_QSORT_R)
 498         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 499 ENDIF ()
 500
 501 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 502 IF (HAVE_QSORT_S)
 503         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 504 ENDIF ()
 505
 506 IF( NOT CMAKE_CONFIGURATION_TYPES )
 507         # Build Debug by default
 508         IF (NOT CMAKE_BUILD_TYPE)
 509                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 510         ENDIF ()
 511 ELSE()
 512         # Using a multi-configuration generator eg MSVC or Xcode
 513         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 514 ENDIF()
 515
 516 IF (SECURITY_FOUND)
 517   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 518   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 519 ENDIF ()
 520
 521 IF (OPENSSL_FOUND)
 522   ADD_DEFINITIONS(-DGIT_OPENSSL)
 523   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 524   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 525 ENDIF()
 526
 527
 528
 529 IF (THREADSAFE)
 530         IF (NOT WIN32)
 531                 FIND_PACKAGE(Threads REQUIRED)
 532         ENDIF()
 533
 534         ADD_DEFINITIONS(-DGIT_THREADS)
 535 ENDIF()
 536
 537 IF (USE_NSEC)
 538         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 539 ENDIF()
 540
 541 IF (HAVE_STRUCT_STAT_ST_ATIMESPEC)
 542         ADD_DEFINITIONS(-DGIT_USE_STAT_ATIMESPEC)
 543 ENDIF()
 544
 545 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 546
 547 # Collect sourcefiles
 548 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 549
 550 # On Windows use specific platform sources
 551 IF (WIN32 AND NOT CYGWIN)
 552         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 553         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 554 ELSEIF (AMIGA)
 555         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 556 ELSE()
 557         IF (VALGRIND)
 558                 ADD_DEFINITIONS(-DNO_MMAP)
 559         ENDIF()
 560         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 561 ENDIF()
 562 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 563
 564 # Determine architecture of the machine
 565 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 566         ADD_DEFINITIONS(-DGIT_ARCH_64)
 567 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 568         ADD_DEFINITIONS(-DGIT_ARCH_32)
 569 ELSE()
 570         MESSAGE(FATAL_ERROR "Unsupported architecture")
 571 ENDIF()
 572
 573 # Compile and link libgit2
 574 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 575 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 576 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 577 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 578 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 579 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 580 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 581 TARGET_OS_LIBRARIES(git2)
 582
 583 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 584 # Win64+MSVC+static libs = linker error
 585 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 586   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 587 ENDIF()
 588
 589 IDE_SPLIT_SOURCES(git2)
 590
 591 IF (SONAME)
 592         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 593         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 594         IF (LIBGIT2_FILENAME)
 595                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 596                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 597         ENDIF()
 598 ENDIF()
 599 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 600 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 601
 602 IF (MSVC_IDE)
 603    # Precompiled headers
 604    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 605    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 606 ENDIF ()
 607
 608 # Install
 609 INSTALL(TARGETS git2
 610         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 611         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 612         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 613 )
 614 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 615 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 616 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 617
 618 # Tests
 619 IF (BUILD_CLAR)
 620         FIND_PACKAGE(PythonInterp)
 621
 622         IF(NOT PYTHONINTERP_FOUND)
 623           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 624             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 625         ENDIF()
 626
 627         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 628         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 629         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 630         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 631         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 632         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 633
 634         INCLUDE_DIRECTORIES(${CLAR_PATH})
 635         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 636         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 637
 638         ADD_CUSTOM_COMMAND(
 639                 OUTPUT ${CLAR_PATH}/clar.suite
 640                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 641                 DEPENDS ${SRC_TEST}
 642                 WORKING_DIRECTORY ${CLAR_PATH}
 643         )
 644
 645         SET_SOURCE_FILES_PROPERTIES(
 646                 ${CLAR_PATH}/clar.c
 647                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 648
 649         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 650
 651         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 652         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 653         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 654         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 655         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 656         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 657         TARGET_OS_LIBRARIES(libgit2_clar)
 658         IDE_SPLIT_SOURCES(libgit2_clar)
 659
 660         IF (MSVC_IDE)
 661                 # Precompiled headers
 662                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 663         ENDIF ()
 664
 665         ENABLE_TESTING()
 666         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 667                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 668         ELSE ()
 669                 ADD_TEST(libgit2_clar libgit2_clar -v)
 670         ENDIF ()
 671 ENDIF ()
 672
 673 IF (TAGS)
 674         FIND_PROGRAM(CTAGS ctags)
 675         IF (NOT CTAGS)
 676                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 677         ENDIF ()
 678
 679         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 680
 681         ADD_CUSTOM_COMMAND(
 682                 OUTPUT tags
 683                 COMMAND ${CTAGS} -a ${SRC_ALL}
 684                 DEPENDS ${SRC_ALL}
 685         )
 686         ADD_CUSTOM_TARGET(
 687                 do_tags ALL
 688                 DEPENDS tags
 689         )
 690 ENDIF ()
 691
 692 IF (BUILD_EXAMPLES)
 693         ADD_SUBDIRECTORY(examples)
 694 ENDIF ()