PVE/HTTPServer.pm

   1 package PVE::HTTPServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::INotify;
   8 use PVE::Tools;
   9 use PVE::APIServer::AnyEvent;
  10
  11 use PVE::RPCEnvironment;
  12 use PVE::AccessControl;
  13 use PVE::Cluster;
  14
  15 use Data::Dumper;
  16
  17 use base('PVE::APIServer::AnyEvent');
  18
  19 use HTTP::Status qw(:constants);
  20
  21 sub new {
  22     my ($this, %args) = @_;
  23
  24     my $class = ref($this) || $this;
  25
  26     my $self = $class->SUPER::new(%args);
  27
  28     $self->{rpcenv} = PVE::RPCEnvironment->init(
  29         $self->{trusted_env} ? 'priv' : 'pub', atfork =>  sub { $self-> atfork_handler() });
  30
  31     return $self;
  32 }
  33
  34 sub verify_spice_connect_url {
  35     my ($self, $connect_str) = @_;
  36
  37     my $rpcenv = $self->{rpcenv};
  38
  39     $rpcenv->init_request();
  40
  41     my ($vmid, $node, $port) = PVE::AccessControl::verify_spice_connect_url($connect_str);
  42
  43     return ($vmid, $node, $port);
  44 }
  45
  46 sub generate_csrf_prevention_token {
  47     my ($username) = @_;
  48
  49     return PVE::AccessControl::assemble_csrf_prevention_token($username);
  50 }
  51
  52 sub auth_handler {
  53     my ($self, $method, $rel_uri, $ticket, $token, $peer_host) = @_;
  54
  55     my $rpcenv = $self->{rpcenv};
  56
  57     # set environment variables
  58     $rpcenv->set_user(undef);
  59     $rpcenv->set_language('C');
  60     $rpcenv->set_client_ip($peer_host);
  61
  62     $rpcenv->init_request();
  63
  64     my $require_auth = 1;
  65
  66     # explicitly allow some calls without auth
  67     if (($rel_uri eq '/access/domains' && $method eq 'GET') ||
  68         ($rel_uri eq '/access/ticket' && ($method eq 'GET' || $method eq 'POST'))) {
  69         $require_auth = 0;
  70     }
  71
  72     my ($username, $age);
  73
  74     my $isUpload = 0;
  75
  76     if ($require_auth) {
  77
  78         die "No ticket\n" if !$ticket;
  79
  80         ($username, $age) = PVE::AccessControl::verify_ticket($ticket);
  81
  82         $rpcenv->set_user($username);
  83
  84         if ($method eq 'POST' && $rel_uri =~ m|^/nodes/([^/]+)/storage/([^/]+)/upload$|) {
  85             my ($node, $storeid) = ($1, $2);
  86             # we disable CSRF checks if $isUpload is set,
  87             # to improve security we check user upload permission here
  88             my $perm = { check => ['perm', "/storage/$storeid", ['Datastore.AllocateTemplate']] };
  89             $rpcenv->check_api2_permissions($perm, $username, {});
  90             $isUpload = 1;
  91         }
  92
  93         # we skip CSRF check for file upload, because it is
  94         # difficult to pass CSRF HTTP headers with native html forms,
  95         # and it should not be necessary at all.
  96         my $euid = $>;
  97         PVE::AccessControl::verify_csrf_prevention_token($username, $token)
  98             if !$isUpload && ($euid != 0) && ($method ne 'GET');
  99     }
 100
 101     return {
 102         ticket => $ticket,
 103         token => $token,
 104         userid => $username,
 105         age => $age,
 106         isUpload => $isUpload,
 107         cookie_name => $self->{cookie_name},
 108     };
 109 }
 110
 111 my $exc_to_res = sub {
 112     my ($info, $err, $status) = @_;
 113
 114     $status = $status || HTTP_INTERNAL_SERVER_ERROR;
 115
 116     my $resp = { info => $info };
 117     if (ref($err) eq "PVE::Exception") {
 118         $resp->{status} = $err->{code} || $status;
 119         $resp->{errors} = $err->{errors} if $err->{errors};
 120         $resp->{message} = $err->{msg};
 121     } else {
 122         $resp->{status} = $status;
 123         $resp->{message} = $err;
 124     }
 125
 126     return $resp;
 127 };
 128
 129 sub rest_handler {
 130     my ($self, $clientip, $method, $rel_uri, $auth, $params) = @_;
 131
 132     my $rpcenv = $self->{rpcenv};
 133
 134     my $base_handler_class = $self->{base_handler_class};
 135
 136     die "no base handler - internal error" if !$base_handler_class;
 137
 138     my $uri_param = {};
 139     my ($handler, $info) = $base_handler_class->find_handler($method, $rel_uri, $uri_param);
 140     if (!$handler || !$info) {
 141         $rpcenv->set_user(undef); # clear after request
 142         return {
 143             status => HTTP_NOT_IMPLEMENTED,
 144             message => "Method '$method $rel_uri' not implemented",
 145         };
 146     }
 147
 148     foreach my $p (keys %{$params}) {
 149         if (defined($uri_param->{$p})) {
 150             $rpcenv->set_user(undef); # clear after request
 151             return {
 152                 status => HTTP_BAD_REQUEST,
 153                 message => "Parameter verification failed - duplicate parameter '$p'",
 154             };
 155         }
 156         $uri_param->{$p} = $params->{$p};
 157     }
 158
 159     # check access permissions
 160     eval { $rpcenv->check_api2_permissions($info->{permissions}, $auth->{userid}, $uri_param); };
 161     if (my $err = $@) {
 162         $rpcenv->set_user(undef); # clear after request
 163         return &$exc_to_res($info, $err, HTTP_FORBIDDEN);
 164     }
 165
 166     if ($info->{proxyto}) {
 167         my $remip;
 168         my $node;
 169         eval {
 170             my $pn = $info->{proxyto};
 171             $node = $uri_param->{$pn};
 172             die "proxy parameter '$pn' does not exists" if !$node;
 173
 174             if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
 175                 die "unable to proxy file uploads" if $auth->{isUpload};
 176                 $remip = $self->remote_node_ip($node);
 177             }
 178         };
 179         if (my $err = $@) {
 180             $rpcenv->set_user(undef); # clear after request
 181             return &$exc_to_res($info, $err);
 182         }
 183         if ($remip) {
 184             $rpcenv->set_user(undef); # clear after request
 185             return { proxy => $remip, proxynode => $node, proxy_params => $params };
 186         }
 187     }
 188
 189     my $euid = $>;
 190     if ($info->{protected} && ($euid != 0)) {
 191         $rpcenv->set_user(undef); # clear after request
 192         return { proxy => 'localhost' , proxy_params => $params }
 193     }
 194
 195     my $resp = {
 196         info => $info, # useful to format output
 197         status => HTTP_OK,
 198     };
 199
 200     eval {
 201         $resp->{data} = $handler->handle($info, $uri_param);
 202
 203         if (my $count = $rpcenv->get_result_attrib('total')) {
 204             $resp->{total} = $count;
 205         }
 206         if (my $diff = $rpcenv->get_result_attrib('changes')) {
 207             $resp->{changes} = $diff;
 208         }
 209     };
 210     if (my $err = $@) {
 211         $rpcenv->set_user(undef); # clear after request
 212         return &$exc_to_res($info, $err);
 213     }
 214
 215     $rpcenv->set_user(undef); # clear after request
 216     return $resp;
 217 }
 218
 219 sub check_cert_fingerprint {
 220     my ($self, $cert) = @_;
 221
 222     return PVE::Cluster::check_cert_fingerprint($cert);
 223 }
 224
 225 sub initialize_cert_cache {
 226     my ($self, $node) = @_;
 227
 228     PVE::Cluster::initialize_cert_cache($node);
 229 }
 230
 231 sub remote_node_ip {
 232     my ($self, $node) = @_;
 233
 234     my $remip = PVE::Cluster::remote_node_ip($node);
 235
 236     die "unable to get remote IP address for node '$node'\n" if !$remip;
 237
 238     return $remip;
 239 }
 240
 241 1;