CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  16
  17 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
  18
  19 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
  20 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
  21 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
  22 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
  23
  24 IF (AMIGA)
  25         # Default AmigaOS to use the PowerPC SHA1
  26         SET(SHA1_TYPE "ppc")
  27 ENDIF()
  28
  29 # Find required dependencies
  30 INCLUDE_DIRECTORIES(src include deps/http-parser)
  31
  32 FILE(GLOB SRC_HTTP deps/http-parser/*.c)
  33
  34 # Specify sha1 implementation
  35 IF (SHA1_TYPE STREQUAL "ppc")
  36         ADD_DEFINITIONS(-DPPC_SHA1)
  37         FILE(GLOB SRC_SHA1 src/ppc/*.c src/ppc/*.S)
  38 ELSE ()
  39         SET (SRC_SHA1)
  40 ENDIF()
  41
  42 IF (NOT WIN32)
  43         FIND_PACKAGE(ZLIB)
  44         IF (CMAKE_SYSTEM_NAME STREQUAL "AmigaOS")
  45                 INCLUDE_DIRECTORIES(deps/regex)
  46                 SET(SRC_REGEX deps/regex/regex.c)
  47         ENDIF()
  48 ELSE()
  49         # Windows doesn't understand POSIX regex on its own
  50         INCLUDE_DIRECTORIES(deps/regex)
  51         SET(SRC_REGEX deps/regex/regex.c)
  52 ENDIF()
  53
  54 IF (ZLIB_FOUND)
  55         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
  56         LINK_LIBRARIES(${ZLIB_LIBRARIES})
  57 ELSE (ZLIB_FOUND)
  58         INCLUDE_DIRECTORIES(deps/zlib)
  59         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
  60         FILE(GLOB SRC_ZLIB deps/zlib/*.c)
  61 ENDIF()
  62
  63 # Installation paths
  64 SET(INSTALL_BIN bin CACHE PATH "Where to install binaries to.")
  65 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
  66 SET(INSTALL_INC include CACHE PATH "Where to install headers to.")
  67
  68 # Build options
  69 OPTION (BUILD_SHARED_LIBS "Build Shared Library (OFF for Static)" ON)
  70 OPTION (THREADSAFE "Build libgit2 as threadsafe" OFF)
  71 OPTION (BUILD_CLAR "Build Tests using the Clar suite" ON)
  72 OPTION (BUILD_EXAMPLES "Build library usage example apps" OFF)
  73 OPTION (TAGS "Generate tags" OFF)
  74 OPTION (PROFILE "Generate profiling information" OFF)
  75
  76 # Platform specific compilation flags
  77 IF (MSVC)
  78         # Not using __stdcall with the CRT causes problems
  79         OPTION (STDCALL "Buildl libgit2 with the __stdcall convention" ON)
  80
  81         SET(CMAKE_C_FLAGS "/W4 /MP /nologo /Zi ${CMAKE_C_FLAGS}")
  82         IF (STDCALL)
  83           SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
  84         ENDIF ()
  85         SET(CMAKE_C_FLAGS_DEBUG "/Od /DEBUG /MTd /RTC1 /RTCs /RTCu")
  86         SET(CMAKE_C_FLAGS_RELEASE "/MT /O2")
  87         SET(WIN_RC "src/win32/git2.rc")
  88
  89    # Precompiled headers
  90 ELSE ()
  91         SET(CMAKE_C_FLAGS "-O2 -g -D_GNU_SOURCE -Wall -Wextra -Wno-missing-field-initializers -Wstrict-aliasing=2 -Wstrict-prototypes -Wmissing-prototypes ${CMAKE_C_FLAGS}")
  92         SET(CMAKE_C_FLAGS_DEBUG "-O0 -g")
  93         IF (MINGW) # MinGW always does PIC and complains if we tell it to
  94                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
  95         ELSE ()
  96                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fPIC")
  97         ENDIF ()
  98         IF (PROFILE)
  99                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 100                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 101         ENDIF ()
 102 ENDIF()
 103
 104 # Build Debug by default
 105 IF (NOT CMAKE_BUILD_TYPE)
 106         SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 107 ENDIF ()
 108
 109 FIND_PACKAGE(OpenSSL)
 110 IF (OPENSSL_FOUND)
 111   ADD_DEFINITIONS(-DGIT_SSL)
 112   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 113   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 114 ENDIF()
 115
 116 IF (THREADSAFE)
 117         IF (NOT WIN32)
 118                 find_package(Threads REQUIRED)
 119         ENDIF()
 120
 121         ADD_DEFINITIONS(-DGIT_THREADS)
 122 ENDIF()
 123
 124 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 125
 126 # Collect sourcefiles
 127 FILE(GLOB SRC_H include/git2/*.h)
 128
 129 # On Windows use specific platform sources
 130 IF (WIN32 AND NOT CYGWIN)
 131         ADD_DEFINITIONS(-DWIN32 -D_DEBUG -D_WIN32_WINNT=0x0501)
 132         FILE(GLOB SRC src/*.c src/transports/*.c src/xdiff/*.c src/win32/*.c src/compat/*.c)
 133 ELSEIF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 134         FILE(GLOB SRC src/*.c src/transports/*.c src/xdiff/*.c src/unix/*.c src/compat/*.c)
 135 ELSEIF (AMIGA)
 136         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R)
 137         FILE(GLOB SRC src/*.c src/transports/*.c src/xdiff/*.c src/amiga/*.c src/compat/*.c)
 138 ELSE()
 139         FILE(GLOB SRC src/*.c src/transports/*.c src/xdiff/*.c src/unix/*.c)
 140 ENDIF ()
 141
 142 # Compile and link libgit2
 143 ADD_LIBRARY(git2 ${SRC} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1} ${WIN_RC})
 144
 145 IF (WIN32)
 146         TARGET_LINK_LIBRARIES(git2 ws2_32)
 147 ELSEIF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 148         TARGET_LINK_LIBRARIES(git2 socket nsl)
 149 ENDIF ()
 150
 151 TARGET_LINK_LIBRARIES(git2 ${CMAKE_THREAD_LIBS_INIT} ${SSL_LIBRARIES})
 152 SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 153 SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_VERSION_MAJOR})
 154 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 155
 156 IF (MSVC)
 157    # Precompiled headers
 158    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 159    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 160 ENDIF ()
 161
 162 # Backward compatibility with INSTALL_LIB variable
 163 if (INSTALL_LIB)
 164         set(LIB_INSTALL_DIR "${INSTALL_LIB}")
 165 ENDIF()
 166
 167 # Install
 168 INSTALL(TARGETS git2
 169         RUNTIME DESTINATION ${INSTALL_BIN}
 170         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 171         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 172 )
 173 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 174 INSTALL(DIRECTORY include/git2 DESTINATION ${INSTALL_INC} )
 175 INSTALL(FILES include/git2.h DESTINATION ${INSTALL_INC} )
 176
 177 # Tests
 178 IF (BUILD_CLAR)
 179
 180         FIND_PACKAGE(PythonInterp REQUIRED)
 181
 182         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests-clar/resources/")
 183         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests-clar")
 184         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests-clar/resources" CACHE PATH "Path to test resources.")
 185         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 186         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 187
 188         INCLUDE_DIRECTORIES(${CLAR_PATH})
 189         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/clar_helpers.c ${CLAR_PATH}/testlib.c)
 190
 191         ADD_CUSTOM_COMMAND(
 192                 OUTPUT ${CLAR_PATH}/clar_main.c ${CLAR_PATH}/clar.h
 193                 COMMAND ${PYTHON_EXECUTABLE} clar -vtap .
 194                 DEPENDS ${CLAR_PATH}/clar ${SRC_TEST}
 195                 WORKING_DIRECTORY ${CLAR_PATH}
 196         )
 197         ADD_EXECUTABLE(libgit2_clar ${SRC} ${CLAR_PATH}/clar_main.c ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX})
 198         TARGET_LINK_LIBRARIES(libgit2_clar ${CMAKE_THREAD_LIBS_INIT} ${SSL_LIBRARIES})
 199
 200         IF (MSVC)
 201            # Precompiled headers
 202            SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 203         ENDIF ()
 204
 205         IF (WIN32)
 206                 TARGET_LINK_LIBRARIES(libgit2_clar ws2_32)
 207         ELSEIF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 208                 TARGET_LINK_LIBRARIES(libgit2_clar socket nsl)
 209         ENDIF ()
 210
 211         ENABLE_TESTING()
 212         ADD_TEST(libgit2_clar libgit2_clar)
 213 ENDIF ()
 214
 215 IF (TAGS)
 216         FIND_PROGRAM(CTAGS ctags)
 217         IF (NOT CTAGS)
 218                 message(FATAL_ERROR "Could not find ctags command")
 219         ENDIF ()
 220
 221         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 222
 223         ADD_CUSTOM_COMMAND(
 224                 OUTPUT tags
 225                 COMMAND ${CTAGS} -a ${SRC_ALL}
 226                 DEPENDS ${SRC_ALL}
 227         )
 228         ADD_CUSTOM_TARGET(
 229                 do_tags ALL
 230                 DEPENDS tags
 231         )
 232 ENDIF ()
 233
 234 IF (BUILD_EXAMPLES)
 235         FILE(GLOB_RECURSE EXAMPLE_SRC examples/network/*.c)
 236         ADD_EXECUTABLE(cgit2 ${EXAMPLE_SRC})
 237         TARGET_LINK_LIBRARIES(cgit2 git2 pthread)
 238
 239         ADD_EXECUTABLE(git-diff examples/diff.c)
 240         TARGET_LINK_LIBRARIES(git-diff git2)
 241
 242         ADD_EXECUTABLE(git-general examples/general.c)
 243         TARGET_LINK_LIBRARIES(git-general git2)
 244
 245         ADD_EXECUTABLE(git-showindex examples/showindex.c)
 246         TARGET_LINK_LIBRARIES(git-showindex git2)
 247 ENDIF ()