PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $ssh_forward_info) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$ssh_forward_info) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @$unix_sockets];
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     my $repl_conf = PVE::ReplicationConfig->new();
 224     $self->{replication_jobcfg} = $repl_conf->find_local_replication_job($vmid, $self->{node});
 225     $self->{is_replicated} = $repl_conf->check_for_existing_jobs($vmid, 1);
 226
 227     if ($self->{replication_jobcfg} && defined($self->{replication_jobcfg}->{remove_job})) {
 228         die "refusing to migrate replicated VM whose replication job is marked for removal\n";
 229     }
 230
 231     PVE::QemuConfig->check_lock($conf);
 232
 233     my $running = 0;
 234     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 235         die "can't migrate running VM without --online\n" if !$online;
 236         $running = $pid;
 237
 238         if ($self->{is_replicated} && !$self->{replication_jobcfg}) {
 239             if ($self->{opts}->{force}) {
 240                 $self->log('warn', "WARNING: Node '$self->{node}' is not a replication target. Existing " .
 241                                    "replication jobs will fail after migration!\n");
 242             } else {
 243                 die "Cannot live-migrate replicated VM to node '$self->{node}' - not a replication " .
 244                     "target. Use 'force' to override.\n";
 245             }
 246         }
 247
 248         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 249
 250         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 251         # Since the parameter itself contains no reference to a custom model,
 252         # this makes migration independent of changes to "cpu-models.conf".
 253         if ($conf->{cpu}) {
 254             my $cpuconf = PVE::JSONSchema::parse_property_string('pve-cpu-conf', $conf->{cpu});
 255             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 256                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 257             }
 258         }
 259     }
 260
 261     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 262     if (scalar @$loc_res) {
 263         if ($self->{running} || !$self->{opts}->{force}) {
 264             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 265         } else {
 266             $self->log('info', "migrating VM which uses local devices");
 267         }
 268     }
 269
 270     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 271
 272     my $need_activate = [];
 273     foreach my $volid (@$vollist) {
 274         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 275
 276         # check if storage is available on both nodes
 277         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 278
 279         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 280         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 281
 282         if ($scfg->{shared}) {
 283             # PVE::Storage::activate_storage checks this for non-shared storages
 284             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 285             warn "Used shared storage '$sid' is not online on source node!\n"
 286                 if !$plugin->check_connection($sid, $scfg);
 287         } else {
 288             # only activate if not shared
 289             next if ($volid =~ m/vm-\d+-cloudinit/);
 290             push @$need_activate, $volid;
 291         }
 292     }
 293
 294     # activate volumes
 295     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 296
 297     # test ssh connection
 298     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 299     eval { $self->cmd_quiet($cmd); };
 300     die "Can't connect to destination address using public key\n" if $@;
 301
 302     return $running;
 303 }
 304
 305 sub sync_disks {
 306     my ($self, $vmid) = @_;
 307
 308     my $conf = $self->{vmconf};
 309
 310     # local volumes which have been copied
 311     # and their old_id => new_id pairs
 312     $self->{volumes} = [];
 313     $self->{volume_map} = {};
 314
 315     my $storecfg = $self->{storecfg};
 316     eval {
 317
 318         # found local volumes and their origin
 319         my $local_volumes = {};
 320         my $local_volumes_errors = {};
 321         my $other_errors = [];
 322         my $abort = 0;
 323
 324         my $log_error = sub {
 325             my ($msg, $volid) = @_;
 326
 327             if (defined($volid)) {
 328                 $local_volumes_errors->{$volid} = $msg;
 329             } else {
 330                 push @$other_errors, $msg;
 331             }
 332             $abort = 1;
 333         };
 334
 335         my @sids = PVE::Storage::storage_ids($storecfg);
 336         foreach my $storeid (@sids) {
 337             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 338             next if $scfg->{shared};
 339             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 340
 341             # get list from PVE::Storage (for unused volumes)
 342             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 343
 344             next if @{$dl->{$storeid}} == 0;
 345
 346             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 347             # check if storage is available on target node
 348             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 349
 350             # grandfather in existing mismatches
 351             if ($targetsid ne $storeid) {
 352                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 353                 die "content type 'images' is not available on storage '$targetsid'\n"
 354                     if !$target_scfg->{content}->{images};
 355             }
 356
 357             PVE::Storage::foreach_volid($dl, sub {
 358                 my ($volid, $sid, $volinfo) = @_;
 359
 360                 $local_volumes->{$volid}->{ref} = 'storage';
 361
 362                 # If with_snapshots is not set for storage migrate, it tries to use
 363                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 364                 # back to qcow2 is currently not possible.
 365                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 366                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 367             });
 368         }
 369
 370         my $replicatable_volumes = !$self->{replication_jobcfg} ? {}
 371             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 372
 373         my $test_volid = sub {
 374             my ($volid, $attr) = @_;
 375
 376             if ($volid =~ m|^/|) {
 377                 return if $attr->{shared};
 378                 $local_volumes->{$volid}->{ref} = 'config';
 379                 die "local file/device\n";
 380             }
 381
 382             my $snaprefs = $attr->{referenced_in_snapshot};
 383
 384             if ($attr->{cdrom}) {
 385                 if ($volid eq 'cdrom') {
 386                     my $msg = "can't migrate local cdrom drive";
 387                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 388                         my $snapnames = join(', ', sort keys %$snaprefs);
 389                         $msg .= " (referenced in snapshot - $snapnames)";
 390                     }
 391                     &$log_error("$msg\n");
 392                     return;
 393                 }
 394                 return if $volid eq 'none';
 395             }
 396
 397             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 398
 399             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 400             # check if storage is available on both nodes
 401             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 402             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 403
 404             return if $scfg->{shared};
 405
 406             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 407             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 408
 409             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 410
 411             if ($attr->{cdrom}) {
 412                 if ($volid =~ /vm-\d+-cloudinit/) {
 413                     $local_volumes->{$volid}->{ref} = 'generated';
 414                     return;
 415                 }
 416                 die "local cdrom image\n";
 417             }
 418
 419             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 420
 421             die "owned by other VM (owner = VM $owner)\n"
 422                 if !$owner || ($owner != $vmid);
 423
 424             return if $attr->{is_vmstate};
 425
 426             if (defined($snaprefs)) {
 427                 $local_volumes->{$volid}->{snapshots} = 1;
 428
 429                 # we cannot migrate shapshots on local storage
 430                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 431
 432                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 433                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 434                     die "non-migratable snapshot exists\n";
 435                 }
 436             }
 437
 438             die "referenced by linked clone(s)\n"
 439                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 440         };
 441
 442         PVE::QemuServer::foreach_volid($conf, sub {
 443             my ($volid, $attr) = @_;
 444             eval { $test_volid->($volid, $attr); };
 445             if (my $err = $@) {
 446                 &$log_error($err, $volid);
 447             }
 448         });
 449
 450         foreach my $vol (sort keys %$local_volumes) {
 451             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 452             my $ref = $local_volumes->{$vol}->{ref};
 453             if ($ref eq 'storage') {
 454                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 455             } elsif ($ref eq 'config') {
 456                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 457                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 458                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 459             } elsif ($ref eq 'snapshot') {
 460                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 461             } elsif ($ref eq 'generated') {
 462                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 463             } else {
 464                 $self->log('info', "found $type disk '$vol'\n");
 465             }
 466         }
 467
 468         foreach my $vol (sort keys %$local_volumes_errors) {
 469             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 470         }
 471         foreach my $err (@$other_errors) {
 472             $self->log('warn', "$err");
 473         }
 474
 475         if ($abort) {
 476             die "can't migrate VM - check log\n";
 477         }
 478
 479         # additional checks for local storage
 480         foreach my $volid (keys %$local_volumes) {
 481             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 482             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 483
 484             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 485
 486             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 487                 if !$migratable;
 488
 489             # image is a linked clone on local storage, se we can't migrate.
 490             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 491                 die "can't migrate '$volid' as it's a clone of '$basename'";
 492             }
 493         }
 494
 495         if ($self->{replication_jobcfg}) {
 496             if ($self->{running}) {
 497
 498                 my $version = PVE::QemuServer::kvm_user_version();
 499                 if (!min_version($version, 4, 2)) {
 500                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 501                 }
 502
 503                 my $live_replicatable_volumes = {};
 504                 PVE::QemuConfig->foreach_volume($conf, sub {
 505                     my ($ds, $drive) = @_;
 506
 507                     my $volid = $drive->{file};
 508                     $live_replicatable_volumes->{$ds} = $volid
 509                         if defined($replicatable_volumes->{$volid});
 510                 });
 511                 foreach my $drive (keys %$live_replicatable_volumes) {
 512                     my $volid = $live_replicatable_volumes->{$drive};
 513
 514                     my $bitmap = "repl_$drive";
 515
 516                     # start tracking before replication to get full delta + a few duplicates
 517                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 518                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 519
 520                     # other info comes from target node in phase 2
 521                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 522                 }
 523             }
 524             $self->log('info', "replicating disk images");
 525
 526             my $start_time = time();
 527             my $logfunc = sub { $self->log('info', shift) };
 528             $self->{replicated_volumes} = PVE::Replication::run_replication(
 529                'PVE::QemuConfig', $self->{replication_jobcfg}, $start_time, $start_time, $logfunc);
 530         }
 531
 532         # sizes in config have to be accurate for remote node to correctly
 533         # allocate disks, rescan to be sure
 534         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 535         PVE::QemuConfig->foreach_volume($conf, sub {
 536             my ($key, $drive) = @_;
 537             return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 538
 539             my $volid = $drive->{file};
 540             return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 541             return if !defined($volid_hash->{$volid});
 542
 543             my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash->{$volid}->{size});
 544             if (defined($updated)) {
 545                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 546                 $self->log('info', "drive '$key': $msg");
 547             }
 548         });
 549
 550         # we want to set the efidisk size in the config to the size of the
 551         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 552         if (defined($conf->{efidisk0})) {
 553             PVE::QemuServer::update_efidisk_size($conf);
 554         }
 555
 556         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 557
 558         foreach my $volid (keys %$local_volumes) {
 559             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 560             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 561             my $ref = $local_volumes->{$volid}->{ref};
 562             if ($self->{running} && $ref eq 'config') {
 563                 push @{$self->{online_local_volumes}}, $volid;
 564             } elsif ($ref eq 'generated') {
 565                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 566                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 567                 push @{$self->{volumes}}, $volid;
 568                 next;
 569             } else {
 570                 next if $self->{replicated_volumes}->{$volid};
 571                 push @{$self->{volumes}}, $volid;
 572                 my $opts = $self->{opts};
 573                 # use 'migrate' limit for transfer to other node
 574                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 575                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 576                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 577
 578                 my $storage_migrate_opts = {
 579                     'ratelimit_bps' => $bwlimit,
 580                     'insecure' => $opts->{migration_type} eq 'insecure',
 581                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 582                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 583                 };
 584
 585                 my $logfunc = sub { $self->log('info', $_[0]); };
 586                 my $new_volid = eval {
 587                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 588                                                   $targetsid, $storage_migrate_opts, $logfunc);
 589                 };
 590                 if (my $err = $@) {
 591                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 592                 }
 593
 594                 $self->{volume_map}->{$volid} = $new_volid;
 595                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 596             }
 597         }
 598     };
 599     die "Failed to sync data - $@" if $@;
 600 }
 601
 602 sub cleanup_remotedisks {
 603     my ($self) = @_;
 604
 605     foreach my $target_drive (keys %{$self->{target_drive}}) {
 606         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 607         next if !defined($drivestr);
 608
 609         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 610
 611         # don't clean up replicated disks!
 612         next if defined($self->{replicated_volumes}->{$drive->{file}});
 613
 614         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 615
 616         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 617
 618         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 619         if (my $err = $@) {
 620             $self->log('err', $err);
 621             $self->{errors} = 1;
 622         }
 623     }
 624 }
 625
 626 sub cleanup_bitmaps {
 627     my ($self) = @_;
 628     foreach my $drive (keys %{$self->{target_drive}}) {
 629         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 630         next if !$bitmap;
 631         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 632         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 633     }
 634 }
 635
 636 sub phase1 {
 637     my ($self, $vmid) = @_;
 638
 639     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 640
 641     my $conf = $self->{vmconf};
 642
 643     # set migrate lock in config file
 644     $conf->{lock} = 'migrate';
 645     PVE::QemuConfig->write_config($vmid, $conf);
 646
 647     sync_disks($self, $vmid);
 648
 649     # sync_disks fixes disk sizes to match their actual size, write changes so
 650     # target allocates correct volumes
 651     PVE::QemuConfig->write_config($vmid, $conf);
 652 };
 653
 654 sub phase1_cleanup {
 655     my ($self, $vmid, $err) = @_;
 656
 657     $self->log('info', "aborting phase 1 - cleanup resources");
 658
 659     my $conf = $self->{vmconf};
 660     delete $conf->{lock};
 661     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 662     if (my $err = $@) {
 663         $self->log('err', $err);
 664     }
 665
 666     if ($self->{volumes}) {
 667         foreach my $volid (@{$self->{volumes}}) {
 668             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 669             # fixme: try to remove ?
 670         }
 671     }
 672
 673     eval { $self->cleanup_bitmaps() };
 674     if (my $err =$@) {
 675         $self->log('err', $err);
 676     }
 677
 678 }
 679
 680 sub phase2 {
 681     my ($self, $vmid) = @_;
 682
 683     my $conf = $self->{vmconf};
 684
 685     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 686
 687     my $raddr;
 688     my $rport;
 689     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 690     my $nodename = PVE::INotify::nodename();
 691
 692     ## start on remote node
 693     my $cmd = [@{$self->{rem_ssh}}];
 694
 695     my $spice_ticket;
 696     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 697         my $res = mon_cmd($vmid, 'query-spice');
 698         $spice_ticket = $res->{ticket};
 699     }
 700
 701     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 702
 703     my $migration_type = $self->{opts}->{migration_type};
 704
 705     push @$cmd, '--migration_type', $migration_type;
 706
 707     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 708       if $self->{opts}->{migration_network};
 709
 710     if ($migration_type eq 'insecure') {
 711         push @$cmd, '--stateuri', 'tcp';
 712     } else {
 713         push @$cmd, '--stateuri', 'unix';
 714     }
 715
 716     if ($self->{forcemachine}) {
 717         push @$cmd, '--machine', $self->{forcemachine};
 718     }
 719
 720     if ($self->{forcecpu}) {
 721         push @$cmd, '--force-cpu', $self->{forcecpu};
 722     }
 723
 724     if ($self->{online_local_volumes}) {
 725         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 726     }
 727
 728     my $spice_port;
 729     my $unix_socket_info = {};
 730     # version > 0 for unix socket support
 731     my $nbd_protocol_version = 1;
 732     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 733     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 734     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 735
 736     my $number_of_online_replicated_volumes = 0;
 737
 738     # prevent auto-vivification
 739     if ($self->{online_local_volumes}) {
 740         foreach my $volid (@{$self->{online_local_volumes}}) {
 741             next if !$self->{replicated_volumes}->{$volid};
 742             $number_of_online_replicated_volumes++;
 743             $input .= "replicated_volume: $volid\n";
 744         }
 745     }
 746
 747     my $target_replicated_volumes = {};
 748
 749     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 750     # instead we pipe it through STDIN
 751     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 752         my $line = shift;
 753
 754         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 755             $raddr = $1;
 756             $rport = int($2);
 757             $ruri = "tcp:$raddr:$rport";
 758         }
 759         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 760             $raddr = $1;
 761             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 762             $ruri = "unix:$raddr";
 763         }
 764         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 765             $raddr = "localhost";
 766             $rport = int($1);
 767             $ruri = "tcp:$raddr:$rport";
 768         }
 769         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 770             $spice_port = int($1);
 771         }
 772         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 773             my $drivestr = $4;
 774             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 775             my $targetdrive = $3;
 776             $targetdrive =~ s/drive-//g;
 777
 778             $self->{stopnbd} = 1;
 779             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 780             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 781         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 782             my $drivestr = $4;
 783             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 784             my $nbd_unix_addr = $1;
 785             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 786             my $targetdrive = $3;
 787             $targetdrive =~ s/drive-//g;
 788
 789             $self->{stopnbd} = 1;
 790             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 791             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 792             $unix_socket_info->{$nbd_unix_addr} = 1;
 793         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 794             my $drive = $1;
 795             my $volid = $2;
 796             $target_replicated_volumes->{$volid} = $drive;
 797         } elsif ($line =~ m/^QEMU: (.*)$/) {
 798             $self->log('info', "[$self->{node}] $1\n");
 799         }
 800     }, errfunc => sub {
 801         my $line = shift;
 802         $self->log('info', "[$self->{node}] $line");
 803     }, noerr => 1);
 804
 805     die "remote command failed with exit code $exitcode\n" if $exitcode;
 806
 807     die "unable to detect remote migration address\n" if !$raddr;
 808
 809     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 810         die "number of replicated disks on source and target node do not match - target node too old?\n"
 811     }
 812
 813     $self->log('info', "start remote tunnel");
 814
 815     if ($migration_type eq 'secure') {
 816
 817         if ($ruri =~ /^unix:/) {
 818             my $ssh_forward_info = ["$raddr:$raddr"];
 819             $unix_socket_info->{$raddr} = 1;
 820
 821             my $unix_sockets = [ keys %$unix_socket_info ];
 822             for my $sock (@$unix_sockets) {
 823                 push @$ssh_forward_info, "$sock:$sock";
 824                 unlink $sock;
 825             }
 826
 827             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 828
 829             my $unix_socket_try = 0; # wait for the socket to become ready
 830             while ($unix_socket_try <= 100) {
 831                 $unix_socket_try++;
 832                 my $available = 0;
 833                 foreach my $sock (@$unix_sockets) {
 834                     if (-S $sock) {
 835                         $available++;
 836                     }
 837                 }
 838
 839                 if ($available == @$unix_sockets) {
 840                     last;
 841                 }
 842
 843                 usleep(50000);
 844             }
 845             if ($unix_socket_try > 100) {
 846                 $self->{errors} = 1;
 847                 $self->finish_tunnel($self->{tunnel});
 848                 die "Timeout, migration socket $ruri did not get ready";
 849             }
 850             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 851
 852         } elsif ($ruri =~ /^tcp:/) {
 853             my $ssh_forward_info = [];
 854             if ($raddr eq "localhost") {
 855                 # for backwards compatibility with older qemu-server versions
 856                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 857                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 858                 push @$ssh_forward_info, "$lport:localhost:$rport";
 859             }
 860
 861             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 862
 863         } else {
 864             die "unsupported protocol in migration URI: $ruri\n";
 865         }
 866     } else {
 867         #fork tunnel for insecure migration, to send faster commands like resume
 868         $self->{tunnel} = $self->fork_tunnel();
 869     }
 870     my $start = time();
 871
 872     my $opt_bwlimit = $self->{opts}->{bwlimit};
 873
 874     if (defined($self->{online_local_volumes})) {
 875         $self->{storage_migration} = 1;
 876         $self->{storage_migration_jobs} = {};
 877         $self->log('info', "starting storage migration");
 878
 879         die "The number of local disks does not match between the source and the destination.\n"
 880             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 881         foreach my $drive (keys %{$self->{target_drive}}){
 882             my $target = $self->{target_drive}->{$drive};
 883             my $nbd_uri = $target->{nbd_uri};
 884
 885             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 886             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 887
 888             my $source_volid = $source_drive->{file};
 889             my $target_volid = $target_drive->{file};
 890
 891             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 892             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 893
 894             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 895             my $bitmap = $target->{bitmap};
 896
 897             $self->log('info', "$drive: start migration to $nbd_uri");
 898             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 899
 900             $self->{volume_map}->{$source_volid} = $target_volid;
 901             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 902         }
 903     }
 904
 905     $self->log('info', "starting online/live migration on $ruri");
 906     $self->{livemigration} = 1;
 907
 908     # load_defaults
 909     my $defaults = PVE::QemuServer::load_defaults();
 910
 911     $self->log('info', "set migration_caps");
 912     eval {
 913         PVE::QemuServer::set_migration_caps($vmid);
 914     };
 915     warn $@ if $@;
 916
 917     my $qemu_migrate_params = {};
 918
 919     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 920     # migrate_speed parameter in qm.conf - take the lower of the two.
 921     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 922     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 923     # migrate_speed is in MB/s, bwlimit in KB/s
 924     $migrate_speed *= 1024;
 925
 926     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 927
 928     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 929     # default of 8192m which is basically unlimited
 930     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 931
 932     # qmp takes migrate_speed in B/s.
 933     $migrate_speed *= 1024;
 934     $self->log('info', "migration speed limit: $migrate_speed B/s");
 935     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 936
 937     my $migrate_downtime = $defaults->{migrate_downtime};
 938     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 939     # migrate-set-parameters expects limit in ms
 940     $migrate_downtime *= 1000;
 941     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 942     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 943
 944     # set cachesize to 10% of the total memory
 945     my $memory =  $conf->{memory} || $defaults->{memory};
 946     my $cachesize = int($memory * 1048576 / 10);
 947     $cachesize = round_powerof2($cachesize);
 948
 949     $self->log('info', "migration cachesize: $cachesize B");
 950     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 951
 952     $self->log('info', "set migration parameters");
 953     eval {
 954         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 955     };
 956     $self->log('info', "migrate-set-parameters error: $@") if $@;
 957
 958     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 959         my $rpcenv = PVE::RPCEnvironment::get();
 960         my $authuser = $rpcenv->get_user();
 961
 962         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 963
 964         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 965         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 966
 967         $self->log('info', "spice client_migrate_info");
 968
 969         eval {
 970             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 971                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 972                                                 'cert-subject' => $subject);
 973         };
 974         $self->log('info', "client_migrate_info error: $@") if $@;
 975
 976     }
 977
 978     $self->log('info', "start migrate command to $ruri");
 979     eval {
 980         mon_cmd($vmid, "migrate", uri => $ruri);
 981     };
 982     my $merr = $@;
 983     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 984
 985     my $lstat = 0;
 986     my $usleep = 1000000;
 987     my $i = 0;
 988     my $err_count = 0;
 989     my $lastrem = undef;
 990     my $downtimecounter = 0;
 991     while (1) {
 992         $i++;
 993         my $avglstat = $lstat ? $lstat / $i : 0;
 994
 995         usleep($usleep);
 996         my $stat;
 997         eval {
 998             $stat = mon_cmd($vmid, "query-migrate");
 999         };
1000         if (my $err = $@) {
1001             $err_count++;
1002             warn "query migrate failed: $err\n";
1003             $self->log('info', "query migrate failed: $err");
1004             if ($err_count <= 5) {
1005                 usleep(1000000);
1006                 next;
1007             }
1008             die "too many query migrate failures - aborting\n";
1009         }
1010
1011         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
1012             sleep(1);
1013             next;
1014         }
1015
1016         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
1017             $merr = undef;
1018             $err_count = 0;
1019             if ($stat->{status} eq 'completed') {
1020                 my $delay = time() - $start;
1021                 if ($delay > 0) {
1022                     my $mbps = sprintf "%.2f", $memory / $delay;
1023                     my $downtime = $stat->{downtime} || 0;
1024                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
1025                 }
1026             }
1027
1028             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1029                 $self->log('info', "migration status error: $stat->{status}");
1030                 die "aborting\n"
1031             }
1032
1033             if ($stat->{status} ne 'active') {
1034                 $self->log('info', "migration status: $stat->{status}");
1035                 last;
1036             }
1037
1038             if ($stat->{ram}->{transferred} ne $lstat) {
1039                 my $trans = $stat->{ram}->{transferred} || 0;
1040                 my $rem = $stat->{ram}->{remaining} || 0;
1041                 my $total = $stat->{ram}->{total} || 0;
1042                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1043                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1044                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1045                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1046                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1047                 # reduce sleep if remainig memory is lower than the average transfer speed
1048                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1049
1050                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1051                            "remaining ${rem}), total ${total})");
1052
1053                 if (${xbzrlecachesize}) {
1054                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1055                 }
1056
1057                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1058                     $downtimecounter++;
1059                 }
1060                 $lastrem = $rem;
1061
1062                 if ($downtimecounter > 5) {
1063                     $downtimecounter = 0;
1064                     $migrate_downtime *= 2;
1065                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1066                     eval {
1067                         # migrate-set-parameters does not touch values not
1068                         # specified, so this only changes downtime-limit
1069                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1070                     };
1071                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1072                 }
1073
1074             }
1075
1076
1077             $lstat = $stat->{ram}->{transferred};
1078
1079         } else {
1080             die $merr if $merr;
1081             die "unable to parse migration status '$stat->{status}' - aborting\n";
1082         }
1083     }
1084 }
1085
1086 sub phase2_cleanup {
1087     my ($self, $vmid, $err) = @_;
1088
1089     return if !$self->{errors};
1090     $self->{phase2errors} = 1;
1091
1092     $self->log('info', "aborting phase 2 - cleanup resources");
1093
1094     $self->log('info', "migrate_cancel");
1095     eval {
1096         mon_cmd($vmid, "migrate_cancel");
1097     };
1098     $self->log('info', "migrate_cancel error: $@") if $@;
1099
1100     my $conf = $self->{vmconf};
1101     delete $conf->{lock};
1102     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1103     if (my $err = $@) {
1104         $self->log('err', $err);
1105     }
1106
1107     # cleanup ressources on target host
1108     if ($self->{storage_migration}) {
1109         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1110         if (my $err = $@) {
1111             $self->log('err', $err);
1112         }
1113     }
1114
1115     eval { $self->cleanup_bitmaps() };
1116     if (my $err =$@) {
1117         $self->log('err', $err);
1118     }
1119
1120     my $nodename = PVE::INotify::nodename();
1121
1122     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1123     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1124     if (my $err = $@) {
1125         $self->log('err', $err);
1126         $self->{errors} = 1;
1127     }
1128
1129     # cleanup after stopping, otherwise disks might be in-use by target VM!
1130     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1131     if (my $err = $@) {
1132         $self->log('err', $err);
1133     }
1134
1135
1136     if ($self->{tunnel}) {
1137         eval { finish_tunnel($self, $self->{tunnel});  };
1138         if (my $err = $@) {
1139             $self->log('err', $err);
1140             $self->{errors} = 1;
1141         }
1142     }
1143 }
1144
1145 sub phase3 {
1146     my ($self, $vmid) = @_;
1147
1148     my $volids = $self->{volumes};
1149     return if $self->{phase2errors};
1150
1151     # destroy local copies
1152     foreach my $volid (@$volids) {
1153         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1154         if (my $err = $@) {
1155             $self->log('err', "removing local copy of '$volid' failed - $err");
1156             $self->{errors} = 1;
1157             last if $err =~ /^interrupted by signal$/;
1158         }
1159     }
1160 }
1161
1162 sub phase3_cleanup {
1163     my ($self, $vmid, $err) = @_;
1164
1165     my $conf = $self->{vmconf};
1166     return if $self->{phase2errors};
1167
1168     my $tunnel = $self->{tunnel};
1169
1170     if ($self->{storage_migration}) {
1171         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1172         # to avoid it trying to re-establish it. We are in blockjob ready state,
1173         # thus, this command changes to it to blockjob complete (see qapi docs)
1174         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1175
1176         if (my $err = $@) {
1177             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1178             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1179             die "Failed to complete storage migration: $err\n";
1180         }
1181     }
1182
1183     if ($self->{volume_map}) {
1184         my $target_drives = $self->{target_drive};
1185
1186         # FIXME: for NBD storage migration we now only update the volid, and
1187         # not the full drivestr from the target node. Workaround that until we
1188         # got some real rescan, to avoid things like wrong format in the drive
1189         delete $conf->{$_} for keys %$target_drives;
1190         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1191
1192         for my $drive (keys %$target_drives) {
1193             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1194         }
1195         PVE::QemuConfig->write_config($vmid, $conf);
1196     }
1197
1198     # transfer replication state before move config
1199     $self->transfer_replication_state() if $self->{is_replicated};
1200
1201     # move config to remote node
1202     my $conffile = PVE::QemuConfig->config_file($vmid);
1203     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1204
1205     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1206         if !rename($conffile, $newconffile);
1207
1208     $self->switch_replication_job_target() if $self->{is_replicated};
1209
1210     if ($self->{livemigration}) {
1211         if ($self->{stopnbd}) {
1212             $self->log('info', "stopping NBD storage migration server on target.");
1213             # stop nbd server on remote vm - requirement for resume since 2.9
1214             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1215
1216             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1217             if (my $err = $@) {
1218                 $self->log('err', $err);
1219                 $self->{errors} = 1;
1220             }
1221         }
1222
1223         # config moved and nbd server stopped - now we can resume vm on target
1224         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1225             eval {
1226                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1227             };
1228             if (my $err = $@) {
1229                 $self->log('err', $err);
1230                 $self->{errors} = 1;
1231             }
1232         } else {
1233             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1234             my $logf = sub {
1235                 my $line = shift;
1236                 $self->log('err', $line);
1237             };
1238             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1239             if (my $err = $@) {
1240                 $self->log('err', $err);
1241                 $self->{errors} = 1;
1242             }
1243         }
1244
1245         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1246             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1247             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1248         }
1249     }
1250
1251     # close tunnel on successful migration, on error phase2_cleanup closed it
1252     if ($tunnel) {
1253         eval { finish_tunnel($self, $tunnel);  };
1254         if (my $err = $@) {
1255             $self->log('err', $err);
1256             $self->{errors} = 1;
1257         }
1258     }
1259
1260     eval {
1261         my $timer = 0;
1262         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1263             $self->log('info', "Waiting for spice server migration");
1264             while (1) {
1265                 my $res = mon_cmd($vmid, 'query-spice');
1266                 last if int($res->{'migrated'}) == 1;
1267                 last if $timer > 50;
1268                 $timer ++;
1269                 usleep(200000);
1270             }
1271         }
1272     };
1273
1274     # always stop local VM
1275     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1276     if (my $err = $@) {
1277         $self->log('err', "stopping vm failed - $err");
1278         $self->{errors} = 1;
1279     }
1280
1281     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1282     eval {
1283         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1284         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1285     };
1286     if (my $err = $@) {
1287         $self->log('err', $err);
1288         $self->{errors} = 1;
1289     }
1290
1291     if($self->{storage_migration}) {
1292         # destroy local copies
1293         my $volids = $self->{online_local_volumes};
1294
1295         foreach my $volid (@$volids) {
1296             # keep replicated volumes!
1297             next if $self->{replicated_volumes}->{$volid};
1298
1299             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1300             if (my $err = $@) {
1301                 $self->log('err', "removing local copy of '$volid' failed - $err");
1302                 $self->{errors} = 1;
1303                 last if $err =~ /^interrupted by signal$/;
1304             }
1305         }
1306
1307     }
1308
1309     # clear migrate lock
1310     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1311     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1312 }
1313
1314 sub final_cleanup {
1315     my ($self, $vmid) = @_;
1316
1317     # nothing to do
1318 }
1319
1320 sub round_powerof2 {
1321     return 1 if $_[0] < 2;
1322     return 2 << int(log($_[0]-1)/log(2));
1323 }
1324
1325 1;