PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use POSIX;
   8 use IO::Socket::IP;
   9 use URI::Escape;
  10
  11 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  12 use PVE::RRD;
  13 use PVE::SafeSyslog;
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  16 use PVE::Storage;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use PVE::RESTHandler;
  19 use PVE::ReplicationConfig;
  20 use PVE::GuestHelpers;
  21 use PVE::QemuConfig;
  22 use PVE::QemuServer;
  23 use PVE::QemuServer::Drive;
  24 use PVE::QemuServer::Monitor qw(mon_cmd);
  25 use PVE::QemuMigrate;
  26 use PVE::RPCEnvironment;
  27 use PVE::AccessControl;
  28 use PVE::INotify;
  29 use PVE::Network;
  30 use PVE::Firewall;
  31 use PVE::API2::Firewall::VM;
  32 use PVE::API2::Qemu::Agent;
  33 use PVE::VZDump::Plugin;
  34 use PVE::DataCenterConfig;
  35 use PVE::SSHInfo;
  36
  37 BEGIN {
  38     if (!$ENV{PVE_GENERATING_DOCS}) {
  39         require PVE::HA::Env::PVE2;
  40         import PVE::HA::Env::PVE2;
  41         require PVE::HA::Config;
  42         import PVE::HA::Config;
  43     }
  44 }
  45
  46 use Data::Dumper; # fixme: remove
  47
  48 use base qw(PVE::RESTHandler);
  49
  50 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  51
  52 my $resolve_cdrom_alias = sub {
  53     my $param = shift;
  54
  55     if (my $value = $param->{cdrom}) {
  56         $value .= ",media=cdrom" if $value !~ m/media=/;
  57         $param->{ide2} = $value;
  58         delete $param->{cdrom};
  59     }
  60 };
  61
  62 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  63 my $check_storage_access = sub {
  64    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  65
  66    PVE::QemuServer::foreach_drive($settings, sub {
  67         my ($ds, $drive) = @_;
  68
  69         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  70
  71         my $volid = $drive->{file};
  72         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  73
  74         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit' || (defined($volname) && $volname eq 'cloudinit'))) {
  75             # nothing to check
  76         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  77             $rpcenv->check($authuser, "/", ['Sys.Console']);
  78         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  79             my ($storeid, $size) = ($2 || $default_storage, $3);
  80             die "no storage ID specified (and no default storage)\n" if !$storeid;
  81             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  82             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  83             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  84                 if !$scfg->{content}->{images};
  85         } else {
  86             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  87         }
  88     });
  89
  90    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  91        if defined($settings->{vmstatestorage});
  92 };
  93
  94 my $check_storage_access_clone = sub {
  95    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  96
  97    my $sharedvm = 1;
  98
  99    PVE::QemuServer::foreach_drive($conf, sub {
 100         my ($ds, $drive) = @_;
 101
 102         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
 103
 104         my $volid = $drive->{file};
 105
 106         return if !$volid || $volid eq 'none';
 107
 108         if ($isCDROM) {
 109             if ($volid eq 'cdrom') {
 110                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 111             } else {
 112                 # we simply allow access
 113                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 114                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 115                 $sharedvm = 0 if !$scfg->{shared};
 116
 117             }
 118         } else {
 119             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 120             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 121             $sharedvm = 0 if !$scfg->{shared};
 122
 123             $sid = $storage if $storage;
 124             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 125         }
 126     });
 127
 128    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 129        if defined($conf->{vmstatestorage});
 130
 131    return $sharedvm;
 132 };
 133
 134 # Note: $pool is only needed when creating a VM, because pool permissions
 135 # are automatically inherited if VM already exists inside a pool.
 136 my $create_disks = sub {
 137     my ($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 138
 139     my $vollist = [];
 140
 141     my $res = {};
 142
 143     my $code = sub {
 144         my ($ds, $disk) = @_;
 145
 146         my $volid = $disk->{file};
 147         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 148
 149         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 150             delete $disk->{size};
 151             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 152         } elsif (defined($volname) && $volname eq 'cloudinit') {
 153             $storeid = $storeid // $default_storage;
 154             die "no storage ID specified (and no default storage)\n" if !$storeid;
 155             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 156             my $name = "vm-$vmid-cloudinit";
 157
 158             my $fmt = undef;
 159             if ($scfg->{path}) {
 160                 $fmt = $disk->{format} // "qcow2";
 161                 $name .= ".$fmt";
 162             } else {
 163                 $fmt = $disk->{format} // "raw";
 164             }
 165
 166             # Initial disk created with 4 MB and aligned to 4MB on regeneration
 167             my $ci_size = PVE::QemuServer::Cloudinit::CLOUDINIT_DISK_SIZE;
 168             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, $name, $ci_size/1024);
 169             $disk->{file} = $volid;
 170             $disk->{media} = 'cdrom';
 171             push @$vollist, $volid;
 172             delete $disk->{format}; # no longer needed
 173             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 174         } elsif ($volid =~ $NEW_DISK_RE) {
 175             my ($storeid, $size) = ($2 || $default_storage, $3);
 176             die "no storage ID specified (and no default storage)\n" if !$storeid;
 177             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 178             my $fmt = $disk->{format} || $defformat;
 179
 180             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 181
 182             my $volid;
 183             if ($ds eq 'efidisk0') {
 184                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt, $arch);
 185             } else {
 186                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 187             }
 188             push @$vollist, $volid;
 189             $disk->{file} = $volid;
 190             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 191             delete $disk->{format}; # no longer needed
 192             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 193         } else {
 194
 195             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 196
 197             my $volid_is_new = 1;
 198
 199             if ($conf->{$ds}) {
 200                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 201                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 202             }
 203
 204             if ($volid_is_new) {
 205
 206                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 207
 208                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 209
 210                 die "volume $volid does not exist\n" if !$size;
 211
 212                 $disk->{size} = $size;
 213             }
 214
 215             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 216         }
 217     };
 218
 219     eval { PVE::QemuServer::foreach_drive($settings, $code); };
 220
 221     # free allocated images on error
 222     if (my $err = $@) {
 223         syslog('err', "VM $vmid creating disks failed");
 224         foreach my $volid (@$vollist) {
 225             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 226             warn $@ if $@;
 227         }
 228         die $err;
 229     }
 230
 231     # modify vm config if everything went well
 232     foreach my $ds (keys %$res) {
 233         $conf->{$ds} = $res->{$ds};
 234     }
 235
 236     return $vollist;
 237 };
 238
 239 my $cpuoptions = {
 240     'cores' => 1,
 241     'cpu' => 1,
 242     'cpulimit' => 1,
 243     'cpuunits' => 1,
 244     'numa' => 1,
 245     'smp' => 1,
 246     'sockets' => 1,
 247     'vcpus' => 1,
 248 };
 249
 250 my $memoryoptions = {
 251     'memory' => 1,
 252     'balloon' => 1,
 253     'shares' => 1,
 254 };
 255
 256 my $hwtypeoptions = {
 257     'acpi' => 1,
 258     'hotplug' => 1,
 259     'kvm' => 1,
 260     'machine' => 1,
 261     'scsihw' => 1,
 262     'smbios1' => 1,
 263     'tablet' => 1,
 264     'vga' => 1,
 265     'watchdog' => 1,
 266     'audio0' => 1,
 267 };
 268
 269 my $generaloptions = {
 270     'agent' => 1,
 271     'autostart' => 1,
 272     'bios' => 1,
 273     'description' => 1,
 274     'keyboard' => 1,
 275     'localtime' => 1,
 276     'migrate_downtime' => 1,
 277     'migrate_speed' => 1,
 278     'name' => 1,
 279     'onboot' => 1,
 280     'ostype' => 1,
 281     'protection' => 1,
 282     'reboot' => 1,
 283     'startdate' => 1,
 284     'startup' => 1,
 285     'tdf' => 1,
 286     'template' => 1,
 287     'tags' => 1,
 288 };
 289
 290 my $vmpoweroptions = {
 291     'freeze' => 1,
 292 };
 293
 294 my $diskoptions = {
 295     'boot' => 1,
 296     'bootdisk' => 1,
 297     'vmstatestorage' => 1,
 298 };
 299
 300 my $cloudinitoptions = {
 301     cicustom => 1,
 302     cipassword => 1,
 303     citype => 1,
 304     ciuser => 1,
 305     nameserver => 1,
 306     searchdomain => 1,
 307     sshkeys => 1,
 308 };
 309
 310 my $check_vm_modify_config_perm = sub {
 311     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 312
 313     return 1 if $authuser eq 'root@pam';
 314
 315     foreach my $opt (@$key_list) {
 316         # some checks (e.g., disk, serial port, usb) need to be done somewhere
 317         # else, as there the permission can be value dependend
 318         next if PVE::QemuServer::is_valid_drivename($opt);
 319         next if $opt eq 'cdrom';
 320         next if $opt =~ m/^(?:unused|serial|usb)\d+$/;
 321
 322
 323         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 324             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 325         } elsif ($memoryoptions->{$opt}) {
 326             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 327         } elsif ($hwtypeoptions->{$opt}) {
 328             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 329         } elsif ($generaloptions->{$opt}) {
 330             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 331             # special case for startup since it changes host behaviour
 332             if ($opt eq 'startup') {
 333                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 334             }
 335         } elsif ($vmpoweroptions->{$opt}) {
 336             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 337         } elsif ($diskoptions->{$opt}) {
 338             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 339         } elsif ($cloudinitoptions->{$opt} || ($opt =~ m/^(?:net|ipconfig)\d+$/)) {
 340             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 341         } elsif ($opt eq 'vmstate') {
 342             # the user needs Disk and PowerMgmt privileges to change the vmstate
 343             # also needs privileges on the storage, that will be checked later
 344             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk', 'VM.PowerMgmt' ]);
 345         } else {
 346             # catches hostpci\d+, args, lock, etc.
 347             # new options will be checked here
 348             die "only root can set '$opt' config\n";
 349         }
 350     }
 351
 352     return 1;
 353 };
 354
 355 __PACKAGE__->register_method({
 356     name => 'vmlist',
 357     path => '',
 358     method => 'GET',
 359     description => "Virtual machine index (per node).",
 360     permissions => {
 361         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 362         user => 'all',
 363     },
 364     proxyto => 'node',
 365     protected => 1, # qemu pid files are only readable by root
 366     parameters => {
 367         additionalProperties => 0,
 368         properties => {
 369             node => get_standard_option('pve-node'),
 370             full => {
 371                 type => 'boolean',
 372                 optional => 1,
 373                 description => "Determine the full status of active VMs.",
 374             },
 375         },
 376     },
 377     returns => {
 378         type => 'array',
 379         items => {
 380             type => "object",
 381             properties => $PVE::QemuServer::vmstatus_return_properties,
 382         },
 383         links => [ { rel => 'child', href => "{vmid}" } ],
 384     },
 385     code => sub {
 386         my ($param) = @_;
 387
 388         my $rpcenv = PVE::RPCEnvironment::get();
 389         my $authuser = $rpcenv->get_user();
 390
 391         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 392
 393         my $res = [];
 394         foreach my $vmid (keys %$vmstatus) {
 395             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 396
 397             my $data = $vmstatus->{$vmid};
 398             push @$res, $data;
 399         }
 400
 401         return $res;
 402     }});
 403
 404 my $parse_restore_archive = sub {
 405     my ($storecfg, $archive) = @_;
 406
 407     my ($archive_storeid, $archive_volname) = PVE::Storage::parse_volume_id($archive);
 408
 409     if (defined($archive_storeid)) {
 410         my $scfg =  PVE::Storage::storage_config($storecfg, $archive_storeid);
 411         if ($scfg->{type} eq 'pbs') {
 412             return {
 413                 type => 'pbs',
 414                 volid => $archive,
 415             };
 416         }
 417     }
 418     my $path = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 419     return {
 420         type => 'file',
 421         path => $path,
 422     };
 423 };
 424
 425
 426 __PACKAGE__->register_method({
 427     name => 'create_vm',
 428     path => '',
 429     method => 'POST',
 430     description => "Create or restore a virtual machine.",
 431     permissions => {
 432         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 433             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 434             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 435         user => 'all', # check inside
 436     },
 437     protected => 1,
 438     proxyto => 'node',
 439     parameters => {
 440         additionalProperties => 0,
 441         properties => PVE::QemuServer::json_config_properties(
 442             {
 443                 node => get_standard_option('pve-node'),
 444                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 445                 archive => {
 446                     description => "The backup archive. Either the file system path to a .tar or .vma file (use '-' to pipe data from stdin) or a proxmox storage backup volume identifier.",
 447                     type => 'string',
 448                     optional => 1,
 449                     maxLength => 255,
 450                     completion => \&PVE::QemuServer::complete_backup_archives,
 451                 },
 452                 storage => get_standard_option('pve-storage-id', {
 453                     description => "Default storage.",
 454                     optional => 1,
 455                     completion => \&PVE::QemuServer::complete_storage,
 456                 }),
 457                 force => {
 458                     optional => 1,
 459                     type => 'boolean',
 460                     description => "Allow to overwrite existing VM.",
 461                     requires => 'archive',
 462                 },
 463                 unique => {
 464                     optional => 1,
 465                     type => 'boolean',
 466                     description => "Assign a unique random ethernet address.",
 467                     requires => 'archive',
 468                 },
 469                 pool => {
 470                     optional => 1,
 471                     type => 'string', format => 'pve-poolid',
 472                     description => "Add the VM to the specified pool.",
 473                 },
 474                 bwlimit => {
 475                     description => "Override I/O bandwidth limit (in KiB/s).",
 476                     optional => 1,
 477                     type => 'integer',
 478                     minimum => '0',
 479                     default => 'restore limit from datacenter or storage config',
 480                 },
 481                 start => {
 482                     optional => 1,
 483                     type => 'boolean',
 484                     default => 0,
 485                     description => "Start VM after it was created successfully.",
 486                 },
 487             }),
 488     },
 489     returns => {
 490         type => 'string',
 491     },
 492     code => sub {
 493         my ($param) = @_;
 494
 495         my $rpcenv = PVE::RPCEnvironment::get();
 496         my $authuser = $rpcenv->get_user();
 497
 498         my $node = extract_param($param, 'node');
 499         my $vmid = extract_param($param, 'vmid');
 500
 501         my $archive = extract_param($param, 'archive');
 502         my $is_restore = !!$archive;
 503
 504         my $bwlimit = extract_param($param, 'bwlimit');
 505         my $force = extract_param($param, 'force');
 506         my $pool = extract_param($param, 'pool');
 507         my $start_after_create = extract_param($param, 'start');
 508         my $storage = extract_param($param, 'storage');
 509         my $unique = extract_param($param, 'unique');
 510
 511         if (defined(my $ssh_keys = $param->{sshkeys})) {
 512                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 513                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 514         }
 515
 516         PVE::Cluster::check_cfs_quorum();
 517
 518         my $filename = PVE::QemuConfig->config_file($vmid);
 519         my $storecfg = PVE::Storage::config();
 520
 521         if (defined($pool)) {
 522             $rpcenv->check_pool_exist($pool);
 523         }
 524
 525         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 526             if defined($storage);
 527
 528         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 529             # OK
 530         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 531             # OK
 532         } elsif ($archive && $force && (-f $filename) &&
 533                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 534             # OK: user has VM.Backup permissions, and want to restore an existing VM
 535         } else {
 536             raise_perm_exc();
 537         }
 538
 539         if (!$archive) {
 540             &$resolve_cdrom_alias($param);
 541
 542             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 543
 544             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 545
 546             foreach my $opt (keys %$param) {
 547                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 548                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 549                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 550
 551                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 552                     $param->{$opt} = PVE::QemuServer::print_drive($drive);
 553                 }
 554             }
 555
 556             PVE::QemuServer::add_random_macs($param);
 557         } else {
 558             my $keystr = join(' ', keys %$param);
 559             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 560
 561             if ($archive eq '-') {
 562                 die "pipe requires cli environment\n"
 563                     if $rpcenv->{type} ne 'cli';
 564                 $archive = { type => 'pipe' };
 565             } else {
 566                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 567
 568                 $archive = $parse_restore_archive->($storecfg, $archive);
 569             }
 570         }
 571
 572         my $emsg = $is_restore ? "unable to restore VM $vmid -" : "unable to create VM $vmid -";
 573
 574         eval { PVE::QemuConfig->create_and_lock_config($vmid, $force) };
 575         die "$emsg $@" if $@;
 576
 577         my $restorefn = sub {
 578             my $conf = PVE::QemuConfig->load_config($vmid);
 579
 580             PVE::QemuConfig->check_protection($conf, $emsg);
 581
 582             die "$emsg vm is running\n" if PVE::QemuServer::check_running($vmid);
 583
 584             my $realcmd = sub {
 585                 my $restore_options = {
 586                     storage => $storage,
 587                     pool => $pool,
 588                     unique => $unique,
 589                     bwlimit => $bwlimit,
 590                 };
 591                 if ($archive->{type} eq 'file' || $archive->{type} eq 'pipe') {
 592                     PVE::QemuServer::restore_file_archive($archive->{path} // '-', $vmid, $authuser, $restore_options);
 593                 } elsif ($archive->{type} eq 'pbs') {
 594                     PVE::QemuServer::restore_proxmox_backup_archive($archive->{volid}, $vmid, $authuser, $restore_options);
 595                 } else {
 596                     die "unknown backup archive type\n";
 597                 }
 598                 my $restored_conf = PVE::QemuConfig->load_config($vmid);
 599                 # Convert restored VM to template if backup was VM template
 600                 if (PVE::QemuConfig->is_template($restored_conf)) {
 601                     warn "Convert to template.\n";
 602                     eval { PVE::QemuServer::template_create($vmid, $restored_conf) };
 603                     warn $@ if $@;
 604                 }
 605
 606                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 607             };
 608
 609             # ensure no old replication state are exists
 610             PVE::ReplicationState::delete_guest_states($vmid);
 611
 612             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 613
 614             if ($start_after_create) {
 615                 print "Execute autostart\n";
 616                 eval { PVE::API2::Qemu->vm_start({ vmid => $vmid, node => $node }) };
 617                 warn $@ if $@;
 618             }
 619         };
 620
 621         my $createfn = sub {
 622             # ensure no old replication state are exists
 623             PVE::ReplicationState::delete_guest_states($vmid);
 624
 625             my $realcmd = sub {
 626                 my $conf = $param;
 627                 my $arch = PVE::QemuServer::get_vm_arch($conf);
 628
 629                 my $vollist = [];
 630                 eval {
 631                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $param, $storage);
 632
 633                     if (!$conf->{bootdisk}) {
 634                         my $firstdisk = PVE::QemuServer::Drive::resolve_first_disk($conf);
 635                         $conf->{bootdisk} = $firstdisk if $firstdisk;
 636                     }
 637
 638                     # auto generate uuid if user did not specify smbios1 option
 639                     if (!$conf->{smbios1}) {
 640                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 641                     }
 642
 643                     if ((!defined($conf->{vmgenid}) || $conf->{vmgenid} eq '1') && $arch ne 'aarch64') {
 644                         $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 645                     }
 646
 647                     PVE::QemuConfig->write_config($vmid, $conf);
 648
 649                 };
 650                 my $err = $@;
 651
 652                 if ($err) {
 653                     foreach my $volid (@$vollist) {
 654                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 655                         warn $@ if $@;
 656                     }
 657                     die "$emsg $err";
 658                 }
 659
 660                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 661             };
 662
 663             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 664
 665             if ($start_after_create) {
 666                 print "Execute autostart\n";
 667                 eval { PVE::API2::Qemu->vm_start({vmid => $vmid, node => $node}) };
 668                 warn $@ if $@;
 669             }
 670         };
 671
 672         my ($code, $worker_name);
 673         if ($is_restore) {
 674             $worker_name = 'qmrestore';
 675             $code = sub {
 676                 eval { $restorefn->() };
 677                 if (my $err = $@) {
 678                     eval { PVE::QemuConfig->remove_lock($vmid, 'create') };
 679                     warn $@ if $@;
 680                     die $err;
 681                 }
 682             };
 683         } else {
 684             $worker_name = 'qmcreate';
 685             $code = sub {
 686                 eval { $createfn->() };
 687                 if (my $err = $@) {
 688                     eval {
 689                         my $conffile = PVE::QemuConfig->config_file($vmid);
 690                         unlink($conffile) or die "failed to remove config file: $!\n";
 691                     };
 692                     warn $@ if $@;
 693                     die $err;
 694                 }
 695             };
 696         }
 697
 698         return $rpcenv->fork_worker($worker_name, $vmid, $authuser, $code);
 699     }});
 700
 701 __PACKAGE__->register_method({
 702     name => 'vmdiridx',
 703     path => '{vmid}',
 704     method => 'GET',
 705     proxyto => 'node',
 706     description => "Directory index",
 707     permissions => {
 708         user => 'all',
 709     },
 710     parameters => {
 711         additionalProperties => 0,
 712         properties => {
 713             node => get_standard_option('pve-node'),
 714             vmid => get_standard_option('pve-vmid'),
 715         },
 716     },
 717     returns => {
 718         type => 'array',
 719         items => {
 720             type => "object",
 721             properties => {
 722                 subdir => { type => 'string' },
 723             },
 724         },
 725         links => [ { rel => 'child', href => "{subdir}" } ],
 726     },
 727     code => sub {
 728         my ($param) = @_;
 729
 730         my $res = [
 731             { subdir => 'config' },
 732             { subdir => 'pending' },
 733             { subdir => 'status' },
 734             { subdir => 'unlink' },
 735             { subdir => 'vncproxy' },
 736             { subdir => 'termproxy' },
 737             { subdir => 'migrate' },
 738             { subdir => 'resize' },
 739             { subdir => 'move' },
 740             { subdir => 'rrd' },
 741             { subdir => 'rrddata' },
 742             { subdir => 'monitor' },
 743             { subdir => 'agent' },
 744             { subdir => 'snapshot' },
 745             { subdir => 'spiceproxy' },
 746             { subdir => 'sendkey' },
 747             { subdir => 'firewall' },
 748             ];
 749
 750         return $res;
 751     }});
 752
 753 __PACKAGE__->register_method ({
 754     subclass => "PVE::API2::Firewall::VM",
 755     path => '{vmid}/firewall',
 756 });
 757
 758 __PACKAGE__->register_method ({
 759     subclass => "PVE::API2::Qemu::Agent",
 760     path => '{vmid}/agent',
 761 });
 762
 763 __PACKAGE__->register_method({
 764     name => 'rrd',
 765     path => '{vmid}/rrd',
 766     method => 'GET',
 767     protected => 1, # fixme: can we avoid that?
 768     permissions => {
 769         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 770     },
 771     description => "Read VM RRD statistics (returns PNG)",
 772     parameters => {
 773         additionalProperties => 0,
 774         properties => {
 775             node => get_standard_option('pve-node'),
 776             vmid => get_standard_option('pve-vmid'),
 777             timeframe => {
 778                 description => "Specify the time frame you are interested in.",
 779                 type => 'string',
 780                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 781             },
 782             ds => {
 783                 description => "The list of datasources you want to display.",
 784                 type => 'string', format => 'pve-configid-list',
 785             },
 786             cf => {
 787                 description => "The RRD consolidation function",
 788                 type => 'string',
 789                 enum => [ 'AVERAGE', 'MAX' ],
 790                 optional => 1,
 791             },
 792         },
 793     },
 794     returns => {
 795         type => "object",
 796         properties => {
 797             filename => { type => 'string' },
 798         },
 799     },
 800     code => sub {
 801         my ($param) = @_;
 802
 803         return PVE::RRD::create_rrd_graph(
 804             "pve2-vm/$param->{vmid}", $param->{timeframe},
 805             $param->{ds}, $param->{cf});
 806
 807     }});
 808
 809 __PACKAGE__->register_method({
 810     name => 'rrddata',
 811     path => '{vmid}/rrddata',
 812     method => 'GET',
 813     protected => 1, # fixme: can we avoid that?
 814     permissions => {
 815         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 816     },
 817     description => "Read VM RRD statistics",
 818     parameters => {
 819         additionalProperties => 0,
 820         properties => {
 821             node => get_standard_option('pve-node'),
 822             vmid => get_standard_option('pve-vmid'),
 823             timeframe => {
 824                 description => "Specify the time frame you are interested in.",
 825                 type => 'string',
 826                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 827             },
 828             cf => {
 829                 description => "The RRD consolidation function",
 830                 type => 'string',
 831                 enum => [ 'AVERAGE', 'MAX' ],
 832                 optional => 1,
 833             },
 834         },
 835     },
 836     returns => {
 837         type => "array",
 838         items => {
 839             type => "object",
 840             properties => {},
 841         },
 842     },
 843     code => sub {
 844         my ($param) = @_;
 845
 846         return PVE::RRD::create_rrd_data(
 847             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 848     }});
 849
 850
 851 __PACKAGE__->register_method({
 852     name => 'vm_config',
 853     path => '{vmid}/config',
 854     method => 'GET',
 855     proxyto => 'node',
 856     description => "Get the virtual machine configuration with pending configuration " .
 857         "changes applied. Set the 'current' parameter to get the current configuration instead.",
 858     permissions => {
 859         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 860     },
 861     parameters => {
 862         additionalProperties => 0,
 863         properties => {
 864             node => get_standard_option('pve-node'),
 865             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 866             current => {
 867                 description => "Get current values (instead of pending values).",
 868                 optional => 1,
 869                 default => 0,
 870                 type => 'boolean',
 871             },
 872             snapshot => get_standard_option('pve-snapshot-name', {
 873                 description => "Fetch config values from given snapshot.",
 874                 optional => 1,
 875                 completion => sub {
 876                     my ($cmd, $pname, $cur, $args) = @_;
 877                     PVE::QemuConfig->snapshot_list($args->[0]);
 878                 },
 879             }),
 880         },
 881     },
 882     returns => {
 883         description => "The VM configuration.",
 884         type => "object",
 885         properties => PVE::QemuServer::json_config_properties({
 886             digest => {
 887                 type => 'string',
 888                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 889             }
 890         }),
 891     },
 892     code => sub {
 893         my ($param) = @_;
 894
 895         raise_param_exc({ snapshot => "cannot use 'snapshot' parameter with 'current'",
 896                           current => "cannot use 'snapshot' parameter with 'current'"})
 897             if ($param->{snapshot} && $param->{current});
 898
 899         my $conf;
 900         if ($param->{snapshot}) {
 901             $conf = PVE::QemuConfig->load_snapshot_config($param->{vmid}, $param->{snapshot});
 902         } else {
 903             $conf = PVE::QemuConfig->load_current_config($param->{vmid}, $param->{current});
 904         }
 905         $conf->{cipassword} = '**********' if $conf->{cipassword};
 906         return $conf;
 907
 908     }});
 909
 910 __PACKAGE__->register_method({
 911     name => 'vm_pending',
 912     path => '{vmid}/pending',
 913     method => 'GET',
 914     proxyto => 'node',
 915     description => "Get the virtual machine configuration with both current and pending values.",
 916     permissions => {
 917         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 918     },
 919     parameters => {
 920         additionalProperties => 0,
 921         properties => {
 922             node => get_standard_option('pve-node'),
 923             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 924         },
 925     },
 926     returns => {
 927         type => "array",
 928         items => {
 929             type => "object",
 930             properties => {
 931                 key => {
 932                     description => "Configuration option name.",
 933                     type => 'string',
 934                 },
 935                 value => {
 936                     description => "Current value.",
 937                     type => 'string',
 938                     optional => 1,
 939                 },
 940                 pending => {
 941                     description => "Pending value.",
 942                     type => 'string',
 943                     optional => 1,
 944                 },
 945                 delete => {
 946                     description => "Indicates a pending delete request if present and not 0. " .
 947                                    "The value 2 indicates a force-delete request.",
 948                     type => 'integer',
 949                     minimum => 0,
 950                     maximum => 2,
 951                     optional => 1,
 952                 },
 953             },
 954         },
 955     },
 956     code => sub {
 957         my ($param) = @_;
 958
 959         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 960
 961         my $pending_delete_hash = PVE::QemuConfig->parse_pending_delete($conf->{pending}->{delete});
 962
 963         $conf->{cipassword} = '**********' if defined($conf->{cipassword});
 964         $conf->{pending}->{cipassword} = '********** ' if defined($conf->{pending}->{cipassword});
 965
 966         return PVE::GuestHelpers::config_with_pending_array($conf, $pending_delete_hash);
 967    }});
 968
 969 # POST/PUT {vmid}/config implementation
 970 #
 971 # The original API used PUT (idempotent) an we assumed that all operations
 972 # are fast. But it turned out that almost any configuration change can
 973 # involve hot-plug actions, or disk alloc/free. Such actions can take long
 974 # time to complete and have side effects (not idempotent).
 975 #
 976 # The new implementation uses POST and forks a worker process. We added
 977 # a new option 'background_delay'. If specified we wait up to
 978 # 'background_delay' second for the worker task to complete. It returns null
 979 # if the task is finished within that time, else we return the UPID.
 980
 981 my $update_vm_api  = sub {
 982     my ($param, $sync) = @_;
 983
 984     my $rpcenv = PVE::RPCEnvironment::get();
 985
 986     my $authuser = $rpcenv->get_user();
 987
 988     my $node = extract_param($param, 'node');
 989
 990     my $vmid = extract_param($param, 'vmid');
 991
 992     my $digest = extract_param($param, 'digest');
 993
 994     my $background_delay = extract_param($param, 'background_delay');
 995
 996     if (defined(my $cipassword = $param->{cipassword})) {
 997         # Same logic as in cloud-init (but with the regex fixed...)
 998         $param->{cipassword} = PVE::Tools::encrypt_pw($cipassword)
 999             if $cipassword !~ /^\$(?:[156]|2[ay])(\$.+){2}/;
1000     }
1001
1002     my @paramarr = (); # used for log message
1003     foreach my $key (sort keys %$param) {
1004         my $value = $key eq 'cipassword' ? '<hidden>' : $param->{$key};
1005         push @paramarr, "-$key", $value;
1006     }
1007
1008     my $skiplock = extract_param($param, 'skiplock');
1009     raise_param_exc({ skiplock => "Only root may use this option." })
1010         if $skiplock && $authuser ne 'root@pam';
1011
1012     my $delete_str = extract_param($param, 'delete');
1013
1014     my $revert_str = extract_param($param, 'revert');
1015
1016     my $force = extract_param($param, 'force');
1017
1018     if (defined(my $ssh_keys = $param->{sshkeys})) {
1019         $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
1020         PVE::Tools::validate_ssh_public_keys($ssh_keys);
1021     }
1022
1023     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
1024
1025     my $storecfg = PVE::Storage::config();
1026
1027     my $defaults = PVE::QemuServer::load_defaults();
1028
1029     &$resolve_cdrom_alias($param);
1030
1031     # now try to verify all parameters
1032
1033     my $revert = {};
1034     foreach my $opt (PVE::Tools::split_list($revert_str)) {
1035         if (!PVE::QemuServer::option_exists($opt)) {
1036             raise_param_exc({ revert => "unknown option '$opt'" });
1037         }
1038
1039         raise_param_exc({ delete => "you can't use '-$opt' and " .
1040                               "-revert $opt' at the same time" })
1041             if defined($param->{$opt});
1042
1043         $revert->{$opt} = 1;
1044     }
1045
1046     my @delete = ();
1047     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1048         $opt = 'ide2' if $opt eq 'cdrom';
1049
1050         raise_param_exc({ delete => "you can't use '-$opt' and " .
1051                               "-delete $opt' at the same time" })
1052             if defined($param->{$opt});
1053
1054         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
1055                               "-revert $opt' at the same time" })
1056             if $revert->{$opt};
1057
1058         if (!PVE::QemuServer::option_exists($opt)) {
1059             raise_param_exc({ delete => "unknown option '$opt'" });
1060         }
1061
1062         push @delete, $opt;
1063     }
1064
1065     my $repl_conf = PVE::ReplicationConfig->new();
1066     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
1067     my $check_replication = sub {
1068         my ($drive) = @_;
1069         return if !$is_replicated;
1070         my $volid = $drive->{file};
1071         return if !$volid || !($drive->{replicate}//1);
1072         return if PVE::QemuServer::drive_is_cdrom($drive);
1073
1074         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1075         return if $volname eq 'cloudinit';
1076
1077         my $format;
1078         if ($volid =~ $NEW_DISK_RE) {
1079             $storeid = $2;
1080             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
1081         } else {
1082             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1083         }
1084         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1085         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1086         return if $scfg->{shared};
1087         die "cannot add non-replicatable volume to a replicated VM\n";
1088     };
1089
1090     foreach my $opt (keys %$param) {
1091         if (PVE::QemuServer::is_valid_drivename($opt)) {
1092             # cleanup drive path
1093             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1094             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1095             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1096             $check_replication->($drive);
1097             $param->{$opt} = PVE::QemuServer::print_drive($drive);
1098         } elsif ($opt =~ m/^net(\d+)$/) {
1099             # add macaddr
1100             my $net = PVE::QemuServer::parse_net($param->{$opt});
1101             $param->{$opt} = PVE::QemuServer::print_net($net);
1102         } elsif ($opt eq 'vmgenid') {
1103             if ($param->{$opt} eq '1') {
1104                 $param->{$opt} = PVE::QemuServer::generate_uuid();
1105             }
1106         } elsif ($opt eq 'hookscript') {
1107             eval { PVE::GuestHelpers::check_hookscript($param->{$opt}, $storecfg); };
1108             raise_param_exc({ $opt => $@ }) if $@;
1109         }
1110     }
1111
1112     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1113
1114     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1115
1116     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1117
1118     my $updatefn =  sub {
1119
1120         my $conf = PVE::QemuConfig->load_config($vmid);
1121
1122         die "checksum missmatch (file change by other user?)\n"
1123             if $digest && $digest ne $conf->{digest};
1124
1125         # FIXME: 'suspended' lock should probabyl be a state or "weak" lock?!
1126         if (scalar(@delete) && grep { $_ eq 'vmstate'} @delete) {
1127             if (defined($conf->{lock}) && $conf->{lock} eq 'suspended') {
1128                 delete $conf->{lock}; # for check lock check, not written out
1129                 push @delete, 'lock'; # this is the real deal to write it out
1130             }
1131             push @delete, 'runningmachine' if $conf->{runningmachine};
1132         }
1133
1134         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1135
1136         foreach my $opt (keys %$revert) {
1137             if (defined($conf->{$opt})) {
1138                 $param->{$opt} = $conf->{$opt};
1139             } elsif (defined($conf->{pending}->{$opt})) {
1140                 push @delete, $opt;
1141             }
1142         }
1143
1144         if ($param->{memory} || defined($param->{balloon})) {
1145             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1146             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1147
1148             die "balloon value too large (must be smaller than assigned memory)\n"
1149                 if $balloon && $balloon > $maxmem;
1150         }
1151
1152         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1153
1154         my $worker = sub {
1155
1156             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1157
1158             # write updates to pending section
1159
1160             my $modified = {}; # record what $option we modify
1161
1162             foreach my $opt (@delete) {
1163                 $modified->{$opt} = 1;
1164                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1165
1166                 # value of what we want to delete, independent if pending or not
1167                 my $val = $conf->{$opt} // $conf->{pending}->{$opt};
1168                 if (!defined($val)) {
1169                     warn "cannot delete '$opt' - not set in current configuration!\n";
1170                     $modified->{$opt} = 0;
1171                     next;
1172                 }
1173                 my $is_pending_val = defined($conf->{pending}->{$opt});
1174                 delete $conf->{pending}->{$opt};
1175
1176                 if ($opt =~ m/^unused/) {
1177                     my $drive = PVE::QemuServer::parse_drive($opt, $val);
1178                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1179                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1180                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1181                         delete $conf->{$opt};
1182                         PVE::QemuConfig->write_config($vmid, $conf);
1183                     }
1184                 } elsif ($opt eq 'vmstate') {
1185                     PVE::QemuConfig->check_protection($conf, "can't remove vmstate '$val'");
1186                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, { file => $val }, $rpcenv, $authuser, 1)) {
1187                         delete $conf->{$opt};
1188                         PVE::QemuConfig->write_config($vmid, $conf);
1189                     }
1190                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1191                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1192                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1193                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $val))
1194                         if $is_pending_val;
1195                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1196                     PVE::QemuConfig->write_config($vmid, $conf);
1197                 } elsif ($opt =~ m/^serial\d+$/) {
1198                     if ($val eq 'socket') {
1199                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1200                     } elsif ($authuser ne 'root@pam') {
1201                         die "only root can delete '$opt' config for real devices\n";
1202                     }
1203                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1204                     PVE::QemuConfig->write_config($vmid, $conf);
1205                 } elsif ($opt =~ m/^usb\d+$/) {
1206                     if ($val =~ m/spice/) {
1207                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1208                     } elsif ($authuser ne 'root@pam') {
1209                         die "only root can delete '$opt' config for real devices\n";
1210                     }
1211                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1212                     PVE::QemuConfig->write_config($vmid, $conf);
1213                 } else {
1214                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1215                     PVE::QemuConfig->write_config($vmid, $conf);
1216                 }
1217             }
1218
1219             foreach my $opt (keys %$param) { # add/change
1220                 $modified->{$opt} = 1;
1221                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1222                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1223
1224                 my $arch = PVE::QemuServer::get_vm_arch($conf);
1225
1226                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1227                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1228                     # FIXME: cloudinit: CDROM or Disk?
1229                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1230                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1231                     } else {
1232                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1233                     }
1234                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1235                         if defined($conf->{pending}->{$opt});
1236
1237                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $arch, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1238                 } elsif ($opt =~ m/^serial\d+/) {
1239                     if ((!defined($conf->{$opt}) || $conf->{$opt} eq 'socket') && $param->{$opt} eq 'socket') {
1240                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1241                     } elsif ($authuser ne 'root@pam') {
1242                         die "only root can modify '$opt' config for real devices\n";
1243                     }
1244                     $conf->{pending}->{$opt} = $param->{$opt};
1245                 } elsif ($opt =~ m/^usb\d+/) {
1246                     if ((!defined($conf->{$opt}) || $conf->{$opt} =~ m/spice/) && $param->{$opt} =~ m/spice/) {
1247                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1248                     } elsif ($authuser ne 'root@pam') {
1249                         die "only root can modify '$opt' config for real devices\n";
1250                     }
1251                     $conf->{pending}->{$opt} = $param->{$opt};
1252                 } else {
1253                     $conf->{pending}->{$opt} = $param->{$opt};
1254                 }
1255                 PVE::QemuConfig->remove_from_pending_delete($conf, $opt);
1256                 PVE::QemuConfig->write_config($vmid, $conf);
1257             }
1258
1259             # remove pending changes when nothing changed
1260             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1261             my $changes = PVE::QemuConfig->cleanup_pending($conf);
1262             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1263
1264             return if !scalar(keys %{$conf->{pending}});
1265
1266             my $running = PVE::QemuServer::check_running($vmid);
1267
1268             # apply pending changes
1269
1270             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1271
1272             my $errors = {};
1273             if ($running) {
1274                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1275             } else {
1276                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running, $errors);
1277             }
1278             raise_param_exc($errors) if scalar(keys %$errors);
1279
1280             return;
1281         };
1282
1283         if ($sync) {
1284             &$worker();
1285             return undef;
1286         } else {
1287             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1288
1289             if ($background_delay) {
1290
1291                 # Note: It would be better to do that in the Event based HTTPServer
1292                 # to avoid blocking call to sleep.
1293
1294                 my $end_time = time() + $background_delay;
1295
1296                 my $task = PVE::Tools::upid_decode($upid);
1297
1298                 my $running = 1;
1299                 while (time() < $end_time) {
1300                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1301                     last if !$running;
1302                     sleep(1); # this gets interrupted when child process ends
1303                 }
1304
1305                 if (!$running) {
1306                     my $status = PVE::Tools::upid_read_status($upid);
1307                     return undef if $status eq 'OK';
1308                     die $status;
1309                 }
1310             }
1311
1312             return $upid;
1313         }
1314     };
1315
1316     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1317 };
1318
1319 my $vm_config_perm_list = [
1320             'VM.Config.Disk',
1321             'VM.Config.CDROM',
1322             'VM.Config.CPU',
1323             'VM.Config.Memory',
1324             'VM.Config.Network',
1325             'VM.Config.HWType',
1326             'VM.Config.Options',
1327     ];
1328
1329 __PACKAGE__->register_method({
1330     name => 'update_vm_async',
1331     path => '{vmid}/config',
1332     method => 'POST',
1333     protected => 1,
1334     proxyto => 'node',
1335     description => "Set virtual machine options (asynchrounous API).",
1336     permissions => {
1337         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1338     },
1339     parameters => {
1340         additionalProperties => 0,
1341         properties => PVE::QemuServer::json_config_properties(
1342             {
1343                 node => get_standard_option('pve-node'),
1344                 vmid => get_standard_option('pve-vmid'),
1345                 skiplock => get_standard_option('skiplock'),
1346                 delete => {
1347                     type => 'string', format => 'pve-configid-list',
1348                     description => "A list of settings you want to delete.",
1349                     optional => 1,
1350                 },
1351                 revert => {
1352                     type => 'string', format => 'pve-configid-list',
1353                     description => "Revert a pending change.",
1354                     optional => 1,
1355                 },
1356                 force => {
1357                     type => 'boolean',
1358                     description => $opt_force_description,
1359                     optional => 1,
1360                     requires => 'delete',
1361                 },
1362                 digest => {
1363                     type => 'string',
1364                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1365                     maxLength => 40,
1366                     optional => 1,
1367                 },
1368                 background_delay => {
1369                     type => 'integer',
1370                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1371                     minimum => 1,
1372                     maximum => 30,
1373                     optional => 1,
1374                 },
1375             }),
1376     },
1377     returns => {
1378         type => 'string',
1379         optional => 1,
1380     },
1381     code => $update_vm_api,
1382 });
1383
1384 __PACKAGE__->register_method({
1385     name => 'update_vm',
1386     path => '{vmid}/config',
1387     method => 'PUT',
1388     protected => 1,
1389     proxyto => 'node',
1390     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1391     permissions => {
1392         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1393     },
1394     parameters => {
1395         additionalProperties => 0,
1396         properties => PVE::QemuServer::json_config_properties(
1397             {
1398                 node => get_standard_option('pve-node'),
1399                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1400                 skiplock => get_standard_option('skiplock'),
1401                 delete => {
1402                     type => 'string', format => 'pve-configid-list',
1403                     description => "A list of settings you want to delete.",
1404                     optional => 1,
1405                 },
1406                 revert => {
1407                     type => 'string', format => 'pve-configid-list',
1408                     description => "Revert a pending change.",
1409                     optional => 1,
1410                 },
1411                 force => {
1412                     type => 'boolean',
1413                     description => $opt_force_description,
1414                     optional => 1,
1415                     requires => 'delete',
1416                 },
1417                 digest => {
1418                     type => 'string',
1419                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1420                     maxLength => 40,
1421                     optional => 1,
1422                 },
1423             }),
1424     },
1425     returns => { type => 'null' },
1426     code => sub {
1427         my ($param) = @_;
1428         &$update_vm_api($param, 1);
1429         return undef;
1430     }
1431 });
1432
1433 __PACKAGE__->register_method({
1434     name => 'destroy_vm',
1435     path => '{vmid}',
1436     method => 'DELETE',
1437     protected => 1,
1438     proxyto => 'node',
1439     description => "Destroy the vm (also delete all used/owned volumes).",
1440     permissions => {
1441         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1442     },
1443     parameters => {
1444         additionalProperties => 0,
1445         properties => {
1446             node => get_standard_option('pve-node'),
1447             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1448             skiplock => get_standard_option('skiplock'),
1449             purge => {
1450                 type => 'boolean',
1451                 description => "Remove vmid from backup cron jobs.",
1452                 optional => 1,
1453             },
1454         },
1455     },
1456     returns => {
1457         type => 'string',
1458     },
1459     code => sub {
1460         my ($param) = @_;
1461
1462         my $rpcenv = PVE::RPCEnvironment::get();
1463         my $authuser = $rpcenv->get_user();
1464         my $vmid = $param->{vmid};
1465
1466         my $skiplock = $param->{skiplock};
1467         raise_param_exc({ skiplock => "Only root may use this option." })
1468             if $skiplock && $authuser ne 'root@pam';
1469
1470         # test if VM exists
1471         my $conf = PVE::QemuConfig->load_config($vmid);
1472         my $storecfg = PVE::Storage::config();
1473         PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1474
1475         my $ha_managed = PVE::HA::Config::service_is_configured("vm:$vmid");
1476
1477         if (!$param->{purge}) {
1478             die "unable to remove VM $vmid - used in HA resources and purge parameter not set.\n"
1479                 if $ha_managed;
1480             # don't allow destroy if with replication jobs but no purge param
1481             my $repl_conf = PVE::ReplicationConfig->new();
1482             $repl_conf->check_for_existing_jobs($vmid);
1483         }
1484
1485         # early tests (repeat after locking)
1486         die "VM $vmid is running - destroy failed\n"
1487             if PVE::QemuServer::check_running($vmid);
1488
1489         my $realcmd = sub {
1490             my $upid = shift;
1491
1492             syslog('info', "destroy VM $vmid: $upid\n");
1493             PVE::QemuConfig->lock_config($vmid, sub {
1494                 die "VM $vmid is running - destroy failed\n"
1495                     if (PVE::QemuServer::check_running($vmid));
1496
1497                 PVE::QemuServer::destroy_vm($storecfg, $vmid, $skiplock, { lock => 'destroyed' });
1498
1499                 PVE::AccessControl::remove_vm_access($vmid);
1500                 PVE::Firewall::remove_vmfw_conf($vmid);
1501                 if ($param->{purge}) {
1502                     print "purging VM $vmid from related configurations..\n";
1503                     PVE::ReplicationConfig::remove_vmid_jobs($vmid);
1504                     PVE::VZDump::Plugin::remove_vmid_from_backup_jobs($vmid);
1505
1506                     if ($ha_managed) {
1507                         PVE::HA::Config::delete_service_from_config("vm:$vmid");
1508                         print "NOTE: removed VM $vmid from HA resource configuration.\n";
1509                     }
1510                 }
1511
1512                 # only now remove the zombie config, else we can have reuse race
1513                 PVE::QemuConfig->destroy_config($vmid);
1514             });
1515         };
1516
1517         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1518     }});
1519
1520 __PACKAGE__->register_method({
1521     name => 'unlink',
1522     path => '{vmid}/unlink',
1523     method => 'PUT',
1524     protected => 1,
1525     proxyto => 'node',
1526     description => "Unlink/delete disk images.",
1527     permissions => {
1528         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1529     },
1530     parameters => {
1531         additionalProperties => 0,
1532         properties => {
1533             node => get_standard_option('pve-node'),
1534             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1535             idlist => {
1536                 type => 'string', format => 'pve-configid-list',
1537                 description => "A list of disk IDs you want to delete.",
1538             },
1539             force => {
1540                 type => 'boolean',
1541                 description => $opt_force_description,
1542                 optional => 1,
1543             },
1544         },
1545     },
1546     returns => { type => 'null'},
1547     code => sub {
1548         my ($param) = @_;
1549
1550         $param->{delete} = extract_param($param, 'idlist');
1551
1552         __PACKAGE__->update_vm($param);
1553
1554         return undef;
1555     }});
1556
1557 my $sslcert;
1558
1559 __PACKAGE__->register_method({
1560     name => 'vncproxy',
1561     path => '{vmid}/vncproxy',
1562     method => 'POST',
1563     protected => 1,
1564     permissions => {
1565         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1566     },
1567     description => "Creates a TCP VNC proxy connections.",
1568     parameters => {
1569         additionalProperties => 0,
1570         properties => {
1571             node => get_standard_option('pve-node'),
1572             vmid => get_standard_option('pve-vmid'),
1573             websocket => {
1574                 optional => 1,
1575                 type => 'boolean',
1576                 description => "starts websockify instead of vncproxy",
1577             },
1578         },
1579     },
1580     returns => {
1581         additionalProperties => 0,
1582         properties => {
1583             user => { type => 'string' },
1584             ticket => { type => 'string' },
1585             cert => { type => 'string' },
1586             port => { type => 'integer' },
1587             upid => { type => 'string' },
1588         },
1589     },
1590     code => sub {
1591         my ($param) = @_;
1592
1593         my $rpcenv = PVE::RPCEnvironment::get();
1594
1595         my $authuser = $rpcenv->get_user();
1596
1597         my $vmid = $param->{vmid};
1598         my $node = $param->{node};
1599         my $websocket = $param->{websocket};
1600
1601         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1602         my $use_serial = ($conf->{vga} && ($conf->{vga} =~ m/^serial\d+$/));
1603
1604         my $authpath = "/vms/$vmid";
1605
1606         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1607
1608         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1609             if !$sslcert;
1610
1611         my $family;
1612         my $remcmd = [];
1613
1614         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1615             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1616             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1617             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1618             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, $use_serial ? '-t' : '-T');
1619         } else {
1620             $family = PVE::Tools::get_host_address_family($node);
1621         }
1622
1623         my $port = PVE::Tools::next_vnc_port($family);
1624
1625         my $timeout = 10;
1626
1627         my $realcmd = sub {
1628             my $upid = shift;
1629
1630             syslog('info', "starting vnc proxy $upid\n");
1631
1632             my $cmd;
1633
1634             if ($use_serial) {
1635
1636                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $conf->{vga}, '-escape', '0' ];
1637
1638                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1639                         '-timeout', $timeout, '-authpath', $authpath,
1640                         '-perm', 'Sys.Console'];
1641
1642                 if ($param->{websocket}) {
1643                     $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
1644                     push @$cmd, '-notls', '-listen', 'localhost';
1645                 }
1646
1647                 push @$cmd, '-c', @$remcmd, @$termcmd;
1648
1649                 PVE::Tools::run_command($cmd);
1650
1651             } else {
1652
1653                 $ENV{LC_PVE_TICKET} = $ticket if $websocket; # set ticket with "qm vncproxy"
1654
1655                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1656
1657                 my $sock = IO::Socket::IP->new(
1658                     ReuseAddr => 1,
1659                     Listen => 1,
1660                     LocalPort => $port,
1661                     Proto => 'tcp',
1662                     GetAddrInfoFlags => 0,
1663                     ) or die "failed to create socket: $!\n";
1664                 # Inside the worker we shouldn't have any previous alarms
1665                 # running anyway...:
1666                 alarm(0);
1667                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1668                 alarm $timeout;
1669                 accept(my $cli, $sock) or die "connection failed: $!\n";
1670                 alarm(0);
1671                 close($sock);
1672                 if (PVE::Tools::run_command($cmd,
1673                     output => '>&'.fileno($cli),
1674                     input => '<&'.fileno($cli),
1675                     noerr => 1) != 0)
1676                 {
1677                     die "Failed to run vncproxy.\n";
1678                 }
1679             }
1680
1681             return;
1682         };
1683
1684         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1685
1686         PVE::Tools::wait_for_vnc_port($port);
1687
1688         return {
1689             user => $authuser,
1690             ticket => $ticket,
1691             port => $port,
1692             upid => $upid,
1693             cert => $sslcert,
1694         };
1695     }});
1696
1697 __PACKAGE__->register_method({
1698     name => 'termproxy',
1699     path => '{vmid}/termproxy',
1700     method => 'POST',
1701     protected => 1,
1702     permissions => {
1703         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1704     },
1705     description => "Creates a TCP proxy connections.",
1706     parameters => {
1707         additionalProperties => 0,
1708         properties => {
1709             node => get_standard_option('pve-node'),
1710             vmid => get_standard_option('pve-vmid'),
1711             serial=> {
1712                 optional => 1,
1713                 type => 'string',
1714                 enum => [qw(serial0 serial1 serial2 serial3)],
1715                 description => "opens a serial terminal (defaults to display)",
1716             },
1717         },
1718     },
1719     returns => {
1720         additionalProperties => 0,
1721         properties => {
1722             user => { type => 'string' },
1723             ticket => { type => 'string' },
1724             port => { type => 'integer' },
1725             upid => { type => 'string' },
1726         },
1727     },
1728     code => sub {
1729         my ($param) = @_;
1730
1731         my $rpcenv = PVE::RPCEnvironment::get();
1732
1733         my $authuser = $rpcenv->get_user();
1734
1735         my $vmid = $param->{vmid};
1736         my $node = $param->{node};
1737         my $serial = $param->{serial};
1738
1739         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1740
1741         if (!defined($serial)) {
1742             if ($conf->{vga} && $conf->{vga} =~ m/^serial\d+$/) {
1743                 $serial = $conf->{vga};
1744             }
1745         }
1746
1747         my $authpath = "/vms/$vmid";
1748
1749         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1750
1751         my $family;
1752         my $remcmd = [];
1753
1754         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1755             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1756             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1757             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, '-t');
1758             push @$remcmd, '--';
1759         } else {
1760             $family = PVE::Tools::get_host_address_family($node);
1761         }
1762
1763         my $port = PVE::Tools::next_vnc_port($family);
1764
1765         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1766         push @$termcmd, '-iface', $serial if $serial;
1767
1768         my $realcmd = sub {
1769             my $upid = shift;
1770
1771             syslog('info', "starting qemu termproxy $upid\n");
1772
1773             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1774                        '--perm', 'VM.Console', '--'];
1775             push @$cmd, @$remcmd, @$termcmd;
1776
1777             PVE::Tools::run_command($cmd);
1778         };
1779
1780         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1781
1782         PVE::Tools::wait_for_vnc_port($port);
1783
1784         return {
1785             user => $authuser,
1786             ticket => $ticket,
1787             port => $port,
1788             upid => $upid,
1789         };
1790     }});
1791
1792 __PACKAGE__->register_method({
1793     name => 'vncwebsocket',
1794     path => '{vmid}/vncwebsocket',
1795     method => 'GET',
1796     permissions => {
1797         description => "You also need to pass a valid ticket (vncticket).",
1798         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1799     },
1800     description => "Opens a weksocket for VNC traffic.",
1801     parameters => {
1802         additionalProperties => 0,
1803         properties => {
1804             node => get_standard_option('pve-node'),
1805             vmid => get_standard_option('pve-vmid'),
1806             vncticket => {
1807                 description => "Ticket from previous call to vncproxy.",
1808                 type => 'string',
1809                 maxLength => 512,
1810             },
1811             port => {
1812                 description => "Port number returned by previous vncproxy call.",
1813                 type => 'integer',
1814                 minimum => 5900,
1815                 maximum => 5999,
1816             },
1817         },
1818     },
1819     returns => {
1820         type => "object",
1821         properties => {
1822             port => { type => 'string' },
1823         },
1824     },
1825     code => sub {
1826         my ($param) = @_;
1827
1828         my $rpcenv = PVE::RPCEnvironment::get();
1829
1830         my $authuser = $rpcenv->get_user();
1831
1832         my $vmid = $param->{vmid};
1833         my $node = $param->{node};
1834
1835         my $authpath = "/vms/$vmid";
1836
1837         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
1838
1839         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
1840
1841         # Note: VNC ports are acessible from outside, so we do not gain any
1842         # security if we verify that $param->{port} belongs to VM $vmid. This
1843         # check is done by verifying the VNC ticket (inside VNC protocol).
1844
1845         my $port = $param->{port};
1846
1847         return { port => $port };
1848     }});
1849
1850 __PACKAGE__->register_method({
1851     name => 'spiceproxy',
1852     path => '{vmid}/spiceproxy',
1853     method => 'POST',
1854     protected => 1,
1855     proxyto => 'node',
1856     permissions => {
1857         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1858     },
1859     description => "Returns a SPICE configuration to connect to the VM.",
1860     parameters => {
1861         additionalProperties => 0,
1862         properties => {
1863             node => get_standard_option('pve-node'),
1864             vmid => get_standard_option('pve-vmid'),
1865             proxy => get_standard_option('spice-proxy', { optional => 1 }),
1866         },
1867     },
1868     returns => get_standard_option('remote-viewer-config'),
1869     code => sub {
1870         my ($param) = @_;
1871
1872         my $rpcenv = PVE::RPCEnvironment::get();
1873
1874         my $authuser = $rpcenv->get_user();
1875
1876         my $vmid = $param->{vmid};
1877         my $node = $param->{node};
1878         my $proxy = $param->{proxy};
1879
1880         my $conf = PVE::QemuConfig->load_config($vmid, $node);
1881         my $title = "VM $vmid";
1882         $title .= " - ". $conf->{name} if $conf->{name};
1883
1884         my $port = PVE::QemuServer::spice_port($vmid);
1885
1886         my ($ticket, undef, $remote_viewer_config) =
1887             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
1888
1889         mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
1890         mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
1891
1892         return $remote_viewer_config;
1893     }});
1894
1895 __PACKAGE__->register_method({
1896     name => 'vmcmdidx',
1897     path => '{vmid}/status',
1898     method => 'GET',
1899     proxyto => 'node',
1900     description => "Directory index",
1901     permissions => {
1902         user => 'all',
1903     },
1904     parameters => {
1905         additionalProperties => 0,
1906         properties => {
1907             node => get_standard_option('pve-node'),
1908             vmid => get_standard_option('pve-vmid'),
1909         },
1910     },
1911     returns => {
1912         type => 'array',
1913         items => {
1914             type => "object",
1915             properties => {
1916                 subdir => { type => 'string' },
1917             },
1918         },
1919         links => [ { rel => 'child', href => "{subdir}" } ],
1920     },
1921     code => sub {
1922         my ($param) = @_;
1923
1924         # test if VM exists
1925         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1926
1927         my $res = [
1928             { subdir => 'current' },
1929             { subdir => 'start' },
1930             { subdir => 'stop' },
1931             { subdir => 'reset' },
1932             { subdir => 'shutdown' },
1933             { subdir => 'suspend' },
1934             { subdir => 'reboot' },
1935             ];
1936
1937         return $res;
1938     }});
1939
1940 __PACKAGE__->register_method({
1941     name => 'vm_status',
1942     path => '{vmid}/status/current',
1943     method => 'GET',
1944     proxyto => 'node',
1945     protected => 1, # qemu pid files are only readable by root
1946     description => "Get virtual machine status.",
1947     permissions => {
1948         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1949     },
1950     parameters => {
1951         additionalProperties => 0,
1952         properties => {
1953             node => get_standard_option('pve-node'),
1954             vmid => get_standard_option('pve-vmid'),
1955         },
1956     },
1957     returns => {
1958         type => 'object',
1959         properties => {
1960             %$PVE::QemuServer::vmstatus_return_properties,
1961             ha => {
1962                 description => "HA manager service status.",
1963                 type => 'object',
1964             },
1965             spice => {
1966                 description => "Qemu VGA configuration supports spice.",
1967                 type => 'boolean',
1968                 optional => 1,
1969             },
1970             agent => {
1971                 description => "Qemu GuestAgent enabled in config.",
1972                 type => 'boolean',
1973                 optional => 1,
1974             },
1975         },
1976     },
1977     code => sub {
1978         my ($param) = @_;
1979
1980         # test if VM exists
1981         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1982
1983         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
1984         my $status = $vmstatus->{$param->{vmid}};
1985
1986         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
1987
1988         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
1989         $status->{agent} = 1 if (PVE::QemuServer::parse_guest_agent($conf)->{enabled});
1990
1991         return $status;
1992     }});
1993
1994 __PACKAGE__->register_method({
1995     name => 'vm_start',
1996     path => '{vmid}/status/start',
1997     method => 'POST',
1998     protected => 1,
1999     proxyto => 'node',
2000     description => "Start virtual machine.",
2001     permissions => {
2002         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2003     },
2004     parameters => {
2005         additionalProperties => 0,
2006         properties => {
2007             node => get_standard_option('pve-node'),
2008             vmid => get_standard_option('pve-vmid',
2009                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
2010             skiplock => get_standard_option('skiplock'),
2011             stateuri => get_standard_option('pve-qm-stateuri'),
2012             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
2013             migration_type => {
2014                 type => 'string',
2015                 enum => ['secure', 'insecure'],
2016                 description => "Migration traffic is encrypted using an SSH " .
2017                   "tunnel by default. On secure, completely private networks " .
2018                   "this can be disabled to increase performance.",
2019                 optional => 1,
2020             },
2021             migration_network => {
2022                 type => 'string', format => 'CIDR',
2023                 description => "CIDR of the (sub) network that is used for migration.",
2024                 optional => 1,
2025             },
2026             machine => get_standard_option('pve-qemu-machine'),
2027             targetstorage => {
2028                 description => "Target storage for the migration. (Can be '1' to use the same storage id as on the source node.)",
2029                 type => 'string',
2030                 optional => 1
2031             },
2032             timeout => {
2033                 description => "Wait maximal timeout seconds.",
2034                 type => 'integer',
2035                 minimum => 0,
2036                 default => 'max(30, vm memory in GiB)',
2037                 optional => 1,
2038             },
2039         },
2040     },
2041     returns => {
2042         type => 'string',
2043     },
2044     code => sub {
2045         my ($param) = @_;
2046
2047         my $rpcenv = PVE::RPCEnvironment::get();
2048         my $authuser = $rpcenv->get_user();
2049
2050         my $node = extract_param($param, 'node');
2051         my $vmid = extract_param($param, 'vmid');
2052         my $timeout = extract_param($param, 'timeout');
2053
2054         my $machine = extract_param($param, 'machine');
2055
2056         my $get_root_param = sub {
2057             my $value = extract_param($param, $_[0]);
2058             raise_param_exc({ "$_[0]" => "Only root may use this option." })
2059                 if $value && $authuser ne 'root@pam';
2060             return $value;
2061         };
2062
2063         my $stateuri = $get_root_param->('stateuri');
2064         my $skiplock = $get_root_param->('skiplock');
2065         my $migratedfrom = $get_root_param->('migratedfrom');
2066         my $migration_type = $get_root_param->('migration_type');
2067         my $migration_network = $get_root_param->('migration_network');
2068         my $targetstorage = $get_root_param->('targetstorage');
2069
2070         raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
2071             if $targetstorage && !$migratedfrom;
2072
2073         # read spice ticket from STDIN
2074         my $spice_ticket;
2075         my $nbd_protocol_version = 0;
2076         if ($stateuri && ($stateuri eq 'tcp' || $stateuri eq 'unix') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
2077             while (defined(my $line = <STDIN>)) {
2078                 chomp $line;
2079                 if ($line =~ m/^spice_ticket: (.+)$/) {
2080                     $spice_ticket = $1;
2081                 } elsif ($line =~ m/^nbd_protocol_version: (\d+)$/) {
2082                     $nbd_protocol_version = $1;
2083                 } else {
2084                     # fallback for old source node
2085                     $spice_ticket = $line;
2086                 }
2087             }
2088         }
2089
2090         PVE::Cluster::check_cfs_quorum();
2091
2092         my $storecfg = PVE::Storage::config();
2093
2094         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&  $rpcenv->{type} ne 'ha') {
2095             my $hacmd = sub {
2096                 my $upid = shift;
2097
2098                 print "Requesting HA start for VM $vmid\n";
2099
2100                 my $cmd = ['ha-manager', 'set',  "vm:$vmid", '--state', 'started'];
2101                 PVE::Tools::run_command($cmd);
2102                 return;
2103             };
2104
2105             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
2106
2107         } else {
2108
2109             my $realcmd = sub {
2110                 my $upid = shift;
2111
2112                 syslog('info', "start VM $vmid: $upid\n");
2113
2114                 PVE::QemuServer::vm_start($storecfg, $vmid, $stateuri, $skiplock, $migratedfrom, undef, $machine,
2115                                           $spice_ticket, $migration_network, $migration_type, $targetstorage, $timeout,
2116                                           $nbd_protocol_version);
2117                 return;
2118             };
2119
2120             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
2121         }
2122     }});
2123
2124 __PACKAGE__->register_method({
2125     name => 'vm_stop',
2126     path => '{vmid}/status/stop',
2127     method => 'POST',
2128     protected => 1,
2129     proxyto => 'node',
2130     description => "Stop virtual machine. The qemu process will exit immediately. This" .
2131         "is akin to pulling the power plug of a running computer and may damage the VM data",
2132     permissions => {
2133         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2134     },
2135     parameters => {
2136         additionalProperties => 0,
2137         properties => {
2138             node => get_standard_option('pve-node'),
2139             vmid => get_standard_option('pve-vmid',
2140                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2141             skiplock => get_standard_option('skiplock'),
2142             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
2143             timeout => {
2144                 description => "Wait maximal timeout seconds.",
2145                 type => 'integer',
2146                 minimum => 0,
2147                 optional => 1,
2148             },
2149             keepActive => {
2150                 description => "Do not deactivate storage volumes.",
2151                 type => 'boolean',
2152                 optional => 1,
2153                 default => 0,
2154             }
2155         },
2156     },
2157     returns => {
2158         type => 'string',
2159     },
2160     code => sub {
2161         my ($param) = @_;
2162
2163         my $rpcenv = PVE::RPCEnvironment::get();
2164         my $authuser = $rpcenv->get_user();
2165
2166         my $node = extract_param($param, 'node');
2167         my $vmid = extract_param($param, 'vmid');
2168
2169         my $skiplock = extract_param($param, 'skiplock');
2170         raise_param_exc({ skiplock => "Only root may use this option." })
2171             if $skiplock && $authuser ne 'root@pam';
2172
2173         my $keepActive = extract_param($param, 'keepActive');
2174         raise_param_exc({ keepActive => "Only root may use this option." })
2175             if $keepActive && $authuser ne 'root@pam';
2176
2177         my $migratedfrom = extract_param($param, 'migratedfrom');
2178         raise_param_exc({ migratedfrom => "Only root may use this option." })
2179             if $migratedfrom && $authuser ne 'root@pam';
2180
2181
2182         my $storecfg = PVE::Storage::config();
2183
2184         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2185
2186             my $hacmd = sub {
2187                 my $upid = shift;
2188
2189                 print "Requesting HA stop for VM $vmid\n";
2190
2191                 my $cmd = ['ha-manager', 'crm-command', 'stop',  "vm:$vmid", '0'];
2192                 PVE::Tools::run_command($cmd);
2193                 return;
2194             };
2195
2196             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2197
2198         } else {
2199             my $realcmd = sub {
2200                 my $upid = shift;
2201
2202                 syslog('info', "stop VM $vmid: $upid\n");
2203
2204                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2205                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2206                 return;
2207             };
2208
2209             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2210         }
2211     }});
2212
2213 __PACKAGE__->register_method({
2214     name => 'vm_reset',
2215     path => '{vmid}/status/reset',
2216     method => 'POST',
2217     protected => 1,
2218     proxyto => 'node',
2219     description => "Reset virtual machine.",
2220     permissions => {
2221         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2222     },
2223     parameters => {
2224         additionalProperties => 0,
2225         properties => {
2226             node => get_standard_option('pve-node'),
2227             vmid => get_standard_option('pve-vmid',
2228                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2229             skiplock => get_standard_option('skiplock'),
2230         },
2231     },
2232     returns => {
2233         type => 'string',
2234     },
2235     code => sub {
2236         my ($param) = @_;
2237
2238         my $rpcenv = PVE::RPCEnvironment::get();
2239
2240         my $authuser = $rpcenv->get_user();
2241
2242         my $node = extract_param($param, 'node');
2243
2244         my $vmid = extract_param($param, 'vmid');
2245
2246         my $skiplock = extract_param($param, 'skiplock');
2247         raise_param_exc({ skiplock => "Only root may use this option." })
2248             if $skiplock && $authuser ne 'root@pam';
2249
2250         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2251
2252         my $realcmd = sub {
2253             my $upid = shift;
2254
2255             PVE::QemuServer::vm_reset($vmid, $skiplock);
2256
2257             return;
2258         };
2259
2260         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2261     }});
2262
2263 __PACKAGE__->register_method({
2264     name => 'vm_shutdown',
2265     path => '{vmid}/status/shutdown',
2266     method => 'POST',
2267     protected => 1,
2268     proxyto => 'node',
2269     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2270         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2271     permissions => {
2272         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2273     },
2274     parameters => {
2275         additionalProperties => 0,
2276         properties => {
2277             node => get_standard_option('pve-node'),
2278             vmid => get_standard_option('pve-vmid',
2279                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2280             skiplock => get_standard_option('skiplock'),
2281             timeout => {
2282                 description => "Wait maximal timeout seconds.",
2283                 type => 'integer',
2284                 minimum => 0,
2285                 optional => 1,
2286             },
2287             forceStop => {
2288                 description => "Make sure the VM stops.",
2289                 type => 'boolean',
2290                 optional => 1,
2291                 default => 0,
2292             },
2293             keepActive => {
2294                 description => "Do not deactivate storage volumes.",
2295                 type => 'boolean',
2296                 optional => 1,
2297                 default => 0,
2298             }
2299         },
2300     },
2301     returns => {
2302         type => 'string',
2303     },
2304     code => sub {
2305         my ($param) = @_;
2306
2307         my $rpcenv = PVE::RPCEnvironment::get();
2308         my $authuser = $rpcenv->get_user();
2309
2310         my $node = extract_param($param, 'node');
2311         my $vmid = extract_param($param, 'vmid');
2312
2313         my $skiplock = extract_param($param, 'skiplock');
2314         raise_param_exc({ skiplock => "Only root may use this option." })
2315             if $skiplock && $authuser ne 'root@pam';
2316
2317         my $keepActive = extract_param($param, 'keepActive');
2318         raise_param_exc({ keepActive => "Only root may use this option." })
2319             if $keepActive && $authuser ne 'root@pam';
2320
2321         my $storecfg = PVE::Storage::config();
2322
2323         my $shutdown = 1;
2324
2325         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2326         # otherwise, we will infer a shutdown command, but run into the timeout,
2327         # then when the vm is resumed, it will instantly shutdown
2328         #
2329         # checking the qmp status here to get feedback to the gui/cli/api
2330         # and the status query should not take too long
2331         my $qmpstatus = eval {
2332             PVE::QemuConfig::assert_config_exists_on_node($vmid);
2333             mon_cmd($vmid, "query-status");
2334         };
2335         my $err = $@ if $@;
2336
2337         if (!$err && $qmpstatus->{status} eq "paused") {
2338             if ($param->{forceStop}) {
2339                 warn "VM is paused - stop instead of shutdown\n";
2340                 $shutdown = 0;
2341             } else {
2342                 die "VM is paused - cannot shutdown\n";
2343             }
2344         }
2345
2346         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
2347
2348             my $timeout = $param->{timeout} // 60;
2349             my $hacmd = sub {
2350                 my $upid = shift;
2351
2352                 print "Requesting HA stop for VM $vmid\n";
2353
2354                 my $cmd = ['ha-manager', 'crm-command', 'stop', "vm:$vmid", "$timeout"];
2355                 PVE::Tools::run_command($cmd);
2356                 return;
2357             };
2358
2359             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2360
2361         } else {
2362
2363             my $realcmd = sub {
2364                 my $upid = shift;
2365
2366                 syslog('info', "shutdown VM $vmid: $upid\n");
2367
2368                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2369                                          $shutdown, $param->{forceStop}, $keepActive);
2370                 return;
2371             };
2372
2373             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2374         }
2375     }});
2376
2377 __PACKAGE__->register_method({
2378     name => 'vm_reboot',
2379     path => '{vmid}/status/reboot',
2380     method => 'POST',
2381     protected => 1,
2382     proxyto => 'node',
2383     description => "Reboot the VM by shutting it down, and starting it again. Applies pending changes.",
2384     permissions => {
2385         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2386     },
2387     parameters => {
2388         additionalProperties => 0,
2389         properties => {
2390             node => get_standard_option('pve-node'),
2391             vmid => get_standard_option('pve-vmid',
2392                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2393             timeout => {
2394                 description => "Wait maximal timeout seconds for the shutdown.",
2395                 type => 'integer',
2396                 minimum => 0,
2397                 optional => 1,
2398             },
2399         },
2400     },
2401     returns => {
2402         type => 'string',
2403     },
2404     code => sub {
2405         my ($param) = @_;
2406
2407         my $rpcenv = PVE::RPCEnvironment::get();
2408         my $authuser = $rpcenv->get_user();
2409
2410         my $node = extract_param($param, 'node');
2411         my $vmid = extract_param($param, 'vmid');
2412
2413         my $qmpstatus = eval {
2414             PVE::QemuConfig::assert_config_exists_on_node($vmid);
2415             mon_cmd($vmid, "query-status");
2416         };
2417         my $err = $@ if $@;
2418
2419         if (!$err && $qmpstatus->{status} eq "paused") {
2420             die "VM is paused - cannot shutdown\n";
2421         }
2422
2423         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2424
2425         my $realcmd = sub {
2426             my $upid = shift;
2427
2428             syslog('info', "requesting reboot of VM $vmid: $upid\n");
2429             PVE::QemuServer::vm_reboot($vmid, $param->{timeout});
2430             return;
2431         };
2432
2433         return $rpcenv->fork_worker('qmreboot', $vmid, $authuser, $realcmd);
2434     }});
2435
2436 __PACKAGE__->register_method({
2437     name => 'vm_suspend',
2438     path => '{vmid}/status/suspend',
2439     method => 'POST',
2440     protected => 1,
2441     proxyto => 'node',
2442     description => "Suspend virtual machine.",
2443     permissions => {
2444         description => "You need 'VM.PowerMgmt' on /vms/{vmid}, and if you have set 'todisk',".
2445             " you need also 'VM.Config.Disk' on /vms/{vmid} and 'Datastore.AllocateSpace'".
2446             " on the storage for the vmstate.",
2447         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2448     },
2449     parameters => {
2450         additionalProperties => 0,
2451         properties => {
2452             node => get_standard_option('pve-node'),
2453             vmid => get_standard_option('pve-vmid',
2454                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2455             skiplock => get_standard_option('skiplock'),
2456             todisk => {
2457                 type => 'boolean',
2458                 default => 0,
2459                 optional => 1,
2460                 description => 'If set, suspends the VM to disk. Will be resumed on next VM start.',
2461             },
2462             statestorage => get_standard_option('pve-storage-id', {
2463                 description => "The storage for the VM state",
2464                 requires => 'todisk',
2465                 optional => 1,
2466                 completion => \&PVE::Storage::complete_storage_enabled,
2467             }),
2468         },
2469     },
2470     returns => {
2471         type => 'string',
2472     },
2473     code => sub {
2474         my ($param) = @_;
2475
2476         my $rpcenv = PVE::RPCEnvironment::get();
2477         my $authuser = $rpcenv->get_user();
2478
2479         my $node = extract_param($param, 'node');
2480         my $vmid = extract_param($param, 'vmid');
2481
2482         my $todisk = extract_param($param, 'todisk') // 0;
2483
2484         my $statestorage = extract_param($param, 'statestorage');
2485
2486         my $skiplock = extract_param($param, 'skiplock');
2487         raise_param_exc({ skiplock => "Only root may use this option." })
2488             if $skiplock && $authuser ne 'root@pam';
2489
2490         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2491
2492         die "Cannot suspend HA managed VM to disk\n"
2493             if $todisk && PVE::HA::Config::vm_is_ha_managed($vmid);
2494
2495         # early check for storage permission, for better user feedback
2496         if ($todisk) {
2497             $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
2498
2499             if (!$statestorage) {
2500                 # get statestorage from config if none is given
2501                 my $conf = PVE::QemuConfig->load_config($vmid);
2502                 my $storecfg = PVE::Storage::config();
2503                 $statestorage = PVE::QemuServer::find_vmstate_storage($conf, $storecfg);
2504             }
2505
2506             $rpcenv->check($authuser, "/storage/$statestorage", ['Datastore.AllocateSpace']);
2507         }
2508
2509         my $realcmd = sub {
2510             my $upid = shift;
2511
2512             syslog('info', "suspend VM $vmid: $upid\n");
2513
2514             PVE::QemuServer::vm_suspend($vmid, $skiplock, $todisk, $statestorage);
2515
2516             return;
2517         };
2518
2519         my $taskname = $todisk ? 'qmsuspend' : 'qmpause';
2520         return $rpcenv->fork_worker($taskname, $vmid, $authuser, $realcmd);
2521     }});
2522
2523 __PACKAGE__->register_method({
2524     name => 'vm_resume',
2525     path => '{vmid}/status/resume',
2526     method => 'POST',
2527     protected => 1,
2528     proxyto => 'node',
2529     description => "Resume virtual machine.",
2530     permissions => {
2531         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2532     },
2533     parameters => {
2534         additionalProperties => 0,
2535         properties => {
2536             node => get_standard_option('pve-node'),
2537             vmid => get_standard_option('pve-vmid',
2538                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2539             skiplock => get_standard_option('skiplock'),
2540             nocheck => { type => 'boolean', optional => 1 },
2541
2542         },
2543     },
2544     returns => {
2545         type => 'string',
2546     },
2547     code => sub {
2548         my ($param) = @_;
2549
2550         my $rpcenv = PVE::RPCEnvironment::get();
2551
2552         my $authuser = $rpcenv->get_user();
2553
2554         my $node = extract_param($param, 'node');
2555
2556         my $vmid = extract_param($param, 'vmid');
2557
2558         my $skiplock = extract_param($param, 'skiplock');
2559         raise_param_exc({ skiplock => "Only root may use this option." })
2560             if $skiplock && $authuser ne 'root@pam';
2561
2562         my $nocheck = extract_param($param, 'nocheck');
2563
2564         my $to_disk_suspended;
2565         eval {
2566             PVE::QemuConfig->lock_config($vmid, sub {
2567                 my $conf = PVE::QemuConfig->load_config($vmid);
2568                 $to_disk_suspended = PVE::QemuConfig->has_lock($conf, 'suspended');
2569             });
2570         };
2571
2572         die "VM $vmid not running\n"
2573             if !$to_disk_suspended && !PVE::QemuServer::check_running($vmid, $nocheck);
2574
2575         my $realcmd = sub {
2576             my $upid = shift;
2577
2578             syslog('info', "resume VM $vmid: $upid\n");
2579
2580             if (!$to_disk_suspended) {
2581                 PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2582             } else {
2583                 my $storecfg = PVE::Storage::config();
2584                 PVE::QemuServer::vm_start($storecfg, $vmid, undef, $skiplock);
2585             }
2586
2587             return;
2588         };
2589
2590         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2591     }});
2592
2593 __PACKAGE__->register_method({
2594     name => 'vm_sendkey',
2595     path => '{vmid}/sendkey',
2596     method => 'PUT',
2597     protected => 1,
2598     proxyto => 'node',
2599     description => "Send key event to virtual machine.",
2600     permissions => {
2601         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2602     },
2603     parameters => {
2604         additionalProperties => 0,
2605         properties => {
2606             node => get_standard_option('pve-node'),
2607             vmid => get_standard_option('pve-vmid',
2608                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2609             skiplock => get_standard_option('skiplock'),
2610             key => {
2611                 description => "The key (qemu monitor encoding).",
2612                 type => 'string'
2613             }
2614         },
2615     },
2616     returns => { type => 'null'},
2617     code => sub {
2618         my ($param) = @_;
2619
2620         my $rpcenv = PVE::RPCEnvironment::get();
2621
2622         my $authuser = $rpcenv->get_user();
2623
2624         my $node = extract_param($param, 'node');
2625
2626         my $vmid = extract_param($param, 'vmid');
2627
2628         my $skiplock = extract_param($param, 'skiplock');
2629         raise_param_exc({ skiplock => "Only root may use this option." })
2630             if $skiplock && $authuser ne 'root@pam';
2631
2632         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2633
2634         return;
2635     }});
2636
2637 __PACKAGE__->register_method({
2638     name => 'vm_feature',
2639     path => '{vmid}/feature',
2640     method => 'GET',
2641     proxyto => 'node',
2642     protected => 1,
2643     description => "Check if feature for virtual machine is available.",
2644     permissions => {
2645         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2646     },
2647     parameters => {
2648         additionalProperties => 0,
2649         properties => {
2650             node => get_standard_option('pve-node'),
2651             vmid => get_standard_option('pve-vmid'),
2652             feature => {
2653                 description => "Feature to check.",
2654                 type => 'string',
2655                 enum => [ 'snapshot', 'clone', 'copy' ],
2656             },
2657             snapname => get_standard_option('pve-snapshot-name', {
2658                 optional => 1,
2659             }),
2660         },
2661     },
2662     returns => {
2663         type => "object",
2664         properties => {
2665             hasFeature => { type => 'boolean' },
2666             nodes => {
2667                 type => 'array',
2668                 items => { type => 'string' },
2669             }
2670         },
2671     },
2672     code => sub {
2673         my ($param) = @_;
2674
2675         my $node = extract_param($param, 'node');
2676
2677         my $vmid = extract_param($param, 'vmid');
2678
2679         my $snapname = extract_param($param, 'snapname');
2680
2681         my $feature = extract_param($param, 'feature');
2682
2683         my $running = PVE::QemuServer::check_running($vmid);
2684
2685         my $conf = PVE::QemuConfig->load_config($vmid);
2686
2687         if($snapname){
2688             my $snap = $conf->{snapshots}->{$snapname};
2689             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2690             $conf = $snap;
2691         }
2692         my $storecfg = PVE::Storage::config();
2693
2694         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2695         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2696
2697         return {
2698             hasFeature => $hasFeature,
2699             nodes => [ keys %$nodelist ],
2700         };
2701     }});
2702
2703 __PACKAGE__->register_method({
2704     name => 'clone_vm',
2705     path => '{vmid}/clone',
2706     method => 'POST',
2707     protected => 1,
2708     proxyto => 'node',
2709     description => "Create a copy of virtual machine/template.",
2710     permissions => {
2711         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2712             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2713             "'Datastore.AllocateSpace' on any used storage.",
2714         check =>
2715         [ 'and',
2716           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2717           [ 'or',
2718             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2719             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2720           ],
2721         ]
2722     },
2723     parameters => {
2724         additionalProperties => 0,
2725         properties => {
2726             node => get_standard_option('pve-node'),
2727             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2728             newid => get_standard_option('pve-vmid', {
2729                 completion => \&PVE::Cluster::complete_next_vmid,
2730                 description => 'VMID for the clone.' }),
2731             name => {
2732                 optional => 1,
2733                 type => 'string', format => 'dns-name',
2734                 description => "Set a name for the new VM.",
2735             },
2736             description => {
2737                 optional => 1,
2738                 type => 'string',
2739                 description => "Description for the new VM.",
2740             },
2741             pool => {
2742                 optional => 1,
2743                 type => 'string', format => 'pve-poolid',
2744                 description => "Add the new VM to the specified pool.",
2745             },
2746             snapname => get_standard_option('pve-snapshot-name', {
2747                 optional => 1,
2748             }),
2749             storage => get_standard_option('pve-storage-id', {
2750                 description => "Target storage for full clone.",
2751                 optional => 1,
2752             }),
2753             'format' => {
2754                 description => "Target format for file storage. Only valid for full clone.",
2755                 type => 'string',
2756                 optional => 1,
2757                 enum => [ 'raw', 'qcow2', 'vmdk'],
2758             },
2759             full => {
2760                 optional => 1,
2761                 type => 'boolean',
2762                 description => "Create a full copy of all disks. This is always done when " .
2763                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2764             },
2765             target => get_standard_option('pve-node', {
2766                 description => "Target node. Only allowed if the original VM is on shared storage.",
2767                 optional => 1,
2768             }),
2769             bwlimit => {
2770                 description => "Override I/O bandwidth limit (in KiB/s).",
2771                 optional => 1,
2772                 type => 'integer',
2773                 minimum => '0',
2774                 default => 'clone limit from datacenter or storage config',
2775             },
2776         },
2777     },
2778     returns => {
2779         type => 'string',
2780     },
2781     code => sub {
2782         my ($param) = @_;
2783
2784         my $rpcenv = PVE::RPCEnvironment::get();
2785         my $authuser = $rpcenv->get_user();
2786
2787         my $node = extract_param($param, 'node');
2788         my $vmid = extract_param($param, 'vmid');
2789         my $newid = extract_param($param, 'newid');
2790         my $pool = extract_param($param, 'pool');
2791         $rpcenv->check_pool_exist($pool) if defined($pool);
2792
2793         my $snapname = extract_param($param, 'snapname');
2794         my $storage = extract_param($param, 'storage');
2795         my $format = extract_param($param, 'format');
2796         my $target = extract_param($param, 'target');
2797
2798         my $localnode = PVE::INotify::nodename();
2799
2800         if ($target && ($target eq $localnode || $target eq 'localhost')) {
2801             undef $target;
2802         }
2803
2804         PVE::Cluster::check_node_exists($target) if $target;
2805
2806         my $storecfg = PVE::Storage::config();
2807
2808         if ($storage) {
2809             # check if storage is enabled on local node
2810             PVE::Storage::storage_check_enabled($storecfg, $storage);
2811             if ($target) {
2812                 # check if storage is available on target node
2813                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
2814                 # clone only works if target storage is shared
2815                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2816                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
2817             }
2818         }
2819
2820         PVE::Cluster::check_cfs_quorum();
2821
2822         my $running = PVE::QemuServer::check_running($vmid) || 0;
2823
2824         # exclusive lock if VM is running - else shared lock is enough;
2825         my $shared_lock = $running ? 0 : 1;
2826
2827         my $clonefn = sub {
2828             # do all tests after lock but before forking worker - if possible
2829
2830             my $conf = PVE::QemuConfig->load_config($vmid);
2831             PVE::QemuConfig->check_lock($conf);
2832
2833             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
2834             die "unexpected state change\n" if $verify_running != $running;
2835
2836             die "snapshot '$snapname' does not exist\n"
2837                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
2838
2839             my $full = extract_param($param, 'full') // !PVE::QemuConfig->is_template($conf);
2840
2841             die "parameter 'storage' not allowed for linked clones\n"
2842                 if defined($storage) && !$full;
2843
2844             die "parameter 'format' not allowed for linked clones\n"
2845                 if defined($format) && !$full;
2846
2847             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
2848
2849             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
2850
2851             die "can't clone VM to node '$target' (VM uses local storage)\n"
2852                 if $target && !$sharedvm;
2853
2854             my $conffile = PVE::QemuConfig->config_file($newid);
2855             die "unable to create VM $newid: config file already exists\n"
2856                 if -f $conffile;
2857
2858             my $newconf = { lock => 'clone' };
2859             my $drives = {};
2860             my $fullclone = {};
2861             my $vollist = [];
2862
2863             foreach my $opt (keys %$oldconf) {
2864                 my $value = $oldconf->{$opt};
2865
2866                 # do not copy snapshot related info
2867                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
2868                     $opt eq 'vmstate' || $opt eq 'snapstate';
2869
2870                 # no need to copy unused images, because VMID(owner) changes anyways
2871                 next if $opt =~ m/^unused\d+$/;
2872
2873                 # always change MAC! address
2874                 if ($opt =~ m/^net(\d+)$/) {
2875                     my $net = PVE::QemuServer::parse_net($value);
2876                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
2877                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
2878                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
2879                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
2880                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
2881                     die "unable to parse drive options for '$opt'\n" if !$drive;
2882                     if (PVE::QemuServer::drive_is_cdrom($drive, 1)) {
2883                         $newconf->{$opt} = $value; # simply copy configuration
2884                     } else {
2885                         if ($full || PVE::QemuServer::drive_is_cloudinit($drive)) {
2886                             die "Full clone feature is not supported for drive '$opt'\n"
2887                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
2888                             $fullclone->{$opt} = 1;
2889                         } else {
2890                             # not full means clone instead of copy
2891                             die "Linked clone feature is not supported for drive '$opt'\n"
2892                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
2893                         }
2894                         $drives->{$opt} = $drive;
2895                         push @$vollist, $drive->{file};
2896                     }
2897                 } else {
2898                     # copy everything else
2899                     $newconf->{$opt} = $value;
2900                 }
2901             }
2902
2903             # auto generate a new uuid
2904             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
2905             $smbios1->{uuid} = PVE::QemuServer::generate_uuid();
2906             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
2907             # auto generate a new vmgenid only if the option was set for template
2908             if ($newconf->{vmgenid}) {
2909                 $newconf->{vmgenid} = PVE::QemuServer::generate_uuid();
2910             }
2911
2912             delete $newconf->{template};
2913
2914             if ($param->{name}) {
2915                 $newconf->{name} = $param->{name};
2916             } else {
2917                 $newconf->{name} = "Copy-of-VM-" . ($oldconf->{name} // $vmid);
2918             }
2919
2920             if ($param->{description}) {
2921                 $newconf->{description} = $param->{description};
2922             }
2923
2924             # create empty/temp config - this fails if VM already exists on other node
2925             # FIXME use PVE::QemuConfig->create_and_lock_config and adapt code
2926             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
2927
2928             my $realcmd = sub {
2929                 my $upid = shift;
2930
2931                 my $newvollist = [];
2932                 my $jobs = {};
2933
2934                 eval {
2935                     local $SIG{INT} =
2936                         local $SIG{TERM} =
2937                         local $SIG{QUIT} =
2938                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2939
2940                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
2941
2942                     my $bwlimit = extract_param($param, 'bwlimit');
2943
2944                     my $total_jobs = scalar(keys %{$drives});
2945                     my $i = 1;
2946
2947                     foreach my $opt (keys %$drives) {
2948                         my $drive = $drives->{$opt};
2949                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
2950                         my $completion = $skipcomplete ? 'skip' : 'wait';
2951
2952                         my $src_sid = PVE::Storage::parse_volume_id($drive->{file});
2953                         my $storage_list = [ $src_sid ];
2954                         push @$storage_list, $storage if defined($storage);
2955                         my $clonelimit = PVE::Storage::get_bandwidth_limit('clone', $storage_list, $bwlimit);
2956
2957                         my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $opt, $drive, $snapname,
2958                                                                    $newid, $storage, $format, $fullclone->{$opt}, $newvollist,
2959                                                                    $jobs, $completion, $oldconf->{agent}, $clonelimit);
2960
2961                         $newconf->{$opt} = PVE::QemuServer::print_drive($newdrive);
2962
2963                         PVE::QemuConfig->write_config($newid, $newconf);
2964                         $i++;
2965                     }
2966
2967                     delete $newconf->{lock};
2968
2969                     # do not write pending changes
2970                     if (my @changes = keys %{$newconf->{pending}}) {
2971                         my $pending = join(',', @changes);
2972                         warn "found pending changes for '$pending', discarding for clone\n";
2973                         delete $newconf->{pending};
2974                     }
2975
2976                     PVE::QemuConfig->write_config($newid, $newconf);
2977
2978                     if ($target) {
2979                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
2980                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
2981                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
2982
2983                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
2984                         die "Failed to move config to node '$target' - rename failed: $!\n"
2985                             if !rename($conffile, $newconffile);
2986                     }
2987
2988                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
2989                 };
2990                 if (my $err = $@) {
2991                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
2992                     sleep 1; # some storage like rbd need to wait before release volume - really?
2993
2994                     foreach my $volid (@$newvollist) {
2995                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2996                         warn $@ if $@;
2997                     }
2998
2999                     PVE::Firewall::remove_vmfw_conf($newid);
3000
3001                     unlink $conffile; # avoid races -> last thing before die
3002
3003                     die "clone failed: $err";
3004                 }
3005
3006                 return;
3007             };
3008
3009             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
3010
3011             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
3012         };
3013
3014         return PVE::QemuConfig->lock_config_mode($vmid, 1, $shared_lock, sub {
3015             # Aquire exclusive lock lock for $newid
3016             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
3017         });
3018
3019     }});
3020
3021 __PACKAGE__->register_method({
3022     name => 'move_vm_disk',
3023     path => '{vmid}/move_disk',
3024     method => 'POST',
3025     protected => 1,
3026     proxyto => 'node',
3027     description => "Move volume to different storage.",
3028     permissions => {
3029         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
3030         check => [ 'and',
3031                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3032                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
3033             ],
3034     },
3035     parameters => {
3036         additionalProperties => 0,
3037         properties => {
3038             node => get_standard_option('pve-node'),
3039             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3040             disk => {
3041                 type => 'string',
3042                 description => "The disk you want to move.",
3043                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3044             },
3045             storage => get_standard_option('pve-storage-id', {
3046                 description => "Target storage.",
3047                 completion => \&PVE::QemuServer::complete_storage,
3048             }),
3049             'format' => {
3050                 type => 'string',
3051                 description => "Target Format.",
3052                 enum => [ 'raw', 'qcow2', 'vmdk' ],
3053                 optional => 1,
3054             },
3055             delete => {
3056                 type => 'boolean',
3057                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
3058                 optional => 1,
3059                 default => 0,
3060             },
3061             digest => {
3062                 type => 'string',
3063                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3064                 maxLength => 40,
3065                 optional => 1,
3066             },
3067             bwlimit => {
3068                 description => "Override I/O bandwidth limit (in KiB/s).",
3069                 optional => 1,
3070                 type => 'integer',
3071                 minimum => '0',
3072                 default => 'move limit from datacenter or storage config',
3073             },
3074         },
3075     },
3076     returns => {
3077         type => 'string',
3078         description => "the task ID.",
3079     },
3080     code => sub {
3081         my ($param) = @_;
3082
3083         my $rpcenv = PVE::RPCEnvironment::get();
3084         my $authuser = $rpcenv->get_user();
3085
3086         my $node = extract_param($param, 'node');
3087         my $vmid = extract_param($param, 'vmid');
3088         my $digest = extract_param($param, 'digest');
3089         my $disk = extract_param($param, 'disk');
3090         my $storeid = extract_param($param, 'storage');
3091         my $format = extract_param($param, 'format');
3092
3093         my $storecfg = PVE::Storage::config();
3094
3095         my $updatefn =  sub {
3096             my $conf = PVE::QemuConfig->load_config($vmid);
3097             PVE::QemuConfig->check_lock($conf);
3098
3099             die "VM config checksum missmatch (file change by other user?)\n"
3100                 if $digest && $digest ne $conf->{digest};
3101
3102             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3103
3104             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3105
3106             die "disk '$disk' has no associated volume\n" if !$drive->{file};
3107             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive, 1);
3108
3109             my $old_volid = $drive->{file};
3110             my $oldfmt;
3111             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
3112             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
3113                 $oldfmt = $1;
3114             }
3115
3116             die "you can't move to the same storage with same format\n" if $oldstoreid eq $storeid &&
3117                 (!$format || !$oldfmt || $oldfmt eq $format);
3118
3119             # this only checks snapshots because $disk is passed!
3120             my $snapshotted = PVE::QemuServer::Drive::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
3121             die "you can't move a disk with snapshots and delete the source\n"
3122                 if $snapshotted && $param->{delete};
3123
3124             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
3125
3126             my $running = PVE::QemuServer::check_running($vmid);
3127
3128             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
3129
3130             my $realcmd = sub {
3131                 my $newvollist = [];
3132
3133                 eval {
3134                     local $SIG{INT} =
3135                         local $SIG{TERM} =
3136                         local $SIG{QUIT} =
3137                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3138
3139                     warn "moving disk with snapshots, snapshots will not be moved!\n"
3140                         if $snapshotted;
3141
3142                     my $bwlimit = extract_param($param, 'bwlimit');
3143                     my $movelimit = PVE::Storage::get_bandwidth_limit('move', [$oldstoreid, $storeid], $bwlimit);
3144
3145                     my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $disk, $drive, undef,
3146                                                                $vmid, $storeid, $format, 1, $newvollist, undef, undef, undef, $movelimit);
3147
3148                     $conf->{$disk} = PVE::QemuServer::print_drive($newdrive);
3149
3150                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
3151
3152                     # convert moved disk to base if part of template
3153                     PVE::QemuServer::template_create($vmid, $conf, $disk)
3154                         if PVE::QemuConfig->is_template($conf);
3155
3156                     PVE::QemuConfig->write_config($vmid, $conf);
3157
3158                     my $do_trim = PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks};
3159                     if ($running && $do_trim && PVE::QemuServer::qga_check_running($vmid)) {
3160                         eval { mon_cmd($vmid, "guest-fstrim") };
3161                     }
3162
3163                     eval {
3164                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
3165                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
3166                             if !$running;
3167                     };
3168                     warn $@ if $@;
3169                 };
3170                 if (my $err = $@) {
3171                     foreach my $volid (@$newvollist) {
3172                         eval { PVE::Storage::vdisk_free($storecfg, $volid) };
3173                         warn $@ if $@;
3174                     }
3175                     die "storage migration failed: $err";
3176                 }
3177
3178                 if ($param->{delete}) {
3179                     eval {
3180                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
3181                         PVE::Storage::vdisk_free($storecfg, $old_volid);
3182                     };
3183                     warn $@ if $@;
3184                 }
3185             };
3186
3187             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
3188         };
3189
3190         return PVE::QemuConfig->lock_config($vmid, $updatefn);
3191     }});
3192
3193 my $check_vm_disks_local = sub {
3194     my ($storecfg, $vmconf, $vmid) = @_;
3195
3196     my $local_disks = {};
3197
3198     # add some more information to the disks e.g. cdrom
3199     PVE::QemuServer::foreach_volid($vmconf, sub {
3200         my ($volid, $attr) = @_;
3201
3202         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
3203         if ($storeid) {
3204             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
3205             return if $scfg->{shared};
3206         }
3207         # The shared attr here is just a special case where the vdisk
3208         # is marked as shared manually
3209         return if $attr->{shared};
3210         return if $attr->{cdrom} and $volid eq "none";
3211
3212         if (exists $local_disks->{$volid}) {
3213             @{$local_disks->{$volid}}{keys %$attr} = values %$attr
3214         } else {
3215             $local_disks->{$volid} = $attr;
3216             # ensure volid is present in case it's needed
3217             $local_disks->{$volid}->{volid} = $volid;
3218         }
3219     });
3220
3221     return $local_disks;
3222 };
3223
3224 __PACKAGE__->register_method({
3225     name => 'migrate_vm_precondition',
3226     path => '{vmid}/migrate',
3227     method => 'GET',
3228     protected => 1,
3229     proxyto => 'node',
3230     description => "Get preconditions for migration.",
3231     permissions => {
3232         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3233     },
3234     parameters => {
3235         additionalProperties => 0,
3236         properties => {
3237             node => get_standard_option('pve-node'),
3238             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3239             target => get_standard_option('pve-node', {
3240                 description => "Target node.",
3241                 completion =>  \&PVE::Cluster::complete_migration_target,
3242                 optional => 1,
3243             }),
3244         },
3245     },
3246     returns => {
3247         type => "object",
3248         properties => {
3249             running => { type => 'boolean' },
3250             allowed_nodes => {
3251                 type => 'array',
3252                 optional => 1,
3253                 description => "List nodes allowed for offline migration, only passed if VM is offline"
3254             },
3255             not_allowed_nodes => {
3256                 type => 'object',
3257                 optional => 1,
3258                 description => "List not allowed nodes with additional informations, only passed if VM is offline"
3259             },
3260             local_disks => {
3261                 type => 'array',
3262                 description => "List local disks including CD-Rom, unsused and not referenced disks"
3263             },
3264             local_resources => {
3265                 type => 'array',
3266                 description => "List local resources e.g. pci, usb"
3267             }
3268         },
3269     },
3270     code => sub {
3271         my ($param) = @_;
3272
3273         my $rpcenv = PVE::RPCEnvironment::get();
3274
3275         my $authuser = $rpcenv->get_user();
3276
3277         PVE::Cluster::check_cfs_quorum();
3278
3279         my $res = {};
3280
3281         my $vmid = extract_param($param, 'vmid');
3282         my $target = extract_param($param, 'target');
3283         my $localnode = PVE::INotify::nodename();
3284
3285
3286         # test if VM exists
3287         my $vmconf = PVE::QemuConfig->load_config($vmid);
3288         my $storecfg = PVE::Storage::config();
3289
3290
3291         # try to detect errors early
3292         PVE::QemuConfig->check_lock($vmconf);
3293
3294         $res->{running} = PVE::QemuServer::check_running($vmid) ? 1:0;
3295
3296         # if vm is not running, return target nodes where local storage is available
3297         # for offline migration
3298         if (!$res->{running}) {
3299             $res->{allowed_nodes} = [];
3300             my $checked_nodes = PVE::QemuServer::check_local_storage_availability($vmconf, $storecfg);
3301             delete $checked_nodes->{$localnode};
3302
3303             foreach my $node (keys %$checked_nodes) {
3304                 if (!defined $checked_nodes->{$node}->{unavailable_storages}) {
3305                     push @{$res->{allowed_nodes}}, $node;
3306                 }
3307
3308             }
3309             $res->{not_allowed_nodes} = $checked_nodes;
3310         }
3311
3312
3313         my $local_disks = &$check_vm_disks_local($storecfg, $vmconf, $vmid);
3314         $res->{local_disks} = [ values %$local_disks ];;
3315
3316         my $local_resources =  PVE::QemuServer::check_local_resources($vmconf, 1);
3317
3318         $res->{local_resources} = $local_resources;
3319
3320         return $res;
3321
3322
3323     }});
3324
3325 __PACKAGE__->register_method({
3326     name => 'migrate_vm',
3327     path => '{vmid}/migrate',
3328     method => 'POST',
3329     protected => 1,
3330     proxyto => 'node',
3331     description => "Migrate virtual machine. Creates a new migration task.",
3332     permissions => {
3333         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3334     },
3335     parameters => {
3336         additionalProperties => 0,
3337         properties => {
3338             node => get_standard_option('pve-node'),
3339             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3340             target => get_standard_option('pve-node', {
3341                 description => "Target node.",
3342                 completion =>  \&PVE::Cluster::complete_migration_target,
3343             }),
3344             online => {
3345                 type => 'boolean',
3346                 description => "Use online/live migration if VM is running. Ignored if VM is stopped.",
3347                 optional => 1,
3348             },
3349             force => {
3350                 type => 'boolean',
3351                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
3352                 optional => 1,
3353             },
3354             migration_type => {
3355                 type => 'string',
3356                 enum => ['secure', 'insecure'],
3357                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
3358                 optional => 1,
3359             },
3360             migration_network => {
3361                 type => 'string', format => 'CIDR',
3362                 description => "CIDR of the (sub) network that is used for migration.",
3363                 optional => 1,
3364             },
3365             "with-local-disks" => {
3366                 type => 'boolean',
3367                 description => "Enable live storage migration for local disk",
3368                 optional => 1,
3369             },
3370             targetstorage => get_standard_option('pve-storage-id', {
3371                 description => "Default target storage.",
3372                 optional => 1,
3373                 completion => \&PVE::QemuServer::complete_migration_storage,
3374             }),
3375             bwlimit => {
3376                 description => "Override I/O bandwidth limit (in KiB/s).",
3377                 optional => 1,
3378                 type => 'integer',
3379                 minimum => '0',
3380                 default => 'migrate limit from datacenter or storage config',
3381             },
3382         },
3383     },
3384     returns => {
3385         type => 'string',
3386         description => "the task ID.",
3387     },
3388     code => sub {
3389         my ($param) = @_;
3390
3391         my $rpcenv = PVE::RPCEnvironment::get();
3392         my $authuser = $rpcenv->get_user();
3393
3394         my $target = extract_param($param, 'target');
3395
3396         my $localnode = PVE::INotify::nodename();
3397         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
3398
3399         PVE::Cluster::check_cfs_quorum();
3400
3401         PVE::Cluster::check_node_exists($target);
3402
3403         my $targetip = PVE::Cluster::remote_node_ip($target);
3404
3405         my $vmid = extract_param($param, 'vmid');
3406
3407         raise_param_exc({ force => "Only root may use this option." })
3408             if $param->{force} && $authuser ne 'root@pam';
3409
3410         raise_param_exc({ migration_type => "Only root may use this option." })
3411             if $param->{migration_type} && $authuser ne 'root@pam';
3412
3413         # allow root only until better network permissions are available
3414         raise_param_exc({ migration_network => "Only root may use this option." })
3415             if $param->{migration_network} && $authuser ne 'root@pam';
3416
3417         # test if VM exists
3418         my $conf = PVE::QemuConfig->load_config($vmid);
3419
3420         # try to detect errors early
3421
3422         PVE::QemuConfig->check_lock($conf);
3423
3424         if (PVE::QemuServer::check_running($vmid)) {
3425             die "can't migrate running VM without --online\n" if !$param->{online};
3426         } else {
3427             warn "VM isn't running. Doing offline migration instead.\n" if $param->{online};
3428             $param->{online} = 0;
3429         }
3430
3431         raise_param_exc({ targetstorage => "Live storage migration can only be done online." })
3432             if !$param->{online} && $param->{targetstorage};
3433
3434         my $storecfg = PVE::Storage::config();
3435
3436         if( $param->{targetstorage}) {
3437             PVE::Storage::storage_check_node($storecfg, $param->{targetstorage}, $target);
3438         } else {
3439             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3440         }
3441
3442         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3443
3444             my $hacmd = sub {
3445                 my $upid = shift;
3446
3447                 print "Requesting HA migration for VM $vmid to node $target\n";
3448
3449                 my $cmd = ['ha-manager', 'migrate', "vm:$vmid", $target];
3450                 PVE::Tools::run_command($cmd);
3451                 return;
3452             };
3453
3454             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3455
3456         } else {
3457
3458             my $realcmd = sub {
3459                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3460             };
3461
3462             my $worker = sub {
3463                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3464             };
3465
3466             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3467         }
3468
3469     }});
3470
3471 __PACKAGE__->register_method({
3472     name => 'monitor',
3473     path => '{vmid}/monitor',
3474     method => 'POST',
3475     protected => 1,
3476     proxyto => 'node',
3477     description => "Execute Qemu monitor commands.",
3478     permissions => {
3479         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3480         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3481     },
3482     parameters => {
3483         additionalProperties => 0,
3484         properties => {
3485             node => get_standard_option('pve-node'),
3486             vmid => get_standard_option('pve-vmid'),
3487             command => {
3488                 type => 'string',
3489                 description => "The monitor command.",
3490             }
3491         },
3492     },
3493     returns => { type => 'string'},
3494     code => sub {
3495         my ($param) = @_;
3496
3497         my $rpcenv = PVE::RPCEnvironment::get();
3498         my $authuser = $rpcenv->get_user();
3499
3500         my $is_ro = sub {
3501             my $command = shift;
3502             return $command =~ m/^\s*info(\s+|$)/
3503                 || $command =~ m/^\s*help\s*$/;
3504         };
3505
3506         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3507             if !&$is_ro($param->{command});
3508
3509         my $vmid = $param->{vmid};
3510
3511         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3512
3513         my $res = '';
3514         eval {
3515             $res = PVE::QemuServer::Monitor::hmp_cmd($vmid, $param->{command});
3516         };
3517         $res = "ERROR: $@" if $@;
3518
3519         return $res;
3520     }});
3521
3522 __PACKAGE__->register_method({
3523     name => 'resize_vm',
3524     path => '{vmid}/resize',
3525     method => 'PUT',
3526     protected => 1,
3527     proxyto => 'node',
3528     description => "Extend volume size.",
3529     permissions => {
3530         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3531     },
3532     parameters => {
3533         additionalProperties => 0,
3534         properties => {
3535             node => get_standard_option('pve-node'),
3536             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3537             skiplock => get_standard_option('skiplock'),
3538             disk => {
3539                 type => 'string',
3540                 description => "The disk you want to resize.",
3541                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3542             },
3543             size => {
3544                 type => 'string',
3545                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3546                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3547             },
3548             digest => {
3549                 type => 'string',
3550                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3551                 maxLength => 40,
3552                 optional => 1,
3553             },
3554         },
3555     },
3556     returns => { type => 'null'},
3557     code => sub {
3558         my ($param) = @_;
3559
3560         my $rpcenv = PVE::RPCEnvironment::get();
3561
3562         my $authuser = $rpcenv->get_user();
3563
3564         my $node = extract_param($param, 'node');
3565
3566         my $vmid = extract_param($param, 'vmid');
3567
3568         my $digest = extract_param($param, 'digest');
3569
3570         my $disk = extract_param($param, 'disk');
3571
3572         my $sizestr = extract_param($param, 'size');
3573
3574         my $skiplock = extract_param($param, 'skiplock');
3575         raise_param_exc({ skiplock => "Only root may use this option." })
3576             if $skiplock && $authuser ne 'root@pam';
3577
3578         my $storecfg = PVE::Storage::config();
3579
3580         my $updatefn =  sub {
3581
3582             my $conf = PVE::QemuConfig->load_config($vmid);
3583
3584             die "checksum missmatch (file change by other user?)\n"
3585                 if $digest && $digest ne $conf->{digest};
3586             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3587
3588             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3589
3590             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3591
3592             my (undef, undef, undef, undef, undef, undef, $format) =
3593                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3594
3595             die "can't resize volume: $disk if snapshot exists\n"
3596                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3597
3598             my $volid = $drive->{file};
3599
3600             die "disk '$disk' has no associated volume\n" if !$volid;
3601
3602             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3603
3604             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3605
3606             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3607
3608             PVE::Storage::activate_volumes($storecfg, [$volid]);
3609             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3610
3611             die "Could not determine current size of volume '$volid'\n" if !defined($size);
3612
3613             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3614             my ($ext, $newsize, $unit) = ($1, $2, $4);
3615             if ($unit) {
3616                 if ($unit eq 'K') {
3617                     $newsize = $newsize * 1024;
3618                 } elsif ($unit eq 'M') {
3619                     $newsize = $newsize * 1024 * 1024;
3620                 } elsif ($unit eq 'G') {
3621                     $newsize = $newsize * 1024 * 1024 * 1024;
3622                 } elsif ($unit eq 'T') {
3623                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3624                 }
3625             }
3626             $newsize += $size if $ext;
3627             $newsize = int($newsize);
3628
3629             die "shrinking disks is not supported\n" if $newsize < $size;
3630
3631             return if $size == $newsize;
3632
3633             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3634
3635             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3636
3637             my $effective_size = eval { PVE::Storage::volume_size_info($storecfg, $volid, 3); };
3638             $drive->{size} = $effective_size // $newsize;
3639             $conf->{$disk} = PVE::QemuServer::print_drive($drive);
3640
3641             PVE::QemuConfig->write_config($vmid, $conf);
3642         };
3643
3644         PVE::QemuConfig->lock_config($vmid, $updatefn);
3645         return undef;
3646     }});
3647
3648 __PACKAGE__->register_method({
3649     name => 'snapshot_list',
3650     path => '{vmid}/snapshot',
3651     method => 'GET',
3652     description => "List all snapshots.",
3653     permissions => {
3654         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3655     },
3656     proxyto => 'node',
3657     protected => 1, # qemu pid files are only readable by root
3658     parameters => {
3659         additionalProperties => 0,
3660         properties => {
3661             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3662             node => get_standard_option('pve-node'),
3663         },
3664     },
3665     returns => {
3666         type => 'array',
3667         items => {
3668             type => "object",
3669             properties => {
3670                 name => {
3671                     description => "Snapshot identifier. Value 'current' identifies the current VM.",
3672                     type => 'string',
3673                 },
3674                 vmstate => {
3675                     description => "Snapshot includes RAM.",
3676                     type => 'boolean',
3677                     optional => 1,
3678                 },
3679                 description => {
3680                     description => "Snapshot description.",
3681                     type => 'string',
3682                 },
3683                 snaptime => {
3684                     description => "Snapshot creation time",
3685                     type => 'integer',
3686                     renderer => 'timestamp',
3687                     optional => 1,
3688                 },
3689                 parent => {
3690                     description => "Parent snapshot identifier.",
3691                     type => 'string',
3692                     optional => 1,
3693                 },
3694             },
3695         },
3696         links => [ { rel => 'child', href => "{name}" } ],
3697     },
3698     code => sub {
3699         my ($param) = @_;
3700
3701         my $vmid = $param->{vmid};
3702
3703         my $conf = PVE::QemuConfig->load_config($vmid);
3704         my $snaphash = $conf->{snapshots} || {};
3705
3706         my $res = [];
3707
3708         foreach my $name (keys %$snaphash) {
3709             my $d = $snaphash->{$name};
3710             my $item = {
3711                 name => $name,
3712                 snaptime => $d->{snaptime} || 0,
3713                 vmstate => $d->{vmstate} ? 1 : 0,
3714                 description => $d->{description} || '',
3715             };
3716             $item->{parent} = $d->{parent} if $d->{parent};
3717             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3718             push @$res, $item;
3719         }
3720
3721         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3722         my $current = {
3723             name => 'current',
3724             digest => $conf->{digest},
3725             running => $running,
3726             description => "You are here!",
3727         };
3728         $current->{parent} = $conf->{parent} if $conf->{parent};
3729
3730         push @$res, $current;
3731
3732         return $res;
3733     }});
3734
3735 __PACKAGE__->register_method({
3736     name => 'snapshot',
3737     path => '{vmid}/snapshot',
3738     method => 'POST',
3739     protected => 1,
3740     proxyto => 'node',
3741     description => "Snapshot a VM.",
3742     permissions => {
3743         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3744     },
3745     parameters => {
3746         additionalProperties => 0,
3747         properties => {
3748             node => get_standard_option('pve-node'),
3749             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3750             snapname => get_standard_option('pve-snapshot-name'),
3751             vmstate => {
3752                 optional => 1,
3753                 type => 'boolean',
3754                 description => "Save the vmstate",
3755             },
3756             description => {
3757                 optional => 1,
3758                 type => 'string',
3759                 description => "A textual description or comment.",
3760             },
3761         },
3762     },
3763     returns => {
3764         type => 'string',
3765         description => "the task ID.",
3766     },
3767     code => sub {
3768         my ($param) = @_;
3769
3770         my $rpcenv = PVE::RPCEnvironment::get();
3771
3772         my $authuser = $rpcenv->get_user();
3773
3774         my $node = extract_param($param, 'node');
3775
3776         my $vmid = extract_param($param, 'vmid');
3777
3778         my $snapname = extract_param($param, 'snapname');
3779
3780         die "unable to use snapshot name 'current' (reserved name)\n"
3781             if $snapname eq 'current';
3782
3783         die "unable to use snapshot name 'pending' (reserved name)\n"
3784             if lc($snapname) eq 'pending';
3785
3786         my $realcmd = sub {
3787             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
3788             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
3789                                              $param->{description});
3790         };
3791
3792         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
3793     }});
3794
3795 __PACKAGE__->register_method({
3796     name => 'snapshot_cmd_idx',
3797     path => '{vmid}/snapshot/{snapname}',
3798     description => '',
3799     method => 'GET',
3800     permissions => {
3801         user => 'all',
3802     },
3803     parameters => {
3804         additionalProperties => 0,
3805         properties => {
3806             vmid => get_standard_option('pve-vmid'),
3807             node => get_standard_option('pve-node'),
3808             snapname => get_standard_option('pve-snapshot-name'),
3809         },
3810     },
3811     returns => {
3812         type => 'array',
3813         items => {
3814             type => "object",
3815             properties => {},
3816         },
3817         links => [ { rel => 'child', href => "{cmd}" } ],
3818     },
3819     code => sub {
3820         my ($param) = @_;
3821
3822         my $res = [];
3823
3824         push @$res, { cmd => 'rollback' };
3825         push @$res, { cmd => 'config' };
3826
3827         return $res;
3828     }});
3829
3830 __PACKAGE__->register_method({
3831     name => 'update_snapshot_config',
3832     path => '{vmid}/snapshot/{snapname}/config',
3833     method => 'PUT',
3834     protected => 1,
3835     proxyto => 'node',
3836     description => "Update snapshot metadata.",
3837     permissions => {
3838         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3839     },
3840     parameters => {
3841         additionalProperties => 0,
3842         properties => {
3843             node => get_standard_option('pve-node'),
3844             vmid => get_standard_option('pve-vmid'),
3845             snapname => get_standard_option('pve-snapshot-name'),
3846             description => {
3847                 optional => 1,
3848                 type => 'string',
3849                 description => "A textual description or comment.",
3850             },
3851         },
3852     },
3853     returns => { type => 'null' },
3854     code => sub {
3855         my ($param) = @_;
3856
3857         my $rpcenv = PVE::RPCEnvironment::get();
3858
3859         my $authuser = $rpcenv->get_user();
3860
3861         my $vmid = extract_param($param, 'vmid');
3862
3863         my $snapname = extract_param($param, 'snapname');
3864
3865         return undef if !defined($param->{description});
3866
3867         my $updatefn =  sub {
3868
3869             my $conf = PVE::QemuConfig->load_config($vmid);
3870
3871             PVE::QemuConfig->check_lock($conf);
3872
3873             my $snap = $conf->{snapshots}->{$snapname};
3874
3875             die "snapshot '$snapname' does not exist\n" if !defined($snap);
3876
3877             $snap->{description} = $param->{description} if defined($param->{description});
3878
3879              PVE::QemuConfig->write_config($vmid, $conf);
3880         };
3881
3882         PVE::QemuConfig->lock_config($vmid, $updatefn);
3883
3884         return undef;
3885     }});
3886
3887 __PACKAGE__->register_method({
3888     name => 'get_snapshot_config',
3889     path => '{vmid}/snapshot/{snapname}/config',
3890     method => 'GET',
3891     proxyto => 'node',
3892     description => "Get snapshot configuration",
3893     permissions => {
3894         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback', 'VM.Audit' ], any => 1],
3895     },
3896     parameters => {
3897         additionalProperties => 0,
3898         properties => {
3899             node => get_standard_option('pve-node'),
3900             vmid => get_standard_option('pve-vmid'),
3901             snapname => get_standard_option('pve-snapshot-name'),
3902         },
3903     },
3904     returns => { type => "object" },
3905     code => sub {
3906         my ($param) = @_;
3907
3908         my $rpcenv = PVE::RPCEnvironment::get();
3909
3910         my $authuser = $rpcenv->get_user();
3911
3912         my $vmid = extract_param($param, 'vmid');
3913
3914         my $snapname = extract_param($param, 'snapname');
3915
3916         my $conf = PVE::QemuConfig->load_config($vmid);
3917
3918         my $snap = $conf->{snapshots}->{$snapname};
3919
3920         die "snapshot '$snapname' does not exist\n" if !defined($snap);
3921
3922         return $snap;
3923     }});
3924
3925 __PACKAGE__->register_method({
3926     name => 'rollback',
3927     path => '{vmid}/snapshot/{snapname}/rollback',
3928     method => 'POST',
3929     protected => 1,
3930     proxyto => 'node',
3931     description => "Rollback VM state to specified snapshot.",
3932     permissions => {
3933         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3934     },
3935     parameters => {
3936         additionalProperties => 0,
3937         properties => {
3938             node => get_standard_option('pve-node'),
3939             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3940             snapname => get_standard_option('pve-snapshot-name'),
3941         },
3942     },
3943     returns => {
3944         type => 'string',
3945         description => "the task ID.",
3946     },
3947     code => sub {
3948         my ($param) = @_;
3949
3950         my $rpcenv = PVE::RPCEnvironment::get();
3951
3952         my $authuser = $rpcenv->get_user();
3953
3954         my $node = extract_param($param, 'node');
3955
3956         my $vmid = extract_param($param, 'vmid');
3957
3958         my $snapname = extract_param($param, 'snapname');
3959
3960         my $realcmd = sub {
3961             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
3962             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
3963         };
3964
3965         my $worker = sub {
3966             # hold migration lock, this makes sure that nobody create replication snapshots
3967             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3968         };
3969
3970         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
3971     }});
3972
3973 __PACKAGE__->register_method({
3974     name => 'delsnapshot',
3975     path => '{vmid}/snapshot/{snapname}',
3976     method => 'DELETE',
3977     protected => 1,
3978     proxyto => 'node',
3979     description => "Delete a VM snapshot.",
3980     permissions => {
3981         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3982     },
3983     parameters => {
3984         additionalProperties => 0,
3985         properties => {
3986             node => get_standard_option('pve-node'),
3987             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3988             snapname => get_standard_option('pve-snapshot-name'),
3989             force => {
3990                 optional => 1,
3991                 type => 'boolean',
3992                 description => "For removal from config file, even if removing disk snapshots fails.",
3993             },
3994         },
3995     },
3996     returns => {
3997         type => 'string',
3998         description => "the task ID.",
3999     },
4000     code => sub {
4001         my ($param) = @_;
4002
4003         my $rpcenv = PVE::RPCEnvironment::get();
4004
4005         my $authuser = $rpcenv->get_user();
4006
4007         my $node = extract_param($param, 'node');
4008
4009         my $vmid = extract_param($param, 'vmid');
4010
4011         my $snapname = extract_param($param, 'snapname');
4012
4013         my $realcmd = sub {
4014             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
4015             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
4016         };
4017
4018         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
4019     }});
4020
4021 __PACKAGE__->register_method({
4022     name => 'template',
4023     path => '{vmid}/template',
4024     method => 'POST',
4025     protected => 1,
4026     proxyto => 'node',
4027     description => "Create a Template.",
4028     permissions => {
4029         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
4030         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
4031     },
4032     parameters => {
4033         additionalProperties => 0,
4034         properties => {
4035             node => get_standard_option('pve-node'),
4036             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
4037             disk => {
4038                 optional => 1,
4039                 type => 'string',
4040                 description => "If you want to convert only 1 disk to base image.",
4041                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
4042             },
4043
4044         },
4045     },
4046     returns => { type => 'null'},
4047     code => sub {
4048         my ($param) = @_;
4049
4050         my $rpcenv = PVE::RPCEnvironment::get();
4051
4052         my $authuser = $rpcenv->get_user();
4053
4054         my $node = extract_param($param, 'node');
4055
4056         my $vmid = extract_param($param, 'vmid');
4057
4058         my $disk = extract_param($param, 'disk');
4059
4060         my $updatefn =  sub {
4061
4062             my $conf = PVE::QemuConfig->load_config($vmid);
4063
4064             PVE::QemuConfig->check_lock($conf);
4065
4066             die "unable to create template, because VM contains snapshots\n"
4067                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
4068
4069             die "you can't convert a template to a template\n"
4070                 if PVE::QemuConfig->is_template($conf) && !$disk;
4071
4072             die "you can't convert a VM to template if VM is running\n"
4073                 if PVE::QemuServer::check_running($vmid);
4074
4075             my $realcmd = sub {
4076                 PVE::QemuServer::template_create($vmid, $conf, $disk);
4077             };
4078
4079             $conf->{template} = 1;
4080             PVE::QemuConfig->write_config($vmid, $conf);
4081
4082             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
4083         };
4084
4085         PVE::QemuConfig->lock_config($vmid, $updatefn);
4086         return undef;
4087     }});
4088
4089 __PACKAGE__->register_method({
4090     name => 'cloudinit_generated_config_dump',
4091     path => '{vmid}/cloudinit/dump',
4092     method => 'GET',
4093     proxyto => 'node',
4094     description => "Get automatically generated cloudinit config.",
4095     permissions => {
4096         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
4097     },
4098     parameters => {
4099         additionalProperties => 0,
4100         properties => {
4101             node => get_standard_option('pve-node'),
4102             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4103             type => {
4104                 description => 'Config type.',
4105                 type => 'string',
4106                 enum => ['user', 'network', 'meta'],
4107             },
4108         },
4109     },
4110     returns => {
4111         type => 'string',
4112     },
4113     code => sub {
4114         my ($param) = @_;
4115
4116         my $conf = PVE::QemuConfig->load_config($param->{vmid});
4117
4118         return PVE::QemuServer::Cloudinit::dump_cloudinit_config($conf, $param->{vmid}, $param->{type});
4119     }});
4120
4121 1;