PVE/HA/Sim/Env.pm

   1 package PVE::HA::Sim::Env;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(strftime EINTR);
   6 use Data::Dumper;
   7 use JSON;
   8 use IO::File;
   9 use Fcntl qw(:DEFAULT :flock);
  10
  11 use PVE::HA::Tools;
  12 use PVE::HA::Env;
  13
  14 sub new {
  15     my ($this, $nodename, $hardware, $log_id) = @_;
  16
  17     die "missing nodename" if !$nodename;
  18     die "missing log_id" if !$log_id;
  19
  20     my $class = ref($this) || $this;
  21
  22     my $self = bless {}, $class;
  23
  24     $self->{statusdir} = $hardware->statusdir();
  25     $self->{nodename} = $nodename;
  26
  27     $self->{hardware} = $hardware;
  28     $self->{lock_timeout} = 120;
  29
  30     $self->{log_id} = $log_id;
  31
  32     return $self;
  33 }
  34
  35 sub nodename {
  36     my ($self) = @_;
  37
  38     return $self->{nodename};
  39 }
  40
  41 sub sim_get_lock {
  42     my ($self, $lock_name, $unlock) = @_;
  43
  44     return 0 if !$self->quorate();
  45
  46     my $filename = "$self->{statusdir}/cluster_locks";
  47
  48     my $code = sub {
  49
  50         my $data = PVE::HA::Tools::read_json_from_file($filename, {});
  51
  52         my $res;
  53
  54         my $nodename = $self->nodename();
  55         my $ctime = $self->get_time();
  56
  57         if ($unlock) {
  58
  59             if (my $d = $data->{$lock_name}) {
  60                 my $tdiff = $ctime - $d->{time};
  61
  62                 if ($tdiff > $self->{lock_timeout}) {
  63                     $res = 1;
  64                 } elsif (($tdiff <= $self->{lock_timeout}) && ($d->{node} eq $nodename)) {
  65                     delete $data->{$lock_name};
  66                     $res = 1;
  67                 } else {
  68                     $res = 0;
  69                 }
  70             }
  71
  72         } else {
  73
  74             if (my $d = $data->{$lock_name}) {
  75
  76                 my $tdiff = $ctime - $d->{time};
  77
  78                 if ($tdiff <= $self->{lock_timeout}) {
  79                     if ($d->{node} eq $nodename) {
  80                         $d->{time} = $ctime;
  81                         $res = 1;
  82                     } else {
  83                         $res = 0;
  84                     }
  85                 } else {
  86                     $self->log('info', "got lock '$lock_name'");
  87                     $d->{node} = $nodename;
  88                     $d->{time} = $ctime;
  89                     $res = 1;
  90                 }
  91
  92             } else {
  93                 $data->{$lock_name} = {
  94                     time => $ctime,
  95                     node => $nodename,
  96                 };
  97                 $self->log('info', "got lock '$lock_name'");
  98                 $res = 1;
  99             }
 100         }
 101
 102         PVE::HA::Tools::write_json_to_file($filename, $data);
 103
 104         return $res;
 105     };
 106
 107     return $self->{hardware}->global_lock($code);
 108 }
 109
 110 sub read_manager_status {
 111     my ($self) = @_;
 112
 113     my $filename = "$self->{statusdir}/manager_status";
 114
 115     return PVE::HA::Tools::read_json_from_file($filename, {});
 116 }
 117
 118 sub write_manager_status {
 119     my ($self, $status_obj) = @_;
 120
 121     my $filename = "$self->{statusdir}/manager_status";
 122
 123     PVE::HA::Tools::write_json_to_file($filename, $status_obj);
 124 }
 125
 126 sub manager_status_exists {
 127     my ($self) = @_;
 128
 129     my $filename = "$self->{statusdir}/manager_status";
 130
 131     return -f $filename ? 1 : 0;
 132 }
 133
 134 sub read_service_config {
 135     my ($self) = @_;
 136
 137     return $self->{hardware}->read_service_config();
 138 }
 139
 140 sub log {
 141     my ($self, $level, $msg) = @_;
 142
 143     chomp $msg;
 144
 145     my $time = $self->get_time();
 146
 147     printf("%-5s %5d %12s: $msg\n", $level, $time, "$self->{nodename}/$self->{log_id}");
 148 }
 149
 150 sub get_time {
 151     my ($self) = @_;
 152
 153     die "implement in subclass";
 154 }
 155
 156 sub sleep {
 157    my ($self, $delay) = @_;
 158
 159    die "implement in subclass";
 160 }
 161
 162 sub sleep_until {
 163    my ($self, $end_time) = @_;
 164
 165    die "implement in subclass";
 166 }
 167
 168 sub get_ha_manager_lock {
 169     my ($self) = @_;
 170
 171     return $self->sim_get_lock('ha_manager_lock');
 172 }
 173
 174 sub get_ha_agent_lock_name {
 175     my ($self, $node) = @_;
 176
 177     $node = $self->nodename() if !$node;
 178
 179     return "ha_agent_${node}_lock";
 180 }
 181
 182 sub get_ha_agent_lock {
 183     my ($self) = @_;
 184
 185     my $lck = $self->get_ha_agent_lock_name();
 186     return $self->sim_get_lock($lck);
 187 }
 188
 189 sub test_ha_agent_lock {
 190     my ($self, $node) = @_;
 191
 192     my $lck = $self->get_ha_agent_lock_name($node);
 193     my $res = $self->sim_get_lock($lck);
 194     $self->sim_get_lock($lck, 1) if $res; # unlock
 195     return $res;
 196 }
 197
 198 # return true when cluster is quorate
 199 sub quorate {
 200     my ($self) = @_;
 201
 202     my ($node_info, $quorate) = $self->{hardware}->get_node_info();
 203     my $node = $self->nodename();
 204     return 0 if !$node_info->{$node}->{online};
 205     return $quorate;
 206 }
 207
 208 sub get_node_info {
 209     my ($self) = @_;
 210
 211     return $self->{hardware}->get_node_info();
 212 }
 213
 214 sub loop_start_hook {
 215     my ($self, $starttime) = @_;
 216
 217     # do nothing, overwrite in subclass
 218 }
 219
 220 sub loop_end_hook {
 221     my ($self) = @_;
 222
 223     # do nothing, overwrite in subclass
 224 }
 225
 226 sub watchdog_open {
 227     my ($self) = @_;
 228
 229     my $node = $self->nodename();
 230
 231     return $self->{hardware}->watchdog_open($node);
 232 }
 233
 234 sub watchdog_update {
 235     my ($self, $wfh) = @_;
 236
 237     return $self->{hardware}->watchdog_update($wfh);
 238 }
 239
 240 sub watchdog_close {
 241     my ($self, $wfh) = @_;
 242
 243     return $self->{hardware}->watchdog_close($wfh);
 244 }
 245
 246 1;