CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckStructHasMember)
  23 INCLUDE(AddCFlagIfSupported)
  24 INCLUDE(FindPkgConfig)
  25
  26 # Build options
  27 #
  28 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  29 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  30 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  31 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  32 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  33 OPTION( TAGS                            "Generate tags"                                                 OFF )
  34 OPTION( PROFILE                         "Generate profiling information"                OFF )
  35 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  36 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  37
  38 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  39 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  40 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  41 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  42 OPTION( CURL                    "User curl for HTTP if available" ON)
  43
  44 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  45         SET( USE_ICONV ON )
  46         FIND_PACKAGE(Security)
  47         FIND_PACKAGE(CoreFoundation REQUIRED)
  48 ENDIF()
  49
  50 IF(MSVC)
  51         # This option is only available when building with MSVC. By default, libgit2
  52         # is build using the cdecl calling convention, which is useful if you're
  53         # writing C. However, the CLR and Win32 API both expect stdcall.
  54         #
  55         # If you are writing a CLR program and want to link to libgit2, you'll want
  56         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  57         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  58
  59         # This option must match the settings used in your program, in particular if you
  60         # are linking statically
  61         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  62
  63         # If you want to embed a copy of libssh2 into libgit2, pass a
  64         # path to libssh2
  65         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  66
  67         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  68         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  69         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  70 ENDIF()
  71
  72
  73 IF(WIN32)
  74         # By default, libgit2 is built with WinHTTP.  To use the built-in
  75         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  76         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  77 ENDIF()
  78
  79 IF(MSVC)
  80         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  81         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  82 ENDIF()
  83
  84 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  85         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  86 ENDIF()
  87
  88 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
  89         HAVE_STRUCT_STAT_NSEC LANGUAGE C)
  90 IF(HAVE_STRUCT_STAT_NSEC)
  91         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  OFF )
  92 ENDIF()
  93
  94 # This variable will contain the libraries we need to put into
  95 # libgit2.pc's Requires.private. That is, what we're linking to or
  96 # what someone who's statically linking us needs to link to.
  97 SET(LIBGIT2_PC_REQUIRES "")
  98 # This will be set later if we use the system's http-parser library or
  99 # use iconv (OSX) and will be written to the Libs.private field in the
 100 # pc file.
 101 SET(LIBGIT2_PC_LIBS "")
 102
 103 # Installation paths
 104 #
 105 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 106 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 107 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 108
 109 # Set a couple variables to be substituted inside the .pc file.
 110 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 111 # or relative paths is both valid and supported by cmake.
 112 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 113
 114 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 115   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 116 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 117   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 118 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 119
 120 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 121   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 122 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 123   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 124 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 125
 126 FUNCTION(TARGET_OS_LIBRARIES target)
 127         IF(WIN32)
 128                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 129         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 130                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 131                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 132                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 133         ENDIF()
 134         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 135         IF(NEED_LIBRT)
 136                 TARGET_LINK_LIBRARIES(${target} rt)
 137                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 138                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 139         ENDIF()
 140
 141         IF(THREADSAFE)
 142                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 143         ENDIF()
 144 ENDFUNCTION()
 145
 146 # For the MSVC IDE, this function splits up the source files like windows
 147 # explorer does. This is esp. useful with the libgit2_clar project, were
 148 # usually 2 or more files share the same name.  Sadly, this file grouping
 149 # is a per-directory option in cmake and not per-target, resulting in
 150 # empty virtual folders "tests" for the git2.dll
 151 FUNCTION(MSVC_SPLIT_SOURCES target)
 152         IF(MSVC_IDE)
 153                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 154                 FOREACH(source ${sources})
 155                         IF(source MATCHES ".*/")
 156                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 157                                 IF(rel)
 158                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 159                                         IF(rel)
 160                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 161                                                 SOURCE_GROUP(${rel} FILES ${source})
 162                                         ENDIF()
 163                                 ENDIF()
 164                         ENDIF()
 165                 ENDFOREACH()
 166         ENDIF()
 167 ENDFUNCTION()
 168
 169 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 170
 171 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 172 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 173 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 174 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 175
 176 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 177 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 178
 179 # Find required dependencies
 180 INCLUDE_DIRECTORIES(src include)
 181
 182 IF (SECURITY_FOUND)
 183   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 184   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 185   IF (HAVE_NEWER_SECURITY)
 186     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 187     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 188   ELSE()
 189     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 190     SET(SECURITY_FOUND "NO")
 191     SET(SECURITY_DIRS "")
 192     SET(SECURITY_DIR "")
 193     SET(USE_OPENSSL "ON")
 194   ENDIF()
 195 ENDIF()
 196
 197 IF (COREFOUNDATION_FOUND)
 198   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 199   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 200 ENDIF()
 201
 202
 203 IF (WIN32 AND EMBED_SSH_PATH)
 204         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 205         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 206         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 207         ADD_DEFINITIONS(-DGIT_SSH)
 208 ENDIF()
 209
 210 IF (WIN32 AND WINHTTP)
 211         ADD_DEFINITIONS(-DGIT_WINHTTP)
 212         INCLUDE_DIRECTORIES(deps/http-parser)
 213         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 214
 215         # Since MinGW does not come with headers or an import library for winhttp,
 216         # we have to include a private header and generate our own import library
 217         IF (MINGW)
 218                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 219                 IF (NOT DLLTOOL)
 220                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 221                 ENDIF ()
 222
 223                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 224                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 225
 226                 IF ("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
 227                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 228                 ELSE()
 229                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 230                 ENDIF()
 231
 232                 ADD_CUSTOM_COMMAND(
 233                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 234                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 235                         DEPENDS ${WINHTTP_DEF}
 236                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 237                 )
 238
 239                 SET_SOURCE_FILES_PROPERTIES(
 240                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 241                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 242                 )
 243
 244                 INCLUDE_DIRECTORIES(deps/winhttp)
 245                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 246         ENDIF ()
 247
 248         LINK_LIBRARIES(winhttp rpcrt4 crypt32)
 249 ELSE ()
 250         IF (CURL)
 251                 PKG_CHECK_MODULES(CURL libcurl)
 252         ENDIF ()
 253
 254         IF (NOT AMIGA AND USE_OPENSSL)
 255                 FIND_PACKAGE(OpenSSL)
 256         ENDIF ()
 257
 258         IF (CURL_FOUND)
 259                 ADD_DEFINITIONS(-DGIT_CURL)
 260                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 261                 LINK_LIBRARIES(${CURL_LIBRARIES})
 262                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 263         ENDIF()
 264
 265         FIND_PACKAGE(HTTP_Parser)
 266         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 267                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 268                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 269                 LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 270         ELSE()
 271                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 272                 INCLUDE_DIRECTORIES(deps/http-parser)
 273                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 274         ENDIF()
 275 ENDIF()
 276
 277 # Specify sha1 implementation
 278 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 279         ADD_DEFINITIONS(-DWIN32_SHA1)
 280         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 281 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 282         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 283 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 284         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 285         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 286                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 287         ELSE()
 288                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 289         ENDIF ()
 290 ELSE()
 291         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 292 ENDIF()
 293
 294 # Enable tracing
 295 IF (ENABLE_TRACE STREQUAL "ON")
 296         ADD_DEFINITIONS(-DGIT_TRACE)
 297 ENDIF()
 298
 299 # Include POSIX regex when it is required
 300 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 301         INCLUDE_DIRECTORIES(deps/regex)
 302         SET(SRC_REGEX deps/regex/regex.c)
 303 ENDIF()
 304
 305 # Optional external dependency: zlib
 306 FIND_PACKAGE(ZLIB)
 307 IF (ZLIB_FOUND)
 308         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 309         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 310         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 311                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 312         ELSE()
 313                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 314         ENDIF()
 315 ELSE()
 316         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 317         INCLUDE_DIRECTORIES(deps/zlib)
 318         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 319         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 320 ENDIF()
 321
 322 # Optional external dependency: libssh2
 323 IF (USE_SSH)
 324         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 325 ENDIF()
 326 IF (LIBSSH2_FOUND)
 327         ADD_DEFINITIONS(-DGIT_SSH)
 328         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 329         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 330         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 331         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 332         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 333
 334         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 335         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 336                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 337         ENDIF()
 338 ELSE()
 339         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 340 ENDIF()
 341
 342 # Optional external dependency: libgssapi
 343 IF (USE_GSSAPI)
 344         FIND_PACKAGE(GSSAPI)
 345 ENDIF()
 346 IF (GSSAPI_FOUND)
 347         ADD_DEFINITIONS(-DGIT_GSSAPI)
 348 ENDIF()
 349
 350 # Optional external dependency: iconv
 351 IF (USE_ICONV)
 352         FIND_PACKAGE(Iconv)
 353 ENDIF()
 354 IF (ICONV_FOUND)
 355         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 356         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 357         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 358 ENDIF()
 359
 360 # Platform specific compilation flags
 361 IF (MSVC)
 362
 363         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 364
 365         # /GF - String pooling
 366         # /MP - Parallel build
 367         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 368
 369         IF (STDCALL)
 370                 # /Gz - stdcall calling convention
 371                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 372         ENDIF ()
 373
 374         IF (STATIC_CRT)
 375                 SET(CRT_FLAG_DEBUG "/MTd")
 376                 SET(CRT_FLAG_RELEASE "/MT")
 377         ELSE()
 378                 SET(CRT_FLAG_DEBUG "/MDd")
 379                 SET(CRT_FLAG_RELEASE "/MD")
 380         ENDIF()
 381
 382         IF (MSVC_CRTDBG)
 383                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 384                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 385         ENDIF()
 386
 387         # /Zi - Create debugging information
 388         # /Od - Disable optimization
 389         # /D_DEBUG - #define _DEBUG
 390         # /MTd - Statically link the multithreaded debug version of the CRT
 391         # /MDd - Dynamically link the multithreaded debug version of the CRT
 392         # /RTC1 - Run time checks
 393         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 394
 395         # /DNDEBUG - Disables asserts
 396         # /MT - Statically link the multithreaded release version of the CRT
 397         # /MD - Dynamically link the multithreaded release version of the CRT
 398         # /O2 - Optimize for speed
 399         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 400         # /GL - Link time code generation (whole program optimization)
 401         # /Gy - Function-level linking
 402         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 403
 404         # /Oy- - Disable frame pointer omission (FPO)
 405         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 406
 407         # /O1 - Optimize for size
 408         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 409
 410         # /DYNAMICBASE - Address space load randomization (ASLR)
 411         # /NXCOMPAT - Data execution prevention (DEP)
 412         # /LARGEADDRESSAWARE - >2GB user address space on x86
 413         # /VERSION - Embed version information in PE header
 414         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 415
 416         # /DEBUG - Create a PDB
 417         # /LTCG - Link time code generation (whole program optimization)
 418         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 419         # /INCREMENTAL:NO - Required to use /LTCG
 420         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 421         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 422         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 423         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 424         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 425
 426         # Same linker settings for DLL as EXE
 427         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 428         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 429         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 430         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 431         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 432
 433         SET(WIN_RC "src/win32/git2.rc")
 434
 435    # Precompiled headers
 436
 437 ELSE ()
 438         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 439
 440         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 441                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 442         ENDIF()
 443
 444         IF (WIN32 AND NOT CYGWIN)
 445                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 446         ENDIF ()
 447
 448         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 449                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 450                 # MinGW >= 3.14 uses the C99-style stdio functions
 451                 # automatically, but forks like mingw-w64 still want
 452                 # us to define this in order to use them
 453                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 454
 455         ELSEIF (BUILD_SHARED_LIBS)
 456                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 457
 458                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 459         ENDIF ()
 460
 461         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 462         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 463         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 464         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 465         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 466         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 467         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 468
 469         IF (APPLE) # Apple deprecated OpenSSL
 470                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 471         ENDIF()
 472
 473         IF (PROFILE)
 474                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 475                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 476         ENDIF ()
 477 ENDIF()
 478
 479 IF( NOT CMAKE_CONFIGURATION_TYPES )
 480         # Build Debug by default
 481         IF (NOT CMAKE_BUILD_TYPE)
 482                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 483         ENDIF ()
 484 ELSE()
 485         # Using a multi-configuration generator eg MSVC or Xcode
 486         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 487 ENDIF()
 488
 489 IF (SECURITY_FOUND)
 490   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 491   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 492 ENDIF ()
 493
 494 IF (OPENSSL_FOUND)
 495   ADD_DEFINITIONS(-DGIT_OPENSSL)
 496   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 497   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 498 ENDIF()
 499
 500
 501
 502 IF (THREADSAFE)
 503         IF (NOT WIN32)
 504                 FIND_PACKAGE(Threads REQUIRED)
 505         ENDIF()
 506
 507         ADD_DEFINITIONS(-DGIT_THREADS)
 508 ENDIF()
 509
 510 IF (USE_NSEC)
 511         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 512 ENDIF()
 513
 514 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 515
 516 # Collect sourcefiles
 517 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 518
 519 # On Windows use specific platform sources
 520 IF (WIN32 AND NOT CYGWIN)
 521         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 522         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 523 ELSEIF (AMIGA)
 524         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 525 ELSE()
 526         IF (VALGRIND)
 527                 ADD_DEFINITIONS(-DNO_MMAP)
 528         ENDIF()
 529         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 530 ENDIF()
 531 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 532
 533 # Determine architecture of the machine
 534 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 535         ADD_DEFINITIONS(-DGIT_ARCH_64)
 536 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 537         ADD_DEFINITIONS(-DGIT_ARCH_32)
 538 ELSE()
 539         MESSAGE(FATAL_ERROR "Unsupported architecture")
 540 ENDIF()
 541
 542 # Compile and link libgit2
 543 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 544 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 545 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 546 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 547 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 548 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 549 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 550 TARGET_OS_LIBRARIES(git2)
 551
 552 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 553 # Win64+MSVC+static libs = linker error
 554 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 555   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 556 ENDIF()
 557
 558 MSVC_SPLIT_SOURCES(git2)
 559
 560 IF (SONAME)
 561         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 562         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 563         IF (LIBGIT2_FILENAME)
 564                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 565                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 566         ENDIF()
 567 ENDIF()
 568 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 569 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 570
 571 IF (MSVC_IDE)
 572    # Precompiled headers
 573    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 574    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 575 ENDIF ()
 576
 577 # Install
 578 INSTALL(TARGETS git2
 579         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 580         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 581         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 582 )
 583 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 584 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 585 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 586
 587 # Tests
 588 IF (BUILD_CLAR)
 589         FIND_PACKAGE(PythonInterp REQUIRED)
 590
 591         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 592         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 593         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 594         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 595         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 596         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 597
 598         INCLUDE_DIRECTORIES(${CLAR_PATH})
 599         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 600         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 601
 602         ADD_CUSTOM_COMMAND(
 603                 OUTPUT ${CLAR_PATH}/clar.suite
 604                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 605                 DEPENDS ${SRC_TEST}
 606                 WORKING_DIRECTORY ${CLAR_PATH}
 607         )
 608
 609         SET_SOURCE_FILES_PROPERTIES(
 610                 ${CLAR_PATH}/clar.c
 611                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 612
 613         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 614
 615         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 616         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 617         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 618         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 619         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 620         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 621         TARGET_OS_LIBRARIES(libgit2_clar)
 622         MSVC_SPLIT_SOURCES(libgit2_clar)
 623
 624         IF (MSVC_IDE)
 625                 # Precompiled headers
 626                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 627         ENDIF ()
 628
 629         ENABLE_TESTING()
 630         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 631                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 632         ELSE ()
 633                 ADD_TEST(libgit2_clar libgit2_clar -v)
 634         ENDIF ()
 635 ENDIF ()
 636
 637 IF (TAGS)
 638         FIND_PROGRAM(CTAGS ctags)
 639         IF (NOT CTAGS)
 640                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 641         ENDIF ()
 642
 643         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 644
 645         ADD_CUSTOM_COMMAND(
 646                 OUTPUT tags
 647                 COMMAND ${CTAGS} -a ${SRC_ALL}
 648                 DEPENDS ${SRC_ALL}
 649         )
 650         ADD_CUSTOM_TARGET(
 651                 do_tags ALL
 652                 DEPENDS tags
 653         )
 654 ENDIF ()
 655
 656 IF (BUILD_EXAMPLES)
 657         ADD_SUBDIRECTORY(examples)
 658 ENDIF ()