PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::JSONSchema qw(get_standard_option);
  10 use PVE::RADOS;
  11 use PVE::Storage::CephTools;
  12 use JSON;
  13
  14 use base qw(PVE::Storage::Plugin);
  15
  16 my $get_parent_image_name = sub {
  17     my ($parent) = @_;
  18     return undef if !$parent;
  19     return $parent->{image} . "@" . $parent->{snapshot};
  20 };
  21
  22 my $add_pool_to_disk = sub {
  23     my ($scfg, $disk) = @_;
  24
  25     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  26
  27     return "$pool/$disk";
  28 };
  29
  30 my $build_cmd = sub {
  31     my ($binary, $scfg, $storeid, $op, @options) = @_;
  32
  33     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  34     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  35
  36     my $cmd = [$binary, '-p', $pool];
  37
  38     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  39     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  40     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  41     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  42     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  43
  44     push @$cmd, $op;
  45
  46     push @$cmd, @options if scalar(@options);
  47
  48     return $cmd;
  49 };
  50
  51 my $rbd_cmd = sub {
  52     my ($scfg, $storeid, $op, @options) = @_;
  53
  54     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  55 };
  56
  57 my $rados_cmd = sub {
  58     my ($scfg, $storeid, $op, @options) = @_;
  59
  60     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  61 };
  62
  63 my $librados_connect = sub {
  64     my ($scfg, $storeid, $options) = @_;
  65
  66     my $librados_config = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  67
  68     my $rados = PVE::RADOS->new(%$librados_config);
  69
  70     return $rados;
  71 };
  72
  73 # needed for volumes created using ceph jewel (or higher)
  74 my $krbd_feature_disable = sub {
  75     my ($scfg, $storeid, $name) = @_;
  76
  77     return 1 if !$scfg->{krbd};
  78
  79     my ($major, undef, undef, undef) = ceph_version();
  80     return 1 if $major < 10;
  81
  82     my $krbd_feature_blacklist = ['deep-flatten', 'fast-diff', 'object-map', 'exclusive-lock'];
  83     my (undef, undef, undef, undef, $features) = rbd_volume_info($scfg, $storeid, $name);
  84
  85     my $active_features = { map { $_ => 1 } $features };
  86     my $incompatible_features = join(',', grep { %$active_features{$_} } @$krbd_feature_blacklist);
  87
  88     if ($incompatible_features) {
  89         my $feature_cmd = &$rbd_cmd($scfg, $storeid, 'feature', 'disable', $name, $incompatible_features);
  90         run_rbd_command($feature_cmd, errmsg => "could not disable krbd-incompatible image features of rbd volume $name");
  91     }
  92 };
  93
  94 my $ceph_version_parser = sub {
  95     my $line = shift;
  96     if ($line =~ m/^ceph version ((\d+)\.(\d+)\.(\d+))(?: \([a-fA-F0-9]+\))/) {
  97         return ($2, $3, $4, $1);
  98     } else {
  99         warn "Could not parse Ceph version: '$line'\n";
 100     }
 101 };
 102
 103 sub ceph_version {
 104     my ($cache) = @_;
 105
 106     my $version_string = $cache;
 107
 108     my $major;
 109     my $minor;
 110     my $bugfix;
 111
 112     if (defined($version_string)) {
 113         ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($version_string);
 114     } else {
 115         run_command('ceph --version', outfunc => sub {
 116             my $line = shift;
 117             ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($line);
 118         });
 119     }
 120     return undef if !defined($version_string);
 121     return wantarray ? ($major, $minor, $bugfix, $version_string) : $version_string;
 122 }
 123
 124 sub run_rbd_command {
 125     my ($cmd, %args) = @_;
 126
 127     my $lasterr;
 128     my $errmsg = $args{errmsg} . ": " || "";
 129     if (!exists($args{errfunc})) {
 130         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 131         # at least 1 child(ren) in pool cephstor1
 132         $args{errfunc} = sub {
 133             my $line = shift;
 134             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 135                 $lasterr = "$1\n";
 136             } else {
 137                 $lasterr = $line;
 138             }
 139             print STDERR $lasterr;
 140             *STDERR->flush();
 141         };
 142     }
 143
 144     eval { run_command($cmd, %args); };
 145     if (my $err = $@) {
 146         die $errmsg . $lasterr if length($lasterr);
 147         die $err;
 148     }
 149
 150     return undef;
 151 }
 152
 153 sub rbd_ls {
 154     my ($scfg, $storeid) = @_;
 155
 156     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 157     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 158
 159     my $raw = '';
 160     my $parser = sub { $raw .= shift };
 161
 162     eval {
 163         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 164     };
 165     my $err = $@;
 166
 167     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 168
 169     my $result = $raw ne '' ? JSON::decode_json($raw) : [];
 170
 171     my $list = {};
 172
 173     foreach my $el (@$result) {
 174         next if defined($el->{snapshot});
 175
 176         my $image = $el->{image};
 177
 178         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 179
 180         $list->{$pool}->{$image} = {
 181             name => $image,
 182             size => $el->{size},
 183             parent => $get_parent_image_name->($el->{parent}),
 184             vmid => $owner
 185         };
 186     }
 187
 188     return $list;
 189 }
 190
 191 sub rbd_volume_info {
 192     my ($scfg, $storeid, $volname, $snap) = @_;
 193
 194     my $cmd = undef;
 195
 196     my @options = ('info', $volname, '--format', 'json');
 197     if ($snap) {
 198         push @options, '--snap', $snap;
 199     }
 200
 201     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 202
 203     my $raw = '';
 204     my $parser = sub { $raw .= shift };
 205
 206     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 207
 208     my $volume = $raw ne '' ? JSON::decode_json($raw) : {};
 209
 210     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 211     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 212
 213     return $volume->@{qw(size parent format protected features)};
 214 }
 215
 216 # Configuration
 217
 218 sub type {
 219     return 'rbd';
 220 }
 221
 222 sub plugindata {
 223     return {
 224         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 225     };
 226 }
 227
 228 sub properties {
 229     return {
 230         monhost => {
 231             description => "IP addresses of monitors (for external clusters).",
 232             type => 'string', format => 'pve-storage-portal-dns-list',
 233         },
 234         pool => {
 235             description => "Pool.",
 236             type => 'string',
 237         },
 238         username => {
 239             description => "RBD Id.",
 240             type => 'string',
 241         },
 242         authsupported => {
 243             description => "Authsupported.",
 244             type => 'string',
 245         },
 246         krbd => {
 247             description => "Access rbd through krbd kernel module.",
 248             type => 'boolean',
 249         },
 250     };
 251 }
 252
 253 sub options {
 254     return {
 255         nodes => { optional => 1 },
 256         disable => { optional => 1 },
 257         monhost => { optional => 1},
 258         pool => { optional => 1 },
 259         username => { optional => 1 },
 260         content => { optional => 1 },
 261         krbd => { optional => 1 },
 262         bwlimit => { optional => 1 },
 263     };
 264 }
 265
 266 # Storage implementation
 267
 268 sub on_add_hook {
 269     my ($class, $storeid, $scfg, %param) = @_;
 270
 271     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 272
 273     PVE::Storage::CephTools::ceph_create_keyfile($scfg->{type}, $storeid);
 274 }
 275
 276 sub on_delete_hook {
 277     my ($class, $storeid, $scfg) = @_;
 278
 279     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 280
 281     PVE::Storage::CephTools::ceph_remove_keyfile($scfg->{type}, $storeid);
 282 }
 283
 284 sub parse_volname {
 285     my ($class, $volname) = @_;
 286
 287     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 288         return ('images', $4, $7, $2, $3, $5, 'raw');
 289     }
 290
 291     die "unable to parse rbd volume name '$volname'\n";
 292 }
 293
 294 sub path {
 295     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 296
 297     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
 298     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 299     $name .= '@'.$snapname if $snapname;
 300
 301     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 302     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 303
 304     my $path = "rbd:$pool/$name";
 305
 306     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 307     if (defined($scfg->{monhost})) {
 308         my $monhost = PVE::Storage::CephTools::hostlist($scfg->{monhost}, ';');
 309         $monhost =~ s/:/\\:/g;
 310         $path .= ":mon_host=$monhost";
 311         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 312     }
 313
 314     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 315
 316     return ($path, $vmid, $vtype);
 317 }
 318
 319 my $find_free_diskname = sub {
 320     my ($storeid, $scfg, $vmid) = @_;
 321
 322     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 323     my $disk_ids = {};
 324
 325     my $parser = sub {
 326         my $line = shift;
 327
 328         if ($line =~  m/^(vm|base)-\Q$vmid\E+-disk-(\d+)$/) {
 329             $disk_ids->{$2} = 1;
 330         }
 331     };
 332
 333     eval {
 334         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 335     };
 336     my $err = $@;
 337
 338     die $err if $err && $err !~ m/doesn't contain rbd images/;
 339
 340     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 341     for (my $i = 1; $i < 100; $i++) {
 342         if (!$disk_ids->{$i}) {
 343             return "vm-$vmid-disk-$i";
 344         }
 345     }
 346
 347     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 348 };
 349
 350 sub create_base {
 351     my ($class, $storeid, $scfg, $volname) = @_;
 352
 353     my $snap = '__base__';
 354
 355     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 356         $class->parse_volname($volname);
 357
 358     die "create_base not possible with base image\n" if $isBase;
 359
 360     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 361     die "rbd volume info on '$name' failed\n" if !($size);
 362
 363     die "rbd image must be at format V2" if $format ne "2";
 364
 365     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 366         if $basename && (!$parent || $parent ne $basename."@".$snap);
 367
 368     my $newname = $name;
 369     $newname =~ s/^vm-/base-/;
 370
 371     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 372
 373     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 374     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 375
 376     my $running  = undef; #fixme : is create_base always offline ?
 377
 378     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 379
 380     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 381
 382     if (!$protected){
 383         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 384         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 385     }
 386
 387     return $newvolname;
 388
 389 }
 390
 391 sub clone_image {
 392     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 393
 394     my $snap = '__base__';
 395     $snap = $snapname if length $snapname;
 396
 397     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 398         $class->parse_volname($volname);
 399
 400     die "$volname is not a base image and snapname is not provided\n"
 401         if !$isBase && !length($snapname);
 402
 403     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 404
 405     warn "clone $volname: $basename snapname $snap to $name\n";
 406
 407     if (length($snapname)) {
 408         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 409
 410         if (!$protected) {
 411             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 412             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 413         }
 414     }
 415
 416     my $newvol = "$basename/$name";
 417     $newvol = $name if length($snapname);
 418
 419     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 420                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 421
 422     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 423
 424     &$krbd_feature_disable($scfg, $storeid, $name);
 425
 426     return $newvol;
 427 }
 428
 429 sub alloc_image {
 430     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 431
 432
 433     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 434         if  $name && $name !~ m/^vm-$vmid-/;
 435
 436     $name = &$find_free_diskname($storeid, $scfg, $vmid) if !$name;
 437
 438     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 439     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 440
 441     &$krbd_feature_disable($scfg, $storeid, $name);
 442
 443     return $name;
 444 }
 445
 446 sub free_image {
 447     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 448
 449     my ($vtype, $name, $vmid, undef, undef, undef) =
 450         $class->parse_volname($volname);
 451
 452     if ($isBase) {
 453         my $snap = '__base__';
 454         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 455         if ($protected){
 456             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 457             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 458         }
 459     }
 460
 461     $class->deactivate_volume($storeid, $scfg, $volname);
 462
 463     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 464     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 465
 466     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 467     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 468
 469     return undef;
 470 }
 471
 472 sub list_images {
 473     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 474
 475     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 476     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 477
 478     my $res = [];
 479
 480     if (my $dat = $cache->{rbd}->{$pool}) {
 481         foreach my $image (keys %$dat) {
 482
 483             my $info = $dat->{$image};
 484
 485             my $volname = $info->{name};
 486             my $parent = $info->{parent};
 487             my $owner = $info->{vmid};
 488
 489             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 490                 $info->{volid} = "$storeid:$1/$volname";
 491             } else {
 492                 $info->{volid} = "$storeid:$volname";
 493             }
 494
 495             if ($vollist) {
 496                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 497                 next if !$found;
 498             } else {
 499                 next if defined ($vmid) && ($owner ne $vmid);
 500             }
 501
 502             $info->{format} = 'raw';
 503
 504             push @$res, $info;
 505         }
 506     }
 507
 508     return $res;
 509 }
 510
 511 sub status {
 512     my ($class, $storeid, $scfg, $cache) = @_;
 513
 514
 515     my $rados = &$librados_connect($scfg, $storeid);
 516     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 517
 518     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 519
 520     # max_avail -> max available space for data w/o replication in the pool
 521     # bytes_used -> data w/o replication in the pool
 522     my $free = $d->{stats}->{max_avail};
 523     my $used = $d->{stats}->{bytes_used};
 524     my $total = $used + $free;
 525     my $active = 1;
 526
 527     return ($total, $free, $used, $active);
 528 }
 529
 530 sub activate_storage {
 531     my ($class, $storeid, $scfg, $cache) = @_;
 532     return 1;
 533 }
 534
 535 sub deactivate_storage {
 536     my ($class, $storeid, $scfg, $cache) = @_;
 537     return 1;
 538 }
 539
 540 sub activate_volume {
 541     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 542
 543     return 1 if !$scfg->{krbd};
 544
 545     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 546     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 547
 548     my $path = "/dev/rbd/$pool/$name";
 549     $path .= '@'.$snapname if $snapname;
 550     return if -b $path;
 551
 552     $name .= '@'.$snapname if $snapname;
 553     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 554     run_rbd_command($cmd, errmsg => "can't mount rbd volume $name");
 555
 556     return 1;
 557 }
 558
 559 sub deactivate_volume {
 560     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 561
 562     return 1 if !$scfg->{krbd};
 563
 564     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 565     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 566
 567     my $path = "/dev/rbd/$pool/$name";
 568     $path .= '@'.$snapname if $snapname;
 569     return if ! -b $path;
 570
 571     my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $path);
 572     run_rbd_command($cmd, errmsg => "can't unmap rbd volume $name");
 573
 574     return 1;
 575 }
 576
 577 sub volume_size_info {
 578     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 579
 580     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 581     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 582     return $size;
 583 }
 584
 585 sub volume_resize {
 586     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 587
 588     return 1 if $running && !$scfg->{krbd};
 589
 590     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 591
 592     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 593     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 594     return undef;
 595 }
 596
 597 sub volume_snapshot {
 598     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 599
 600     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 601
 602     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 603     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 604     return undef;
 605 }
 606
 607 sub volume_snapshot_rollback {
 608     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 609
 610     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 611
 612     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 613     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 614 }
 615
 616 sub volume_snapshot_delete {
 617     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 618
 619     return 1 if $running && !$scfg->{krbd};
 620
 621     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 622
 623     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 624
 625     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 626     if ($protected){
 627         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 628         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 629     }
 630
 631     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 632
 633     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 634
 635     return undef;
 636 }
 637
 638 sub volume_has_feature {
 639     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 640
 641    my $features = {
 642         snapshot => { current => 1, snap => 1},
 643         clone => { base => 1, snap => 1},
 644         template => { current => 1},
 645         copy => { base => 1, current => 1, snap => 1},
 646         sparseinit => { base => 1, current => 1},
 647     };
 648
 649     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 650         $class->parse_volname($volname);
 651
 652     my $key = undef;
 653     if($snapname){
 654         $key = 'snap';
 655     }else{
 656         $key =  $isBase ? 'base' : 'current';
 657     }
 658     return 1 if $features->{$feature}->{$key};
 659
 660     return undef;
 661 }
 662
 663 1;