CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(AddCFlagIfSupported)
  23 INCLUDE(FindPkgConfig)
  24
  25 # Build options
  26 #
  27 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  28 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  29 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  30 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  31 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  32 OPTION( TAGS                            "Generate tags"                                                 OFF )
  33 OPTION( PROFILE                         "Generate profiling information"                OFF )
  34 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  35 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  36
  37 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  38 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  39 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  40 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  41
  42 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  43         SET( USE_ICONV ON )
  44         FIND_PACKAGE(Security)
  45         FIND_PACKAGE(CoreFoundation REQUIRED)
  46 ENDIF()
  47
  48 IF(MSVC)
  49         # This option is only available when building with MSVC. By default, libgit2
  50         # is build using the cdecl calling convention, which is useful if you're
  51         # writing C. However, the CLR and Win32 API both expect stdcall.
  52         #
  53         # If you are writing a CLR program and want to link to libgit2, you'll want
  54         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  55         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  56
  57         # This option must match the settings used in your program, in particular if you
  58         # are linking statically
  59         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  60
  61         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  62         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  63         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  64 ENDIF()
  65
  66
  67 IF(WIN32)
  68         # By default, libgit2 is built with WinHTTP.  To use the built-in
  69         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  70         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  71 ENDIF()
  72
  73 IF(MSVC)
  74         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  75         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  76 ENDIF()
  77
  78 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  79         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  80 ENDIF()
  81
  82 # This variable will contain the libraries we need to put into
  83 # libgit2.pc's Requires.private. That is, what we're linking to or
  84 # what someone who's statically linking us needs to link to.
  85 SET(LIBGIT2_PC_REQUIRES "")
  86 # This will be set later if we use the system's http-parser library or
  87 # use iconv (OSX) and will be written to the Libs.private field in the
  88 # pc file.
  89 SET(LIBGIT2_PC_LIBS "")
  90
  91 # Installation paths
  92 #
  93 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
  94 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
  95 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
  96
  97 FUNCTION(TARGET_OS_LIBRARIES target)
  98         IF(WIN32)
  99                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 100         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 101                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 102                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lsocket -lnsl" PARENT_SCOPE)
 103         ENDIF()
 104         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 105         IF(NEED_LIBRT)
 106                 TARGET_LINK_LIBRARIES(${target} rt)
 107                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lrt" PARENT_SCOPE)
 108         ENDIF()
 109
 110         IF(THREADSAFE)
 111                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 112         ENDIF()
 113 ENDFUNCTION()
 114
 115 # For the MSVC IDE, this function splits up the source files like windows
 116 # explorer does. This is esp. useful with the libgit2_clar project, were
 117 # usually 2 or more files share the same name.  Sadly, this file grouping
 118 # is a per-directory option in cmake and not per-target, resulting in
 119 # empty virtual folders "tests" for the git2.dll
 120 FUNCTION(MSVC_SPLIT_SOURCES target)
 121         IF(MSVC_IDE)
 122                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 123                 FOREACH(source ${sources})
 124                         IF(source MATCHES ".*/")
 125                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 126                                 IF(rel)
 127                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 128                                         IF(rel)
 129                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 130                                                 SOURCE_GROUP(${rel} FILES ${source})
 131                                         ENDIF()
 132                                 ENDIF()
 133                         ENDIF()
 134                 ENDFOREACH()
 135         ENDIF()
 136 ENDFUNCTION()
 137
 138 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 139
 140 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 141 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 142 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 143 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 144
 145 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 146 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 147
 148 # Find required dependencies
 149 INCLUDE_DIRECTORIES(src include)
 150
 151 IF (SECURITY_FOUND)
 152   MESSAGE("-- Found Security ${SECURITY_DIRS}")
 153   SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -framework Security")
 154 ENDIF()
 155
 156 IF (COREFOUNDATION_FOUND)
 157   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 158   SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -framework CoreFoundation")
 159 ENDIF()
 160
 161
 162 IF (WIN32 AND WINHTTP)
 163         ADD_DEFINITIONS(-DGIT_WINHTTP)
 164         INCLUDE_DIRECTORIES(deps/http-parser)
 165         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 166
 167         # Since MinGW does not come with headers or an import library for winhttp,
 168         # we have to include a private header and generate our own import library
 169         IF (MINGW)
 170                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 171                 IF (NOT DLLTOOL)
 172                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 173                 ENDIF ()
 174
 175                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 176                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 177
 178                 IF ("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
 179                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 180                 ELSE()
 181                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 182                 ENDIF()
 183
 184                 ADD_CUSTOM_COMMAND(
 185                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 186                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 187                         DEPENDS ${WINHTTP_DEF}
 188                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 189                 )
 190
 191                 SET_SOURCE_FILES_PROPERTIES(
 192                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 193                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 194                 )
 195
 196                 INCLUDE_DIRECTORIES(deps/winhttp)
 197                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 198         ENDIF ()
 199
 200         LINK_LIBRARIES(winhttp rpcrt4 crypt32)
 201 ELSE ()
 202         IF (NOT AMIGA AND USE_OPENSSL)
 203                 FIND_PACKAGE(OpenSSL)
 204         ENDIF ()
 205
 206         FIND_PACKAGE(HTTP_Parser)
 207         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 208                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 209                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 210                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lhttp_parser")
 211         ELSE()
 212                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 213                 INCLUDE_DIRECTORIES(deps/http-parser)
 214                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 215         ENDIF()
 216 ENDIF()
 217
 218 # Specify sha1 implementation
 219 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 220         ADD_DEFINITIONS(-DWIN32_SHA1)
 221         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 222 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 223         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 224 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 225         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 226         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 227                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lssl")
 228         ELSE()
 229                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 230         ENDIF ()
 231 ELSE()
 232         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 233 ENDIF()
 234
 235 # Enable tracing
 236 IF (ENABLE_TRACE STREQUAL "ON")
 237         ADD_DEFINITIONS(-DGIT_TRACE)
 238 ENDIF()
 239
 240 # Include POSIX regex when it is required
 241 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 242         INCLUDE_DIRECTORIES(deps/regex)
 243         SET(SRC_REGEX deps/regex/regex.c)
 244 ENDIF()
 245
 246 # Optional external dependency: zlib
 247 FIND_PACKAGE(ZLIB)
 248 IF (ZLIB_FOUND)
 249         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 250         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 251         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 252                 SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lz")
 253         ELSE()
 254                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 255         ENDIF()
 256 ELSE()
 257         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 258         INCLUDE_DIRECTORIES(deps/zlib)
 259         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 260         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 261 ENDIF()
 262
 263 # Optional external dependency: libssh2
 264 IF (USE_SSH)
 265         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 266 ENDIF()
 267 IF (LIBSSH2_FOUND)
 268         ADD_DEFINITIONS(-DGIT_SSH)
 269         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 270         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 271         SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} libssh2")
 272         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 273 ELSE()
 274         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 275 ENDIF()
 276
 277 # Optional external dependency: libgssapi
 278 IF (USE_GSSAPI)
 279         FIND_PACKAGE(GSSAPI)
 280 ENDIF()
 281 IF (GSSAPI_FOUND)
 282         ADD_DEFINITIONS(-DGIT_GSSAPI)
 283 ENDIF()
 284
 285 # Optional external dependency: iconv
 286 IF (USE_ICONV)
 287         FIND_PACKAGE(Iconv)
 288 ENDIF()
 289 IF (ICONV_FOUND)
 290         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 291         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 292         SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${ICONV_LIBRARIES}")
 293 ENDIF()
 294
 295 # Platform specific compilation flags
 296 IF (MSVC)
 297
 298         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 299
 300         # /GF - String pooling
 301         # /MP - Parallel build
 302         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 303
 304         IF (STDCALL)
 305                 # /Gz - stdcall calling convention
 306                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 307         ENDIF ()
 308
 309         IF (STATIC_CRT)
 310                 SET(CRT_FLAG_DEBUG "/MTd")
 311                 SET(CRT_FLAG_RELEASE "/MT")
 312         ELSE()
 313                 SET(CRT_FLAG_DEBUG "/MDd")
 314                 SET(CRT_FLAG_RELEASE "/MD")
 315         ENDIF()
 316
 317         IF (MSVC_CRTDBG)
 318                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 319         ENDIF()
 320
 321         # /Zi - Create debugging information
 322         # /Od - Disable optimization
 323         # /D_DEBUG - #define _DEBUG
 324         # /MTd - Statically link the multithreaded debug version of the CRT
 325         # /MDd - Dynamically link the multithreaded debug version of the CRT
 326         # /RTC1 - Run time checks
 327         SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 328
 329         # /DNDEBUG - Disables asserts
 330         # /MT - Statically link the multithreaded release version of the CRT
 331         # /MD - Dynamically link the multithreaded release version of the CRT
 332         # /O2 - Optimize for speed
 333         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 334         # /GL - Link time code generation (whole program optimization)
 335         # /Gy - Function-level linking
 336         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 337
 338         # /Oy- - Disable frame pointer omission (FPO)
 339         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 340
 341         # /O1 - Optimize for size
 342         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 343
 344         # /DYNAMICBASE - Address space load randomization (ASLR)
 345         # /NXCOMPAT - Data execution prevention (DEP)
 346         # /LARGEADDRESSAWARE - >2GB user address space on x86
 347         # /VERSION - Embed version information in PE header
 348         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 349
 350         # /DEBUG - Create a PDB
 351         # /LTCG - Link time code generation (whole program optimization)
 352         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 353         # /INCREMENTAL:NO - Required to use /LTCG
 354         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 355         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 356         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 357         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 358         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 359
 360         # Same linker settings for DLL as EXE
 361         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 362         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 363         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 364         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 365         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 366
 367         SET(WIN_RC "src/win32/git2.rc")
 368
 369    # Precompiled headers
 370
 371 ELSE ()
 372         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 373
 374         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 375                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 376         ENDIF()
 377
 378         IF (WIN32 AND NOT CYGWIN)
 379                 SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
 380         ENDIF ()
 381
 382         IF (MINGW) # MinGW always does PIC and complains if we tell it to
 383                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 384                 # MinGW >= 3.14 uses the C99-style stdio functions
 385                 # automatically, but forks like mingw-w64 still want
 386                 # us to define this in order to use them
 387                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 388
 389         ELSEIF (BUILD_SHARED_LIBS)
 390                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 391
 392                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 393         ENDIF ()
 394
 395         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 396         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 397         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 398         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 399         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 400         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 401
 402         IF (APPLE) # Apple deprecated OpenSSL
 403                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 404         ENDIF()
 405
 406         IF (PROFILE)
 407                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 408                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 409         ENDIF ()
 410 ENDIF()
 411
 412 IF( NOT CMAKE_CONFIGURATION_TYPES )
 413         # Build Debug by default
 414         IF (NOT CMAKE_BUILD_TYPE)
 415                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 416         ENDIF ()
 417 ELSE()
 418         # Using a multi-configuration generator eg MSVC or Xcode
 419         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 420 ENDIF()
 421
 422 IF (SECURITY_FOUND)
 423   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 424   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 425 ENDIF ()
 426
 427 IF (OPENSSL_FOUND)
 428   ADD_DEFINITIONS(-DGIT_OPENSSL)
 429   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 430   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 431 ENDIF()
 432
 433
 434
 435 IF (THREADSAFE)
 436         IF (NOT WIN32)
 437                 FIND_PACKAGE(Threads REQUIRED)
 438         ENDIF()
 439
 440         ADD_DEFINITIONS(-DGIT_THREADS)
 441 ENDIF()
 442
 443 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 444
 445 # Collect sourcefiles
 446 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 447
 448 # On Windows use specific platform sources
 449 IF (WIN32 AND NOT CYGWIN)
 450         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 451         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 452 ELSEIF (AMIGA)
 453         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 454 ELSE()
 455         IF (VALGRIND)
 456                 ADD_DEFINITIONS(-DNO_MMAP)
 457         ENDIF()
 458         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 459 ENDIF()
 460 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 461
 462 # Determine architecture of the machine
 463 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 464         ADD_DEFINITIONS(-DGIT_ARCH_64)
 465 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 466         ADD_DEFINITIONS(-DGIT_ARCH_32)
 467 ELSE()
 468         MESSAGE(FATAL_ERROR "Unsupported architecture")
 469 ENDIF()
 470
 471 # Compile and link libgit2
 472 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1} ${WIN_RC})
 473 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 474 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 475 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 476 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 477 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 478 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 479 TARGET_OS_LIBRARIES(git2)
 480
 481 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 482 # Win64+MSVC+static libs = linker error
 483 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 484   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 485 ENDIF()
 486
 487 MSVC_SPLIT_SOURCES(git2)
 488
 489 IF (SONAME)
 490         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 491         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 492         IF (LIBGIT2_FILENAME)
 493                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 494                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 495         ENDIF()
 496 ENDIF()
 497 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 498
 499 IF (MSVC_IDE)
 500    # Precompiled headers
 501    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 502    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 503 ENDIF ()
 504
 505 # Install
 506 INSTALL(TARGETS git2
 507         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 508         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 509         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 510 )
 511 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 512 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 513 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 514
 515 # Tests
 516 IF (BUILD_CLAR)
 517         FIND_PACKAGE(PythonInterp REQUIRED)
 518
 519         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 520         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 521         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 522         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 523         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 524         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 525
 526         INCLUDE_DIRECTORIES(${CLAR_PATH})
 527         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 528         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 529
 530         ADD_CUSTOM_COMMAND(
 531                 OUTPUT ${CLAR_PATH}/clar.suite
 532                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 533                 DEPENDS ${SRC_TEST}
 534                 WORKING_DIRECTORY ${CLAR_PATH}
 535         )
 536
 537         SET_SOURCE_FILES_PROPERTIES(
 538                 ${CLAR_PATH}/clar.c
 539                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 540
 541         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1})
 542
 543         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 544         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 545         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 546         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 547         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 548         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 549         TARGET_OS_LIBRARIES(libgit2_clar)
 550         MSVC_SPLIT_SOURCES(libgit2_clar)
 551
 552         IF (MSVC_IDE)
 553                 # Precompiled headers
 554                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 555         ENDIF ()
 556
 557         ENABLE_TESTING()
 558         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 559                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 560         ELSE ()
 561                 ADD_TEST(libgit2_clar libgit2_clar -v)
 562         ENDIF ()
 563 ENDIF ()
 564
 565 IF (TAGS)
 566         FIND_PROGRAM(CTAGS ctags)
 567         IF (NOT CTAGS)
 568                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 569         ENDIF ()
 570
 571         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 572
 573         ADD_CUSTOM_COMMAND(
 574                 OUTPUT tags
 575                 COMMAND ${CTAGS} -a ${SRC_ALL}
 576                 DEPENDS ${SRC_ALL}
 577         )
 578         ADD_CUSTOM_TARGET(
 579                 do_tags ALL
 580                 DEPENDS tags
 581         )
 582 ENDIF ()
 583
 584 IF (BUILD_EXAMPLES)
 585         ADD_SUBDIRECTORY(examples)
 586 ENDIF ()