PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::JSONSchema qw(get_standard_option);
  10
  11 use base qw(PVE::Storage::Plugin);
  12
  13 my $pveceph_config = '/etc/pve/ceph.conf';
  14
  15 my $rbd_unittobytes = {
  16     "k"  => 1024,
  17     "M"  => 1024*1024,
  18     "G"  => 1024*1024*1024,
  19     "T"  => 1024*1024*1024*1024,
  20 };
  21
  22 my $add_pool_to_disk = sub {
  23     my ($scfg, $disk) = @_;
  24
  25     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  26
  27     return "$pool/$disk";
  28 };
  29
  30 my $hostlist = sub {
  31     my ($list_text, $separator) = @_;
  32
  33     my @monhostlist = PVE::Tools::split_list($list_text);
  34     return join($separator, map {
  35         my ($host, $port) = PVE::Tools::parse_host_and_port($_);
  36         $port = defined($port) ? ":$port" : '';
  37         $host = "[$host]" if Net::IP::ip_is_ipv6($host);
  38         "${host}${port}"
  39     } @monhostlist);
  40 };
  41
  42 my $build_cmd = sub {
  43     my ($binary, $scfg, $storeid, $op, @options) = @_;
  44
  45     my $keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
  46     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  47     my $username =  $scfg->{username} ? $scfg->{username} : 'admin';
  48
  49     my $cmd = [$binary, '-p', $pool];
  50     my $pveceph_managed = !defined($scfg->{monhost});
  51
  52     if ($pveceph_managed) {
  53         push @$cmd, '-c', $pveceph_config;
  54     } else {
  55         push @$cmd, '-m', $hostlist->($scfg->{monhost}, ',');
  56         push @$cmd, '--auth_supported', -e $keyring ? 'cephx' : 'none';
  57     }
  58
  59     if (-e $keyring) {
  60         push @$cmd, '-n', "client.$username";
  61         push @$cmd, '--keyring', $keyring;
  62     }
  63
  64     my $cephconfig = "/etc/pve/priv/ceph/${storeid}.conf";
  65
  66     if (-e $cephconfig) {
  67         if ($pveceph_managed) {
  68             warn "ignoring custom ceph config for storage '$storeid', 'monhost' is not set (assuming pveceph managed cluster)!\n";
  69         } else {
  70             push @$cmd, '-c', $cephconfig;
  71         }
  72     }
  73
  74     push @$cmd, $op;
  75
  76     push @$cmd, @options if scalar(@options);
  77
  78     return $cmd;
  79 };
  80
  81 my $rbd_cmd = sub {
  82     my ($scfg, $storeid, $op, @options) = @_;
  83
  84     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  85 };
  86
  87 my $rados_cmd = sub {
  88     my ($scfg, $storeid, $op, @options) = @_;
  89
  90     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  91 };
  92
  93 # needed for volumes created using ceph jewel (or higher)
  94 my $krbd_feature_disable = sub {
  95     my ($scfg, $storeid, $name) = @_;
  96
  97     return 1 if !$scfg->{krbd};
  98
  99     my ($major, undef, undef, undef) = ceph_version();
 100     return 1 if $major < 10;
 101
 102     my $krbd_feature_blacklist = ['deep-flatten', 'fast-diff', 'object-map', 'exclusive-lock'];
 103     my (undef, undef, undef, undef, $features) = rbd_volume_info($scfg, $storeid, $name);
 104
 105     my $active_features = { map { $_ => 1 } PVE::Tools::split_list($features)};
 106     my $incompatible_features = join(',', grep { %$active_features{$_} } @$krbd_feature_blacklist);
 107
 108     if ($incompatible_features) {
 109         my $feature_cmd = &$rbd_cmd($scfg, $storeid, 'feature', 'disable', $name, $incompatible_features);
 110         run_rbd_command($feature_cmd, errmsg => "could not disable krbd-incompatible image features of rbd volume $name");
 111     }
 112 };
 113
 114 my $ceph_version_parser = sub {
 115     my $line = shift;
 116     if ($line =~ m/^ceph version ((\d+)\.(\d+)\.(\d+))(?: \([a-fA-F0-9]+\))/) {
 117         return ($2, $3, $4, $1);
 118     } else {
 119         warn "Could not parse Ceph version: '$line'\n";
 120     }
 121 };
 122
 123 sub ceph_version {
 124     my ($cache) = @_;
 125
 126     my $version_string = $cache;
 127
 128     my $major;
 129     my $minor;
 130     my $bugfix;
 131
 132     if (defined($version_string)) {
 133         ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($version_string);
 134     } else {
 135         run_command('ceph --version', outfunc => sub {
 136             my $line = shift;
 137             ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($line);
 138         });
 139     }
 140     return undef if !defined($version_string);
 141     return wantarray ? ($major, $minor, $bugfix, $version_string) : $version_string;
 142 }
 143
 144 sub run_rbd_command {
 145     my ($cmd, %args) = @_;
 146
 147     my $lasterr;
 148     my $errmsg = $args{errmsg} . ": " || "";
 149     if (!exists($args{errfunc})) {
 150         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 151         # at least 1 child(ren) in pool cephstor1
 152         $args{errfunc} = sub {
 153             my $line = shift;
 154             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 155                 $lasterr = "$1\n";
 156             } else {
 157                 $lasterr = $line;
 158             }
 159             print STDERR $lasterr;
 160             *STDERR->flush();
 161         };
 162     }
 163
 164     eval { run_command($cmd, %args); };
 165     if (my $err = $@) {
 166         die $errmsg . $lasterr if length($lasterr);
 167         die $err;
 168     }
 169
 170     return undef;
 171 }
 172
 173 sub rbd_ls {
 174     my ($scfg, $storeid) = @_;
 175
 176     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l');
 177     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 178
 179     my $list = {};
 180
 181     my $parser = sub {
 182         my $line = shift;
 183
 184         if ($line =~  m/^((vm|base)-(\d+)-\S+)\s+(\d+)(k|M|G|T)\s((\S+)\/((vm|base)-\d+-\S+@\S+))?/) {
 185             my ($image, $owner, $size, $unit, $parent) = ($1, $3, $4, $5, $8);
 186             return if $image =~ /@/; #skip snapshots
 187
 188             $list->{$pool}->{$image} = {
 189                 name => $image,
 190                 size => $size*$rbd_unittobytes->{$unit},
 191                 parent => $parent,
 192                 vmid => $owner
 193             };
 194         }
 195     };
 196
 197     eval {
 198         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 199     };
 200     my $err = $@;
 201
 202     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 203
 204     return $list;
 205 }
 206
 207 sub rbd_volume_info {
 208     my ($scfg, $storeid, $volname, $snap) = @_;
 209
 210     my $cmd = undef;
 211
 212     if($snap){
 213        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname, '--snap', $snap);
 214     }else{
 215        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname);
 216     }
 217
 218     my $size = undef;
 219     my $parent = undef;
 220     my $format = undef;
 221     my $protected = undef;
 222     my $features = undef;
 223
 224     my $parser = sub {
 225         my $line = shift;
 226
 227         if ($line =~ m/size (\d+) (k|M|G|T)B in (\d+) objects/) {
 228             $size = $1 * $rbd_unittobytes->{$2} if ($1);
 229         } elsif ($line =~ m/parent:\s(\S+)\/(\S+)/) {
 230             $parent = $2;
 231         } elsif ($line =~ m/format:\s(\d+)/) {
 232             $format = $1;
 233         } elsif ($line =~ m/protected:\s(\S+)/) {
 234             $protected = 1 if $1 eq "True";
 235         } elsif ($line =~ m/features:\s(.+)/) {
 236             $features = $1;
 237         }
 238
 239     };
 240
 241     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 242
 243     return ($size, $parent, $format, $protected, $features);
 244 }
 245
 246 # Configuration
 247
 248 sub type {
 249     return 'rbd';
 250 }
 251
 252 sub plugindata {
 253     return {
 254         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 255     };
 256 }
 257
 258 sub properties {
 259     return {
 260         monhost => {
 261             description => "IP addresses of monitors (for external clusters).",
 262             type => 'string', format => 'pve-storage-portal-dns-list',
 263         },
 264         pool => {
 265             description => "Pool.",
 266             type => 'string',
 267         },
 268         username => {
 269             description => "RBD Id.",
 270             type => 'string',
 271         },
 272         authsupported => {
 273             description => "Authsupported.",
 274             type => 'string',
 275         },
 276         krbd => {
 277             description => "Access rbd through krbd kernel module.",
 278             type => 'boolean',
 279         },
 280     };
 281 }
 282
 283 sub options {
 284     return {
 285         nodes => { optional => 1 },
 286         disable => { optional => 1 },
 287         monhost => { optional => 1},
 288         pool => { optional => 1 },
 289         username => { optional => 1 },
 290         content => { optional => 1 },
 291         krbd => { optional => 1 },
 292         bwlimit => { optional => 1 },
 293     };
 294 }
 295
 296 # Storage implementation
 297
 298 sub parse_volname {
 299     my ($class, $volname) = @_;
 300
 301     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 302         return ('images', $4, $7, $2, $3, $5, 'raw');
 303     }
 304
 305     die "unable to parse rbd volume name '$volname'\n";
 306 }
 307
 308 sub path {
 309     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 310
 311     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 312     $name .= '@'.$snapname if $snapname;
 313
 314     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 315     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 316
 317     my $username =  $scfg->{username} ? $scfg->{username} : 'admin';
 318
 319     my $path = "rbd:$pool/$name";
 320     my $pveceph_managed = !defined($scfg->{monhost});
 321     my $keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
 322
 323     if ($pveceph_managed) {
 324         $path .= ":conf=$pveceph_config";
 325     } else {
 326         my $monhost = $hostlist->($scfg->{monhost}, ';');
 327         $monhost =~ s/:/\\:/g;
 328         $path .= ":mon_host=$monhost";
 329         $path .= -e $keyring ? ":auth_supported=cephx" : ":auth_supported=none";
 330     }
 331
 332     $path .= ":id=$username:keyring=$keyring" if -e $keyring;
 333
 334     my $cephconfig = "/etc/pve/priv/ceph/${storeid}.conf";
 335
 336     if (-e $cephconfig) {
 337         if ($pveceph_managed) {
 338             warn "ignoring custom ceph config for storage '$storeid', 'monhost' is not set (assuming pveceph managed cluster)!\n";
 339         } else {
 340             $path .= ":conf=$cephconfig";
 341         }
 342     }
 343
 344     return ($path, $vmid, $vtype);
 345 }
 346
 347 my $find_free_diskname = sub {
 348     my ($storeid, $scfg, $vmid) = @_;
 349
 350     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 351     my $disk_ids = {};
 352
 353     my $parser = sub {
 354         my $line = shift;
 355
 356         if ($line =~  m/^(vm|base)-\Q$vmid\E+-disk-(\d+)$/) {
 357             $disk_ids->{$2} = 1;
 358         }
 359     };
 360
 361     eval {
 362         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 363     };
 364     my $err = $@;
 365
 366     die $err if $err && $err !~ m/doesn't contain rbd images/;
 367
 368     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 369     for (my $i = 1; $i < 100; $i++) {
 370         if (!$disk_ids->{$i}) {
 371             return "vm-$vmid-disk-$i";
 372         }
 373     }
 374
 375     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 376 };
 377
 378 sub create_base {
 379     my ($class, $storeid, $scfg, $volname) = @_;
 380
 381     my $snap = '__base__';
 382
 383     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 384         $class->parse_volname($volname);
 385
 386     die "create_base not possible with base image\n" if $isBase;
 387
 388     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 389     die "rbd volume info on '$name' failed\n" if !($size);
 390
 391     die "rbd image must be at format V2" if $format ne "2";
 392
 393     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 394         if $basename && (!$parent || $parent ne $basename."@".$snap);
 395
 396     my $newname = $name;
 397     $newname =~ s/^vm-/base-/;
 398
 399     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 400
 401     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 402     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 403
 404     my $running  = undef; #fixme : is create_base always offline ?
 405
 406     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 407
 408     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 409
 410     if (!$protected){
 411         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 412         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 413     }
 414
 415     return $newvolname;
 416
 417 }
 418
 419 sub clone_image {
 420     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 421
 422     my $snap = '__base__';
 423     $snap = $snapname if length $snapname;
 424
 425     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 426         $class->parse_volname($volname);
 427
 428     die "$volname is not a base image and snapname is not provided\n"
 429         if !$isBase && !length($snapname);
 430
 431     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 432
 433     warn "clone $volname: $basename snapname $snap to $name\n";
 434
 435     if (length($snapname)) {
 436         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 437
 438         if (!$protected) {
 439             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 440             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 441         }
 442     }
 443
 444     my $newvol = "$basename/$name";
 445     $newvol = $name if length($snapname);
 446
 447     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 448                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 449
 450     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 451
 452     &$krbd_feature_disable($scfg, $storeid, $name);
 453
 454     return $newvol;
 455 }
 456
 457 sub alloc_image {
 458     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 459
 460
 461     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 462         if  $name && $name !~ m/^vm-$vmid-/;
 463
 464     $name = &$find_free_diskname($storeid, $scfg, $vmid) if !$name;
 465
 466     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 467     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 468
 469     &$krbd_feature_disable($scfg, $storeid, $name);
 470
 471     return $name;
 472 }
 473
 474 sub free_image {
 475     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 476
 477     my ($vtype, $name, $vmid, undef, undef, undef) =
 478         $class->parse_volname($volname);
 479
 480     if ($isBase) {
 481         my $snap = '__base__';
 482         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 483         if ($protected){
 484             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 485             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 486         }
 487     }
 488
 489     $class->deactivate_volume($storeid, $scfg, $volname);
 490
 491     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 492     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 493
 494     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 495     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 496
 497     return undef;
 498 }
 499
 500 sub list_images {
 501     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 502
 503     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 504     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 505
 506     my $res = [];
 507
 508     if (my $dat = $cache->{rbd}->{$pool}) {
 509         foreach my $image (keys %$dat) {
 510
 511             my $info = $dat->{$image};
 512
 513             my $volname = $info->{name};
 514             my $parent = $info->{parent};
 515             my $owner = $info->{vmid};
 516
 517             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 518                 $info->{volid} = "$storeid:$1/$volname";
 519             } else {
 520                 $info->{volid} = "$storeid:$volname";
 521             }
 522
 523             if ($vollist) {
 524                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 525                 next if !$found;
 526             } else {
 527                 next if defined ($vmid) && ($owner ne $vmid);
 528             }
 529
 530             $info->{format} = 'raw';
 531
 532             push @$res, $info;
 533         }
 534     }
 535
 536     return $res;
 537 }
 538
 539 sub status {
 540     my ($class, $storeid, $scfg, $cache) = @_;
 541
 542     my $cmd = &$rados_cmd($scfg, $storeid, 'df');
 543
 544     my $stats = {};
 545
 546     my $parser = sub {
 547         my $line = shift;
 548         if ($line =~ m/^\s*total(?:\s|_)(\S+)\s+(\d+)(k|M|G|T)?/) {
 549             $stats->{$1} = $2;
 550             # luminous has units here..
 551             if ($3) {
 552                 $stats->{$1} *= $rbd_unittobytes->{$3}/1024;
 553             }
 554         }
 555     };
 556
 557     eval {
 558         run_rbd_command($cmd, errmsg => "rados error", errfunc => sub {}, outfunc => $parser);
 559     };
 560
 561     my $total = $stats->{space} ? $stats->{space}*1024 : 0;
 562     my $free = $stats->{avail} ? $stats->{avail}*1024 : 0;
 563     my $used = $stats->{used} ? $stats->{used}*1024: 0;
 564     my $active = 1;
 565
 566     return ($total, $free, $used, $active);
 567 }
 568
 569 sub activate_storage {
 570     my ($class, $storeid, $scfg, $cache) = @_;
 571     return 1;
 572 }
 573
 574 sub deactivate_storage {
 575     my ($class, $storeid, $scfg, $cache) = @_;
 576     return 1;
 577 }
 578
 579 sub activate_volume {
 580     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 581
 582     return 1 if !$scfg->{krbd};
 583
 584     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 585     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 586
 587     my $path = "/dev/rbd/$pool/$name";
 588     $path .= '@'.$snapname if $snapname;
 589     return if -b $path;
 590
 591     $name .= '@'.$snapname if $snapname;
 592     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 593     run_rbd_command($cmd, errmsg => "can't mount rbd volume $name");
 594
 595     return 1;
 596 }
 597
 598 sub deactivate_volume {
 599     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 600
 601     return 1 if !$scfg->{krbd};
 602
 603     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 604     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 605
 606     my $path = "/dev/rbd/$pool/$name";
 607     $path .= '@'.$snapname if $snapname;
 608     return if ! -b $path;
 609
 610     my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $path);
 611     run_rbd_command($cmd, errmsg => "can't unmap rbd volume $name");
 612
 613     return 1;
 614 }
 615
 616 sub volume_size_info {
 617     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 618
 619     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 620     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 621     return $size;
 622 }
 623
 624 sub volume_resize {
 625     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 626
 627     return 1 if $running && !$scfg->{krbd};
 628
 629     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 630
 631     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 632     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 633     return undef;
 634 }
 635
 636 sub volume_snapshot {
 637     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 638
 639     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 640
 641     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 642     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 643     return undef;
 644 }
 645
 646 sub volume_snapshot_rollback {
 647     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 648
 649     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 650
 651     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 652     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 653 }
 654
 655 sub volume_snapshot_delete {
 656     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 657
 658     return 1 if $running && !$scfg->{krbd};
 659
 660     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 661
 662     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 663
 664     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 665     if ($protected){
 666         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 667         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 668     }
 669
 670     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 671
 672     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 673
 674     return undef;
 675 }
 676
 677 sub volume_has_feature {
 678     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 679
 680    my $features = {
 681         snapshot => { current => 1, snap => 1},
 682         clone => { base => 1, snap => 1},
 683         template => { current => 1},
 684         copy => { base => 1, current => 1, snap => 1},
 685         sparseinit => { base => 1, current => 1},
 686     };
 687
 688     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 689         $class->parse_volname($volname);
 690
 691     my $key = undef;
 692     if($snapname){
 693         $key = 'snap';
 694     }else{
 695         $key =  $isBase ? 'base' : 'current';
 696     }
 697     return 1 if $features->{$feature}->{$key};
 698
 699     return undef;
 700 }
 701
 702 1;