PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use JSON;
   8 use Net::IP;
   9
  10 use PVE::CephConfig;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::ProcFSTools;
  13 use PVE::RADOS;
  14 use PVE::Storage::Plugin;
  15 use PVE::Tools qw(run_command trim);
  16
  17 use base qw(PVE::Storage::Plugin);
  18
  19 my $get_parent_image_name = sub {
  20     my ($parent) = @_;
  21     return undef if !$parent;
  22     return $parent->{image} . "@" . $parent->{snapshot};
  23 };
  24
  25 my $add_pool_to_disk = sub {
  26     my ($scfg, $disk) = @_;
  27
  28     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  29
  30     return "$pool/$disk";
  31 };
  32
  33 my $build_cmd = sub {
  34     my ($binary, $scfg, $storeid, $op, @options) = @_;
  35
  36     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  37     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  38
  39     my $cmd = [$binary, '-p', $pool];
  40
  41     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  42     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  43     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  44     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  45     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  46
  47     push @$cmd, $op;
  48
  49     push @$cmd, @options if scalar(@options);
  50
  51     return $cmd;
  52 };
  53
  54 my $rbd_cmd = sub {
  55     my ($scfg, $storeid, $op, @options) = @_;
  56
  57     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  58 };
  59
  60 my $rados_cmd = sub {
  61     my ($scfg, $storeid, $op, @options) = @_;
  62
  63     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  64 };
  65
  66 my $librados_connect = sub {
  67     my ($scfg, $storeid, $options) = @_;
  68
  69     my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  70
  71     my $rados = PVE::RADOS->new(%$librados_config);
  72
  73     return $rados;
  74 };
  75
  76 # needed for volumes created using ceph jewel (or higher)
  77 my $krbd_feature_update = sub {
  78     my ($scfg, $storeid, $name) = @_;
  79
  80     my ($versionparts) = ceph_version();
  81     return 1 if $versionparts->[0] < 10;
  82
  83     my (@disable, @enable);
  84     my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version();
  85
  86     if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) {
  87         # 'deep-flatten' can only be disabled, not enabled after image creation
  88         push @enable, 'fast-diff', 'object-map';
  89     } else {
  90         push @disable, 'fast-diff', 'object-map', 'deep-flatten';
  91     }
  92
  93     if ($kmajor >= 5) {
  94         push @enable, 'exclusive-lock';
  95     } else {
  96         push @disable, 'exclusive-lock';
  97     }
  98
  99     my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4];
 100     my $active_features = { map { $_ => 1 } @$active_features_list };
 101
 102     my $to_disable = join(',', grep {  $active_features->{$_} } @disable);
 103     my $to_enable  = join(',', grep { !$active_features->{$_} } @enable );
 104
 105     if ($to_disable) {
 106         print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n";
 107         my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable);
 108         run_rbd_command(
 109             $cmd,
 110             errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name",
 111         );
 112     }
 113     if ($to_enable) {
 114         print "enable RBD image features this kernel RBD drivers supports: $to_enable\n";
 115         eval {
 116             my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable);
 117             run_rbd_command(
 118                 $cmd,
 119                 errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name",
 120             );
 121         };
 122         warn "$@" if $@;
 123     }
 124 };
 125
 126 my $ceph_version_parser = sub {
 127     my $ceph_version = shift;
 128     # FIXME this is the same as pve-manager PVE::Ceph::Tools get_local_version
 129     if ($ceph_version =~ /^ceph.*\s(\d+(?:\.\d+)+(?:-pve\d+)?)\s+(?:\(([a-zA-Z0-9]+)\))?/) {
 130         my ($version, $buildcommit) = ($1, $2);
 131         my $subversions = [ split(/\.|-/, $version) ];
 132
 133         return ($subversions, $version, $buildcommit);
 134     }
 135     warn "Could not parse Ceph version: '$ceph_version'\n";
 136 };
 137
 138 sub ceph_version {
 139     my ($cache) = @_;
 140
 141     my $version_string = $cache;
 142     if (!defined($version_string)) {
 143         run_command('ceph --version', outfunc => sub {
 144             $version_string = shift;
 145         });
 146     }
 147     return undef if !defined($version_string);
 148     # subversion is an array ref. with the version parts from major to minor
 149     # version is the filtered version string
 150     my ($subversions, $version) = $ceph_version_parser->($version_string);
 151
 152     return wantarray ? ($subversions, $version) : $version;
 153 }
 154
 155 sub run_rbd_command {
 156     my ($cmd, %args) = @_;
 157
 158     my $lasterr;
 159     my $errmsg = $args{errmsg} . ": " || "";
 160     if (!exists($args{errfunc})) {
 161         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 162         # at least 1 child(ren) in pool cephstor1
 163         $args{errfunc} = sub {
 164             my $line = shift;
 165             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 166                 $lasterr = "$1\n";
 167             } else {
 168                 $lasterr = $line;
 169             }
 170             print STDERR $lasterr;
 171             *STDERR->flush();
 172         };
 173     }
 174
 175     eval { run_command($cmd, %args); };
 176     if (my $err = $@) {
 177         die $errmsg . $lasterr if length($lasterr);
 178         die $err;
 179     }
 180
 181     return undef;
 182 }
 183
 184 sub rbd_ls {
 185     my ($scfg, $storeid) = @_;
 186
 187     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 188     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 189
 190     my $raw = '';
 191     my $parser = sub { $raw .= shift };
 192
 193     eval {
 194         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 195     };
 196     my $err = $@;
 197
 198     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 199
 200     my $result;
 201     if ($raw eq '') {
 202         $result = [];
 203     } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint
 204         $result = JSON::decode_json($1);
 205     } else {
 206         die "got unexpected data from rbd ls: '$raw'\n";
 207     }
 208
 209     my $list = {};
 210
 211     foreach my $el (@$result) {
 212         next if defined($el->{snapshot});
 213
 214         my $image = $el->{image};
 215
 216         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 217         next if !defined($owner);
 218
 219         $list->{$pool}->{$image} = {
 220             name => $image,
 221             size => $el->{size},
 222             parent => $get_parent_image_name->($el->{parent}),
 223             vmid => $owner
 224         };
 225     }
 226
 227     return $list;
 228 }
 229
 230 sub rbd_ls_snap {
 231     my ($scfg, $storeid, $name) = @_;
 232
 233     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'ls', $name, '--format', 'json');
 234
 235     my $raw = '';
 236     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => sub { $raw .= shift; });
 237
 238     my $list;
 239     if ($raw =~ m/^(\[.*\])$/s) { # untaint
 240         $list = eval { JSON::decode_json($1) };
 241         die "invalid JSON output from 'rbd snap ls $name': $@\n" if $@;
 242     } else {
 243         die "got unexpected data from 'rbd snap ls $name': '$raw'\n";
 244     }
 245
 246     $list = [] if !defined($list);
 247
 248     my $res = {};
 249     foreach my $el (@$list) {
 250         my $snap = $el->{name};
 251         my $protected = defined($el->{protected}) && $el->{protected} eq "true" ? 1 : undef;
 252         $res->{$snap} = {
 253             name => $snap,
 254             id => $el->{id} // undef,
 255             size => $el->{size} // 0,
 256             protected => $protected,
 257         };
 258     }
 259     return $res;
 260 }
 261
 262 sub rbd_volume_info {
 263     my ($scfg, $storeid, $volname, $snap) = @_;
 264
 265     my $cmd = undef;
 266
 267     my @options = ('info', $volname, '--format', 'json');
 268     if ($snap) {
 269         push @options, '--snap', $snap;
 270     }
 271
 272     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 273
 274     my $raw = '';
 275     my $parser = sub { $raw .= shift };
 276
 277     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 278
 279     my $volume;
 280     if ($raw eq '') {
 281         $volume = {};
 282     } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint
 283         $volume = JSON::decode_json($1);
 284     } else {
 285         die "got unexpected data from rbd info: '$raw'\n";
 286     }
 287
 288     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 289     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 290
 291     return $volume->@{qw(size parent format protected features)};
 292 }
 293
 294 # Configuration
 295
 296 sub type {
 297     return 'rbd';
 298 }
 299
 300 sub plugindata {
 301     return {
 302         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 303     };
 304 }
 305
 306 sub properties {
 307     return {
 308         monhost => {
 309             description => "IP addresses of monitors (for external clusters).",
 310             type => 'string', format => 'pve-storage-portal-dns-list',
 311         },
 312         pool => {
 313             description => "Pool.",
 314             type => 'string',
 315         },
 316         username => {
 317             description => "RBD Id.",
 318             type => 'string',
 319         },
 320         authsupported => {
 321             description => "Authsupported.",
 322             type => 'string',
 323         },
 324         krbd => {
 325             description => "Always access rbd through krbd kernel module.",
 326             type => 'boolean',
 327         },
 328     };
 329 }
 330
 331 sub options {
 332     return {
 333         nodes => { optional => 1 },
 334         disable => { optional => 1 },
 335         monhost => { optional => 1},
 336         pool => { optional => 1 },
 337         username => { optional => 1 },
 338         content => { optional => 1 },
 339         krbd => { optional => 1 },
 340         bwlimit => { optional => 1 },
 341     };
 342 }
 343
 344 # Storage implementation
 345
 346 sub on_add_hook {
 347     my ($class, $storeid, $scfg, %param) = @_;
 348
 349     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 350
 351     PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
 352 }
 353
 354 sub on_delete_hook {
 355     my ($class, $storeid, $scfg) = @_;
 356
 357     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 358
 359     PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
 360 }
 361
 362 sub parse_volname {
 363     my ($class, $volname) = @_;
 364
 365     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 366         return ('images', $4, $7, $2, $3, $5, 'raw');
 367     }
 368
 369     die "unable to parse rbd volume name '$volname'\n";
 370 }
 371
 372 sub path {
 373     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 374
 375     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
 376     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 377     $name .= '@'.$snapname if $snapname;
 378
 379     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 380     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 381
 382     my $path = "rbd:$pool/$name";
 383
 384     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 385     if (defined($scfg->{monhost})) {
 386         my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';');
 387         $monhost =~ s/:/\\:/g;
 388         $path .= ":mon_host=$monhost";
 389         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 390     }
 391
 392     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 393
 394     return ($path, $vmid, $vtype);
 395 }
 396
 397 sub find_free_diskname {
 398     my ($class, $storeid, $scfg, $vmid, $fmt, $add_fmt_suffix) = @_;
 399
 400     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 401     my $disk_list = [];
 402
 403     my $parser = sub {
 404         my $line = shift;
 405         if ($line =~ m/^(.*)$/) { # untaint
 406             push @$disk_list, $1;
 407         }
 408     };
 409
 410     eval {
 411         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 412     };
 413     my $err = $@;
 414
 415     die $err if $err && $err !~ m/doesn't contain rbd images/;
 416
 417     return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg);
 418 }
 419
 420 sub create_base {
 421     my ($class, $storeid, $scfg, $volname) = @_;
 422
 423     my $snap = '__base__';
 424
 425     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 426         $class->parse_volname($volname);
 427
 428     die "create_base not possible with base image\n" if $isBase;
 429
 430     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 431     die "rbd volume info on '$name' failed\n" if !($size);
 432
 433     die "rbd image must be at format V2" if $format ne "2";
 434
 435     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 436         if $basename && (!$parent || $parent ne $basename."@".$snap);
 437
 438     my $newname = $name;
 439     $newname =~ s/^vm-/base-/;
 440
 441     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 442
 443     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 444     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 445
 446     my $running  = undef; #fixme : is create_base always offline ?
 447
 448     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 449
 450     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 451
 452     if (!$protected){
 453         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 454         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 455     }
 456
 457     return $newvolname;
 458
 459 }
 460
 461 sub clone_image {
 462     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 463
 464     my $snap = '__base__';
 465     $snap = $snapname if length $snapname;
 466
 467     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 468         $class->parse_volname($volname);
 469
 470     die "$volname is not a base image and snapname is not provided\n"
 471         if !$isBase && !length($snapname);
 472
 473     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 474
 475     warn "clone $volname: $basename snapname $snap to $name\n";
 476
 477     if (length($snapname)) {
 478         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 479
 480         if (!$protected) {
 481             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 482             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 483         }
 484     }
 485
 486     my $newvol = "$basename/$name";
 487     $newvol = $name if length($snapname);
 488
 489     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 490                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 491
 492     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 493
 494     return $newvol;
 495 }
 496
 497 sub alloc_image {
 498     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 499
 500
 501     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 502         if  $name && $name !~ m/^vm-$vmid-/;
 503
 504     $name = $class->find_free_diskname($storeid, $scfg, $vmid) if !$name;
 505
 506     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 507     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 508
 509     return $name;
 510 }
 511
 512 sub free_image {
 513     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 514
 515     my ($vtype, $name, $vmid, undef, undef, undef) =
 516         $class->parse_volname($volname);
 517
 518     my $snaps = rbd_ls_snap($scfg, $storeid, $name);
 519     foreach my $snap (keys %$snaps) {
 520         if ($snaps->{$snap}->{protected}) {
 521             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 522             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 523         }
 524     }
 525
 526     $class->deactivate_volume($storeid, $scfg, $volname);
 527
 528     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 529     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 530
 531     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 532     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 533
 534     return undef;
 535 }
 536
 537 sub list_images {
 538     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 539
 540     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 541     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 542
 543     my $res = [];
 544
 545     if (my $dat = $cache->{rbd}->{$pool}) {
 546         foreach my $image (keys %$dat) {
 547
 548             my $info = $dat->{$image};
 549
 550             my $volname = $info->{name};
 551             my $parent = $info->{parent};
 552             my $owner = $info->{vmid};
 553
 554             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 555                 $info->{volid} = "$storeid:$1/$volname";
 556             } else {
 557                 $info->{volid} = "$storeid:$volname";
 558             }
 559
 560             if ($vollist) {
 561                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 562                 next if !$found;
 563             } else {
 564                 next if defined ($vmid) && ($owner ne $vmid);
 565             }
 566
 567             $info->{format} = 'raw';
 568
 569             push @$res, $info;
 570         }
 571     }
 572
 573     return $res;
 574 }
 575
 576 sub status {
 577     my ($class, $storeid, $scfg, $cache) = @_;
 578
 579
 580     my $rados = &$librados_connect($scfg, $storeid);
 581     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 582
 583     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 584
 585     # max_avail -> max available space for data w/o replication in the pool
 586     # bytes_used -> data w/o replication in the pool
 587     my $free = $d->{stats}->{max_avail};
 588     my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used};
 589     my $total = $used + $free;
 590     my $active = 1;
 591
 592     return ($total, $free, $used, $active);
 593 }
 594
 595 sub activate_storage {
 596     my ($class, $storeid, $scfg, $cache) = @_;
 597     return 1;
 598 }
 599
 600 sub deactivate_storage {
 601     my ($class, $storeid, $scfg, $cache) = @_;
 602     return 1;
 603 }
 604
 605 my $get_kernel_device_name = sub {
 606     my ($pool, $name) = @_;
 607
 608     return "/dev/rbd/$pool/$name";
 609 };
 610
 611 sub map_volume {
 612     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 613
 614     my ($vtype, $img_name, $vmid) = $class->parse_volname($volname);
 615
 616     my $name = $img_name;
 617     $name .= '@'.$snapname if $snapname;
 618
 619     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 620
 621     my $kerneldev = $get_kernel_device_name->($pool, $name);
 622
 623     return $kerneldev if -b $kerneldev; # already mapped
 624
 625     # features can only be enabled/disabled for image, not for snapshot!
 626     $krbd_feature_update->($scfg, $storeid, $img_name);
 627
 628     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 629     run_rbd_command($cmd, errmsg => "can't map rbd volume $name");
 630
 631     return $kerneldev;
 632 }
 633
 634 sub unmap_volume {
 635     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 636
 637     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 638     $name .= '@'.$snapname if $snapname;
 639
 640     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 641
 642     my $kerneldev = $get_kernel_device_name->($pool, $name);
 643
 644     if (-b $kerneldev) {
 645         my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $kerneldev);
 646         run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev");
 647     }
 648
 649     return 1;
 650 }
 651
 652 sub activate_volume {
 653     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 654
 655     $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd};
 656
 657     return 1;
 658 }
 659
 660 sub deactivate_volume {
 661     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 662
 663     $class->unmap_volume($storeid, $scfg, $volname, $snapname);
 664
 665     return 1;
 666 }
 667
 668 sub volume_size_info {
 669     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 670
 671     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 672     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 673     return $size;
 674 }
 675
 676 sub volume_resize {
 677     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 678
 679     return 1 if $running && !$scfg->{krbd}; # FIXME???
 680
 681     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 682
 683     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 684     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 685     return undef;
 686 }
 687
 688 sub volume_snapshot {
 689     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 690
 691     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 692
 693     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 694     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 695     return undef;
 696 }
 697
 698 sub volume_snapshot_rollback {
 699     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 700
 701     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 702
 703     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 704     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 705 }
 706
 707 sub volume_snapshot_delete {
 708     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 709
 710     return 1 if $running && !$scfg->{krbd}; # FIXME: ????
 711
 712     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 713
 714     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 715
 716     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 717     if ($protected){
 718         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 719         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 720     }
 721
 722     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 723
 724     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 725
 726     return undef;
 727 }
 728
 729 sub volume_has_feature {
 730     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 731
 732    my $features = {
 733         snapshot => { current => 1, snap => 1},
 734         clone => { base => 1, snap => 1},
 735         template => { current => 1},
 736         copy => { base => 1, current => 1, snap => 1},
 737         sparseinit => { base => 1, current => 1},
 738     };
 739
 740     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 741         $class->parse_volname($volname);
 742
 743     my $key = undef;
 744     if($snapname){
 745         $key = 'snap';
 746     }else{
 747         $key =  $isBase ? 'base' : 'current';
 748     }
 749     return 1 if $features->{$feature}->{$key};
 750
 751     return undef;
 752 }
 753
 754 1;