PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::JSONSchema qw(get_standard_option);
  10 use PVE::RADOS;
  11 use PVE::Storage::CephTools;
  12 use JSON;
  13
  14 use base qw(PVE::Storage::Plugin);
  15
  16 my $rbd_unittobytes = {
  17     "k"  => 1024,
  18     "M"  => 1024*1024,
  19     "G"  => 1024*1024*1024,
  20     "T"  => 1024*1024*1024*1024,
  21 };
  22
  23 my $get_parent_image_name = sub {
  24     my ($parent) = @_;
  25     return undef if !$parent;
  26     return $parent->{image} . "@" . $parent->{snapshot};
  27 };
  28
  29 my $add_pool_to_disk = sub {
  30     my ($scfg, $disk) = @_;
  31
  32     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  33
  34     return "$pool/$disk";
  35 };
  36
  37 my $build_cmd = sub {
  38     my ($binary, $scfg, $storeid, $op, @options) = @_;
  39
  40     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  41     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  42
  43     my $cmd = [$binary, '-p', $pool];
  44
  45     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  46     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  47     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  48     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  49     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  50
  51     push @$cmd, $op;
  52
  53     push @$cmd, @options if scalar(@options);
  54
  55     return $cmd;
  56 };
  57
  58 my $rbd_cmd = sub {
  59     my ($scfg, $storeid, $op, @options) = @_;
  60
  61     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  62 };
  63
  64 my $rados_cmd = sub {
  65     my ($scfg, $storeid, $op, @options) = @_;
  66
  67     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  68 };
  69
  70 my $librados_connect = sub {
  71     my ($scfg, $storeid, $options) = @_;
  72
  73     my $librados_config = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  74
  75     my $rados = PVE::RADOS->new(%$librados_config);
  76
  77     return $rados;
  78 };
  79
  80 # needed for volumes created using ceph jewel (or higher)
  81 my $krbd_feature_disable = sub {
  82     my ($scfg, $storeid, $name) = @_;
  83
  84     return 1 if !$scfg->{krbd};
  85
  86     my ($major, undef, undef, undef) = ceph_version();
  87     return 1 if $major < 10;
  88
  89     my $krbd_feature_blacklist = ['deep-flatten', 'fast-diff', 'object-map', 'exclusive-lock'];
  90     my (undef, undef, undef, undef, $features) = rbd_volume_info($scfg, $storeid, $name);
  91
  92     my $active_features = { map { $_ => 1 } $features };
  93     my $incompatible_features = join(',', grep { %$active_features{$_} } @$krbd_feature_blacklist);
  94
  95     if ($incompatible_features) {
  96         my $feature_cmd = &$rbd_cmd($scfg, $storeid, 'feature', 'disable', $name, $incompatible_features);
  97         run_rbd_command($feature_cmd, errmsg => "could not disable krbd-incompatible image features of rbd volume $name");
  98     }
  99 };
 100
 101 my $ceph_version_parser = sub {
 102     my $line = shift;
 103     if ($line =~ m/^ceph version ((\d+)\.(\d+)\.(\d+))(?: \([a-fA-F0-9]+\))/) {
 104         return ($2, $3, $4, $1);
 105     } else {
 106         warn "Could not parse Ceph version: '$line'\n";
 107     }
 108 };
 109
 110 sub ceph_version {
 111     my ($cache) = @_;
 112
 113     my $version_string = $cache;
 114
 115     my $major;
 116     my $minor;
 117     my $bugfix;
 118
 119     if (defined($version_string)) {
 120         ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($version_string);
 121     } else {
 122         run_command('ceph --version', outfunc => sub {
 123             my $line = shift;
 124             ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($line);
 125         });
 126     }
 127     return undef if !defined($version_string);
 128     return wantarray ? ($major, $minor, $bugfix, $version_string) : $version_string;
 129 }
 130
 131 sub run_rbd_command {
 132     my ($cmd, %args) = @_;
 133
 134     my $lasterr;
 135     my $errmsg = $args{errmsg} . ": " || "";
 136     if (!exists($args{errfunc})) {
 137         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 138         # at least 1 child(ren) in pool cephstor1
 139         $args{errfunc} = sub {
 140             my $line = shift;
 141             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 142                 $lasterr = "$1\n";
 143             } else {
 144                 $lasterr = $line;
 145             }
 146             print STDERR $lasterr;
 147             *STDERR->flush();
 148         };
 149     }
 150
 151     eval { run_command($cmd, %args); };
 152     if (my $err = $@) {
 153         die $errmsg . $lasterr if length($lasterr);
 154         die $err;
 155     }
 156
 157     return undef;
 158 }
 159
 160 sub rbd_ls {
 161     my ($scfg, $storeid) = @_;
 162
 163     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 164     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 165
 166     my $raw = '';
 167
 168     my $parser = sub {
 169         $raw .= shift;
 170     };
 171
 172     eval {
 173         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 174     };
 175     my $err = $@;
 176
 177     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 178
 179     my $result = $raw ne '' ? JSON::decode_json($raw) : [];
 180
 181     my $list = {};
 182
 183     foreach my $el (@$result) {
 184         next if defined($el->{snapshot});
 185
 186         my $image = $el->{image};
 187
 188         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 189
 190         $list->{$pool}->{$image} = {
 191             name => $image,
 192             size => $el->{size},
 193             parent => $get_parent_image_name->($el->{parent}),
 194             vmid => $owner
 195         };
 196     }
 197
 198     return $list;
 199 }
 200
 201 sub rbd_volume_info {
 202     my ($scfg, $storeid, $volname, $snap) = @_;
 203
 204     my $cmd = undef;
 205
 206     my @options = ('info', $volname, '--format', 'json');
 207     if($snap){
 208         push @options, '--snap', $snap;
 209     }
 210
 211     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 212
 213     my $size = undef;
 214     my $parent = undef;
 215     my $format = undef;
 216     my $protected = undef;
 217     my $features = undef;
 218
 219     my $raw = '';
 220     my $parser = sub {
 221         $raw .= shift;
 222     };
 223
 224     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 225     my $volume = $raw ne '' ? JSON::decode_json($raw) : {};
 226     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 227     if (defined($volume->{protected})) {
 228         $volume->{protected} = $volume->{protected} eq "true" ? 1 : undef;
 229     }
 230
 231     return $volume->@{qw(size parent format protected features)};
 232 }
 233
 234 # Configuration
 235
 236 sub type {
 237     return 'rbd';
 238 }
 239
 240 sub plugindata {
 241     return {
 242         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 243     };
 244 }
 245
 246 sub properties {
 247     return {
 248         monhost => {
 249             description => "IP addresses of monitors (for external clusters).",
 250             type => 'string', format => 'pve-storage-portal-dns-list',
 251         },
 252         pool => {
 253             description => "Pool.",
 254             type => 'string',
 255         },
 256         username => {
 257             description => "RBD Id.",
 258             type => 'string',
 259         },
 260         authsupported => {
 261             description => "Authsupported.",
 262             type => 'string',
 263         },
 264         krbd => {
 265             description => "Access rbd through krbd kernel module.",
 266             type => 'boolean',
 267         },
 268     };
 269 }
 270
 271 sub options {
 272     return {
 273         nodes => { optional => 1 },
 274         disable => { optional => 1 },
 275         monhost => { optional => 1},
 276         pool => { optional => 1 },
 277         username => { optional => 1 },
 278         content => { optional => 1 },
 279         krbd => { optional => 1 },
 280         bwlimit => { optional => 1 },
 281     };
 282 }
 283
 284 # Storage implementation
 285
 286 sub on_add_hook {
 287     my ($class, $storeid, $scfg, %param) = @_;
 288
 289     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 290
 291     PVE::Storage::CephTools::ceph_create_keyfile($scfg->{type}, $storeid);
 292 }
 293
 294 sub on_delete_hook {
 295     my ($class, $storeid, $scfg) = @_;
 296
 297     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 298
 299     PVE::Storage::CephTools::ceph_remove_keyfile($scfg->{type}, $storeid);
 300 }
 301
 302 sub parse_volname {
 303     my ($class, $volname) = @_;
 304
 305     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 306         return ('images', $4, $7, $2, $3, $5, 'raw');
 307     }
 308
 309     die "unable to parse rbd volume name '$volname'\n";
 310 }
 311
 312 sub path {
 313     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 314
 315     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
 316     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 317     $name .= '@'.$snapname if $snapname;
 318
 319     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 320     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 321
 322     my $path = "rbd:$pool/$name";
 323
 324     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 325     if (defined($scfg->{monhost})) {
 326         my $monhost = PVE::Storage::CephTools::hostlist($scfg->{monhost}, ';');
 327         $monhost =~ s/:/\\:/g;
 328         $path .= ":mon_host=$monhost";
 329         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 330     }
 331
 332     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 333
 334     return ($path, $vmid, $vtype);
 335 }
 336
 337 my $find_free_diskname = sub {
 338     my ($storeid, $scfg, $vmid) = @_;
 339
 340     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 341     my $disk_ids = {};
 342
 343     my $parser = sub {
 344         my $line = shift;
 345
 346         if ($line =~  m/^(vm|base)-\Q$vmid\E+-disk-(\d+)$/) {
 347             $disk_ids->{$2} = 1;
 348         }
 349     };
 350
 351     eval {
 352         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 353     };
 354     my $err = $@;
 355
 356     die $err if $err && $err !~ m/doesn't contain rbd images/;
 357
 358     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 359     for (my $i = 1; $i < 100; $i++) {
 360         if (!$disk_ids->{$i}) {
 361             return "vm-$vmid-disk-$i";
 362         }
 363     }
 364
 365     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 366 };
 367
 368 sub create_base {
 369     my ($class, $storeid, $scfg, $volname) = @_;
 370
 371     my $snap = '__base__';
 372
 373     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 374         $class->parse_volname($volname);
 375
 376     die "create_base not possible with base image\n" if $isBase;
 377
 378     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 379     die "rbd volume info on '$name' failed\n" if !($size);
 380
 381     die "rbd image must be at format V2" if $format ne "2";
 382
 383     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 384         if $basename && (!$parent || $parent ne $basename."@".$snap);
 385
 386     my $newname = $name;
 387     $newname =~ s/^vm-/base-/;
 388
 389     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 390
 391     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 392     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 393
 394     my $running  = undef; #fixme : is create_base always offline ?
 395
 396     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 397
 398     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 399
 400     if (!$protected){
 401         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 402         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 403     }
 404
 405     return $newvolname;
 406
 407 }
 408
 409 sub clone_image {
 410     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 411
 412     my $snap = '__base__';
 413     $snap = $snapname if length $snapname;
 414
 415     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 416         $class->parse_volname($volname);
 417
 418     die "$volname is not a base image and snapname is not provided\n"
 419         if !$isBase && !length($snapname);
 420
 421     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 422
 423     warn "clone $volname: $basename snapname $snap to $name\n";
 424
 425     if (length($snapname)) {
 426         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 427
 428         if (!$protected) {
 429             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 430             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 431         }
 432     }
 433
 434     my $newvol = "$basename/$name";
 435     $newvol = $name if length($snapname);
 436
 437     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 438                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 439
 440     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 441
 442     &$krbd_feature_disable($scfg, $storeid, $name);
 443
 444     return $newvol;
 445 }
 446
 447 sub alloc_image {
 448     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 449
 450
 451     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 452         if  $name && $name !~ m/^vm-$vmid-/;
 453
 454     $name = &$find_free_diskname($storeid, $scfg, $vmid) if !$name;
 455
 456     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 457     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 458
 459     &$krbd_feature_disable($scfg, $storeid, $name);
 460
 461     return $name;
 462 }
 463
 464 sub free_image {
 465     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 466
 467     my ($vtype, $name, $vmid, undef, undef, undef) =
 468         $class->parse_volname($volname);
 469
 470     if ($isBase) {
 471         my $snap = '__base__';
 472         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 473         if ($protected){
 474             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 475             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 476         }
 477     }
 478
 479     $class->deactivate_volume($storeid, $scfg, $volname);
 480
 481     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 482     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 483
 484     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 485     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 486
 487     return undef;
 488 }
 489
 490 sub list_images {
 491     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 492
 493     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 494     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 495
 496     my $res = [];
 497
 498     if (my $dat = $cache->{rbd}->{$pool}) {
 499         foreach my $image (keys %$dat) {
 500
 501             my $info = $dat->{$image};
 502
 503             my $volname = $info->{name};
 504             my $parent = $info->{parent};
 505             my $owner = $info->{vmid};
 506
 507             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 508                 $info->{volid} = "$storeid:$1/$volname";
 509             } else {
 510                 $info->{volid} = "$storeid:$volname";
 511             }
 512
 513             if ($vollist) {
 514                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 515                 next if !$found;
 516             } else {
 517                 next if defined ($vmid) && ($owner ne $vmid);
 518             }
 519
 520             $info->{format} = 'raw';
 521
 522             push @$res, $info;
 523         }
 524     }
 525
 526     return $res;
 527 }
 528
 529 sub status {
 530     my ($class, $storeid, $scfg, $cache) = @_;
 531
 532
 533     my $rados = &$librados_connect($scfg, $storeid);
 534     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 535
 536     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 537
 538     # max_avail -> max available space for data w/o replication in the pool
 539     # bytes_used -> data w/o replication in the pool
 540     my $free = $d->{stats}->{max_avail};
 541     my $used = $d->{stats}->{bytes_used};
 542     my $total = $used + $free;
 543     my $active = 1;
 544
 545     return ($total, $free, $used, $active);
 546 }
 547
 548 sub activate_storage {
 549     my ($class, $storeid, $scfg, $cache) = @_;
 550     return 1;
 551 }
 552
 553 sub deactivate_storage {
 554     my ($class, $storeid, $scfg, $cache) = @_;
 555     return 1;
 556 }
 557
 558 sub activate_volume {
 559     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 560
 561     return 1 if !$scfg->{krbd};
 562
 563     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 564     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 565
 566     my $path = "/dev/rbd/$pool/$name";
 567     $path .= '@'.$snapname if $snapname;
 568     return if -b $path;
 569
 570     $name .= '@'.$snapname if $snapname;
 571     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 572     run_rbd_command($cmd, errmsg => "can't mount rbd volume $name");
 573
 574     return 1;
 575 }
 576
 577 sub deactivate_volume {
 578     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 579
 580     return 1 if !$scfg->{krbd};
 581
 582     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 583     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 584
 585     my $path = "/dev/rbd/$pool/$name";
 586     $path .= '@'.$snapname if $snapname;
 587     return if ! -b $path;
 588
 589     my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $path);
 590     run_rbd_command($cmd, errmsg => "can't unmap rbd volume $name");
 591
 592     return 1;
 593 }
 594
 595 sub volume_size_info {
 596     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 597
 598     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 599     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 600     return $size;
 601 }
 602
 603 sub volume_resize {
 604     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 605
 606     return 1 if $running && !$scfg->{krbd};
 607
 608     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 609
 610     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 611     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 612     return undef;
 613 }
 614
 615 sub volume_snapshot {
 616     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 617
 618     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 619
 620     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 621     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 622     return undef;
 623 }
 624
 625 sub volume_snapshot_rollback {
 626     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 627
 628     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 629
 630     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 631     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 632 }
 633
 634 sub volume_snapshot_delete {
 635     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 636
 637     return 1 if $running && !$scfg->{krbd};
 638
 639     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 640
 641     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 642
 643     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 644     if ($protected){
 645         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 646         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 647     }
 648
 649     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 650
 651     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 652
 653     return undef;
 654 }
 655
 656 sub volume_has_feature {
 657     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 658
 659    my $features = {
 660         snapshot => { current => 1, snap => 1},
 661         clone => { base => 1, snap => 1},
 662         template => { current => 1},
 663         copy => { base => 1, current => 1, snap => 1},
 664         sparseinit => { base => 1, current => 1},
 665     };
 666
 667     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 668         $class->parse_volname($volname);
 669
 670     my $key = undef;
 671     if($snapname){
 672         $key = 'snap';
 673     }else{
 674         $key =  $isBase ? 'base' : 'current';
 675     }
 676     return 1 if $features->{$feature}->{$key};
 677
 678     return undef;
 679 }
 680
 681 1;