CMakeLists.txt

   1 # CMake build script for the libgit2 project
   2 #
   3 # Building (out of source build):
   4 # > mkdir build && cd build
   5 # > cmake .. [-DSETTINGS=VALUE]
   6 # > cmake --build .
   7 #
   8 # Testing:
   9 # > ctest -V
  10 #
  11 # Install:
  12 # > cmake --build . --target install
  13
  14 PROJECT(libgit2 C)
  15 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  16 CMAKE_POLICY(SET CMP0015 NEW)
  17
  18 # Add find modules to the path
  19 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
  20
  21 INCLUDE(CheckLibraryExists)
  22 INCLUDE(CheckFunctionExists)
  23 INCLUDE(CheckStructHasMember)
  24 INCLUDE(AddCFlagIfSupported)
  25 INCLUDE(FindPkgConfig)
  26
  27 # Build options
  28 #
  29 OPTION( SONAME                          "Set the (SO)VERSION of the target"             ON  )
  30 OPTION( BUILD_SHARED_LIBS       "Build Shared Library (OFF for Static)" ON  )
  31 OPTION( THREADSAFE                      "Build libgit2 as threadsafe"                   ON )
  32 OPTION( BUILD_CLAR                      "Build Tests using the Clar suite"              ON  )
  33 OPTION( BUILD_EXAMPLES          "Build library usage example apps"              OFF )
  34 OPTION( TAGS                            "Generate tags"                                                 OFF )
  35 OPTION( PROFILE                         "Generate profiling information"                OFF )
  36 OPTION( ENABLE_TRACE            "Enables tracing support"                               OFF )
  37 OPTION( LIBGIT2_FILENAME        "Name of the produced binary"                   OFF )
  38
  39 OPTION( USE_ICONV                       "Link with and use iconv library"               OFF )
  40 OPTION( USE_SSH                         "Link with libssh to enable SSH support" ON )
  41 OPTION( USE_GSSAPI                      "Link with libgssapi for SPNEGO auth"   OFF )
  42 OPTION( VALGRIND                        "Configure build for valgrind"                  OFF )
  43 OPTION( CURL                    "Use curl for HTTP if available" ON)
  44 OPTION( DEBUG_POOL                      "Enable debug pool allocator"                   OFF )
  45
  46 IF(DEBUG_POOL)
  47         ADD_DEFINITIONS(-DGIT_DEBUG_POOL)
  48 ENDIF()
  49
  50 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  51         SET( USE_ICONV ON )
  52         FIND_PACKAGE(Security)
  53         FIND_PACKAGE(CoreFoundation REQUIRED)
  54 ENDIF()
  55
  56 IF(MSVC)
  57         # This option is only available when building with MSVC. By default, libgit2
  58         # is build using the cdecl calling convention, which is useful if you're
  59         # writing C. However, the CLR and Win32 API both expect stdcall.
  60         #
  61         # If you are writing a CLR program and want to link to libgit2, you'll want
  62         # to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
  63         OPTION( STDCALL                 "Build libgit2 with the __stdcall convention"   OFF  )
  64
  65         # This option must match the settings used in your program, in particular if you
  66         # are linking statically
  67         OPTION( STATIC_CRT              "Link the static CRT libraries" ON  )
  68
  69         # If you want to embed a copy of libssh2 into libgit2, pass a
  70         # path to libssh2
  71         OPTION( EMBED_SSH_PATH          "Path to libssh2 to embed (Windows)" OFF )
  72
  73         ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
  74         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
  75         ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  76 ENDIF()
  77
  78
  79 IF(WIN32)
  80         # By default, libgit2 is built with WinHTTP.  To use the built-in
  81         # HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
  82         OPTION( WINHTTP                 "Use Win32 WinHTTP routines"    ON      )
  83 ENDIF()
  84
  85 IF(MSVC)
  86         # Enable MSVC CRTDBG memory leak reporting when in debug mode.
  87         OPTION(MSVC_CRTDBG "Enable CRTDBG memory leak reporting" OFF)
  88 ENDIF()
  89
  90 IF (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  91         OPTION( USE_OPENSSL                     "Link with and use openssl library"             ON )
  92 ENDIF()
  93
  94 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtim "sys/types.h;sys/stat.h"
  95         HAVE_STRUCT_STAT_ST_MTIM LANGUAGE C)
  96 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtimespec "sys/types.h;sys/stat.h"
  97         HAVE_STRUCT_STAT_ST_MTIMESPEC LANGUAGE C)
  98 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_nsec sys/stat.h
  99         HAVE_STRUCT_STAT_MTIME_NSEC LANGUAGE C)
 100
 101 IF (HAVE_STRUCT_STAT_ST_MTIM)
 102         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 103                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 104 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 105         CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 106                 HAVE_STRUCT_STAT_NSEC LANGUAGE C)
 107 ELSE ()
 108         SET( HAVE_STRUCT_STAT_NSEC ON )
 109 ENDIF()
 110
 111 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 112         OPTION( USE_NSEC                "Care about sub-second file mtimes and ctimes"  OFF )
 113 ENDIF()
 114
 115 # This variable will contain the libraries we need to put into
 116 # libgit2.pc's Requires.private. That is, what we're linking to or
 117 # what someone who's statically linking us needs to link to.
 118 SET(LIBGIT2_PC_REQUIRES "")
 119 # This will be set later if we use the system's http-parser library or
 120 # use iconv (OSX) and will be written to the Libs.private field in the
 121 # pc file.
 122 SET(LIBGIT2_PC_LIBS "")
 123
 124 # Installation paths
 125 #
 126 SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
 127 SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
 128 SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
 129
 130 # Set a couple variables to be substituted inside the .pc file.
 131 # We can't just use LIB_INSTALL_DIR in the .pc file, as passing them as absolue
 132 # or relative paths is both valid and supported by cmake.
 133 SET (PKGCONFIG_PREFIX ${CMAKE_INSTALL_PREFIX})
 134
 135 IF(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 136   SET (PKGCONFIG_LIBDIR ${LIB_INSTALL_DIR})
 137 ELSE(IS_ABSOLUTE ${LIB_INSTALL_DIR})
 138   SET (PKGCONFIG_LIBDIR "\${prefix}/${LIB_INSTALL_DIR}")
 139 ENDIF (IS_ABSOLUTE ${LIB_INSTALL_DIR})
 140
 141 IF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 142   SET (PKGCONFIG_INCLUDEDIR ${INCLUDE_INSTALL_DIR})
 143 ELSE(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 144   SET (PKGCONFIG_INCLUDEDIR "\${prefix}/${INCLUDE_INSTALL_DIR}")
 145 ENDIF(IS_ABSOLUTE ${INCLUDE_INSTALL_DIR})
 146
 147 FUNCTION(TARGET_OS_LIBRARIES target)
 148         IF(WIN32)
 149                 TARGET_LINK_LIBRARIES(${target} ws2_32)
 150         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 151                 TARGET_LINK_LIBRARIES(${target} socket nsl)
 152                 LIST(APPEND LIBGIT2_PC_LIBS "-lsocket" "-lnsl")
 153                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 154         ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Haiku")
 155                 TARGET_LINK_LIBRARIES(${target} network)
 156                 LIST(APPEND LIBGIT2_PC_LIBS "-lnetwork")
 157                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 158         ENDIF()
 159         CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
 160         IF(NEED_LIBRT)
 161                 TARGET_LINK_LIBRARIES(${target} rt)
 162                 LIST(APPEND LIBGIT2_PC_LIBS "-lrt")
 163                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 164         ENDIF()
 165
 166         IF(THREADSAFE)
 167                 TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
 168                 LIST(APPEND LIBGIT2_PC_LIBS ${CMAKE_THREAD_LIBS_INIT})
 169                 SET(LIBGIT2_PC_LIBS ${LIBGIT2_PC_LIBS} PARENT_SCOPE)
 170         ENDIF()
 171 ENDFUNCTION()
 172
 173 # This function splits the sources files up into their appropriate
 174 # subdirectories.  This is especially useful for IDEs like Xcode and
 175 # Visual Studio, so that you can navigate into the libgit2_clar project,
 176 # and see the folders within the tests folder (instead of just seeing all
 177 # source and tests in a single folder.)
 178 FUNCTION(IDE_SPLIT_SOURCES target)
 179         IF(MSVC_IDE OR CMAKE_GENERATOR STREQUAL Xcode)
 180                 GET_TARGET_PROPERTY(sources ${target} SOURCES)
 181                 FOREACH(source ${sources})
 182                         IF(source MATCHES ".*/")
 183                                 STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
 184                                 IF(rel)
 185                                         STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
 186                                         IF(rel)
 187                                                 STRING(REPLACE "/" "\\\\" rel ${rel})
 188                                                 SOURCE_GROUP(${rel} FILES ${source})
 189                                         ENDIF()
 190                                 ENDIF()
 191                         ENDIF()
 192                 ENDFOREACH()
 193         ENDIF()
 194 ENDFUNCTION()
 195
 196 FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
 197
 198 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
 199 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
 200 STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
 201 SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
 202
 203 FILE(STRINGS "include/git2/version.h" GIT2_HEADER_SOVERSION REGEX "^#define LIBGIT2_SOVERSION [0-9]+$")
 204 STRING(REGEX REPLACE "^.*LIBGIT2_SOVERSION ([0-9]+)$" "\\1" LIBGIT2_SOVERSION "${GIT2_HEADER_SOVERSION}")
 205
 206 # Find required dependencies
 207 INCLUDE_DIRECTORIES(src include)
 208
 209 IF (SECURITY_FOUND)
 210   # OS X 10.7 and older do not have some functions we use, fall back to OpenSSL there
 211   CHECK_LIBRARY_EXISTS("${SECURITY_DIRS}" SSLCreateContext "Security/SecureTransport.h" HAVE_NEWER_SECURITY)
 212   IF (HAVE_NEWER_SECURITY)
 213     MESSAGE("-- Found Security ${SECURITY_DIRS}")
 214     LIST(APPEND LIBGIT2_PC_LIBS "-framework Security")
 215   ELSE()
 216     MESSAGE("-- Security framework is too old, falling back to OpenSSL")
 217     SET(SECURITY_FOUND "NO")
 218     SET(SECURITY_DIRS "")
 219     SET(SECURITY_DIR "")
 220     SET(USE_OPENSSL "ON")
 221   ENDIF()
 222 ENDIF()
 223
 224 IF (COREFOUNDATION_FOUND)
 225   MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_DIRS}")
 226   LIST(APPEND LIBGIT2_PC_LIBS "-framework CoreFoundation")
 227 ENDIF()
 228
 229
 230 IF (WIN32 AND EMBED_SSH_PATH)
 231         FILE(GLOB SRC_SSH "${EMBED_SSH_PATH}/src/*.c")
 232         INCLUDE_DIRECTORIES("${EMBED_SSH_PATH}/include")
 233         FILE(WRITE "${EMBED_SSH_PATH}/src/libssh2_config.h" "#define HAVE_WINCNG\n#define LIBSSH2_WINCNG\n#include \"../win32/libssh2_config.h\"")
 234         ADD_DEFINITIONS(-DGIT_SSH)
 235 ENDIF()
 236
 237 IF (WIN32 AND WINHTTP)
 238         ADD_DEFINITIONS(-DGIT_WINHTTP)
 239         INCLUDE_DIRECTORIES(deps/http-parser)
 240         FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 241
 242         # Since MinGW does not come with headers or an import library for winhttp,
 243         # we have to include a private header and generate our own import library
 244         IF (MINGW)
 245                 FIND_PROGRAM(DLLTOOL dlltool CMAKE_FIND_ROOT_PATH_BOTH)
 246                 IF (NOT DLLTOOL)
 247                         MESSAGE(FATAL_ERROR "Could not find dlltool command")
 248                 ENDIF ()
 249
 250                 SET(LIBWINHTTP_PATH "${CMAKE_CURRENT_BINARY_DIR}/deps/winhttp")
 251                 FILE(MAKE_DIRECTORY ${LIBWINHTTP_PATH})
 252
 253                 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 254                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp64.def")
 255                 ELSE()
 256                         set(WINHTTP_DEF "${CMAKE_CURRENT_SOURCE_DIR}/deps/winhttp/winhttp.def")
 257                 ENDIF()
 258
 259                 ADD_CUSTOM_COMMAND(
 260                         OUTPUT ${LIBWINHTTP_PATH}/libwinhttp.a
 261                         COMMAND ${DLLTOOL} -d ${WINHTTP_DEF} -k -D winhttp.dll -l libwinhttp.a
 262                         DEPENDS ${WINHTTP_DEF}
 263                         WORKING_DIRECTORY ${LIBWINHTTP_PATH}
 264                 )
 265
 266                 SET_SOURCE_FILES_PROPERTIES(
 267                         ${CMAKE_CURRENT_SOURCE_DIR}/src/transports/winhttp.c
 268                         PROPERTIES OBJECT_DEPENDS ${LIBWINHTTP_PATH}/libwinhttp.a
 269                 )
 270
 271                 INCLUDE_DIRECTORIES(deps/winhttp)
 272                 LINK_DIRECTORIES(${LIBWINHTTP_PATH})
 273         ENDIF ()
 274
 275         LINK_LIBRARIES(winhttp rpcrt4 crypt32 ole32)
 276         LIST(APPEND LIBGIT2_PC_LIBS "-lwinhttp" "-lrpcrt4" "-lcrypt32" "-lole32")
 277 ELSE ()
 278         IF (CURL)
 279                 PKG_CHECK_MODULES(CURL libcurl)
 280         ENDIF ()
 281
 282         IF (NOT AMIGA AND USE_OPENSSL)
 283                 FIND_PACKAGE(OpenSSL)
 284         ENDIF ()
 285
 286         IF (CURL_FOUND)
 287                 ADD_DEFINITIONS(-DGIT_CURL)
 288                 INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIRS})
 289                 LINK_DIRECTORIES(${CURL_LIBRARY_DIRS})
 290                 LINK_LIBRARIES(${CURL_LIBRARIES})
 291                 LIST(APPEND LIBGIT2_PC_LIBS ${CURL_LDFLAGS})
 292         ENDIF()
 293
 294         FIND_PACKAGE(HTTP_Parser)
 295         IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
 296                 INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
 297                 LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
 298                 LIST(APPEND LIBGIT2_PC_LIBS "-lhttp_parser")
 299         ELSE()
 300                 MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
 301                 INCLUDE_DIRECTORIES(deps/http-parser)
 302                 FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
 303         ENDIF()
 304 ENDIF()
 305
 306 # Specify sha1 implementation
 307 IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
 308         ADD_DEFINITIONS(-DWIN32_SHA1)
 309         FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
 310 ELSEIF (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 311         ADD_DEFINITIONS(-DGIT_COMMON_CRYPTO)
 312 ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
 313         ADD_DEFINITIONS(-DOPENSSL_SHA1)
 314         IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 315                 LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
 316         ELSE()
 317                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
 318         ENDIF ()
 319 ELSE()
 320         FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
 321 ENDIF()
 322
 323 # Enable tracing
 324 IF (ENABLE_TRACE STREQUAL "ON")
 325         ADD_DEFINITIONS(-DGIT_TRACE)
 326 ENDIF()
 327
 328 # Include POSIX regex when it is required
 329 IF(WIN32 OR AMIGA OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 330         INCLUDE_DIRECTORIES(deps/regex)
 331         SET(SRC_REGEX deps/regex/regex.c)
 332 ENDIF()
 333
 334 # Optional external dependency: zlib
 335 FIND_PACKAGE(ZLIB)
 336 IF (ZLIB_FOUND)
 337         INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
 338         LINK_LIBRARIES(${ZLIB_LIBRARIES})
 339         IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 340                 LIST(APPEND LIBGIT2_PC_LIBS "-lz")
 341         ELSE()
 342                 SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
 343         ENDIF()
 344 ELSE()
 345         MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
 346         INCLUDE_DIRECTORIES(deps/zlib)
 347         ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
 348         FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
 349 ENDIF()
 350
 351 # Optional external dependency: libssh2
 352 IF (USE_SSH)
 353         PKG_CHECK_MODULES(LIBSSH2 libssh2)
 354 ENDIF()
 355 IF (LIBSSH2_FOUND)
 356         ADD_DEFINITIONS(-DGIT_SSH)
 357         INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIRS})
 358         LINK_DIRECTORIES(${LIBSSH2_LIBRARY_DIRS})
 359         LIST(APPEND LIBGIT2_PC_LIBS ${LIBSSH2_LDFLAGS})
 360         #SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${LIBSSH2_LDFLAGS}")
 361         SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
 362
 363         CHECK_LIBRARY_EXISTS("${LIBSSH2_LIBRARIES}" libssh2_userauth_publickey_frommemory "${LIBSSH2_LIBRARY_DIRS}" HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 364         IF (HAVE_LIBSSH2_MEMORY_CREDENTIALS)
 365                 ADD_DEFINITIONS(-DGIT_SSH_MEMORY_CREDENTIALS)
 366         ENDIF()
 367 ELSE()
 368         MESSAGE(STATUS "LIBSSH2 not found. Set CMAKE_PREFIX_PATH if it is installed outside of the default search path.")
 369 ENDIF()
 370
 371 # Optional external dependency: libgssapi
 372 IF (USE_GSSAPI)
 373         FIND_PACKAGE(GSSAPI)
 374 ENDIF()
 375 IF (GSSAPI_FOUND)
 376         ADD_DEFINITIONS(-DGIT_GSSAPI)
 377 ENDIF()
 378
 379 # Optional external dependency: iconv
 380 IF (USE_ICONV)
 381         FIND_PACKAGE(Iconv)
 382 ENDIF()
 383 IF (ICONV_FOUND)
 384         ADD_DEFINITIONS(-DGIT_USE_ICONV)
 385         INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 386         LIST(APPEND LIBGIT2_PC_LIBS ${ICONV_LIBRARIES})
 387 ENDIF()
 388
 389 # Platform specific compilation flags
 390 IF (MSVC)
 391
 392         STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 393
 394         # /GF - String pooling
 395         # /MP - Parallel build
 396         SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
 397
 398         IF (STDCALL)
 399                 # /Gz - stdcall calling convention
 400                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
 401         ENDIF ()
 402
 403         IF (STATIC_CRT)
 404                 SET(CRT_FLAG_DEBUG "/MTd")
 405                 SET(CRT_FLAG_RELEASE "/MT")
 406         ELSE()
 407                 SET(CRT_FLAG_DEBUG "/MDd")
 408                 SET(CRT_FLAG_RELEASE "/MD")
 409         ENDIF()
 410
 411         IF (MSVC_CRTDBG)
 412                 SET(CRT_FLAG_DEBUG "${CRT_FLAG_DEBUG} /DGIT_MSVC_CRTDBG")
 413                 SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}" "Dbghelp.lib")
 414         ENDIF()
 415
 416         # /Zi - Create debugging information
 417         # /Od - Disable optimization
 418         # /D_DEBUG - #define _DEBUG
 419         # /MTd - Statically link the multithreaded debug version of the CRT
 420         # /MDd - Dynamically link the multithreaded debug version of the CRT
 421         # /RTC1 - Run time checks
 422         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
 423
 424         # /DNDEBUG - Disables asserts
 425         # /MT - Statically link the multithreaded release version of the CRT
 426         # /MD - Dynamically link the multithreaded release version of the CRT
 427         # /O2 - Optimize for speed
 428         # /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
 429         # /GL - Link time code generation (whole program optimization)
 430         # /Gy - Function-level linking
 431         SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 432
 433         # /Oy- - Disable frame pointer omission (FPO)
 434         SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
 435
 436         # /O1 - Optimize for size
 437         SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
 438
 439         # /DYNAMICBASE - Address space load randomization (ASLR)
 440         # /NXCOMPAT - Data execution prevention (DEP)
 441         # /LARGEADDRESSAWARE - >2GB user address space on x86
 442         # /VERSION - Embed version information in PE header
 443         SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
 444
 445         # /DEBUG - Create a PDB
 446         # /LTCG - Link time code generation (whole program optimization)
 447         # /OPT:REF /OPT:ICF - Fold out duplicate code at link step
 448         # /INCREMENTAL:NO - Required to use /LTCG
 449         # /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
 450         SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
 451         SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 452         SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
 453         SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
 454
 455         # Same linker settings for DLL as EXE
 456         SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 457         SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 458         SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 459         SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 460         SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 461
 462         SET(WIN_RC "src/win32/git2.rc")
 463
 464    # Precompiled headers
 465
 466 ELSE ()
 467         SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
 468
 469         IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
 470                 SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
 471         ENDIF()
 472
 473         IF (WIN32 AND NOT CYGWIN)
 474                 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 475         ENDIF ()
 476
 477         IF (MINGW OR MSYS) # MinGW and MSYS always do PIC and complain if we tell them to
 478                 STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
 479         ELSEIF (BUILD_SHARED_LIBS)
 480                 ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
 481
 482                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 483         ENDIF ()
 484
 485         IF (MINGW)
 486                 # MinGW >= 3.14 uses the C99-style stdio functions
 487                 # automatically, but forks like mingw-w64 still want
 488                 # us to define this in order to use them
 489                 ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
 490         ENDIF ()
 491
 492         ADD_C_FLAG_IF_SUPPORTED(-Wdocumentation)
 493         ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
 494         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
 495         ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
 496         ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
 497         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
 498         ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
 499
 500         IF (APPLE) # Apple deprecated OpenSSL
 501                 ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
 502         ENDIF()
 503
 504         IF (PROFILE)
 505                 SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
 506                 SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
 507         ENDIF ()
 508 ENDIF()
 509
 510 CHECK_FUNCTION_EXISTS(futimens HAVE_FUTIMENS)
 511 IF (HAVE_FUTIMENS)
 512         ADD_DEFINITIONS(-DHAVE_FUTIMENS)
 513 ENDIF ()
 514
 515 CHECK_FUNCTION_EXISTS(qsort_r HAVE_QSORT_R)
 516 IF (HAVE_QSORT_R)
 517         ADD_DEFINITIONS(-DHAVE_QSORT_R)
 518 ENDIF ()
 519
 520 CHECK_FUNCTION_EXISTS(qsort_s HAVE_QSORT_S)
 521 IF (HAVE_QSORT_S)
 522         ADD_DEFINITIONS(-DHAVE_QSORT_S)
 523 ENDIF ()
 524
 525 IF( NOT CMAKE_CONFIGURATION_TYPES )
 526         # Build Debug by default
 527         IF (NOT CMAKE_BUILD_TYPE)
 528                 SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
 529         ENDIF ()
 530 ELSE()
 531         # Using a multi-configuration generator eg MSVC or Xcode
 532         # that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
 533 ENDIF()
 534
 535 IF (SECURITY_FOUND)
 536   ADD_DEFINITIONS(-DGIT_SECURE_TRANSPORT)
 537   INCLUDE_DIRECTORIES(${SECURITY_INCLUDE_DIR})
 538 ENDIF ()
 539
 540 IF (OPENSSL_FOUND)
 541   ADD_DEFINITIONS(-DGIT_OPENSSL)
 542   INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 543   SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 544 ENDIF()
 545
 546
 547
 548 IF (THREADSAFE)
 549         IF (NOT WIN32)
 550                 FIND_PACKAGE(Threads REQUIRED)
 551         ENDIF()
 552
 553         ADD_DEFINITIONS(-DGIT_THREADS)
 554 ENDIF()
 555
 556 IF (USE_NSEC)
 557         ADD_DEFINITIONS(-DGIT_USE_NSEC)
 558 ENDIF()
 559
 560 IF (HAVE_STRUCT_STAT_ST_MTIM)
 561         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIM)
 562 ELSEIF (HAVE_STRUCT_STAT_ST_MTIMESPEC)
 563         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIMESPEC)
 564 ELSEIF (HAVE_STRUCT_STAT_ST_MTIME_NSEC)
 565         ADD_DEFINITIONS(-DGIT_USE_STAT_MTIME_NSEC)
 566 ENDIF()
 567
 568 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 569
 570 # Collect sourcefiles
 571 FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)
 572
 573 # On Windows use specific platform sources
 574 IF (WIN32 AND NOT CYGWIN)
 575         ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
 576         FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
 577 ELSEIF (AMIGA)
 578         ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
 579 ELSE()
 580         IF (VALGRIND)
 581                 ADD_DEFINITIONS(-DNO_MMAP)
 582         ENDIF()
 583         FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
 584 ENDIF()
 585 FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)
 586
 587 # Determine architecture of the machine
 588 IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
 589         ADD_DEFINITIONS(-DGIT_ARCH_64)
 590 ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
 591         ADD_DEFINITIONS(-DGIT_ARCH_32)
 592 ELSE()
 593         MESSAGE(FATAL_ERROR "Unsupported architecture")
 594 ENDIF()
 595
 596 # Compile and link libgit2
 597 ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1} ${WIN_RC})
 598 TARGET_LINK_LIBRARIES(git2 ${SECURITY_DIRS})
 599 TARGET_LINK_LIBRARIES(git2 ${COREFOUNDATION_DIRS})
 600 TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
 601 TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
 602 TARGET_LINK_LIBRARIES(git2 ${GSSAPI_LIBRARIES})
 603 TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
 604 TARGET_OS_LIBRARIES(git2)
 605
 606 # Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
 607 # Win64+MSVC+static libs = linker error
 608 IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
 609   SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
 610 ENDIF()
 611
 612 IDE_SPLIT_SOURCES(git2)
 613
 614 IF (SONAME)
 615         SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
 616         SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_SOVERSION})
 617         IF (LIBGIT2_FILENAME)
 618                 ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
 619                 SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
 620         ELSEIF (DEFINED LIBGIT2_PREFIX)
 621                 SET_TARGET_PROPERTIES(git2 PROPERTIES PREFIX "${LIBGIT2_PREFIX}")
 622         ENDIF()
 623 ENDIF()
 624 STRING(REPLACE ";" " " LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS}")
 625 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
 626
 627 IF (MSVC_IDE)
 628    # Precompiled headers
 629    SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 630    SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
 631 ENDIF ()
 632
 633 # Install
 634 INSTALL(TARGETS git2
 635         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 636         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 637         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 638 )
 639 INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 640 INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
 641 INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
 642
 643 # Tests
 644 IF (BUILD_CLAR)
 645         FIND_PACKAGE(PythonInterp)
 646
 647         IF(NOT PYTHONINTERP_FOUND)
 648           MESSAGE(FATAL_ERROR "Could not find a python interpeter, which is needed to build the tests. "
 649             "Make sure python is available, or pass -DBUILD_CLAR=OFF to skip building the tests")
 650         ENDIF()
 651
 652         SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
 653         SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
 654         SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
 655         ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
 656         ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
 657         ADD_DEFINITIONS(-DCLAR_TMPDIR=\"libgit2_tests\")
 658
 659         INCLUDE_DIRECTORIES(${CLAR_PATH})
 660         FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
 661         SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar_libgit2_trace.c" "${CLAR_PATH}/clar_libgit2_timer.c" "${CLAR_PATH}/clar.c")
 662
 663         ADD_CUSTOM_COMMAND(
 664                 OUTPUT ${CLAR_PATH}/clar.suite
 665                 COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
 666                 DEPENDS ${SRC_TEST}
 667                 WORKING_DIRECTORY ${CLAR_PATH}
 668         )
 669
 670         SET_SOURCE_FILES_PROPERTIES(
 671                 ${CLAR_PATH}/clar.c
 672                 PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
 673
 674         ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SSH} ${SRC_SHA1})
 675
 676         TARGET_LINK_LIBRARIES(libgit2_clar ${COREFOUNDATION_DIRS})
 677         TARGET_LINK_LIBRARIES(libgit2_clar ${SECURITY_DIRS})
 678         TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
 679         TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
 680         TARGET_LINK_LIBRARIES(libgit2_clar ${GSSAPI_LIBRARIES})
 681         TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
 682         TARGET_OS_LIBRARIES(libgit2_clar)
 683         IDE_SPLIT_SOURCES(libgit2_clar)
 684
 685         IF (MSVC_IDE)
 686                 # Precompiled headers
 687                 SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
 688         ENDIF ()
 689
 690         ENABLE_TESTING()
 691         IF (WINHTTP OR OPENSSL_FOUND OR SECURITY_FOUND)
 692                 ADD_TEST(libgit2_clar libgit2_clar -ionline)
 693         ELSE ()
 694                 ADD_TEST(libgit2_clar libgit2_clar -v)
 695         ENDIF ()
 696
 697         # Add a test target which runs the cred callback tests, to be
 698         # called after setting the url and user
 699         ADD_TEST(libgit2_clar-cred_callback libgit2_clar -v -sonline::clone::cred_callback)
 700 ENDIF ()
 701
 702 IF (TAGS)
 703         FIND_PROGRAM(CTAGS ctags)
 704         IF (NOT CTAGS)
 705                 MESSAGE(FATAL_ERROR "Could not find ctags command")
 706         ENDIF ()
 707
 708         FILE(GLOB_RECURSE SRC_ALL *.[ch])
 709
 710         ADD_CUSTOM_COMMAND(
 711                 OUTPUT tags
 712                 COMMAND ${CTAGS} -a ${SRC_ALL}
 713                 DEPENDS ${SRC_ALL}
 714         )
 715         ADD_CUSTOM_TARGET(
 716                 do_tags ALL
 717                 DEPENDS tags
 718         )
 719 ENDIF ()
 720
 721 IF (BUILD_EXAMPLES)
 722         ADD_SUBDIRECTORY(examples)
 723 ENDIF ()