CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(CheckSymbolExists)
  24 INCLUDE(CheckStructHasMember)
  25 INCLUDE(AddCFlagIfSupported)
  26 INCLUDE(FindPkgConfig)
  27
  28 # Build options
  29 #
  30 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  31 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  32 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  33 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  34 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  35 OPTION( TAGS                            "Generate tags"                                                 OFF )
  36 OPTION( PROFILE                         "Generate profiling information"                OFF )
  37 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  38 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  39
  40 OPTION( USE_SHA1DC                      "Use SHA-1 with collision detection"    OFF )
  41 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  42 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  43 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  44 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  45 OPTION( CURL                    "Use curl for HTTP if available" ON)
  46 OPTION( DEBUG_POOL                      "Enable debug pool allocator"                   OFF )
  47
  48 IF(DEBUG_POOL)
  49         ADD_DEFINITIONS(-DGIT_DEBUG_POOL)
  50 ENDIF()
  51
  52 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  53         SET( USE_ICONV ON )
  54         FIND_PACKAGE(Security)
  55         FIND_PACKAGE(CoreFoundation REQUIRED)
  56 ENDIF()
  57
  58 IF(MSVC)
  59         # This option is only available when building with MSVC. By default, libgit2
  60         # is build using the cdecl calling convention, which is useful if you're
  61         # writing C. However, the CLR and Win32 API both expect stdcall.
  62         #
  63         # If you are writing a CLR program and want to link to libgit2, you'll want
  64         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  65         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  66
  67         # This option must match the settings used in your program, in particular if you
  68         # are linking statically
  69         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  70
  71         # If you want to embed a copy of libssh2 into libgit2, pass a
  72         # path to libssh2
  73         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  74
  75         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  76         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  77         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  78 ENDIF()
  79
  80
  81 IF(WIN32)
  82         # By default, libgit2 is built with WinHTTP.  To use the built-in
  83         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  84         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  85 ENDIF()
  86
  87 IF(MSVC)
  88         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  89         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  90 ENDIF()
  91
  92 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  93         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  94 ENDIF()
  95
  96 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtim "sys/types.h;sys/stat.h"
  97         HAVE_STRUCT_STAT_ST_MTIM LANGUAGE C)
  98 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtimespec "sys/types.h;sys/stat.h"
  99         HAVE_STRUCT_STAT_ST_MTIMESPEC LANGUAGE C)
 100 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_nsec sys/stat.h
 101         HAVE_STRUCT_STAT_MTIME_NSEC LANGUAGE C)
 102
 103 IF (HAVE_STRUCT_STAT_ST_MTIM)
 104         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 105                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 106 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 107         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 108                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 109 ELSE ()
 110         SET( HAVE_STRUCT_STAT_NSEC ON )
 111 ENDIF()
 112
 113 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 114         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  ON  )
 115 ENDIF()
 116
 117 # This variable will contain the libraries we need to put into
 118 # libgit2.pc's Requires.private. That is, what we're linking to or
 119 # what someone who's statically linking us needs to link to.
 120 SET(LIBGIT2_PC_REQUIRES "")
 121 # This will be set later if we use the system's http-parser library or
 122 # use iconv (OSX) and will be written to the Libs.private field in the
 123 # pc file.
 124 SET(LIBGIT2_PC_LIBS "")
 125
 126 # Installation paths
 127 #
 128 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 129 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 130 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 131
 132 # Set a couple variables to be substituted inside the .pc file.
 133 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 134 # or relative paths is both valid and supported by cmake.
 135 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 136
 137 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 138   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 139 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 140   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 141 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 142
 143 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 144   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 145 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 146   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 147 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 148
 149 FUNCTION(TARGET_OS_LIBRARIES target)
 150         IF(WIN32)
 151                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 152         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 153                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 154                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 155                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 156         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Haiku")
 157                 TARGET_LINK_LIBRARIES(${target} network)
 158                 LIST(APPEND LIBGIT2_PC_LIBS "-lnetwork")
 159                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 160         ENDIF()
 161         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 162         IF(NEED_LIBRT)
 163                 TARGET_LINK_LIBRARIES(${target} rt)
 164                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 165                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 166         ENDIF()
 167
 168         IF(THREADSAFE)
 169                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 170                 LIST(APPEND LIBGIT2_PC_LIBS ${CMAKE_THREAD_LIBS_INIT})
 171                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 172         ENDIF()
 173 ENDFUNCTION()
 174
 175 # This function splits the sources files up into their appropriate
 176 # subdirectories.  This is especially useful for IDEs like Xcode and
 177 # Visual Studio, so that you can navigate into the libgit2_clar project,
 178 # and see the folders within the tests folder (instead of just seeing all
 179 # source and tests in a single folder.)
 180 FUNCTION(IDE_SPLIT_SOURCES target)
 181         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 182                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 183                 FOREACH(source ${sources})
 184                         IF(source MATCHES ".*/")
 185                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 186                                 IF(rel)
 187                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 188                                         IF(rel)
 189                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 190                                                 SOURCE_GROUP(${rel} FILES ${source})
 191                                         ENDIF()
 192                                 ENDIF()
 193                         ENDIF()
 194                 ENDFOREACH()
 195         ENDIF()
 196 ENDFUNCTION()
 197
 198 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 199
 200 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 201 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 202 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 203 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 204
 205 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 206 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 207
 208 # Find required dependencies
 209 INCLUDE_DIRECTORIES(src include)
 210
 211 IF (SECURITY_FOUND)
 212   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 213   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 214   IF (HAVE_NEWER_SECURITY)
 215     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 216     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 217   ELSE()
 218     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 219     SET(SECURITY_FOUND "NO")
 220     SET(SECURITY_DIRS "")
 221     SET(SECURITY_DIR "")
 222     SET(USE_OPENSSL "ON")
 223   ENDIF()
 224 ENDIF()
 225
 226 IF (COREFOUNDATION_FOUND)
 227   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 228   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 229 ENDIF()
 230
 231
 232 IF (WIN32 AND EMBED_SSH_PATH)
 233         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 234         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 235         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 236         ADD_DEFINITIONS(-DGIT_SSH)
 237 ENDIF()
 238
 239 IF (WIN32 AND WINHTTP)
 240         ADD_DEFINITIONS(-DGIT_WINHTTP)
 241         ADD_DEFINITIONS(-DGIT_HTTPS)
 242
 243         # Since MinGW does not come with headers or an import library for winhttp,
 244         # we have to include a private header and generate our own import library
 245         IF (MINGW)
 246                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 247                 IF (NOT DLLTOOL)
 248                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 249                 ENDIF ()
 250
 251                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 252                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 253
 254                 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 255                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 256                 ELSE()
 257                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 258                 ENDIF()
 259
 260                 ADD_CUSTOM_COMMAND(
 261                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 262                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 263                         DEPENDS ${WINHTTP_DEF}
 264                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 265                 )
 266
 267                 SET_SOURCE_FILES_PROPERTIES(
 268                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 269                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 270                 )
 271
 272                 INCLUDE_DIRECTORIES(deps/winhttp)
 273                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 274         ENDIF ()
 275
 276         LINK_LIBRARIES(winhttp rpcrt4 crypt32 ole32)
 277         LIST(APPEND LIBGIT2_PC_LIBS "-lwinhttp" "-lrpcrt4" "-lcrypt32" "-lole32")
 278 ELSE ()
 279         IF (CURL)
 280                 PKG_CHECK_MODULES(CURL libcurl)
 281         ENDIF ()
 282
 283         IF (NOT AMIGA AND USE_OPENSSL)
 284                 FIND_PACKAGE(OpenSSL)
 285         ENDIF ()
 286
 287         IF (CURL_FOUND)
 288                 ADD_DEFINITIONS(-DGIT_CURL)
 289                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 290                 LINK_DIRECTORIES(${CURL_LIBRARY_DIRS})
 291                 LINK_LIBRARIES(${CURL_LIBRARIES})
 292                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 293         ENDIF()
 294 ENDIF()
 295
 296 # Specify sha1 implementation
 297 IF (USE_SHA1DC)
 298         ADD_DEFINITIONS(-DGIT_SHA1_COLLISIONDETECT)
 299         ADD_DEFINITIONS(-DSHA1DC_NO_STANDARD_INCLUDES=1)
 300         ADD_DEFINITIONS(-DSHA1DC_CUSTOM_INCLUDE_SHA1_C=\"common.h\")
 301         ADD_DEFINITIONS(-DSHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C=\"common.h\")
 302         FILE(GLOB SRC_SHA1 src/hash/hash_collisiondetect.c src/hash/sha1dc/*)
 303 ELSEIF (WIN32 AND NOT MINGW)
 304         ADD_DEFINITIONS(-DGIT_SHA1_WIN32)
 305         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 306 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 307         ADD_DEFINITIONS(-DGIT_SHA1_COMMON_CRYPTO)
 308 ELSEIF (OPENSSL_FOUND)
 309         ADD_DEFINITIONS(-DGIT_SHA1_OPENSSL)
 310         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 311                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 312         ELSE()
 313                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 314         ENDIF ()
 315 ELSE()
 316         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 317 ENDIF()
 318
 319 # Enable tracing
 320 IF (ENABLE_TRACE STREQUAL "ON")
 321         ADD_DEFINITIONS(-DGIT_TRACE)
 322 ENDIF()
 323
 324 # Include POSIX regex when it is required
 325 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 326         INCLUDE_DIRECTORIES(deps/regex)
 327         SET(SRC_REGEX deps/regex/regex.c)
 328 ENDIF()
 329
 330 # Optional external dependency: http-parser
 331 FIND_PACKAGE(HTTP_Parser)
 332 IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 333         INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 334         LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 335         LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 336 ELSE()
 337         MESSAGE(STATUS "http-parser version 2 was not found; using bundled 3rd-party sources.")
 338         INCLUDE_DIRECTORIES(deps/http-parser)
 339         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 340 ENDIF()
 341
 342 # Optional external dependency: zlib
 343 FIND_PACKAGE(ZLIB)
 344 IF (ZLIB_FOUND)
 345         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 346         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 347         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 348                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 349         ELSE()
 350                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 351         ENDIF()
 352 ELSE()
 353         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 354         INCLUDE_DIRECTORIES(deps/zlib)
 355         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 356         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 357 ENDIF()
 358
 359 # Optional external dependency: libssh2
 360 IF (USE_SSH)
 361         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 362 ENDIF()
 363 IF (LIBSSH2_FOUND)
 364         ADD_DEFINITIONS(-DGIT_SSH)
 365         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 366         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 367         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 368         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 369         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 370
 371         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 372         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 373                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 374         ENDIF()
 375 ELSE()
 376         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 377 ENDIF()
 378
 379 # Optional external dependency: libgssapi
 380 IF (USE_GSSAPI)
 381         FIND_PACKAGE(GSSAPI)
 382 ENDIF()
 383 IF (GSSAPI_FOUND)
 384         ADD_DEFINITIONS(-DGIT_GSSAPI)
 385 ENDIF()
 386
 387 # Optional external dependency: iconv
 388 IF (USE_ICONV)
 389         FIND_PACKAGE(Iconv)
 390 ENDIF()
 391 IF (ICONV_FOUND)
 392         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 393         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 394         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 395 ENDIF()
 396
 397 # Platform specific compilation flags
 398 IF (MSVC)
 399
 400         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 401
 402         # /GF - String pooling
 403         # /MP - Parallel build
 404         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 405
 406         IF (STDCALL)
 407                 # /Gz - stdcall calling convention
 408                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 409         ENDIF ()
 410
 411         IF (STATIC_CRT)
 412                 SET(CRT_FLAG_DEBUG "/MTd")
 413                 SET(CRT_FLAG_RELEASE "/MT")
 414         ELSE()
 415                 SET(CRT_FLAG_DEBUG "/MDd")
 416                 SET(CRT_FLAG_RELEASE "/MD")
 417         ENDIF()
 418
 419         IF (MSVC_CRTDBG)
 420                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 421                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 422         ENDIF()
 423
 424         # /Zi - Create debugging information
 425         # /Od - Disable optimization
 426         # /D_DEBUG - #define _DEBUG
 427         # /MTd - Statically link the multithreaded debug version of the CRT
 428         # /MDd - Dynamically link the multithreaded debug version of the CRT
 429         # /RTC1 - Run time checks
 430         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 431
 432         # /DNDEBUG - Disables asserts
 433         # /MT - Statically link the multithreaded release version of the CRT
 434         # /MD - Dynamically link the multithreaded release version of the CRT
 435         # /O2 - Optimize for speed
 436         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 437         # /GL - Link time code generation (whole program optimization)
 438         # /Gy - Function-level linking
 439         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 440
 441         # /Oy- - Disable frame pointer omission (FPO)
 442         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 443
 444         # /O1 - Optimize for size
 445         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 446
 447         # /DYNAMICBASE - Address space load randomization (ASLR)
 448         # /NXCOMPAT - Data execution prevention (DEP)
 449         # /LARGEADDRESSAWARE - >2GB user address space on x86
 450         # /VERSION - Embed version information in PE header
 451         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 452
 453         # /DEBUG - Create a PDB
 454         # /LTCG - Link time code generation (whole program optimization)
 455         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 456         # /INCREMENTAL:NO - Required to use /LTCG
 457         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 458         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 459         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 460         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 461         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 462
 463         # Same linker settings for DLL as EXE
 464         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 465         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 466         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 467         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 468         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 469
 470         SET(WIN_RC "src/win32/git2.rc")
 471
 472    # Precompiled headers
 473
 474 ELSE ()
 475         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE ${CMAKE_C_FLAGS}")
 476
 477         ADD_C_FLAG_IF_SUPPORTED(-Wall)
 478         ADD_C_FLAG_IF_SUPPORTED(-Wextra)
 479
 480         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 481                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 482         ENDIF()
 483
 484         IF (WIN32 AND NOT CYGWIN)
 485                 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 486         ENDIF ()
 487
 488         IF (MINGW OR MSYS) # MinGW and MSYS always do PIC and complain if we tell them to
 489                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 490         ELSEIF (BUILD_SHARED_LIBS)
 491                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 492
 493                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 494         ENDIF ()
 495
 496         IF (MINGW)
 497                 # MinGW >= 3.14 uses the C99-style stdio functions
 498                 # automatically, but forks like mingw-w64 still want
 499                 # us to define this in order to use them
 500                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 501         ENDIF ()
 502
 503         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 504         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 505         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 506         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 507         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 508         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 509         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 510
 511         IF (APPLE) # Apple deprecated OpenSSL
 512                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 513         ENDIF()
 514
 515         IF (PROFILE)
 516                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 517                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 518         ENDIF ()
 519 ENDIF()
 520
 521 CHECK_SYMBOL_EXISTS(regcomp_l "regex.h;xlocale.h" HAVE_REGCOMP_L)
 522 IF (HAVE_REGCOMP_L)
 523         ADD_DEFINITIONS(-DHAVE_REGCOMP_L)
 524 ENDIF ()
 525
 526 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 527 IF (HAVE_FUTIMENS)
 528         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 529 ENDIF ()
 530
 531 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 532 IF (HAVE_QSORT_R)
 533         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 534 ENDIF ()
 535
 536 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 537 IF (HAVE_QSORT_S)
 538         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 539 ENDIF ()
 540
 541 IF( NOT CMAKE_CONFIGURATION_TYPES )
 542         # Build Debug by default
 543         IF (NOT CMAKE_BUILD_TYPE)
 544                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 545         ENDIF ()
 546 ELSE()
 547         # Using a multi-configuration generator eg MSVC or Xcode
 548         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 549 ENDIF()
 550
 551 IF (SECURITY_FOUND)
 552   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 553   ADD_DEFINITIONS(-DGIT_HTTPS)
 554   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 555 ENDIF ()
 556
 557 IF (OPENSSL_FOUND)
 558   ADD_DEFINITIONS(-DGIT_OPENSSL)
 559   ADD_DEFINITIONS(-DGIT_HTTPS)
 560   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 561   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 562 ENDIF()
 563
 564
 565
 566 IF (THREADSAFE)
 567         IF (NOT WIN32)
 568                 FIND_PACKAGE(Threads REQUIRED)
 569         ENDIF()
 570
 571         ADD_DEFINITIONS(-DGIT_THREADS)
 572 ENDIF()
 573
 574 IF (USE_NSEC)
 575         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 576 ENDIF()
 577
 578 IF (HAVE_STRUCT_STAT_ST_MTIM)
 579         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIM)
 580 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 581         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIMESPEC)
 582 ELSEIF (HAVE_STRUCT_STAT_ST_MTIME_NSEC)
 583         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIME_NSEC)
 584 ENDIF()
 585
 586 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 587
 588 # Collect sourcefiles
 589 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 590
 591 # On Windows use specific platform sources
 592 IF (WIN32 AND NOT CYGWIN)
 593         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 594         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 595 ELSEIF (AMIGA)
 596         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 597 ELSE()
 598         IF (VALGRIND)
 599                 ADD_DEFINITIONS(-DNO_MMAP)
 600         ENDIF()
 601         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 602 ENDIF()
 603 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 604
 605 # Determine architecture of the machine
 606 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 607         ADD_DEFINITIONS(-DGIT_ARCH_64)
 608 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 609         ADD_DEFINITIONS(-DGIT_ARCH_32)
 610 ELSEIF (CMAKE_SIZEOF_VOID_P)
 611         MESSAGE(FATAL_ERROR "Unsupported architecture (pointer size is ${CMAKE_SIZEOF_VOID_P} bytes)")
 612 ELSE()
 613         MESSAGE(FATAL_ERROR "Unsupported architecture (CMAKE_SIZEOF_VOID_P is unset)")
 614 ENDIF()
 615
 616 # Compile and link libgit2
 617 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 618 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 619 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 620 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 621 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 622 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 623 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 624 TARGET_OS_LIBRARIES(git2)
 625
 626 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 627 # Win64+MSVC+static libs = linker error
 628 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 629   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 630 ENDIF()
 631
 632 IDE_SPLIT_SOURCES(git2)
 633
 634 IF (SONAME)
 635         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 636         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 637         IF (LIBGIT2_FILENAME)
 638                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 639                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 640         ELSEIF (DEFINED LIBGIT2_PREFIX)
 641                 SET_TARGET_PROPERTIES(git2 PROPERTIES PREFIX "${LIBGIT2_PREFIX}")
 642         ENDIF()
 643 ENDIF()
 644 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 645 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 646
 647 IF (MSVC_IDE)
 648    # Precompiled headers
 649    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 650    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 651 ENDIF ()
 652
 653 # Install
 654 INSTALL(TARGETS git2
 655         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 656         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 657         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 658 )
 659 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 660 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 661 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 662
 663 # Tests
 664 IF (BUILD_CLAR)
 665         FIND_PACKAGE(PythonInterp)
 666
 667         IF(NOT PYTHONINTERP_FOUND)
 668           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 669             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 670         ENDIF()
 671
 672         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 673         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 674         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 675         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 676         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 677         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 678
 679         INCLUDE_DIRECTORIES(${CLAR_PATH})
 680         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 681         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 682
 683         ADD_CUSTOM_COMMAND(
 684                 OUTPUT ${CLAR_PATH}/clar.suite
 685                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 686                 DEPENDS ${SRC_TEST}
 687                 WORKING_DIRECTORY ${CLAR_PATH}
 688         )
 689
 690         SET_SOURCE_FILES_PROPERTIES(
 691                 ${CLAR_PATH}/clar.c
 692                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 693
 694         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 695
 696         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 697         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 698         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 699         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 700         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 701         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 702         TARGET_OS_LIBRARIES(libgit2_clar)
 703         IDE_SPLIT_SOURCES(libgit2_clar)
 704
 705         IF (MSVC_IDE)
 706                 # Precompiled headers
 707                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 708         ENDIF ()
 709
 710         ENABLE_TESTING()
 711         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 712                 ADD_TEST(libgit2_clar libgit2_clar -ionline -xclone::local::git_style_unc_paths -xclone::local::standard_unc_paths_are_written_git_style)
 713         ELSE ()
 714                 ADD_TEST(libgit2_clar libgit2_clar -v -xclone::local::git_style_unc_paths -xclone::local::standard_unc_paths_are_written_git_style)
 715         ENDIF ()
 716
 717         # Add a test target which runs the cred callback tests, to be
 718         # called after setting the url and user
 719         ADD_TEST(libgit2_clar-cred_callback libgit2_clar -v -sonline::clone::cred_callback)
 720         ADD_TEST(libgit2_clar-proxy_credentials_in_url libgit2_clar -v -sonline::clone::proxy_credentials_in_url)
 721         ADD_TEST(libgit2_clar-proxy_credentials_request libgit2_clar -v -sonline::clone::proxy_credentials_request)
 722 ENDIF ()
 723
 724 IF (TAGS)
 725         FIND_PROGRAM(CTAGS ctags)
 726         IF (NOT CTAGS)
 727                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 728         ENDIF ()
 729
 730         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 731
 732         ADD_CUSTOM_COMMAND(
 733                 OUTPUT tags
 734                 COMMAND ${CTAGS} -a ${SRC_ALL}
 735                 DEPENDS ${SRC_ALL}
 736         )
 737         ADD_CUSTOM_TARGET(
 738                 do_tags ALL
 739                 DEPENDS tags
 740         )
 741 ENDIF ()
 742
 743 IF (BUILD_EXAMPLES)
 744         ADD_SUBDIRECTORY(examples)
 745 ENDIF ()