CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(CheckSymbolExists)
  24 INCLUDE(CheckStructHasMember)
  25 INCLUDE(AddCFlagIfSupported)
  26 INCLUDE(FindPkgConfig)
  27
  28 # Build options
  29 #
  30 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  31 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  32 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  33 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  34 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  35 OPTION( TAGS                            "Generate tags"                                                 OFF )
  36 OPTION( PROFILE                         "Generate profiling information"                OFF )
  37 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  38 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  39
  40 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  41 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  42 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  43 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  44 OPTION( CURL                    "Use curl for HTTP if available" ON)
  45 OPTION( DEBUG_POOL                      "Enable debug pool allocator"                   OFF )
  46
  47 IF(DEBUG_POOL)
  48         ADD_DEFINITIONS(-DGIT_DEBUG_POOL)
  49 ENDIF()
  50
  51 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  52         SET( USE_ICONV ON )
  53         FIND_PACKAGE(Security)
  54         FIND_PACKAGE(CoreFoundation REQUIRED)
  55 ENDIF()
  56
  57 IF(MSVC)
  58         # This option is only available when building with MSVC. By default, libgit2
  59         # is build using the cdecl calling convention, which is useful if you're
  60         # writing C. However, the CLR and Win32 API both expect stdcall.
  61         #
  62         # If you are writing a CLR program and want to link to libgit2, you'll want
  63         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  64         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  65
  66         # This option must match the settings used in your program, in particular if you
  67         # are linking statically
  68         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  69
  70         # If you want to embed a copy of libssh2 into libgit2, pass a
  71         # path to libssh2
  72         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  73
  74         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  75         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  76         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  77 ENDIF()
  78
  79
  80 IF(WIN32)
  81         # By default, libgit2 is built with WinHTTP.  To use the built-in
  82         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  83         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  84 ENDIF()
  85
  86 IF(MSVC)
  87         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  88         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  89 ENDIF()
  90
  91 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  92         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  93 ENDIF()
  94
  95 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtim "sys/types.h;sys/stat.h"
  96         HAVE_STRUCT_STAT_ST_MTIM LANGUAGE C)
  97 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtimespec "sys/types.h;sys/stat.h"
  98         HAVE_STRUCT_STAT_ST_MTIMESPEC LANGUAGE C)
  99 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_nsec sys/stat.h
 100         HAVE_STRUCT_STAT_MTIME_NSEC LANGUAGE C)
 101
 102 IF (HAVE_STRUCT_STAT_ST_MTIM)
 103         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 104                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 105 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 106         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 107                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 108 ELSE ()
 109         SET( HAVE_STRUCT_STAT_NSEC ON )
 110 ENDIF()
 111
 112 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 113         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  ON  )
 114 ENDIF()
 115
 116 # This variable will contain the libraries we need to put into
 117 # libgit2.pc's Requires.private. That is, what we're linking to or
 118 # what someone who's statically linking us needs to link to.
 119 SET(LIBGIT2_PC_REQUIRES "")
 120 # This will be set later if we use the system's http-parser library or
 121 # use iconv (OSX) and will be written to the Libs.private field in the
 122 # pc file.
 123 SET(LIBGIT2_PC_LIBS "")
 124
 125 # Installation paths
 126 #
 127 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 128 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 129 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 130
 131 # Set a couple variables to be substituted inside the .pc file.
 132 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 133 # or relative paths is both valid and supported by cmake.
 134 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 135
 136 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 137   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 138 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 139   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 140 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 141
 142 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 143   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 144 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 145   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 146 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 147
 148 FUNCTION(TARGET_OS_LIBRARIES target)
 149         IF(WIN32)
 150                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 151         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 152                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 153                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 154                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 155         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Haiku")
 156                 TARGET_LINK_LIBRARIES(${target} network)
 157                 LIST(APPEND LIBGIT2_PC_LIBS "-lnetwork")
 158                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 159         ENDIF()
 160         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 161         IF(NEED_LIBRT)
 162                 TARGET_LINK_LIBRARIES(${target} rt)
 163                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 164                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 165         ENDIF()
 166
 167         IF(THREADSAFE)
 168                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 169                 LIST(APPEND LIBGIT2_PC_LIBS ${CMAKE_THREAD_LIBS_INIT})
 170                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 171         ENDIF()
 172 ENDFUNCTION()
 173
 174 # This function splits the sources files up into their appropriate
 175 # subdirectories.  This is especially useful for IDEs like Xcode and
 176 # Visual Studio, so that you can navigate into the libgit2_clar project,
 177 # and see the folders within the tests folder (instead of just seeing all
 178 # source and tests in a single folder.)
 179 FUNCTION(IDE_SPLIT_SOURCES target)
 180         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 181                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 182                 FOREACH(source ${sources})
 183                         IF(source MATCHES ".*/")
 184                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 185                                 IF(rel)
 186                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 187                                         IF(rel)
 188                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 189                                                 SOURCE_GROUP(${rel} FILES ${source})
 190                                         ENDIF()
 191                                 ENDIF()
 192                         ENDIF()
 193                 ENDFOREACH()
 194         ENDIF()
 195 ENDFUNCTION()
 196
 197 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 198
 199 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 200 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 201 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 202 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 203
 204 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 205 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 206
 207 # Find required dependencies
 208 INCLUDE_DIRECTORIES(src include)
 209
 210 IF (SECURITY_FOUND)
 211   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 212   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 213   IF (HAVE_NEWER_SECURITY)
 214     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 215     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 216   ELSE()
 217     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 218     SET(SECURITY_FOUND "NO")
 219     SET(SECURITY_DIRS "")
 220     SET(SECURITY_DIR "")
 221     SET(USE_OPENSSL "ON")
 222   ENDIF()
 223 ENDIF()
 224
 225 IF (COREFOUNDATION_FOUND)
 226   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 227   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 228 ENDIF()
 229
 230
 231 IF (WIN32 AND EMBED_SSH_PATH)
 232         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 233         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 234         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 235         ADD_DEFINITIONS(-DGIT_SSH)
 236 ENDIF()
 237
 238 IF (WIN32 AND WINHTTP)
 239         ADD_DEFINITIONS(-DGIT_WINHTTP)
 240
 241         # Since MinGW does not come with headers or an import library for winhttp,
 242         # we have to include a private header and generate our own import library
 243         IF (MINGW)
 244                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 245                 IF (NOT DLLTOOL)
 246                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 247                 ENDIF ()
 248
 249                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 250                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 251
 252                 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 253                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 254                 ELSE()
 255                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 256                 ENDIF()
 257
 258                 ADD_CUSTOM_COMMAND(
 259                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 260                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 261                         DEPENDS ${WINHTTP_DEF}
 262                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 263                 )
 264
 265                 SET_SOURCE_FILES_PROPERTIES(
 266                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 267                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 268                 )
 269
 270                 INCLUDE_DIRECTORIES(deps/winhttp)
 271                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 272         ENDIF ()
 273
 274         LINK_LIBRARIES(winhttp rpcrt4 crypt32 ole32)
 275         LIST(APPEND LIBGIT2_PC_LIBS "-lwinhttp" "-lrpcrt4" "-lcrypt32" "-lole32")
 276 ELSE ()
 277         IF (CURL)
 278                 PKG_CHECK_MODULES(CURL libcurl)
 279         ENDIF ()
 280
 281         IF (NOT AMIGA AND USE_OPENSSL)
 282                 FIND_PACKAGE(OpenSSL)
 283         ENDIF ()
 284
 285         IF (CURL_FOUND)
 286                 ADD_DEFINITIONS(-DGIT_CURL)
 287                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 288                 LINK_DIRECTORIES(${CURL_LIBRARY_DIRS})
 289                 LINK_LIBRARIES(${CURL_LIBRARIES})
 290                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 291         ENDIF()
 292 ENDIF()
 293
 294 # Specify sha1 implementation
 295 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 296         ADD_DEFINITIONS(-DWIN32_SHA1)
 297         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 298 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 299         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 300 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 301         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 302         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 303                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 304         ELSE()
 305                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 306         ENDIF ()
 307 ELSE()
 308         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 309 ENDIF()
 310
 311 # Enable tracing
 312 IF (ENABLE_TRACE STREQUAL "ON")
 313         ADD_DEFINITIONS(-DGIT_TRACE)
 314 ENDIF()
 315
 316 # Include POSIX regex when it is required
 317 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 318         INCLUDE_DIRECTORIES(deps/regex)
 319         SET(SRC_REGEX deps/regex/regex.c)
 320 ENDIF()
 321
 322 # Optional external dependency: http-parser
 323 FIND_PACKAGE(HTTP_Parser)
 324 IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 325         INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 326         LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 327         LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 328 ELSE()
 329         MESSAGE(STATUS "http-parser version 2 was not found; using bundled 3rd-party sources.")
 330         INCLUDE_DIRECTORIES(deps/http-parser)
 331         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 332 ENDIF()
 333
 334 # Optional external dependency: zlib
 335 FIND_PACKAGE(ZLIB)
 336 IF (ZLIB_FOUND)
 337         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 338         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 339         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 340                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 341         ELSE()
 342                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 343         ENDIF()
 344 ELSE()
 345         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 346         INCLUDE_DIRECTORIES(deps/zlib)
 347         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 348         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 349 ENDIF()
 350
 351 # Optional external dependency: libssh2
 352 IF (USE_SSH)
 353         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 354 ENDIF()
 355 IF (LIBSSH2_FOUND)
 356         ADD_DEFINITIONS(-DGIT_SSH)
 357         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 358         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 359         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 360         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 361         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 362
 363         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 364         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 365                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 366         ENDIF()
 367 ELSE()
 368         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 369 ENDIF()
 370
 371 # Optional external dependency: libgssapi
 372 IF (USE_GSSAPI)
 373         FIND_PACKAGE(GSSAPI)
 374 ENDIF()
 375 IF (GSSAPI_FOUND)
 376         ADD_DEFINITIONS(-DGIT_GSSAPI)
 377 ENDIF()
 378
 379 # Optional external dependency: iconv
 380 IF (USE_ICONV)
 381         FIND_PACKAGE(Iconv)
 382 ENDIF()
 383 IF (ICONV_FOUND)
 384         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 385         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 386         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 387 ENDIF()
 388
 389 # Platform specific compilation flags
 390 IF (MSVC)
 391
 392         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 393
 394         # /GF - String pooling
 395         # /MP - Parallel build
 396         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 397
 398         IF (STDCALL)
 399                 # /Gz - stdcall calling convention
 400                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 401         ENDIF ()
 402
 403         IF (STATIC_CRT)
 404                 SET(CRT_FLAG_DEBUG "/MTd")
 405                 SET(CRT_FLAG_RELEASE "/MT")
 406         ELSE()
 407                 SET(CRT_FLAG_DEBUG "/MDd")
 408                 SET(CRT_FLAG_RELEASE "/MD")
 409         ENDIF()
 410
 411         IF (MSVC_CRTDBG)
 412                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 413                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 414         ENDIF()
 415
 416         # /Zi - Create debugging information
 417         # /Od - Disable optimization
 418         # /D_DEBUG - #define _DEBUG
 419         # /MTd - Statically link the multithreaded debug version of the CRT
 420         # /MDd - Dynamically link the multithreaded debug version of the CRT
 421         # /RTC1 - Run time checks
 422         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 423
 424         # /DNDEBUG - Disables asserts
 425         # /MT - Statically link the multithreaded release version of the CRT
 426         # /MD - Dynamically link the multithreaded release version of the CRT
 427         # /O2 - Optimize for speed
 428         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 429         # /GL - Link time code generation (whole program optimization)
 430         # /Gy - Function-level linking
 431         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 432
 433         # /Oy- - Disable frame pointer omission (FPO)
 434         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 435
 436         # /O1 - Optimize for size
 437         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 438
 439         # /DYNAMICBASE - Address space load randomization (ASLR)
 440         # /NXCOMPAT - Data execution prevention (DEP)
 441         # /LARGEADDRESSAWARE - >2GB user address space on x86
 442         # /VERSION - Embed version information in PE header
 443         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 444
 445         # /DEBUG - Create a PDB
 446         # /LTCG - Link time code generation (whole program optimization)
 447         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 448         # /INCREMENTAL:NO - Required to use /LTCG
 449         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 450         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 451         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 452         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 453         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 454
 455         # Same linker settings for DLL as EXE
 456         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 457         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 458         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 459         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 460         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 461
 462         SET(WIN_RC "src/win32/git2.rc")
 463
 464    # Precompiled headers
 465
 466 ELSE ()
 467         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 468
 469         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 470                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 471         ENDIF()
 472
 473         IF (WIN32 AND NOT CYGWIN)
 474                 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 475         ENDIF ()
 476
 477         IF (MINGW OR MSYS) # MinGW and MSYS always do PIC and complain if we tell them to
 478                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 479         ELSEIF (BUILD_SHARED_LIBS)
 480                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 481
 482                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 483         ENDIF ()
 484
 485         IF (MINGW)
 486                 # MinGW >= 3.14 uses the C99-style stdio functions
 487                 # automatically, but forks like mingw-w64 still want
 488                 # us to define this in order to use them
 489                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 490         ENDIF ()
 491
 492         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 493         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 494         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 495         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 496         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 497         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 498         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 499
 500         IF (APPLE) # Apple deprecated OpenSSL
 501                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 502         ENDIF()
 503
 504         IF (PROFILE)
 505                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 506                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 507         ENDIF ()
 508 ENDIF()
 509
 510 CHECK_SYMBOL_EXISTS(regcomp_l "regex.h;xlocale.h" HAVE_REGCOMP_L)
 511 IF (HAVE_REGCOMP_L)
 512         ADD_DEFINITIONS(-DHAVE_REGCOMP_L)
 513 ENDIF ()
 514
 515 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 516 IF (HAVE_FUTIMENS)
 517         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 518 ENDIF ()
 519
 520 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 521 IF (HAVE_QSORT_R)
 522         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 523 ENDIF ()
 524
 525 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 526 IF (HAVE_QSORT_S)
 527         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 528 ENDIF ()
 529
 530 IF( NOT CMAKE_CONFIGURATION_TYPES )
 531         # Build Debug by default
 532         IF (NOT CMAKE_BUILD_TYPE)
 533                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 534         ENDIF ()
 535 ELSE()
 536         # Using a multi-configuration generator eg MSVC or Xcode
 537         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 538 ENDIF()
 539
 540 IF (SECURITY_FOUND)
 541   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 542   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 543 ENDIF ()
 544
 545 IF (OPENSSL_FOUND)
 546   ADD_DEFINITIONS(-DGIT_OPENSSL)
 547   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 548   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 549 ENDIF()
 550
 551
 552
 553 IF (THREADSAFE)
 554         IF (NOT WIN32)
 555                 FIND_PACKAGE(Threads REQUIRED)
 556         ENDIF()
 557
 558         ADD_DEFINITIONS(-DGIT_THREADS)
 559 ENDIF()
 560
 561 IF (USE_NSEC)
 562         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 563 ENDIF()
 564
 565 IF (HAVE_STRUCT_STAT_ST_MTIM)
 566         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIM)
 567 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 568         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIMESPEC)
 569 ELSEIF (HAVE_STRUCT_STAT_ST_MTIME_NSEC)
 570         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIME_NSEC)
 571 ENDIF()
 572
 573 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 574
 575 # Collect sourcefiles
 576 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 577
 578 # On Windows use specific platform sources
 579 IF (WIN32 AND NOT CYGWIN)
 580         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 581         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 582 ELSEIF (AMIGA)
 583         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 584 ELSE()
 585         IF (VALGRIND)
 586                 ADD_DEFINITIONS(-DNO_MMAP)
 587         ENDIF()
 588         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 589 ENDIF()
 590 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 591
 592 # Determine architecture of the machine
 593 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 594         ADD_DEFINITIONS(-DGIT_ARCH_64)
 595 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 596         ADD_DEFINITIONS(-DGIT_ARCH_32)
 597 ELSEIF (CMAKE_SIZEOF_VOID_P)
 598         MESSAGE(FATAL_ERROR "Unsupported architecture (pointer size is ${CMAKE_SIZEOF_VOID_P} bytes)")
 599 ELSE()
 600         MESSAGE(FATAL_ERROR "Unsupported architecture (CMAKE_SIZEOF_VOID_P is unset)")
 601 ENDIF()
 602
 603 # Compile and link libgit2
 604 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 605 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 606 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 607 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 608 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 609 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 610 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 611 TARGET_OS_LIBRARIES(git2)
 612
 613 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 614 # Win64+MSVC+static libs = linker error
 615 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 616   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 617 ENDIF()
 618
 619 IDE_SPLIT_SOURCES(git2)
 620
 621 IF (SONAME)
 622         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 623         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 624         IF (LIBGIT2_FILENAME)
 625                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 626                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 627         ELSEIF (DEFINED LIBGIT2_PREFIX)
 628                 SET_TARGET_PROPERTIES(git2 PROPERTIES PREFIX "${LIBGIT2_PREFIX}")
 629         ENDIF()
 630 ENDIF()
 631 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 632 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 633
 634 IF (MSVC_IDE)
 635    # Precompiled headers
 636    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 637    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 638 ENDIF ()
 639
 640 # Install
 641 INSTALL(TARGETS git2
 642         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 643         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 644         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 645 )
 646 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 647 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 648 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 649
 650 # Tests
 651 IF (BUILD_CLAR)
 652         FIND_PACKAGE(PythonInterp)
 653
 654         IF(NOT PYTHONINTERP_FOUND)
 655           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 656             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 657         ENDIF()
 658
 659         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 660         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 661         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 662         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 663         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 664         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 665
 666         INCLUDE_DIRECTORIES(${CLAR_PATH})
 667         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 668         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 669
 670         ADD_CUSTOM_COMMAND(
 671                 OUTPUT ${CLAR_PATH}/clar.suite
 672                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 673                 DEPENDS ${SRC_TEST}
 674                 WORKING_DIRECTORY ${CLAR_PATH}
 675         )
 676
 677         SET_SOURCE_FILES_PROPERTIES(
 678                 ${CLAR_PATH}/clar.c
 679                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 680
 681         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 682
 683         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 684         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 685         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 686         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 687         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 688         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 689         TARGET_OS_LIBRARIES(libgit2_clar)
 690         IDE_SPLIT_SOURCES(libgit2_clar)
 691
 692         IF (MSVC_IDE)
 693                 # Precompiled headers
 694                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 695         ENDIF ()
 696
 697         ENABLE_TESTING()
 698         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 699                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 700         ELSE ()
 701                 ADD_TEST(libgit2_clar libgit2_clar -v)
 702         ENDIF ()
 703
 704         # Add a test target which runs the cred callback tests, to be
 705         # called after setting the url and user
 706         ADD_TEST(libgit2_clar-cred_callback libgit2_clar -v -sonline::clone::cred_callback)
 707         ADD_TEST(libgit2_clar-proxy_credentials_in_url libgit2_clar -v -sonline::clone::proxy_credentials_in_url)
 708         ADD_TEST(libgit2_clar-proxy_credentials_request libgit2_clar -v -sonline::clone::proxy_credentials_request)
 709 ENDIF ()
 710
 711 IF (TAGS)
 712         FIND_PROGRAM(CTAGS ctags)
 713         IF (NOT CTAGS)
 714                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 715         ENDIF ()
 716
 717         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 718
 719         ADD_CUSTOM_COMMAND(
 720                 OUTPUT tags
 721                 COMMAND ${CTAGS} -a ${SRC_ALL}
 722                 DEPENDS ${SRC_ALL}
 723         )
 724         ADD_CUSTOM_TARGET(
 725                 do_tags ALL
 726                 DEPENDS tags
 727         )
 728 ENDIF ()
 729
 730 IF (BUILD_EXAMPLES)
 731         ADD_SUBDIRECTORY(examples)
 732 ENDIF ()