PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use JSON;
   8 use Net::IP;
   9
  10 use PVE::CephConfig;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::ProcFSTools;
  13 use PVE::RADOS;
  14 use PVE::Storage::Plugin;
  15 use PVE::Tools qw(run_command trim);
  16
  17 use base qw(PVE::Storage::Plugin);
  18
  19 my $get_parent_image_name = sub {
  20     my ($parent) = @_;
  21     return undef if !$parent;
  22     return $parent->{image} . "@" . $parent->{snapshot};
  23 };
  24
  25 my $add_pool_to_disk = sub {
  26     my ($scfg, $disk) = @_;
  27
  28     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  29
  30     return "$pool/$disk";
  31 };
  32
  33 my $build_cmd = sub {
  34     my ($binary, $scfg, $storeid, $op, @options) = @_;
  35
  36     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  37     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  38
  39     my $cmd = [$binary, '-p', $pool];
  40
  41     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  42     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  43     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  44     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  45     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  46
  47     push @$cmd, $op;
  48
  49     push @$cmd, @options if scalar(@options);
  50
  51     return $cmd;
  52 };
  53
  54 my $rbd_cmd = sub {
  55     my ($scfg, $storeid, $op, @options) = @_;
  56
  57     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  58 };
  59
  60 my $rados_cmd = sub {
  61     my ($scfg, $storeid, $op, @options) = @_;
  62
  63     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  64 };
  65
  66 my $librados_connect = sub {
  67     my ($scfg, $storeid, $options) = @_;
  68
  69     my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  70
  71     my $rados = PVE::RADOS->new(%$librados_config);
  72
  73     return $rados;
  74 };
  75
  76 # needed for volumes created using ceph jewel (or higher)
  77 my $krbd_feature_update = sub {
  78     my ($scfg, $storeid, $name) = @_;
  79
  80     my ($versionparts) = ceph_version();
  81     return 1 if $versionparts->[0] < 10;
  82
  83     my (@disable, @enable);
  84     my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version();
  85
  86     if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) {
  87         # 'deep-flatten' can only be disabled, not enabled after image creation
  88         push @enable, 'fast-diff', 'object-map';
  89     } else {
  90         push @disable, 'fast-diff', 'object-map', 'deep-flatten';
  91     }
  92
  93     if ($kmajor >= 5) {
  94         push @enable, 'exclusive-lock';
  95     } else {
  96         push @disable, 'exclusive-lock';
  97     }
  98
  99     my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4];
 100     my $active_features = { map { $_ => 1 } @$active_features_list };
 101
 102     my $to_disable = join(',', grep {  $active_features->{$_} } @disable);
 103     my $to_enable  = join(',', grep { !$active_features->{$_} } @enable );
 104
 105     if ($to_disable) {
 106         print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n";
 107         my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable);
 108         run_rbd_command(
 109             $cmd,
 110             errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name",
 111         );
 112     }
 113     if ($to_enable) {
 114         print "enable RBD image features this kernel RBD drivers supports: $to_enable\n";
 115         eval {
 116             my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable);
 117             run_rbd_command(
 118                 $cmd,
 119                 errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name",
 120             );
 121         };
 122         warn "$@" if $@;
 123     }
 124 };
 125
 126 my $ceph_version_parser = sub {
 127     my $ceph_version = shift;
 128     # FIXME this is the same as pve-manager PVE::Ceph::Tools get_local_version
 129     if ($ceph_version =~ /^ceph.*\s(\d+(?:\.\d+)+(?:-pve\d+)?)\s+(?:\(([a-zA-Z0-9]+)\))?/) {
 130         my ($version, $buildcommit) = ($1, $2);
 131         my $subversions = [ split(/\.|-/, $version) ];
 132
 133         return ($subversions, $version, $buildcommit);
 134     }
 135     warn "Could not parse Ceph version: '$ceph_version'\n";
 136 };
 137
 138 sub ceph_version {
 139     my ($cache) = @_;
 140
 141     my $version_string = $cache;
 142     if (!defined($version_string)) {
 143         run_command('ceph --version', outfunc => sub {
 144             $version_string = shift;
 145         });
 146     }
 147     return undef if !defined($version_string);
 148     # subversion is an array ref. with the version parts from major to minor
 149     # version is the filtered version string
 150     my ($subversions, $version) = $ceph_version_parser->($version_string);
 151
 152     return wantarray ? ($subversions, $version) : $version;
 153 }
 154
 155 sub run_rbd_command {
 156     my ($cmd, %args) = @_;
 157
 158     my $lasterr;
 159     my $errmsg = $args{errmsg} . ": " || "";
 160     if (!exists($args{errfunc})) {
 161         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 162         # at least 1 child(ren) in pool cephstor1
 163         $args{errfunc} = sub {
 164             my $line = shift;
 165             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 166                 $lasterr = "$1\n";
 167             } else {
 168                 $lasterr = $line;
 169             }
 170             print STDERR $lasterr;
 171             *STDERR->flush();
 172         };
 173     }
 174
 175     eval { run_command($cmd, %args); };
 176     if (my $err = $@) {
 177         die $errmsg . $lasterr if length($lasterr);
 178         die $err;
 179     }
 180
 181     return undef;
 182 }
 183
 184 sub rbd_ls {
 185     my ($scfg, $storeid) = @_;
 186
 187     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 188     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 189
 190     my $raw = '';
 191     my $parser = sub { $raw .= shift };
 192
 193     eval {
 194         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 195     };
 196     my $err = $@;
 197
 198     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 199
 200     my $result;
 201     if ($raw eq '') {
 202         $result = [];
 203     } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint
 204         $result = JSON::decode_json($1);
 205     } else {
 206         die "got unexpected data from rbd ls: '$raw'\n";
 207     }
 208
 209     my $list = {};
 210
 211     foreach my $el (@$result) {
 212         next if defined($el->{snapshot});
 213
 214         my $image = $el->{image};
 215
 216         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 217         next if !defined($owner);
 218
 219         $list->{$pool}->{$image} = {
 220             name => $image,
 221             size => $el->{size},
 222             parent => $get_parent_image_name->($el->{parent}),
 223             vmid => $owner
 224         };
 225     }
 226
 227     return $list;
 228 }
 229
 230 sub rbd_volume_info {
 231     my ($scfg, $storeid, $volname, $snap) = @_;
 232
 233     my $cmd = undef;
 234
 235     my @options = ('info', $volname, '--format', 'json');
 236     if ($snap) {
 237         push @options, '--snap', $snap;
 238     }
 239
 240     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 241
 242     my $raw = '';
 243     my $parser = sub { $raw .= shift };
 244
 245     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 246
 247     my $volume;
 248     if ($raw eq '') {
 249         $volume = {};
 250     } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint
 251         $volume = JSON::decode_json($1);
 252     } else {
 253         die "got unexpected data from rbd info: '$raw'\n";
 254     }
 255
 256     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 257     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 258
 259     return $volume->@{qw(size parent format protected features)};
 260 }
 261
 262 # Configuration
 263
 264 sub type {
 265     return 'rbd';
 266 }
 267
 268 sub plugindata {
 269     return {
 270         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 271     };
 272 }
 273
 274 sub properties {
 275     return {
 276         monhost => {
 277             description => "IP addresses of monitors (for external clusters).",
 278             type => 'string', format => 'pve-storage-portal-dns-list',
 279         },
 280         pool => {
 281             description => "Pool.",
 282             type => 'string',
 283         },
 284         username => {
 285             description => "RBD Id.",
 286             type => 'string',
 287         },
 288         authsupported => {
 289             description => "Authsupported.",
 290             type => 'string',
 291         },
 292         krbd => {
 293             description => "Always access rbd through krbd kernel module.",
 294             type => 'boolean',
 295         },
 296     };
 297 }
 298
 299 sub options {
 300     return {
 301         nodes => { optional => 1 },
 302         disable => { optional => 1 },
 303         monhost => { optional => 1},
 304         pool => { optional => 1 },
 305         username => { optional => 1 },
 306         content => { optional => 1 },
 307         krbd => { optional => 1 },
 308         bwlimit => { optional => 1 },
 309     };
 310 }
 311
 312 # Storage implementation
 313
 314 sub on_add_hook {
 315     my ($class, $storeid, $scfg, %param) = @_;
 316
 317     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 318
 319     PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
 320 }
 321
 322 sub on_delete_hook {
 323     my ($class, $storeid, $scfg) = @_;
 324
 325     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 326
 327     PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
 328 }
 329
 330 sub parse_volname {
 331     my ($class, $volname) = @_;
 332
 333     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 334         return ('images', $4, $7, $2, $3, $5, 'raw');
 335     }
 336
 337     die "unable to parse rbd volume name '$volname'\n";
 338 }
 339
 340 sub path {
 341     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 342
 343     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
 344     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 345     $name .= '@'.$snapname if $snapname;
 346
 347     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 348     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 349
 350     my $path = "rbd:$pool/$name";
 351
 352     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 353     if (defined($scfg->{monhost})) {
 354         my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';');
 355         $monhost =~ s/:/\\:/g;
 356         $path .= ":mon_host=$monhost";
 357         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 358     }
 359
 360     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 361
 362     return ($path, $vmid, $vtype);
 363 }
 364
 365 my $find_free_diskname = sub {
 366     my ($storeid, $scfg, $vmid) = @_;
 367
 368     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 369     my $disk_list = [];
 370
 371     my $parser = sub {
 372         my $line = shift;
 373         if ($line =~ m/^(.*)$/) { # untaint
 374             push @$disk_list, $1;
 375         }
 376     };
 377
 378     eval {
 379         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 380     };
 381     my $err = $@;
 382
 383     die $err if $err && $err !~ m/doesn't contain rbd images/;
 384
 385     return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg);
 386 };
 387
 388 sub create_base {
 389     my ($class, $storeid, $scfg, $volname) = @_;
 390
 391     my $snap = '__base__';
 392
 393     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 394         $class->parse_volname($volname);
 395
 396     die "create_base not possible with base image\n" if $isBase;
 397
 398     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 399     die "rbd volume info on '$name' failed\n" if !($size);
 400
 401     die "rbd image must be at format V2" if $format ne "2";
 402
 403     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 404         if $basename && (!$parent || $parent ne $basename."@".$snap);
 405
 406     my $newname = $name;
 407     $newname =~ s/^vm-/base-/;
 408
 409     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 410
 411     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 412     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 413
 414     my $running  = undef; #fixme : is create_base always offline ?
 415
 416     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 417
 418     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 419
 420     if (!$protected){
 421         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 422         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 423     }
 424
 425     return $newvolname;
 426
 427 }
 428
 429 sub clone_image {
 430     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 431
 432     my $snap = '__base__';
 433     $snap = $snapname if length $snapname;
 434
 435     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 436         $class->parse_volname($volname);
 437
 438     die "$volname is not a base image and snapname is not provided\n"
 439         if !$isBase && !length($snapname);
 440
 441     my $name = $find_free_diskname->($storeid, $scfg, $vmid);
 442
 443     warn "clone $volname: $basename snapname $snap to $name\n";
 444
 445     if (length($snapname)) {
 446         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 447
 448         if (!$protected) {
 449             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 450             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 451         }
 452     }
 453
 454     my $newvol = "$basename/$name";
 455     $newvol = $name if length($snapname);
 456
 457     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 458                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 459
 460     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 461
 462     return $newvol;
 463 }
 464
 465 sub alloc_image {
 466     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 467
 468
 469     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 470         if  $name && $name !~ m/^vm-$vmid-/;
 471
 472     $name = $find_free_diskname->($storeid, $scfg, $vmid) if !$name;
 473
 474     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 475     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 476
 477     return $name;
 478 }
 479
 480 sub free_image {
 481     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 482
 483     my ($vtype, $name, $vmid, undef, undef, undef) =
 484         $class->parse_volname($volname);
 485
 486     if ($isBase) {
 487         my $snap = '__base__';
 488         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 489         if ($protected){
 490             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 491             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 492         }
 493     }
 494
 495     $class->deactivate_volume($storeid, $scfg, $volname);
 496
 497     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 498     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 499
 500     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 501     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 502
 503     return undef;
 504 }
 505
 506 sub list_images {
 507     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 508
 509     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 510     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 511
 512     my $res = [];
 513
 514     if (my $dat = $cache->{rbd}->{$pool}) {
 515         foreach my $image (keys %$dat) {
 516
 517             my $info = $dat->{$image};
 518
 519             my $volname = $info->{name};
 520             my $parent = $info->{parent};
 521             my $owner = $info->{vmid};
 522
 523             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 524                 $info->{volid} = "$storeid:$1/$volname";
 525             } else {
 526                 $info->{volid} = "$storeid:$volname";
 527             }
 528
 529             if ($vollist) {
 530                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 531                 next if !$found;
 532             } else {
 533                 next if defined ($vmid) && ($owner ne $vmid);
 534             }
 535
 536             $info->{format} = 'raw';
 537
 538             push @$res, $info;
 539         }
 540     }
 541
 542     return $res;
 543 }
 544
 545 sub status {
 546     my ($class, $storeid, $scfg, $cache) = @_;
 547
 548
 549     my $rados = &$librados_connect($scfg, $storeid);
 550     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 551
 552     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 553
 554     # max_avail -> max available space for data w/o replication in the pool
 555     # bytes_used -> data w/o replication in the pool
 556     my $free = $d->{stats}->{max_avail};
 557     my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used};
 558     my $total = $used + $free;
 559     my $active = 1;
 560
 561     return ($total, $free, $used, $active);
 562 }
 563
 564 sub activate_storage {
 565     my ($class, $storeid, $scfg, $cache) = @_;
 566     return 1;
 567 }
 568
 569 sub deactivate_storage {
 570     my ($class, $storeid, $scfg, $cache) = @_;
 571     return 1;
 572 }
 573
 574 my $get_kernel_device_name = sub {
 575     my ($pool, $name) = @_;
 576
 577     return "/dev/rbd/$pool/$name";
 578 };
 579
 580 sub map_volume {
 581     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 582
 583     my ($vtype, $img_name, $vmid) = $class->parse_volname($volname);
 584
 585     my $name = $img_name;
 586     $name .= '@'.$snapname if $snapname;
 587
 588     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 589
 590     my $kerneldev = $get_kernel_device_name->($pool, $name);
 591
 592     return $kerneldev if -b $kerneldev; # already mapped
 593
 594     # features can only be enabled/disabled for image, not for snapshot!
 595     $krbd_feature_update->($scfg, $storeid, $img_name);
 596
 597     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 598     run_rbd_command($cmd, errmsg => "can't map rbd volume $name");
 599
 600     return $kerneldev;
 601 }
 602
 603 sub unmap_volume {
 604     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 605
 606     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 607     $name .= '@'.$snapname if $snapname;
 608
 609     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 610
 611     my $kerneldev = $get_kernel_device_name->($pool, $name);
 612
 613     if (-b $kerneldev) {
 614         my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $kerneldev);
 615         run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev");
 616     }
 617
 618     return 1;
 619 }
 620
 621 sub activate_volume {
 622     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 623
 624     $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd};
 625
 626     return 1;
 627 }
 628
 629 sub deactivate_volume {
 630     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 631
 632     $class->unmap_volume($storeid, $scfg, $volname, $snapname);
 633
 634     return 1;
 635 }
 636
 637 sub volume_size_info {
 638     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 639
 640     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 641     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 642     return $size;
 643 }
 644
 645 sub volume_resize {
 646     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 647
 648     return 1 if $running && !$scfg->{krbd}; # FIXME???
 649
 650     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 651
 652     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 653     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 654     return undef;
 655 }
 656
 657 sub volume_snapshot {
 658     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 659
 660     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 661
 662     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 663     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 664     return undef;
 665 }
 666
 667 sub volume_snapshot_rollback {
 668     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 669
 670     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 671
 672     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 673     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 674 }
 675
 676 sub volume_snapshot_delete {
 677     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 678
 679     return 1 if $running && !$scfg->{krbd}; # FIXME: ????
 680
 681     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 682
 683     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 684
 685     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 686     if ($protected){
 687         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 688         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 689     }
 690
 691     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 692
 693     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 694
 695     return undef;
 696 }
 697
 698 sub volume_has_feature {
 699     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 700
 701    my $features = {
 702         snapshot => { current => 1, snap => 1},
 703         clone => { base => 1, snap => 1},
 704         template => { current => 1},
 705         copy => { base => 1, current => 1, snap => 1},
 706         sparseinit => { base => 1, current => 1},
 707     };
 708
 709     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 710         $class->parse_volname($volname);
 711
 712     my $key = undef;
 713     if($snapname){
 714         $key = 'snap';
 715     }else{
 716         $key =  $isBase ? 'base' : 'current';
 717     }
 718     return 1 if $features->{$feature}->{$key};
 719
 720     return undef;
 721 }
 722
 723 1;