PVE/Network/SDN/Ipams/PVEPlugin.pm

   1 package PVE::Network::SDN::Ipams::PVEPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::INotify;
   6 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_register_file cfs_lock_file);
   7 use PVE::Tools;
   8 use JSON;
   9 use NetAddr::IP;
  10 use Net::IP;
  11 use Digest::SHA;
  12
  13 use base('PVE::Network::SDN::Ipams::Plugin');
  14
  15
  16 my $ipamdb_file = "priv/ipam.db";
  17
  18 PVE::Cluster::cfs_register_file($ipamdb_file,
  19                                  sub { PVE::Network::SDN::Ipams::PVEPlugin->parse_config(@_); },
  20                                  sub { PVE::Network::SDN::Ipams::PVEPlugin->write_config(@_); });
  21
  22 sub type {
  23     return 'pve';
  24 }
  25
  26 sub properties {
  27 }
  28
  29 sub options {
  30 }
  31
  32 # Plugin implementation
  33
  34 sub add_subnet {
  35     my ($class, $plugin_config, $subnetid, $subnet) = @_;
  36
  37     my $cidr = $subnet->{cidr};
  38     my $zone = $subnet->{zone};
  39     my $gateway = $subnet->{gateway};
  40
  41
  42     cfs_lock_file($ipamdb_file, undef, sub {
  43         my $db = {};
  44         $db = read_db();
  45
  46         $db->{zones}->{$zone} = {} if !$db->{zones}->{$zone};
  47         my $zonedb = $db->{zones}->{$zone};
  48
  49         if(!$zonedb->{subnets}->{$cidr}) {
  50             #create subnet
  51             $zonedb->{subnets}->{$cidr}->{ips} = {};
  52             write_db($db);
  53         }
  54     });
  55     die "$@" if $@;
  56 }
  57
  58 sub del_subnet {
  59     my ($class, $plugin_config, $subnetid, $subnet) = @_;
  60
  61     my $cidr = $subnet->{cidr};
  62     my $zone = $subnet->{zone};
  63
  64     cfs_lock_file($ipamdb_file, undef, sub {
  65
  66         my $db = read_db();
  67
  68         my $dbzone = $db->{zones}->{$zone};
  69         die "zone '$zone' doesn't exist in IPAM DB\n" if !$dbzone;
  70         my $dbsubnet = $dbzone->{subnets}->{$cidr};
  71         die "subnet '$cidr' doesn't exist in IPAM DB\n" if !$dbsubnet;
  72
  73         die "cannot delete subnet '$cidr', not empty\n" if keys %{$dbsubnet->{ips}} > 0;
  74
  75         delete $dbzone->{subnets}->{$cidr};
  76
  77         write_db($db);
  78     });
  79     die "$@" if $@;
  80
  81 }
  82
  83 sub add_ip {
  84     my ($class, $plugin_config, $subnetid, $subnet, $ip, $is_gateway) = @_;
  85
  86     my $cidr = $subnet->{cidr};
  87     my $zone = $subnet->{zone};
  88
  89     cfs_lock_file($ipamdb_file, undef, sub {
  90
  91         my $db = read_db();
  92
  93         my $dbzone = $db->{zones}->{$zone};
  94         die "zone '$zone' doesn't exist in IPAM DB\n" if !$dbzone;
  95         my $dbsubnet = $dbzone->{subnets}->{$cidr};
  96         die "subnet '$cidr' doesn't exist in IPAM DB\n" if !$dbsubnet;
  97
  98         die "IP '$ip' already exist\n" if defined($dbsubnet->{ips}->{$ip});
  99
 100         $dbsubnet->{ips}->{$ip} = 1;
 101
 102         write_db($db);
 103     });
 104     die "$@" if $@;
 105 }
 106
 107 sub add_next_freeip {
 108     my ($class, $plugin_config, $subnetid, $subnet) = @_;
 109
 110     my $cidr = $subnet->{cidr};
 111     my $network = $subnet->{network};
 112     my $zone = $subnet->{zone};
 113     my $mask = $subnet->{mask};
 114     my $freeip = undef;
 115
 116     cfs_lock_file($ipamdb_file, undef, sub {
 117
 118         my $db = read_db();
 119         my $dbzone = $db->{zones}->{$zone};
 120         die "zone '$zone' doesn't exist in IPAM DB\n" if !$dbzone;
 121         my $dbsubnet = $dbzone->{subnets}->{$cidr};
 122         die "subnet '$cidr' doesn't exist in IPAM DB" if !$dbsubnet;
 123
 124         if (Net::IP::ip_is_ipv4($network) && $mask == 32) {
 125             die "cannot find free IP in subnet '$cidr'\n" if defined($dbsubnet->{ips}->{$network});
 126             $freeip = $network;
 127         } else {
 128             my $iplist = new NetAddr::IP($cidr);
 129             my $broadcast = $iplist->broadcast();
 130
 131             while(1) {
 132                 $iplist++;
 133                 last if $iplist eq $broadcast;
 134                 my $ip = $iplist->addr();
 135                 next if defined($dbsubnet->{ips}->{$ip});
 136                 $freeip = $ip;
 137                 last;
 138             }
 139         }
 140
 141         die "can't find free ip in subnet '$cidr'\n" if !$freeip;
 142
 143         $dbsubnet->{ips}->{$freeip} = 1;
 144         write_db($db);
 145     });
 146     die "$@" if $@;
 147
 148     return "$freeip/$mask";
 149 }
 150
 151 sub del_ip {
 152     my ($class, $plugin_config, $subnetid, $subnet, $ip) = @_;
 153
 154     my $cidr = $subnet->{cidr};
 155     my $zone = $subnet->{zone};
 156
 157     cfs_lock_file($ipamdb_file, undef, sub {
 158
 159         my $db = read_db();
 160         die "zone $zone don't exist in ipam db" if !$db->{zones}->{$zone};
 161         my $dbzone = $db->{zones}->{$zone};
 162         die "subnet $cidr don't exist in ipam db" if !$dbzone->{subnets}->{$cidr};
 163         my $dbsubnet = $dbzone->{subnets}->{$cidr};
 164
 165         die "IP '$ip' does not exist in IPAM DB\n" if !defined($dbsubnet->{ips}->{$ip});
 166         delete $dbsubnet->{ips}->{$ip};
 167
 168         write_db($db);
 169     });
 170     die "$@" if $@;
 171 }
 172
 173 #helpers
 174
 175 sub read_db {
 176     my $db = cfs_read_file($ipamdb_file);
 177     return $db;
 178 }
 179
 180 sub write_db {
 181     my ($cfg) = @_;
 182
 183     my $json = to_json($cfg);
 184     cfs_write_file($ipamdb_file, $json);
 185 }
 186
 187 sub write_config {
 188     my ($class, $filename, $cfg) = @_;
 189
 190     return $cfg;
 191 }
 192
 193 sub parse_config {
 194     my ($class, $filename, $raw) = @_;
 195
 196     $raw = '{}' if !defined($raw) ||$raw eq '';
 197     my $cfg = from_json($raw);
 198
 199     return $cfg;
 200 }
 201
 202 1;